zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only lines starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a use function
  99 # with bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Some shortcuts for colors.
 129 local red="%{${fg[red]}%}"
 130 local blue="%{${fg[blue]}%}"
 131 local green="%{${fg[green]}%}"
 132 local yellow="%{${fg[yellow]}%}"
 133 local default="%{${fg[default]}%}"
 134
 135 # Set the default prompt. The current host and working directory is displayed,
 136 # the exit code of the last command if it wasn't 0, the number of running jobs
 137 # if not 0 and a + if this shell is running inside another shell.
 138 # The prompt is in green and blue to make easily detectable, the error exit
 139 # code in red and bold and the job count in yellow.
 140 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 141 %(1j.$yellow%j$default.)%# \
 142 %(?..($red%B%?%b$default%) )"
 143
 144 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 145 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 146 # symbolic link to current checkout of Zsh's sources).
 147 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 148       -d ~/.zsh/functions/vcs_info ]]; then
 149     # Update fpath to allow loading the vcs_info functions.
 150     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 151        fpath=(~/.zsh/functions/vcs_info/
 152               ~/.zsh/functions/vcs_info/Backends
 153               $fpath)
 154     fi
 155
 156     # Allow substitutions and expansions in the prompt, necessary for
 157     # vcs_info.
 158     setopt promptsubst
 159     # Load vcs_info to display information about version control repositories.
 160     autoload -Uz vcs_info
 161     # Only look for git and mercurial repositories; the only I use.
 162     zstyle ':vcs_info:*' enable git hg
 163     # Check the repository for changes so they can be used in %u/%c (see
 164     # below). This comes with a speed penalty for bigger repositories.
 165     zstyle ':vcs_info:*' check-for-changes true
 166
 167     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 168     # is displayed. If there is an special action going on (merge, rebase)
 169     # it's also displayed (red). Also display if there are unstaged or staged
 170     # (%u/%c) changes.
 171     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 172           -d ~/.zsh/functions/vcs_info ]]; then
 173         zstyle ':vcs_info:*' formats \
 174             "($green%b%u%c$default:$blue%s$default)"
 175         zstyle ':vcs_info:*' actionformats \
 176             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 177     else
 178         # In older versions %u and %c are not defined yet and are not
 179         # correctly expanded.
 180         zstyle ':vcs_info:*' formats \
 181             "($green%b$default:$blue%s$default)"
 182         zstyle ':vcs_info:*' actionformats \
 183             "($green%b$default/$red%a$default:$blue%s$default)"
 184     fi
 185     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 186     # changes are detected in the repository; check-for-changes must be set to
 187     # true for this to work. Thanks to Bart Trojanowski
 188     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 189     # (2010-03-11 00:20).
 190     zstyle ':vcs_info:*' unstagedstr '¹'
 191     zstyle ':vcs_info:*' stagedstr   '²'
 192
 193     # Call vcs_info as precmd before every prompt.
 194     prompt_precmd() {
 195         vcs_info
 196     }
 197     add-zsh-hook precmd prompt_precmd
 198
 199     # Display the VCS information in the right prompt.
 200     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 201         RPROMPT='${vcs_info_msg_0_}'
 202     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 203     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 204     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 205     else
 206         RPROMPT='${vcs_info_msg_0_:- }'
 207     fi
 208 fi
 209
 210 unset red blue green yellow default
 211
 212 # When screen, xterm or rxvt is used set the name of the window to the
 213 # currently running program.
 214 #
 215 # When a program is started preexec() sets the window's name to it; when it
 216 # stops precmd() resets the window's name to 'zsh'.
 217 #
 218 # It works with screen, xterm and rxvt.
 219 #
 220 # If a command is run with sudo or if the shell is running as root then a ! is
 221 # added at the beginning of the command to make this clear. If a command is
 222 # running on a different computer with ssh a @ is added at the beginning. This
 223 # only works if the .zshrc on the server also uses this command.
 224 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 225     # Is set to a non empty value to reset the window name in the next
 226     # precmd() call.
 227     window_reset=yes
 228     # Is set to a non empty value when the shell is running as root.
 229     if [[ $(id -u) -eq 0 ]]; then
 230         window_root=yes
 231     fi
 232
 233     window_preexec() {
 234         # Get the program name with its arguments.
 235         local program_name=$1
 236
 237         # When sudo is used use real program name instead, but with an
 238         # exclamation mark at the beginning (handled below).
 239         local program_sudo=
 240         if [[ $program_name == sudo* ]]; then
 241             program_name=${program_name#sudo }
 242             program_sudo=yes
 243         fi
 244         # Remove all arguments from the program name.
 245         program_name=${program_name%% *}
 246
 247         # Ignore often used commands which are only running for a very short
 248         # time. This prevents a "blinking" name when it's changed to "cd" for
 249         # example and then some milliseconds later back to "zsh".
 250         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 251
 252         # Change my shortcuts so the real name of the program is displayed.
 253         case $program_name in
 254             e)
 255                 program_name=elinks
 256                 ;;
 257             g)
 258                 program_name=git
 259                 ;;
 260             m)
 261                 program_name=mutt
 262                 ;;
 263             v|vi)
 264                 program_name=vim
 265                 ;;
 266         esac
 267
 268         # Add an exclamation mark at the beginning if running with sudo or if
 269         # running zsh as root.
 270         if [[ -n $program_sudo || -n $window_root ]]; then
 271             program_name=!$program_name
 272         fi
 273
 274         # Add an at mark at the beginning if running through ssh on a
 275         # different computer.
 276         if [[ -n $SSH_CONNECTION ]]; then
 277             program_name="@$program_name"
 278         fi
 279
 280         # Set the window name to the currently running program.
 281         window_title "$program_name"
 282
 283         # Tell precmd() to reset the window name when the program stops.
 284         window_reset=yes
 285     }
 286
 287     window_precmd() {
 288         # Abort if no window name reset is necessary.
 289         [[ -z $window_reset ]] && return
 290
 291         # Reset the window name to 'zsh'.
 292         local name="zsh"
 293         # If the function was called with an argument then reset the window
 294         # name to '.zsh' (used by clear alias).
 295         if [[ -n $1 ]]; then
 296             name=".zsh"
 297         fi
 298
 299         # Prepend prefixes like in window_preexec().
 300         if [[ -n $SSH_CONNECTION ]]; then
 301             window_title "@$name"
 302         elif [[ -n $window_root ]]; then
 303             window_title "!$name"
 304         else
 305             window_title $name
 306         fi
 307
 308         # Just reset the name, so no screen reset necessary for the moment.
 309         window_reset=
 310     }
 311
 312     # Sets the window title. Works with screen, xterm and rxvt.
 313     window_title() {
 314         if [[ $TERM == screen* ]]; then
 315             print -n "\ek$1\e\\"
 316
 317         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 318             print -n "\e]2;$1\e\\"
 319         fi
 320     }
 321
 322     # Add the preexec() and precmd() hooks.
 323     add-zsh-hook preexec window_preexec
 324     add-zsh-hook precmd window_precmd
 325 fi
 326
 327
 328 # COMPLETION SETTINGS
 329
 330 # Load the complist module which provides additions to completion lists
 331 # (coloring, scrollable).
 332 zmodload zsh/complist
 333 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 334 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 335 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 336 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 337
 338 # Use cache to speed up completions.
 339 zstyle ':completion:*' use-cache on
 340 zstyle ':completion:*' cache-path ~/.zsh/cache
 341
 342 # Complete arguments and fix spelling mistakes when possible.
 343 zstyle ':completion:*' completer _complete _match _correct _approximate
 344
 345 # Make sure the list of possible completions is displayed after pressing <TAB>
 346 # the first time.
 347 setopt nolistambiguous
 348 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 349 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 350 bindkey "^I" expand-or-complete-prefix
 351 # Try uppercase if the currently typed string doesn't match. This allows
 352 # typing in lowercase most of the time and completion fixes the case.
 353 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 354
 355 # Use ls like colors for completions.
 356 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 357
 358 # Make completion lists scrollable so "do you wish to see all n possibilities"
 359 # is no longer displayed.
 360 zstyle ':completion:*' list-prompt '%p'
 361 # Display group name (like 'external command', 'alias', etc.) when there are
 362 # multiple matches in bold.
 363 zstyle ':completion:*' format '    %B%d%b:'
 364 # Display different types of matches separately.
 365 zstyle ':completion:*' group-name ''
 366
 367 # Ignore completion functions.
 368 zstyle ':completion:*:functions' ignored-patterns '_*'
 369 # Ignore parent directory.
 370 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 371 # When unsetting variables make sure every variable name is only suggested
 372 # once.
 373 zstyle ':completion:*:unset:*' ignore-line yes
 374 # When working with Mercurial and Git don't complete the same file multiple
 375 # times. Very useful when completing file names.
 376 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 377
 378
 379 # CUSTOM ALIASES AND FUNCTIONS
 380
 381 # If ^C is pressed while typing a command, add it to the history so it can be
 382 # easily retrieved later and then abort like ^C normally does. This is useful
 383 # when I want to abort an command to do something in between and then finish
 384 # typing the command.
 385 #
 386 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 387 # starting with - don't cause errors.
 388 TRAPINT() {
 389     # Store the current buffer in the history.
 390     zle && print -s -- $BUFFER
 391
 392     # Return the default exit code so zsh aborts the current command.
 393     return $1
 394 }
 395
 396 # Colorize stderr. Very useful when looking for errors. Thanks to
 397 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 398 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 399 # perfect and doesn't work with some interactive stderr output, but in those
 400 # cases the E alias can be used as workaround.
 401 exec 2>>(while read -r line; do
 402     printf '\e[91m%s\e[0m\n' "$line"
 403     print -n $'\0';
 404 done &)
 405
 406 # Load aliases and similar functions also used by other shells.
 407 if [[ -f ~/.shell/aliases ]]; then
 408     . ~/.shell/aliases
 409 fi
 410
 411 # Make sure aliases are expanded when using sudo.
 412 alias sudo='sudo '
 413
 414 # Global aliases for often used commands in the command line.
 415 alias -g E='2>&1'
 416 alias -g L='E | less'
 417 alias -g D='E | colordiff L'
 418 alias -g G='| grep'
 419 alias -g S='| sort'
 420 alias -g U='| uniq'
 421
 422 # Make going up directories simple.
 423 alias -g ...='../..'
 424 alias -g ....='../../..'
 425 alias -g .....='../../../..'
 426
 427 # If the window naming feature is used (see above) then use ".zsh" (leading
 428 # dot) as title name after running clear so it's clear to me that the window
 429 # is empty. I open so much windows that I don't know in which I have something
 430 # important. This helps me to remember which windows are empty (I run clear
 431 # after I finished my work in a window).
 432 if [[ -n $window_reset ]]; then
 433     alias clear='clear; window_reset=yes; window_precmd reset'
 434 fi
 435
 436 # Display all branches (except stash) in gitk but only 200 commits as this is
 437 # much faster. Also put in the background and disown. Thanks to sitaram in
 438 # #git on Freenode (2009-04-20 15:51).
 439 gitk() {
 440     command gitk \
 441         --max-count=200 \
 442         $(git rev-parse --symbolic-full-name --remotes --branches) \
 443         $@ &
 444     disown %command
 445 }
 446 # Same for tig (except the disown part as it's no GUI program).
 447 tig() {
 448     command tig \
 449         --max-count=200 \
 450         $(git rev-parse --symbolic-full-name --remotes --branches) \
 451         $@
 452 }
 453
 454
 455 # OS SPECIFIC SETTINGS
 456
 457 if [[ $(uname) == Linux ]]; then
 458     # Settings when creating Debian packages.
 459     DEBEMAIL=simon@ruderich.org
 460     export DEBEMAIL
 461     DEBFULLNAME="Simon Ruderich"
 462     export DEBFULLNAME
 463
 464 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 465     # Store the current clipboard in CLIPBOARD before every command so it can
 466     # be used in commands.
 467     os_darwin_preexec() {
 468         export CLIPBOARD="$(pbpaste)"
 469     }
 470     # Add the function as preexec hook.
 471     add-zsh-hook preexec os_darwin_preexec
 472
 473     # Initialize CLIPBOARD so it's available for completion directly after
 474     # startup.
 475     CLIPBOARD=""
 476     export CLIPBOARD
 477
 478     # Fetch current URL in clipboard with wget.
 479     alias wnc='wget --no-proxy $CLIPBOARD'
 480 fi
 481
 482
 483 # LOAD ADDITIONAL CONFIGURATION FILES
 484
 485 # Load rc file for current hostname (first part before a dot) or rc.local.
 486 source_config ~/.zsh host rc ${$(hostname)//.*/}
 487
 488
 489 # RUN COMMANDS
 490
 491 # If not already in screen reattach to a running session or create a new one.
 492 #
 493 # screen* is necessary as `screen` uses screen.linux for example for a linux
 494 # console which would otherwise cause an infinite loop.
 495 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 496     # Get running detached sessions.
 497     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 498     # Create a new session if none is running.
 499     if [[ -z $session ]]; then
 500         screen
 501     # Reattach to a running session.
 502     else
 503         screen -r $session
 504     fi
 505 fi
 506
 507
 508 source_debug "finished sourcing ~/.zsh/rc"
 509
 510 # vim: ft=zsh