zsh/rc

   1 # Zsh configuration file.
   2
   3 # Copyright (C) 2011-2012  Simon Ruderich
   4 #
   5 # This file is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This file is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 source_debug '. ~/.zsh/rc'
  20
  21
  22 # HELPER FUNCTIONS
  23
  24 # Return the name of the program which is called in the foreground with `fg`.
  25 # $1 is the name of the program (optional). If it's not 'fg' or 'fg *' it's
  26 # returned unchanged.
  27 resolve_fg_to_resumed_job_name() {
  28     # $REPLY is used by convention for scalars ($reply for arrays) to return
  29     # values from functions. unset it here to prevent problems when REPLY is
  30     # bound to an integer or similar. Thanks to Mikachu in #zsh on Freenode
  31     # (2012-09-27 17:14 CEST) for this hint.
  32     unset REPLY
  33
  34     # Replace fg with the resumed job name.
  35     if [[ $1 == fg ]]; then
  36         REPLY="${jobtexts[%+]}"
  37     elif [[ $1 == fg\ * ]]; then
  38         REPLY="${jobtexts[${1#fg }]}"
  39     # Normal program, return as is.
  40     else
  41         REPLY="$1"
  42     fi
  43 }
  44
  45
  46 # MISCELLANEOUS SETTINGS
  47
  48 # Be paranoid, new files are readable/writable by me only, but not as root.
  49 if [[ $UID -ne 0 ]]; then
  50     umask 077
  51 fi
  52
  53 # Disable beeps.
  54 setopt nobeep
  55
  56 # Prevent overwriting existing files with '> filename', use '>| filename'
  57 # (or >!) instead.
  58 setopt noclobber
  59
  60 # Entering the name of a directory (if it's not a command) will automatically
  61 # cd to that directory.
  62 setopt autocd
  63
  64 # When entering a nonexistent command name automatically try to find a similar
  65 # one.
  66 setopt correct
  67
  68 # Enable zsh's extended glob abilities.
  69 setopt extendedglob
  70
  71 # Don't exit if <C-D> is pressed. Prevents exiting the shell by accident (e.g.
  72 # pressing <C-D> twice).
  73 setopt ignoreeof
  74
  75
  76 # KEY BINDINGS
  77
  78 # Not all bindings are done here, only those not specific to a given section.
  79
  80 # Use Vi(m) style key bindings.
  81 bindkey -v
  82
  83 # Use jj and jk to exit insert mode.
  84 bindkey 'jj' vi-cmd-mode
  85 bindkey 'jk' vi-cmd-mode
  86
  87 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  88 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  89 # Also not in Vi mode.
  90 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  91
  92
  93 # FUNCTION SETTINGS
  94
  95 # Make sure every entry in $fpath is unique.
  96 typeset -U fpath
  97 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  98 # of a Zsh Git checkout. Use it to get the newest completions if available.
  99 if [[ -d ~/.zsh/functions/completion ]]; then
 100     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
 101 fi
 102 # Set correct fpath to allow loading my functions (including completion
 103 # functions).
 104 fpath=(~/.zsh/functions $fpath)
 105 # Autoload my functions (except completion functions and hidden files). Thanks
 106 # to caphuso from the Zsh example files for this idea.
 107 if [[ -d ~/.zsh/functions ]]; then
 108     autoload -Uz ${fpath[1]}/^_*(^/:t)
 109 fi
 110
 111 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
 112 # the moment only precmd(), preexec() and chpwd() are simulated.
 113 if [[ $ZSH_VERSION != (4.3.<4->*|4.<4->*|<5->*) ]]; then
 114     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
 115     # arrays.
 116     function precmd() {
 117         for function in $precmd_functions; do
 118             $function "$@"
 119         done
 120     }
 121     function preexec() {
 122         for function in $preexec_functions; do
 123             $function "$@"
 124         done
 125     }
 126     function chpwd() {
 127         for function in $chpwd_functions; do
 128             $function "$@"
 129         done
 130     }
 131 fi
 132
 133 # Load zmv (zsh move) which is a powerful file renamer.
 134 autoload -Uz zmv
 135
 136
 137 # HISTORY SETTINGS
 138
 139 # Use history and store it in ~/.zsh/history.
 140 HISTSIZE=50000
 141 SAVEHIST=50000
 142 HISTFILE=~/.zsh/history
 143 # Append to the history file instead of overwriting it and do it immediately
 144 # when a command is executed.
 145 setopt appendhistory
 146 setopt incappendhistory
 147 # If the same command is run multiple times store it only once in the history.
 148 setopt histignoredups
 149 # Don't add lines starting with a space to the history.
 150 setopt histignorespace
 151 # Vim like completions of previous executed commands (also enter Vi-mode). If
 152 # called at the beginning it just recalls old commands (like cursor up), if
 153 # called after typing something, only lines starting with the typed text are
 154 # returned. Very useful to get old commands quickly - in addition to the
 155 # history commands (!..). Thanks to Mikachu in #zsh on Freenode (2010-01-17
 156 # 12:47 CET) for the information how to a use function with bindkey.
 157 zle -N my-vi-history-beginning-search-backward
 158 my-vi-history-beginning-search-backward() {
 159     local not_at_beginning_of_line
 160     if [[ $CURSOR -ne 0 ]]; then
 161         not_at_beginning_of_line=yes
 162     fi
 163
 164     zle history-beginning-search-backward
 165
 166     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 167     # this counters it).
 168     zle vi-cmd-mode
 169     if [[ -n $not_at_beginning_of_line ]]; then
 170         zle vi-forward-char
 171     fi
 172 }
 173 bindkey '^P' my-vi-history-beginning-search-backward
 174 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 175 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 176 # after calling ^P.
 177 bindkey -a '^N' history-beginning-search-forward
 178
 179 # Automatically push cd-ed directories on the directory stack.
 180 setopt autopushd
 181 # Don't push duplicates on the directory stack.
 182 setopt pushdignoredups
 183 # Exchange the meaning of + and - when specifying a directory on the stack.
 184 # This way cd -<Tab> lists the last used directory first, which is more
 185 # natural because cd - goes to the last directory.
 186 setopt pushdminus
 187
 188
 189 # PROMPT SETTINGS
 190
 191 # Use colorized output, necessary for prompts and completions.
 192 autoload -Uz colors && colors
 193
 194 # Necessary for $EPOCHSECONDS, the UNIX time.
 195 zmodload zsh/datetime
 196
 197 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 198 # doesn't need any space, necessary for correct prompt drawing.
 199 local red="%{${fg[red]}%}"
 200 local blue="%{${fg[blue]}%}"
 201 local green="%{${fg[green]}%}"
 202 local yellow="%{${fg[yellow]}%}"
 203 local default="%{${fg[default]}%}"
 204
 205 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 206 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 207 # symbolic link to current checkout of Zsh's sources).
 208 if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
 209       -d ~/.zsh/functions/vcs_info ]]; then
 210     # Update fpath to allow loading the vcs_info functions.
 211     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 212        fpath=(~/.zsh/functions/vcs_info/
 213               ~/.zsh/functions/vcs_info/Backends
 214               $fpath)
 215     fi
 216
 217     # Load vcs_info to display information about version control repositories.
 218     autoload -Uz vcs_info
 219     # Only look for git and mercurial repositories; the only I use.
 220     zstyle ':vcs_info:*' enable git hg
 221     # Check the repository for changes so they can be used in %u/%c (see
 222     # below). This comes with a speed penalty for bigger repositories.
 223     zstyle ':vcs_info:*' check-for-changes yes
 224
 225     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 226     # is displayed. If there is an special action going on (merge, rebase)
 227     # it's also displayed (red). Also display if there are unstaged or staged
 228     # (%u/%c) changes.
 229     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
 230           -d ~/.zsh/functions/vcs_info ]]; then
 231         zstyle ':vcs_info:*' formats \
 232             "($green%b%u%c$default:$blue%s$default)"
 233         zstyle ':vcs_info:*' actionformats \
 234             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 235     else
 236         # In older versions %u and %c are not defined yet and are not
 237         # correctly expanded.
 238         zstyle ':vcs_info:*' formats \
 239             "($green%b$default:$blue%s$default)"
 240         zstyle ':vcs_info:*' actionformats \
 241             "($green%b$default/$red%a$default:$blue%s$default)"
 242     fi
 243     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 244     # changes are detected in the repository; check-for-changes must be set to
 245     # true for this to work. Thanks to Bart Trojanowski
 246     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 247     # (2010-03-11 00:20 CET).
 248     zstyle ':vcs_info:*' unstagedstr '¹'
 249     zstyle ':vcs_info:*' stagedstr   '²'
 250
 251     # Default to run vcs_info. If possible we prevent running it later for
 252     # speed reasons. If set to a non empty value vcs_info is run.
 253     FORCE_RUN_VCS_INFO=1
 254
 255     # Cache system inspired by Bart Trojanowski
 256     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 257     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 258     +vi-pre-get-data() {
 259         # Only Git and Mercurial support and need caching. Abort if any other
 260         # VCS is used.
 261         [[ "$vcs" != git && "$vcs" != hg ]] && return
 262
 263         # If the shell just started up or we changed directories (or for other
 264         # custom reasons) we must run vcs_info.
 265         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 266             FORCE_RUN_VCS_INFO=
 267             return
 268         fi
 269
 270         # Don't run vcs_info by default to speed up the shell.
 271         ret=1
 272         # If a git/hg command was run then run vcs_info as the status might
 273         # need to be updated.
 274         case "$(fc -ln $(($HISTCMD-1)))" in
 275             git* | g\ *)
 276                 ret=0
 277                 ;;
 278             hg*)
 279                 ret=0
 280                 ;;
 281         esac
 282     }
 283
 284     # Must run vcs_info when changing directories.
 285     prompt_chpwd() {
 286         FORCE_RUN_VCS_INFO=1
 287     }
 288     chpwd_functions+=(prompt_chpwd)
 289
 290     # Used by prompt code below to determine if vcs_info should be run.
 291     RUN_VCS_INFO=1
 292 else
 293     RUN_VCS_INFO=
 294 fi
 295
 296 typeset -a longrun_data
 297 longrun_data=()
 298 # Display runtime in seconds for long running programs (> 60 seconds) and send
 299 # a bell to notify me.
 300 longrun_preexec() {
 301     local program="$3"
 302
 303     # Handle fg.
 304     local REPLY
 305     resolve_fg_to_resumed_job_name "$program"
 306     program="$REPLY"
 307
 308     # Don't track the time for certain (possible) long running processes which
 309     # need no automatic notification.
 310     for ignore in elinks man mutt vim; do
 311         case $program in
 312             $ignore | $ignore\ *)
 313                 longrun_data=()
 314                 return
 315                 ;;
 316         esac
 317     done
 318
 319     longrun_data=("$program" $EPOCHSECONDS)
 320 }
 321 longrun_precmd() {
 322     # No previous timestamp available or disabled for this command, ignore.
 323     if [[ -z $longrun_data ]]; then
 324         return
 325     fi
 326
 327     local difference=$(( EPOCHSECONDS - longrun_data[2] ))
 328     if [[ $difference -gt 60 ]]; then
 329         echo
 330         echo -n "${fg[yellow]}"
 331         echo -n "~> ${(V)longrun_data[1]} took $difference seconds."
 332         echo -n "${fg[default]}"
 333         echo    "\a" # send bell
 334     fi
 335
 336     # Clear status. Prevents displaying old status information when pressing
 337     # enter with an empty command line.
 338     longrun_data=()
 339 }
 340 preexec_functions+=(longrun_preexec)
 341 precmd_functions+=(longrun_precmd)
 342
 343 # Set the prompt. A two line prompt is used. On the top left the current
 344 # working directory is displayed, on the right vcs_info (if available) and the
 345 # current time in hex. On the bottom left current user name and host is shown,
 346 # the exit code of the last command if it wasn't 0, the number of running jobs
 347 # if not 0.
 348 #
 349 # The prompt is in green and blue to make easily detectable, the error exit
 350 # code in red and bold and the job count in yellow. Designed for dark
 351 # terminals.
 352 #
 353 # Thanks to Adam's prompt for the basic idea of this prompt.
 354 prompt_precmd() {
 355     # Regex to remove elements which take no space. Used to calculate the
 356     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 357     # Functions/Prompts/prompt_*_setup.
 358     local zero='%([BSUbfksu]|([FB]|){*})'
 359
 360     # Call vcs_info before every prompt.
 361     if [[ -n $RUN_VCS_INFO ]]; then
 362         vcs_info
 363     else
 364         vcs_info_msg_0_=
 365     fi
 366
 367     # Setup. Create variables holding the formatted content.
 368
 369     # Current directory in yellow, truncated if necessary (WIDTH is replaced
 370     # below).
 371     local directory="${yellow}%WIDTH<..<%~%<<${default}"
 372
 373     # Information about the VCS in this directory.
 374     local vcs="${vcs_info_msg_0_}"
 375     # Current time (seconds since epoch) in Hex in bright blue.
 376     local seconds="${blue}%B0x$(([##16] EPOCHSECONDS))%b${default}"
 377
 378     # User name (%n) in bright green.
 379     local user="${green}%B%n%b${default}"
 380     # Host name (%m) in bright green; underlined if running on a remote system
 381     # through SSH.
 382     local host="${green}%B%m%b${default}"
 383     if [[ -n $SSH_CONNECTION ]]; then
 384         host="%U${host}%u"
 385     fi
 386
 387     # Number of background processes in yellow if not zero.
 388     local background="%(1j.${yellow}%j${default}.)"
 389     # Exit code in bright red in parentheses if not zero.
 390     local exitcode="%(?..(${red}%B%?%b${default}%) )"
 391
 392     # Prefix characters in first and second line.
 393     local top_prefix="${blue}%B.-%b${default}"
 394     local bottom_prefix="${blue}%B'%b${default}"
 395
 396     # Combine them to create the prompt.
 397
 398     local top_right="${vcs}(${seconds})"
 399
 400     local width_top_prefix=${#${(S%%)top_prefix//$~zero/}}
 401     local width_top_right=${#${(S%%)top_right//$~zero/}}
 402
 403     # Calculate the maximum width of ${top_left}. -2 are the braces of
 404     # ${top_left}, -1 is one separator from ${top_separator} (we want at least
 405     # one between left and right parts).
 406     local top_left_width_max=$((
 407         COLUMNS - $width_top_prefix - 2 - 1 - $width_top_right
 408     ))
 409     # Truncate directory if necessary.
 410     local top_left="(${directory/WIDTH/${top_left_width_max}})"
 411     local width_top_left=${#${(S%%)top_left//$~zero/}}
 412
 413     # Calculate the width of the top prompt to fill the middle with "-".
 414     local width=$((
 415         COLUMNS - width_top_prefix - width_top_left - width_top_right
 416     ))
 417     local top_separator="%B${blue}${(l:${width}::-:)}%b${default}"
 418
 419     PROMPT="${top_prefix}${top_left}${top_separator}${top_right}
 420 ${bottom_prefix}${user}@${host} ${background}%# ${exitcode}"
 421 }
 422 precmd_functions+=(prompt_precmd)
 423
 424
 425 # When GNU screen, tmux, xterm or rxvt is used set the name of the window to
 426 # the currently running program.
 427 #
 428 # When a program is started preexec() sets the window's name to it; when it
 429 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
 430 # the window's name to the resumed job.
 431 #
 432 # It works with GNU screen, tmux, xterm and rxvt.
 433 #
 434 # If a command is run with sudo or if the shell is running as root then a ! is
 435 # added at the beginning of the command to make this clear. If a command is
 436 # running on a different computer with ssh a @ is added at the beginning. If
 437 # screen/tmux is running on the remote machine instead of @screen @:hostname
 438 # (or @tmux ..; hostname replaced by the machine's hostname) is displayed.
 439 # This only works if the .zshrc on the server also uses this command.
 440 #
 441 # screen* is necessary as `screen` uses screen.linux for example for a linux
 442 # console.
 443 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 444     # Is set to a non empty value to reset the window name in the next
 445     # precmd() call.
 446     window_reset=yes
 447     # Is set to a non empty value when the shell is running as root.
 448     if [[ $UID -eq 0 ]]; then
 449         window_root=yes
 450     fi
 451
 452     window_preexec() {
 453         # Get the program name with its arguments.
 454         local program_name=$1
 455
 456         # When sudo is used, use real program name instead, but with an
 457         # exclamation mark at the beginning (handled below).
 458         local program_sudo=
 459         if [[ $program_name == sudo* ]]; then
 460             program_name=${program_name#sudo }
 461             program_sudo=yes
 462         fi
 463
 464         # Handle fg.
 465         local REPLY
 466         resolve_fg_to_resumed_job_name "$program_name"
 467         program_name="$REPLY"
 468
 469         # Remove all arguments from the program name.
 470         program_name=${program_name%% *}
 471
 472         # Ignore often used commands which are only running for a very short
 473         # time. This prevents a "blinking" name when it's changed to "cd" for
 474         # example and then some milliseconds later back to "zsh".
 475         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
 476
 477         # Change my shortcuts so the real name of the program is displayed.
 478         case $program_name in
 479             e)
 480                 program_name=elinks
 481                 ;;
 482             g)
 483                 program_name=git
 484                 ;;
 485             m)
 486                 program_name=mutt
 487                 ;;
 488             v)
 489                 program_name=vim
 490                 ;;
 491         esac
 492
 493         # Add an exclamation mark at the beginning if running with sudo or if
 494         # running zsh as root.
 495         if [[ -n $program_sudo || -n $window_root ]]; then
 496             program_name=!$program_name
 497         fi
 498
 499         # Add an at mark at the beginning if running through ssh on a
 500         # different computer.
 501         if [[ -n $SSH_CONNECTION ]]; then
 502             program_name="@$program_name"
 503
 504             # If screen is running in SSH then display "@:hostname" as title
 505             # in the term/outer screen.
 506             if [[ $program_name == @screen || $program_name == @tmux ]]; then
 507                 program_name="@:${HOST//.*/}"
 508             # Use "@:!hostname" for root screens.
 509             elif [[ $program_name == @!screen || $program_name == @!tmux ]]; then
 510                 program_name="@:!${HOST//.*/}"
 511             fi
 512         fi
 513
 514         # Set the window name to the currently running program.
 515         window_title "$program_name"
 516
 517         # Tell precmd() to reset the window name when the program stops.
 518         window_reset=yes
 519     }
 520
 521     window_precmd() {
 522         # Abort if no window name reset is necessary.
 523         [[ -z $window_reset ]] && return
 524
 525         # Reset the window name to 'zsh'.
 526         local name=zsh
 527         # If the function was called with an argument then reset the window
 528         # name to '.zsh' (used by clear alias).
 529         if [[ -n $1 ]]; then
 530             name=.zsh
 531         fi
 532
 533         # Prepend prefixes like in window_preexec().
 534         if [[ -n $window_root ]]; then
 535             name="!$name"
 536         fi
 537         if [[ -n $SSH_CONNECTION ]]; then
 538             name="@$name"
 539         fi
 540         window_title $name
 541
 542         # Just reset the name, so no screen reset necessary for the moment.
 543         window_reset=
 544     }
 545
 546     # Sets the window title. Works with GNU screen, tmux (which uses screen as
 547     # TERM), xterm and rxvt. (V) escapes all non-printable characters, thanks
 548     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
 549     if [[ $TERM == screen* ]]; then
 550         window_title() {
 551             print -n "\ek${(V)1}\e\\"
 552         }
 553     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 554         window_title() {
 555             print -n "\e]2;${(V)1}\e\\"
 556         }
 557     else
 558         # Fallback if another TERM is used.
 559         window_title() { }
 560     fi
 561
 562     # Add the preexec() and precmd() hooks.
 563     preexec_functions+=(window_preexec)
 564     precmd_functions+=(window_precmd)
 565 else
 566     # Fallback if another TERM is used, necessary to run screen (see below in
 567     # "RUN COMMANDS").
 568     window_preexec() { }
 569 fi
 570
 571
 572 # COMPLETION SETTINGS
 573
 574 # Load the complist module which provides additional features to completion
 575 # lists (coloring, scrolling).
 576 zmodload zsh/complist
 577 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 578 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 579 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
 580 # problem.
 581 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
 582
 583 # Use cache to speed up some slow completions (dpkg, perl modules, etc.).
 584 zstyle ':completion:*' use-cache yes
 585 zstyle ':completion:*' cache-path ~/.zsh/cache
 586
 587 # Let the completion system handle all completions, including expanding of
 588 # shell wildcards (which is handled by other shell mechanisms if the default
 589 # expand-or-complete is used).
 590 bindkey '^I' complete-word
 591 # If there are multiple matches after pressing <Tab> always display them
 592 # immediately without requiring another <Tab>. a<Tab> completes to aa and
 593 # lists aaa, aab, aac as possible completions if the directory contains aaa,
 594 # aab, aac, bbb instead of only completing to aa.
 595 setopt nolistambiguous
 596 # Support completions in the middle of a word, without this option zsh jumps
 597 # to the end of the word before the completion process begins. Is required for
 598 # the _prefix completer.
 599 setopt completeinword
 600
 601 zstyle ':completion:::::' completer \
 602     _expand _complete _prefix _ignored _approximate
 603
 604 # Match specification to be tried when completing items. Each group ('...') is
 605 # tried after another if no matches were found, once matches are found no
 606 # other groups are tried. Thanks to Mikachu in #zsh on Freenode (2012-08-28
 607 # 18:48 CEST) for explanations.
 608 #
 609 # When matching also include the uppercase variant of typed characters
 610 # ('m:{a-z}={A-Z}'); using '' before this group would try the unmodified match
 611 # first, but I prefer to get all matches immediately (e.g. if Makefile and
 612 # makefile exist in the current directory echo m<tab> matches both, with '' it
 613 # would only match makefile because it found one match). This allows typing in
 614 # lowercase most of the time and completion fixes the case, which is faster.
 615 #
 616 # Don't perform these fixes in _approximate to prevent it from changing the
 617 # input too much. Thanks to the book "From Bash to Z Shell" page 249.
 618 zstyle ':completion:*:(^approximate):*' matcher-list 'm:{a-z}={A-Z}'
 619
 620 # Allow one mistake per three characters. Thanks to the book "From Bash to Z
 621 # Shell" page 248.
 622 zstyle -e ':completion:*:approximate:*' max-errors \
 623     'reply=( $(( ($#PREFIX + $#SUFFIX) / 3 )) )'
 624
 625 # Expand shell wildcards to all matching files after <Tab>. echo *<Tab>
 626 # results in a b c if the directory contains the files a, b, c. Thanks to the
 627 # book "From Bash to Z Shell" page 246.
 628 zstyle ':completion:*:expand:*' tag-order all-expansions
 629 # Keep prefixes unexpanded if possible: $HOME/<Tab> doesn't expand $HOME,
 630 # while $HOME<Tab> does.
 631 zstyle ':completion:*:expand:*' keep-prefix yes
 632
 633 # When completing multiple path components display all matching ambiguous
 634 # components. For example /u/s/d/r/README<Tab> lists all matching READMEs
 635 # instead of just the matching paths up to the r/ component. Can be slow if
 636 # there are many matching files.
 637 zstyle ':completion:*' list-suffixes yes
 638
 639 # Use ls-like colors for completions.
 640 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 641
 642 # Make completion lists scrollable so "do you wish to see all n possibilities"
 643 # is no longer displayed. Display current position in percent (%p).
 644 zstyle ':completion:*:default' list-prompt '%p'
 645 # Display group name (%d) (like 'external command', 'alias', etc.), in bold.
 646 # Also display a message if _approximate found errors and no matches were
 647 # found.
 648 zstyle ':completion:*'             format '    %B%d%b:'
 649 zstyle ':completion:*:corrections' format '    %B%d%b (errors: %e)'
 650 zstyle ':completion:*:warnings'    format '    %Bno matches for %d%b'
 651 # Display different types of matches separately.
 652 zstyle ':completion:*' group-name ''
 653
 654 # Separate man pages by section.
 655 zstyle ':completion:*' separate-sections yes
 656
 657 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
 658 # on Freenode for the fix (2010-12-17 13:46 CET).
 659 zle_highlight=(suffix:none)
 660
 661 # Ignore completion functions.
 662 zstyle ':completion:*:functions' ignored-patterns '_*'
 663 # Ignore parent directory.
 664 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 665 # Always complete file names only once in the current line. This makes it easy
 666 # to complete multiple file names because I can just press tab to get all
 667 # possible values. Otherwise I would have to skip the first value again and
 668 # again. Thanks to Mikachu in #zsh on Freenode (2011-08-11 14:42 CEST) for the
 669 # hint to use other. other is necessary so prefix<Tab> lists both prefix and
 670 # prefixrest if the directory contains prefix and prefixrest.
 671 zstyle ':completion:*:all-files' ignore-line other
 672 # Except for mv and cp, because I often want to use to similar names, so I
 673 # complete to the same and change it.
 674 zstyle ':completion:*:(mv|cp):all-files' ignore-line no
 675
 676 # Don't complete ./config.* files, this makes running ./configure much
 677 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
 678 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 679 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
 680 # Freenode (2010-06-06 04:54 CEST). See below for a way to complete them.
 681 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns \
 682     '*.aux' '*.log' '*.pdf' \
 683     '*.class'
 684
 685 # Provide a fallback completer which always completes files. Useful when Zsh's
 686 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 687 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 688 zle -C complete-files complete-word _generic
 689 zstyle ':completion:complete-files:*' completer _files
 690 bindkey '^F' complete-files
 691
 692
 693 # CUSTOM ALIASES AND FUNCTIONS
 694
 695 # If ^C is pressed while typing a command, add it to the history so it can be
 696 # easily retrieved later and then abort like ^C normally does. This is useful
 697 # when I want to abort an command to do something in between and then finish
 698 # typing the command.
 699 #
 700 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 701 # starting with - don't cause errors; and to Nadav Har'El
 702 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 703 # correctly, both on the Zsh mailing list.
 704 TRAPINT() {
 705     # Don't store this line in history if histignorespace is enabled and the
 706     # line starts with a space.
 707     if [[ -o histignorespace && ${BUFFER[1]} = " " ]]; then
 708         return $1
 709     fi
 710
 711     # Store the current buffer in the history.
 712     zle && print -s -r -- $BUFFER
 713
 714     # Return the default exit code so Zsh aborts the current command.
 715     return $1
 716 }
 717
 718 # Load aliases and similar functions also used by other shells.
 719 if [[ -f ~/.shell/aliases ]]; then
 720     . ~/.shell/aliases
 721 fi
 722
 723 # Make sure aliases are expanded when using sudo.
 724 alias sudo='sudo '
 725
 726 # Global aliases for often used redirections.
 727 alias -g E='2>&1'
 728 alias -g N='>/dev/null'
 729 alias -g EN='2>/dev/null'
 730 alias -g L='2>&1 | less'
 731 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
 732 alias -g D='2>&1 | colordiff | less'
 733 # Global aliases for often used commands.
 734 alias -g A='| awk'
 735 alias -g G='| grep'
 736 alias -g H='| head'
 737 alias -g P='| perl'
 738 alias -g S='| sort'
 739 alias -g T='| tail'
 740 alias -g U='| uniq'
 741
 742 # Make going up directories simple.
 743 alias -g ...='../..'
 744 alias -g ....='../../..'
 745 alias -g .....='../../../..'
 746
 747 # If the window naming feature is used (see above) then use ".zsh" (leading
 748 # dot) as title name after running clear so it's clear to me that the window
 749 # is empty. I open so much windows that I don't know in which I have something
 750 # important. This helps me to remember which windows are empty (I run clear
 751 # after I finished my work in a window).
 752 if [[ -n $window_reset ]]; then
 753     alias clear='clear; window_reset=yes; window_precmd reset'
 754 fi
 755
 756
 757 # CUSTOM COMMANDS
 758
 759 # Display all branches (except stash) in gitk but only 200 commits as this is
 760 # much faster. Also put in the background and disown. Thanks to drizzd in #git
 761 # on Freenode (2010-04-03 17:55 CEST).
 762 (( $+commands[gitk] )) && gitk() {
 763     command gitk --max-count=200 --branches --remotes --tags "$@" &
 764     disown %command
 765 }
 766 # Same for tig (except the disown part as it's no GUI program).
 767 (( $+commands[tig] )) && tig() {
 768     command tig --max-count=200 --branches --remotes --tags "$@"
 769 }
 770
 771 # Pipe output through less.
 772 (( $+commands[tree] )) && tree() {
 773     command tree -C "$@" | less
 774 }
 775
 776 # Choose the "best" PDF viewer available: xpdf, then zathura (in the past
 777 # zathura was preferred, but recent versions are completely broken: still no
 778 # working search and no page-wise scrolling anymore). Also setup completion
 779 # for `pdf`.
 780 if (( $+commands[xpdf] )); then
 781     pdf() {
 782         command xpdf "$@" 2>/dev/null &
 783         disown %command
 784     }
 785     compdef _xpdf pdf
 786 elif (( $+commands[zathura] )); then
 787     pdf() {
 788         command zathura "$@" 2>/dev/null &
 789         disown %command
 790     }
 791     # No completion for zathura yet.
 792     compdef _xpdf pdf
 793 fi
 794
 795 # GHCI doesn't use readline, force it if rlwrap is available.
 796 (( $+commands[rlwrap] )) && ghci() {
 797     command rlwrap \
 798         --always-readline --complete-filenames -t dumb \
 799         --histsize 5000 \
 800         --file ~/.shell/rlwrap/ghci \
 801         ghci "$@" 2>&1
 802 }
 803
 804
 805 # OS SPECIFIC SETTINGS
 806
 807 if [[ $OSTYPE == linux* ]]; then
 808     # Settings when creating Debian packages.
 809     export DEBEMAIL=simon@ruderich.org
 810     export DEBFULLNAME='Simon Ruderich'
 811 fi
 812
 813
 814 # LOAD ADDITIONAL CONFIGURATION FILES
 815
 816 # Configuration option for rc.local to use GNU screen/tmux. By default GNU
 817 # screen is used. Possible values: screen, tmux and empty (no value).
 818 use_multiplexer=screen
 819
 820 source_config ~/.zsh/rc.local
 821
 822
 823 # RUN COMMANDS
 824
 825 # If not already in screen or tmux, reattach to a running session or create a
 826 # new one. This also starts screen/tmux on a remote server when connecting
 827 # through ssh.
 828 if [[ $TERM != dumb && $TERM != linux && -z $STY && -z $TMUX ]]; then
 829     # Get running detached sessions.
 830     if [[ $use_multiplexer = screen ]]; then
 831         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 832     elif [[ $use_multiplexer = tmux ]]; then
 833         session=$(tmux list-sessions 2>/dev/null \
 834                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
 835     fi
 836
 837     # As we exec later we have to set the title here.
 838     if [[ $use_multiplexer = screen ]]; then
 839         window_preexec screen
 840     elif [[ $use_multiplexer = tmux ]]; then
 841         window_preexec tmux
 842     fi
 843
 844     # Create a new session if none is running.
 845     if [[ -z $session ]]; then
 846         if [[ $use_multiplexer = screen ]]; then
 847             exec screen
 848         elif [[ $use_multiplexer = tmux ]]; then
 849             exec tmux
 850         fi
 851     # Reattach to a running session.
 852     else
 853         if [[ $use_multiplexer = screen ]]; then
 854             exec screen -r $session
 855         elif [[ $use_multiplexer = tmux ]]; then
 856             exec tmux attach-session -t $session
 857         fi
 858     fi
 859 fi
 860
 861 # Colorize stderr in red. Very useful when looking for errors. Thanks to
 862 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 863 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
 864 # yet perfect and doesn't work with su and git for example, but it can handle
 865 # most interactive output quite well (even with no trailing new line) and in
 866 # cases it doesn't work, the E alias can be used as workaround.
 867 #
 868 # Moved in the "run commands" section to prevent one unnecessary zsh process
 869 # when starting GNU screen/tmux (see above).
 870 exec 2>>(while read -r -k -u 0 line; do
 871     printf '\e[91m%s\e[0m' "$line"
 872     print -n $'\0'
 873 done &)
 874
 875 # Run the following programs every 4 hours (and when zsh starts).
 876 PERIOD=14400
 877 periodic() {
 878     # Display fortunes.
 879     (( $+commands[fortune] )) && fortune -ac
 880     # Display reminders.
 881     (( $+commands[rem] )) && [[ -f ~/.reminders ]] && rem -h
 882 }
 883
 884
 885 source_debug '. ~/.zsh/rc (done)'
 886
 887 # vim: ft=zsh