zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Make sure every entry in $fpath is unique.
  36 typeset -U fpath
  37 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  38 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  39 if [[ -d ~/.zsh/functions/completion ]]; then
  40     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  41 fi
  42 # Set correct fpath to allow loading my functions (including completion
  43 # functions).
  44 fpath=(~/.zsh/functions $fpath)
  45 # Autoload my functions (except completion functions and hidden files). Thanks
  46 # to caphuso from the Zsh example files for this idea.
  47 autoload ${fpath[1]}/^_*(^/:t)
  48
  49 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  50 # the moment only precmd() and preexec() are simulated.
  51 #
  52 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  53 # so the compatibility version is used there too.
  54 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  55     # Provide add-zsh-hook which was added in 4.3.4.
  56     fpath=(~/.zsh/functions/compatibility $fpath)
  57
  58     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  59     function precmd() {
  60         for function in $precmd_functions; do
  61             $function $@
  62         done
  63     }
  64     function preexec() {
  65         for function in $preexec_functions; do
  66             $function $@
  67         done
  68     }
  69 fi
  70
  71 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  72 autoload -Uz add-zsh-hook
  73
  74
  75 # HISTORY SETTINGS
  76
  77 # Use history and store it in ~/.zsh/history.
  78 HISTSIZE=5000
  79 SAVEHIST=5000
  80 HISTFILE=~/.zsh/history
  81 # Append to the history file instead of overwriting it and do it immediately
  82 # when a command is executed.
  83 setopt appendhistory
  84 setopt incappendhistory
  85 # If the same command is run multiple times store it only once in the history.
  86 setopt histignoredups
  87 # Vim like completions of previous executed commands.
  88 bindkey "^P" history-beginning-search-backward
  89 bindkey "^N" history-beginning-search-forward
  90
  91
  92 # PROMPT SETTINGS
  93
  94 # Use colorized output, necessary for prompts and completions.
  95 autoload -U colors && colors
  96
  97 # Set the default prompt. The current host and working directory is displayed,
  98 # the exit code of the last command if it wasn't 0, the number of running jobs
  99 # if not 0 and a + if this shell is running inside another shell.
 100 # The prompt is in green and blue to make easily detectable, the error exit
 101 # code in red and bold and the job count in yellow.
 102 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 103 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 104 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 105 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 106
 107 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 108 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 109 # symbolic link to current checkout of Zsh's sources).
 110 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 111       -d ~/.zsh/functions/vcs_info ]]; then
 112     # Update fpath to allow loading the VCS_Info functions.
 113     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 114        fpath=(~/.zsh/functions/vcs_info/
 115               ~/.zsh/functions/vcs_info/Backends
 116               $fpath)
 117     fi
 118
 119     # Allow substitutions and expansions in the prompt, necessary for
 120     # vcs_info.
 121     setopt promptsubst
 122     # Load vcs_info to display information about version control repositories.
 123     autoload -Uz vcs_info
 124     # Only look for git and mercurial repositories; the only I use.
 125     zstyle ':vcs_info:*' enable git hg
 126     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 127     # is displayed. If there is an special action going on (merge, rebase)
 128     # it's also displayed (red).
 129     zstyle ':vcs_info:*' formats \
 130     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 131 %{${fg[blue]}%}%s%{${fg[default]}%})"
 132     zstyle ':vcs_info:*' actionformats \
 133     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 134 %{${fg[red]}%}%a%{${fg[default]}%}:\
 135 %{${fg[blue]}%}%s%{${fg[default]}%})"
 136     # Call vcs_info as precmd before every prompt.
 137     prompt_precmd() {
 138         vcs_info
 139     }
 140     add-zsh-hook precmd prompt_precmd
 141
 142     # Display the vcs information in the right prompt.
 143     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 144         RPROMPT='${vcs_info_msg_0_}'
 145     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 146     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 147     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 148     else
 149         RPROMPT='${vcs_info_msg_0_:- }'
 150     fi
 151 fi
 152
 153 # When screen, xterm or rxvt is used set the name of the window to the
 154 # currently running program.
 155 #
 156 # When a program is started preexec() sets the window's name to it; when it
 157 # stops precmd() resets the window's name to 'zsh'.
 158 #
 159 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 160 # and stumpwm is running then the window title is also set in stumpwm using
 161 # stumpish.
 162 #
 163 # If a command is run with sudo or if the shell is running as root then a ! is
 164 # added at the beginning of the command to make this clear. If a command is
 165 # running on a different computer with ssh a @ is added at the beginning. This
 166 # only works if the .zshrc on the server also uses this command.
 167 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 168     # Is set to a non empty value to reset the window name in the next
 169     # precmd() call.
 170     window_reset=yes
 171     # Is set to a non empty value when the stump window manager is running.
 172     ps aux | grep -q stumpwm | grep -v grep
 173     if [[ $? -eq 0 ]]; then
 174         window_stumpwm=yes
 175     fi
 176     # Is set to a non empty value when the shell is running as root.
 177     if [[ $(id -u) -eq 0 ]]; then
 178         window_root=yes
 179     fi
 180
 181     window_preexec() {
 182         # Get the program name with its arguments.
 183         local program_name=$1
 184
 185         # When sudo is used use real program name instead, but with an
 186         # exclamation mark at the beginning.
 187         local program_sudo=
 188         if [[ $program_name == sudo* ]]; then
 189             program_name=${program_name#sudo }
 190             program_sudo=yes
 191         fi
 192         # Remove all arguments from the program name.
 193         program_name=${program_name%% *}
 194
 195         # Ignore often used commands which are only running for a very short
 196         # time. This prevents a "blinking" name when it's changed to "cd" for
 197         # example and then some milliseconds later back to "zsh".
 198         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 199
 200         # Change my shortcuts so the real name of the program is displayed.
 201         case $program_name in
 202             e)
 203                 program_name=elinks
 204                 ;;
 205             g)
 206                 program_name=git
 207                 ;;
 208             m)
 209                 program_name=mutt
 210                 ;;
 211             v|vi)
 212                 program_name=vim
 213                 ;;
 214         esac
 215
 216         # Add an exclamation mark at the beginning if running with sudo or if
 217         # running zsh as root.
 218         if [[ -n $program_sudo || -n $window_root ]]; then
 219             program_name=!$program_name
 220         fi
 221
 222         # Add an at mark at the beginning if running through ssh on a
 223         # different computer.
 224         if [[ -n $SSH_CONNECTION ]]; then
 225             program_name="@$program_name"
 226         fi
 227
 228         # Set the window name to the currently running program.
 229         window_title "$program_name"
 230
 231         # Tell precmd() to reset the window name when the program stops.
 232         window_reset=yes
 233     }
 234
 235     window_precmd() {
 236         # Abort if no window name reset is necessary.
 237         [[ -z $window_reset ]] && return
 238
 239         # Reset the window name to 'zsh'.
 240         if [[ -n $SSH_CONNECTION ]]; then
 241             window_title "@zsh"
 242         elif [[ -n $window_root ]]; then
 243             window_title "!zsh"
 244         else
 245             window_title "zsh"
 246         fi
 247
 248         # Just reset the name, so no screen reset necessary for the moment.
 249         window_reset=
 250     }
 251
 252     # Sets the window title. Works with screen, xterm and rxvt.
 253     window_title() {
 254         if [[ $TERM == screen* ]]; then
 255             print -n "\ek$1\e\\"
 256
 257             # Update window name in stumpwm if running screen in X11 and when
 258             # stumpwm is used.
 259             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 260                 echo "$1" | stumpish -e "title" > /dev/null
 261             fi
 262
 263         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 264             print -n "\e]2;$1\e\\"
 265         fi
 266     }
 267
 268     # Add the preexec() and precmd() hooks.
 269     add-zsh-hook preexec window_preexec
 270     add-zsh-hook precmd window_precmd
 271 fi
 272
 273
 274 # COMPLETION SETTINGS
 275
 276 # Load the complist module which provides additions to completion lists
 277 # (coloring, scrollable).
 278 zmodload zsh/complist
 279 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 280 # cluttering of ~/.
 281 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 282
 283 # Use cache to speed up completions.
 284 zstyle ':completion:*' use-cache on
 285 zstyle ':completion:*' cache-path ~/.zsh/cache
 286
 287 # Complete arguments and fix spelling mistakes when possible.
 288 zstyle ':completion:*' completer _complete _match _correct _approximate
 289
 290 # Make sure the list of possible completions is displayed after pressing <TAB>
 291 # the first time.
 292 setopt nolistambiguous
 293 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 294 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 295 bindkey "^I" expand-or-complete-prefix
 296 # Try uppercase if the currently typed string doesn't match. This allows
 297 # typing in lowercase most of the time and completion fixes the case.
 298 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 299
 300 # Use ls like colors for completions.
 301 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 302
 303 # Make completion lists scrollable so "do you wish to see all n possibilities"
 304 # is no longer displayed.
 305 zstyle ':completion:*' list-prompt '%p'
 306 # Display group name (like 'external command', 'alias', etc.) when there are
 307 # multiple matches in bold.
 308 zstyle ':completion:*' format '    %B%d%b:'
 309 # Display different types of matches separately.
 310 zstyle ':completion:*' group-name ''
 311
 312 # Ignore completion functions.
 313 zstyle ':completion:*:functions' ignored-patterns '_*'
 314 # Ignore parent directory.
 315 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 316 # When unsetting variables make sure every variable name is only suggested
 317 # once.
 318 zstyle ':completion:*:unset:*' ignore-line yes
 319 # When working with Mercurial and Git don't complete the same file multiple
 320 # times. Very useful when completing file names.
 321 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 322
 323
 324 # CUSTOM ALIASES AND FUNCTIONS
 325
 326 # If ^C is pressed while typing a command, add it to the history so it can be
 327 # easily retrieved later and then abort like ^C normally does. This is useful
 328 # when I want to abort an command to do something in between and then finish
 329 # typing the command.
 330 #
 331 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 332 # starting with - don't cause errors.
 333 TRAPINT() {
 334     # Store the current buffer in the history.
 335     zle && print -s -- $BUFFER
 336
 337     # Return the default exit code so zsh aborts the current command.
 338     return $1
 339 }
 340
 341 # Colorize stderr. Very useful when looking for errors. Thanks to
 342 # http://gentoo-wiki.com/wiki/Zsh
 343 exec 2>>(while read line; do
 344     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 345
 346 # Make sure aliases are expanded when using sudo.
 347 alias sudo='sudo '
 348
 349 # Global aliases for often used commands used in the command line.
 350 alias -g E='2>&1'
 351 alias -g L='E | less'
 352 alias -g D='E | colordiff L'
 353 alias -g G='| grep'
 354 alias -g S='| sort'
 355
 356 # Make going up directories simple.
 357 alias -g ...='../..'
 358 alias -g ....='../../..'
 359 alias -g .....='../../../..'
 360
 361 # Shortcuts for often used programs.
 362 alias c='clear'
 363 alias e='elinks'
 364 alias g='git'
 365 alias m='mutt'
 366 alias v='vim'
 367 alias vi='vim'
 368
 369 # Improved ls which displays the files in columns (-C), visualizes
 370 # directories, links and other special files (-F) and pages everything through
 371 # less (L).
 372 #
 373 # If available use GNU ls with colorized output. If it isn't available use
 374 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 375 # pager.
 376 ls --color &> /dev/null
 377 if [[ $? -eq 0 ]]; then
 378     alias ls='ls --color'
 379 else
 380     alias ls='CLICOLOR_FORCE=1 ls -G'
 381 fi
 382 # Main ls function.
 383 function ls() {
 384     command ls -C -F $* L
 385 }
 386 # Helper function to list all files.
 387 function la() {
 388     ls -a $*
 389 }
 390 # Helper function to list all files in list format with access rights, etc.
 391 function ll() {
 392     la -l $*
 393 }
 394
 395 # If the window naming feature is used (see above) then use ".zsh" (leading
 396 # dot) as title name after running clear so it's clear to me that the window
 397 # is empty. I open so much windows that I don't know in which I have something
 398 # important. This helps me to remember which windows are empty (I run clear
 399 # after I finished my work in a window).
 400 if [[ -n $window_reset ]]; then
 401     alias clear='clear; window_title .zsh'
 402 fi
 403
 404 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 405 # shell.
 406 alias :q='echo "This is not Vim!" >&2'
 407
 408 # Automatically use unified diffs.
 409 alias diff='diff -u'
 410
 411 # Display all files and use human readable sizes.
 412 alias du='du -sh'
 413
 414 # Use human readable sizes.
 415 alias df='df -h'
 416
 417 # Edit the mercurial patch queue series file for the current mercurial
 418 # repository in Vim. Also change Vim's pwd to the patches directory so other
 419 # patches can easily be opened.
 420 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 421
 422 # Display all branches (except stash) in gitk but only 200 commits as this is
 423 # much faster. Also put in the background and disown. Thanks to sitaram in
 424 # #git on Freenode (2009-04-20 15:51).
 425 gitk() {
 426     command gitk \
 427         --max-count=200 \
 428         $(git rev-parse --symbolic-full-name --remotes --branches) \
 429         $@ &
 430     disown %command
 431 }
 432 # Same for tig (except the disown part as it's no GUI program).
 433 tig() {
 434     command tig \
 435         --max-count=200 \
 436         $(git rev-parse --symbolic-full-name --remotes --branches) \
 437         $@
 438 }
 439
 440
 441 # RUN COMMANDS
 442
 443 # If not already in screen reattach to a running session or create a new one.
 444 #
 445 # screen* is necessary as `screen` uses screen.linux for example for a linux
 446 # console which would otherwise cause an infinite loop.
 447 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 448     # Get running detached sessions.
 449     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 450     # Create a new session if none is running.
 451     if [[ -z $session ]]; then
 452         screen
 453     # Reattach to a running session.
 454     else
 455         screen -r $session
 456     fi
 457 fi
 458
 459
 460 # Load rc file for current OS.
 461 source_config ~/.zsh os rc $(uname) nolocal
 462 # Load rc file for current hostname (first part before a dot) or rc.local.
 463 source_config ~/.zsh host rc ${$(hostname)//.*/}
 464
 465 source_debug "finished sourcing ~/.zsh/rc"
 466
 467 # vim: ft=zsh