zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only lines starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a use function
  99 # with bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Set the default prompt. The current host and working directory is displayed,
 129 # the exit code of the last command if it wasn't 0, the number of running jobs
 130 # if not 0 and a + if this shell is running inside another shell.
 131 # The prompt is in green and blue to make easily detectable, the error exit
 132 # code in red and bold and the job count in yellow.
 133 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 134 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 135 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 136 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 137
 138 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 139 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 140 # symbolic link to current checkout of Zsh's sources).
 141 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 142       -d ~/.zsh/functions/vcs_info ]]; then
 143     # Update fpath to allow loading the VCS_Info functions.
 144     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 145        fpath=(~/.zsh/functions/vcs_info/
 146               ~/.zsh/functions/vcs_info/Backends
 147               $fpath)
 148     fi
 149
 150     # Allow substitutions and expansions in the prompt, necessary for
 151     # vcs_info.
 152     setopt promptsubst
 153     # Load vcs_info to display information about version control repositories.
 154     autoload -Uz vcs_info
 155     # Only look for git and mercurial repositories; the only I use.
 156     zstyle ':vcs_info:*' enable git hg
 157     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 158     # is displayed. If there is an special action going on (merge, rebase)
 159     # it's also displayed (red).
 160     zstyle ':vcs_info:*' formats \
 161     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 162 %{${fg[blue]}%}%s%{${fg[default]}%})"
 163     zstyle ':vcs_info:*' actionformats \
 164     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 165 %{${fg[red]}%}%a%{${fg[default]}%}:\
 166 %{${fg[blue]}%}%s%{${fg[default]}%})"
 167     # Call vcs_info as precmd before every prompt.
 168     prompt_precmd() {
 169         vcs_info
 170     }
 171     add-zsh-hook precmd prompt_precmd
 172
 173     # Display the vcs information in the right prompt.
 174     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 175         RPROMPT='${vcs_info_msg_0_}'
 176     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 177     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 178     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 179     else
 180         RPROMPT='${vcs_info_msg_0_:- }'
 181     fi
 182 fi
 183
 184 # When screen, xterm or rxvt is used set the name of the window to the
 185 # currently running program.
 186 #
 187 # When a program is started preexec() sets the window's name to it; when it
 188 # stops precmd() resets the window's name to 'zsh'.
 189 #
 190 # It works with screen, xterm and rxvt. If screen is running in X11 (DISPLAY
 191 # is set) and stumpwm is running then the window title is also set in stumpwm
 192 # using stumpish (I don't use stumpwm actually anymore but I left the changes
 193 # in as a reference).
 194 #
 195 # If a command is run with sudo or if the shell is running as root then a ! is
 196 # added at the beginning of the command to make this clear. If a command is
 197 # running on a different computer with ssh a @ is added at the beginning. This
 198 # only works if the .zshrc on the server also uses this command.
 199 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 200     # Is set to a non empty value to reset the window name in the next
 201     # precmd() call.
 202     window_reset=yes
 203     # Is set to a non empty value when the stump window manager is running.
 204     ps aux | grep -q stumpwm | grep -v grep
 205     if [[ $? -eq 0 ]]; then
 206         window_stumpwm=yes
 207     fi
 208     # Is set to a non empty value when the shell is running as root.
 209     if [[ $(id -u) -eq 0 ]]; then
 210         window_root=yes
 211     fi
 212
 213     window_preexec() {
 214         # Get the program name with its arguments.
 215         local program_name=$1
 216
 217         # When sudo is used use real program name instead, but with an
 218         # exclamation mark at the beginning (handled below).
 219         local program_sudo=
 220         if [[ $program_name == sudo* ]]; then
 221             program_name=${program_name#sudo }
 222             program_sudo=yes
 223         fi
 224         # Remove all arguments from the program name.
 225         program_name=${program_name%% *}
 226
 227         # Ignore often used commands which are only running for a very short
 228         # time. This prevents a "blinking" name when it's changed to "cd" for
 229         # example and then some milliseconds later back to "zsh".
 230         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 231
 232         # Change my shortcuts so the real name of the program is displayed.
 233         case $program_name in
 234             e)
 235                 program_name=elinks
 236                 ;;
 237             g)
 238                 program_name=git
 239                 ;;
 240             m)
 241                 program_name=mutt
 242                 ;;
 243             v|vi)
 244                 program_name=vim
 245                 ;;
 246         esac
 247
 248         # Add an exclamation mark at the beginning if running with sudo or if
 249         # running zsh as root.
 250         if [[ -n $program_sudo || -n $window_root ]]; then
 251             program_name=!$program_name
 252         fi
 253
 254         # Add an at mark at the beginning if running through ssh on a
 255         # different computer.
 256         if [[ -n $SSH_CONNECTION ]]; then
 257             program_name="@$program_name"
 258         fi
 259
 260         # Set the window name to the currently running program.
 261         window_title "$program_name"
 262
 263         # Tell precmd() to reset the window name when the program stops.
 264         window_reset=yes
 265     }
 266
 267     window_precmd() {
 268         # Abort if no window name reset is necessary.
 269         [[ -z $window_reset ]] && return
 270
 271         # Reset the window name to 'zsh'.
 272         local name="zsh"
 273         # If the function was called with an argument then reset the window
 274         # name to '.zsh' (used by clear alias).
 275         if [[ -n $1 ]]; then
 276             name=".zsh"
 277         fi
 278
 279         # Prepend prefixes like in window_preexec().
 280         if [[ -n $SSH_CONNECTION ]]; then
 281             window_title "@$name"
 282         elif [[ -n $window_root ]]; then
 283             window_title "!$name"
 284         else
 285             window_title $name
 286         fi
 287
 288         # Just reset the name, so no screen reset necessary for the moment.
 289         window_reset=
 290     }
 291
 292     # Sets the window title. Works with screen, xterm and rxvt.
 293     window_title() {
 294         if [[ $TERM == screen* ]]; then
 295             print -n "\ek$1\e\\"
 296
 297             # Update window name in stumpwm if running screen in X11 and when
 298             # stumpwm is used.
 299             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 300                 echo "$1" | stumpish -e "title" > /dev/null
 301             fi
 302
 303         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 304             print -n "\e]2;$1\e\\"
 305         fi
 306     }
 307
 308     # Add the preexec() and precmd() hooks.
 309     add-zsh-hook preexec window_preexec
 310     add-zsh-hook precmd window_precmd
 311 fi
 312
 313
 314 # COMPLETION SETTINGS
 315
 316 # Load the complist module which provides additions to completion lists
 317 # (coloring, scrollable).
 318 zmodload zsh/complist
 319 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 320 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 321 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 322 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 323
 324 # Use cache to speed up completions.
 325 zstyle ':completion:*' use-cache on
 326 zstyle ':completion:*' cache-path ~/.zsh/cache
 327
 328 # Complete arguments and fix spelling mistakes when possible.
 329 zstyle ':completion:*' completer _complete _match _correct _approximate
 330
 331 # Make sure the list of possible completions is displayed after pressing <TAB>
 332 # the first time.
 333 setopt nolistambiguous
 334 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 335 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 336 bindkey "^I" expand-or-complete-prefix
 337 # Try uppercase if the currently typed string doesn't match. This allows
 338 # typing in lowercase most of the time and completion fixes the case.
 339 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 340
 341 # Use ls like colors for completions.
 342 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 343
 344 # Make completion lists scrollable so "do you wish to see all n possibilities"
 345 # is no longer displayed.
 346 zstyle ':completion:*' list-prompt '%p'
 347 # Display group name (like 'external command', 'alias', etc.) when there are
 348 # multiple matches in bold.
 349 zstyle ':completion:*' format '    %B%d%b:'
 350 # Display different types of matches separately.
 351 zstyle ':completion:*' group-name ''
 352
 353 # Ignore completion functions.
 354 zstyle ':completion:*:functions' ignored-patterns '_*'
 355 # Ignore parent directory.
 356 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 357 # When unsetting variables make sure every variable name is only suggested
 358 # once.
 359 zstyle ':completion:*:unset:*' ignore-line yes
 360 # When working with Mercurial and Git don't complete the same file multiple
 361 # times. Very useful when completing file names.
 362 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 363
 364
 365 # CUSTOM ALIASES AND FUNCTIONS
 366
 367 # If ^C is pressed while typing a command, add it to the history so it can be
 368 # easily retrieved later and then abort like ^C normally does. This is useful
 369 # when I want to abort an command to do something in between and then finish
 370 # typing the command.
 371 #
 372 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 373 # starting with - don't cause errors.
 374 TRAPINT() {
 375     # Store the current buffer in the history.
 376     zle && print -s -- $BUFFER
 377
 378     # Return the default exit code so zsh aborts the current command.
 379     return $1
 380 }
 381
 382 # Colorize stderr. Very useful when looking for errors. Thanks to
 383 # http://gentoo-wiki.com/wiki/Zsh
 384 exec 2>>(while read line; do
 385     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 386
 387 # Make sure aliases are expanded when using sudo.
 388 alias sudo='sudo '
 389
 390 # Global aliases for often used commands in the command line.
 391 alias -g E='2>&1'
 392 alias -g L='E | less'
 393 alias -g D='E | colordiff L'
 394 alias -g G='| grep'
 395 alias -g S='| sort'
 396 alias -g U='| uniq'
 397
 398 # Make going up directories simple.
 399 alias -g ...='../..'
 400 alias -g ....='../../..'
 401 alias -g .....='../../../..'
 402
 403 # Shortcuts for often used programs.
 404 alias c='clear'
 405 alias e='elinks'
 406 alias g='git'
 407 alias m='mutt'
 408 alias v='vim'
 409 alias vi='vim'
 410
 411 # Improved ls which displays the files in columns (-C), visualizes
 412 # directories, links and other special files (-F) and pages everything through
 413 # less (L).
 414 #
 415 # If available use GNU ls with colorized output. If it isn't available use
 416 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 417 # pager.
 418 ls --color &> /dev/null
 419 if [[ $? -eq 0 ]]; then
 420     alias ls='ls --color'
 421 else
 422     alias ls='CLICOLOR_FORCE=1 ls -G'
 423 fi
 424 # Main ls function.
 425 function ls() {
 426     command ls -C -F $* L
 427 }
 428 # Helper function to list all files.
 429 function la() {
 430     ls -a $*
 431 }
 432 # Helper function to list all files in list format with access rights, etc.
 433 function ll() {
 434     la -l $*
 435 }
 436
 437 # If the window naming feature is used (see above) then use ".zsh" (leading
 438 # dot) as title name after running clear so it's clear to me that the window
 439 # is empty. I open so much windows that I don't know in which I have something
 440 # important. This helps me to remember which windows are empty (I run clear
 441 # after I finished my work in a window).
 442 if [[ -n $window_reset ]]; then
 443     alias clear='clear; window_reset=yes; window_precmd reset'
 444 fi
 445
 446 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 447 # shell.
 448 alias :q='echo "This is not Vim!" >&2'
 449
 450 # Automatically use unified diffs.
 451 alias diff='diff -u'
 452
 453 # Display all files and use human readable sizes.
 454 alias du='du -sh'
 455
 456 # Use human readable sizes.
 457 alias df='df -h'
 458
 459 # Edit the mercurial patch queue series file for the current mercurial
 460 # repository in Vim. Also change Vim's pwd to the patches directory so other
 461 # patches can easily be opened.
 462 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 463
 464 # Display all branches (except stash) in gitk but only 200 commits as this is
 465 # much faster. Also put in the background and disown. Thanks to sitaram in
 466 # #git on Freenode (2009-04-20 15:51).
 467 gitk() {
 468     command gitk \
 469         --max-count=200 \
 470         $(git rev-parse --symbolic-full-name --remotes --branches) \
 471         $@ &
 472     disown %command
 473 }
 474 # Same for tig (except the disown part as it's no GUI program).
 475 tig() {
 476     command tig \
 477         --max-count=200 \
 478         $(git rev-parse --symbolic-full-name --remotes --branches) \
 479         $@
 480 }
 481
 482
 483 # RUN COMMANDS
 484
 485 # If not already in screen reattach to a running session or create a new one.
 486 #
 487 # screen* is necessary as `screen` uses screen.linux for example for a linux
 488 # console which would otherwise cause an infinite loop.
 489 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 490     # Get running detached sessions.
 491     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 492     # Create a new session if none is running.
 493     if [[ -z $session ]]; then
 494         screen
 495     # Reattach to a running session.
 496     else
 497         screen -r $session
 498     fi
 499 fi
 500
 501
 502 # OS SPECIFIC SETTINGS
 503
 504 if [[ $(uname) == Linux ]]; then
 505     # Settings when creating Debian packages.
 506     DEBEMAIL=simon@ruderich.org
 507     export DEBEMAIL
 508     DEBFULLNAME="Simon Ruderich"
 509     export DEBFULLNAME
 510
 511 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 512     # Store the current clipboard in CLIPBOARD before every command so it can
 513     # be used in commands.
 514     os_darwin_preexec() {
 515         export CLIPBOARD="$(pbpaste)"
 516     }
 517     # Add the function as preexec hook.
 518     add-zsh-hook preexec os_darwin_preexec
 519
 520     # Initialize CLIPBOARD so it's available for completion directly after
 521     # startup.
 522     CLIPBOARD=""
 523     export CLIPBOARD
 524
 525     # Fetch current URL in clipboard with wget.
 526     alias wnc='wget --no-proxy $CLIPBOARD'
 527 fi
 528
 529
 530 # Load rc file for current hostname (first part before a dot) or rc.local.
 531 source_config ~/.zsh host rc ${$(hostname)//.*/}
 532
 533 source_debug "finished sourcing ~/.zsh/rc"
 534
 535 # vim: ft=zsh