zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd(), preexec() and chpwd() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  64     # arrays.
  65     function precmd() {
  66         for function in $precmd_functions; do
  67             $function $@
  68         done
  69     }
  70     function preexec() {
  71         for function in $preexec_functions; do
  72             $function $@
  73         done
  74     }
  75     function chpwd() {
  76         for function in $chpwd_functions; do
  77             $function $@
  78         done
  79     }
  80 fi
  81
  82 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  83 autoload -Uz add-zsh-hook
  84
  85 # Load zmv (zsh move) which is powerful to rename files.
  86 autoload zmv
  87
  88
  89 # HISTORY SETTINGS
  90
  91 # Use history and store it in ~/.zsh/history.
  92 HISTSIZE=50000
  93 SAVEHIST=50000
  94 HISTFILE=~/.zsh/history
  95 # Append to the history file instead of overwriting it and do it immediately
  96 # when a command is executed.
  97 setopt appendhistory
  98 setopt incappendhistory
  99 # If the same command is run multiple times store it only once in the history.
 100 setopt histignoredups
 101 # Vim like completions of previous executed commands (also enter Vi-mode). If
 102 # called at the beginning it just recalls old commands (like cursor up), if
 103 # called after typing something, only lines starting with the typed are
 104 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 105 # on Freenode (2010-01-17 12:47) for the information how to a use function
 106 # with bindkey.
 107 zle -N my-vi-history-beginning-search-backward
 108 my-vi-history-beginning-search-backward() {
 109     local not_at_beginning_of_line
 110     if [[ $CURSOR -ne 0 ]]; then
 111         not_at_beginning_of_line=yes
 112     fi
 113
 114     zle history-beginning-search-backward
 115
 116     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 117     # this counters it).
 118     zle vi-cmd-mode
 119     if [[ -n $not_at_beginning_of_line ]]; then
 120         zle vi-forward-char
 121     fi
 122 }
 123 bindkey "^P" my-vi-history-beginning-search-backward
 124 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 125 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 126 # after calling ^P.
 127 bindkey -a "^N" history-beginning-search-forward
 128
 129
 130 # PROMPT SETTINGS
 131
 132 # Use colorized output, necessary for prompts and completions.
 133 autoload -U colors && colors
 134
 135 # Some shortcuts for colors.
 136 local red="%{${fg[red]}%}"
 137 local blue="%{${fg[blue]}%}"
 138 local green="%{${fg[green]}%}"
 139 local yellow="%{${fg[yellow]}%}"
 140 local default="%{${fg[default]}%}"
 141
 142 # Set the default prompt. The current host and working directory is displayed,
 143 # the exit code of the last command if it wasn't 0, the number of running jobs
 144 # if not 0.
 145 #
 146 # The prompt is in green and blue to make easily detectable, the error exit
 147 # code in red and bold and the job count in yellow.
 148 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 149 %(1j.$yellow%j$default.)%# \
 150 %(?..($red%B%?%b$default%) )"
 151
 152 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 153 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 154 # symbolic link to current checkout of Zsh's sources).
 155 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 156       -d ~/.zsh/functions/vcs_info ]]; then
 157     # Update fpath to allow loading the vcs_info functions.
 158     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 159        fpath=(~/.zsh/functions/vcs_info/
 160               ~/.zsh/functions/vcs_info/Backends
 161               $fpath)
 162     fi
 163
 164     # Allow substitutions and expansions in the prompt, necessary for
 165     # vcs_info.
 166     setopt promptsubst
 167     # Load vcs_info to display information about version control repositories.
 168     autoload -Uz vcs_info
 169     # Only look for git and mercurial repositories; the only I use.
 170     zstyle ':vcs_info:*' enable git hg
 171     # Check the repository for changes so they can be used in %u/%c (see
 172     # below). This comes with a speed penalty for bigger repositories.
 173     zstyle ':vcs_info:*' check-for-changes true
 174
 175     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 176     # is displayed. If there is an special action going on (merge, rebase)
 177     # it's also displayed (red). Also display if there are unstaged or staged
 178     # (%u/%c) changes.
 179     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 180           -d ~/.zsh/functions/vcs_info ]]; then
 181         zstyle ':vcs_info:*' formats \
 182             "($green%b%u%c$default:$blue%s$default)"
 183         zstyle ':vcs_info:*' actionformats \
 184             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 185     else
 186         # In older versions %u and %c are not defined yet and are not
 187         # correctly expanded.
 188         zstyle ':vcs_info:*' formats \
 189             "($green%b$default:$blue%s$default)"
 190         zstyle ':vcs_info:*' actionformats \
 191             "($green%b$default/$red%a$default:$blue%s$default)"
 192     fi
 193     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 194     # changes are detected in the repository; check-for-changes must be set to
 195     # true for this to work. Thanks to Bart Trojanowski
 196     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 197     # (2010-03-11 00:20).
 198     zstyle ':vcs_info:*' unstagedstr '¹'
 199     zstyle ':vcs_info:*' stagedstr   '²'
 200
 201     # Call vcs_info as precmd before every prompt.
 202     prompt_precmd() {
 203         vcs_info
 204     }
 205     add-zsh-hook precmd prompt_precmd
 206
 207     # Display the VCS information in the right prompt.
 208     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 209         RPROMPT='${vcs_info_msg_0_}'
 210     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 211     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 212     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 213     else
 214         RPROMPT='${vcs_info_msg_0_:- }'
 215     fi
 216 fi
 217
 218 unset red blue green yellow default
 219
 220 # When screen, xterm or rxvt is used set the name of the window to the
 221 # currently running program.
 222 #
 223 # When a program is started preexec() sets the window's name to it; when it
 224 # stops precmd() resets the window's name to 'zsh'.
 225 #
 226 # It works with screen, xterm and rxvt.
 227 #
 228 # If a command is run with sudo or if the shell is running as root then a ! is
 229 # added at the beginning of the command to make this clear. If a command is
 230 # running on a different computer with ssh a @ is added at the beginning. This
 231 # only works if the .zshrc on the server also uses this command.
 232 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 233     # Is set to a non empty value to reset the window name in the next
 234     # precmd() call.
 235     window_reset=yes
 236     # Is set to a non empty value when the shell is running as root.
 237     if [[ $(id -u) -eq 0 ]]; then
 238         window_root=yes
 239     fi
 240
 241     window_preexec() {
 242         # Get the program name with its arguments.
 243         local program_name=$1
 244
 245         # When sudo is used use real program name instead, but with an
 246         # exclamation mark at the beginning (handled below).
 247         local program_sudo=
 248         if [[ $program_name == sudo* ]]; then
 249             program_name=${program_name#sudo }
 250             program_sudo=yes
 251         fi
 252         # Remove all arguments from the program name.
 253         program_name=${program_name%% *}
 254
 255         # Ignore often used commands which are only running for a very short
 256         # time. This prevents a "blinking" name when it's changed to "cd" for
 257         # example and then some milliseconds later back to "zsh".
 258         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 259
 260         # Change my shortcuts so the real name of the program is displayed.
 261         case $program_name in
 262             e)
 263                 program_name=elinks
 264                 ;;
 265             g)
 266                 program_name=git
 267                 ;;
 268             m)
 269                 program_name=mutt
 270                 ;;
 271             v|vi)
 272                 program_name=vim
 273                 ;;
 274         esac
 275
 276         # Add an exclamation mark at the beginning if running with sudo or if
 277         # running zsh as root.
 278         if [[ -n $program_sudo || -n $window_root ]]; then
 279             program_name=!$program_name
 280         fi
 281
 282         # Add an at mark at the beginning if running through ssh on a
 283         # different computer.
 284         if [[ -n $SSH_CONNECTION ]]; then
 285             program_name="@$program_name"
 286         fi
 287
 288         # Set the window name to the currently running program.
 289         window_title "$program_name"
 290
 291         # Tell precmd() to reset the window name when the program stops.
 292         window_reset=yes
 293     }
 294
 295     window_precmd() {
 296         # Abort if no window name reset is necessary.
 297         [[ -z $window_reset ]] && return
 298
 299         # Reset the window name to 'zsh'.
 300         local name="zsh"
 301         # If the function was called with an argument then reset the window
 302         # name to '.zsh' (used by clear alias).
 303         if [[ -n $1 ]]; then
 304             name=".zsh"
 305         fi
 306
 307         # Prepend prefixes like in window_preexec().
 308         if [[ -n $SSH_CONNECTION ]]; then
 309             window_title "@$name"
 310         elif [[ -n $window_root ]]; then
 311             window_title "!$name"
 312         else
 313             window_title $name
 314         fi
 315
 316         # Just reset the name, so no screen reset necessary for the moment.
 317         window_reset=
 318     }
 319
 320     # Sets the window title. Works with screen, xterm and rxvt.
 321     window_title() {
 322         if [[ $TERM == screen* ]]; then
 323             print -n "\ek$1\e\\"
 324
 325         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 326             print -n "\e]2;$1\e\\"
 327         fi
 328     }
 329
 330     # Add the preexec() and precmd() hooks.
 331     add-zsh-hook preexec window_preexec
 332     add-zsh-hook precmd window_precmd
 333 fi
 334
 335
 336 # COMPLETION SETTINGS
 337
 338 # Load the complist module which provides additions to completion lists
 339 # (coloring, scrollable).
 340 zmodload zsh/complist
 341 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 342 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 343 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 344 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 345
 346 # Use cache to speed up completions.
 347 zstyle ':completion:*' use-cache on
 348 zstyle ':completion:*' cache-path ~/.zsh/cache
 349
 350 # Complete arguments and fix spelling mistakes when possible.
 351 zstyle ':completion:*' completer _complete _match _correct _approximate
 352
 353 # Make sure the list of possible completions is displayed after pressing <TAB>
 354 # the first time.
 355 setopt nolistambiguous
 356 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 357 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 358 bindkey "^I" expand-or-complete-prefix
 359 # Try uppercase if the currently typed string doesn't match. This allows
 360 # typing in lowercase most of the time and completion fixes the case.
 361 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 362
 363 # Use ls like colors for completions.
 364 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 365
 366 # Make completion lists scrollable so "do you wish to see all n possibilities"
 367 # is no longer displayed.
 368 zstyle ':completion:*' list-prompt '%p'
 369 # Display group name (like 'external command', 'alias', etc.) when there are
 370 # multiple matches in bold.
 371 zstyle ':completion:*' format '    %B%d%b:'
 372 # Display different types of matches separately.
 373 zstyle ':completion:*' group-name ''
 374
 375 # Ignore completion functions.
 376 zstyle ':completion:*:functions' ignored-patterns '_*'
 377 # Ignore parent directory.
 378 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 379 # When unsetting variables make sure every variable name is only suggested
 380 # once.
 381 zstyle ':completion:*:unset:*' ignore-line yes
 382 # When working with Mercurial and Git don't complete the same file multiple
 383 # times. Very useful when completing file names.
 384 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 385
 386
 387 # CUSTOM ALIASES AND FUNCTIONS
 388
 389 # If ^C is pressed while typing a command, add it to the history so it can be
 390 # easily retrieved later and then abort like ^C normally does. This is useful
 391 # when I want to abort an command to do something in between and then finish
 392 # typing the command.
 393 #
 394 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 395 # starting with - don't cause errors.
 396 TRAPINT() {
 397     # Store the current buffer in the history.
 398     zle && print -s -- $BUFFER
 399
 400     # Return the default exit code so Zsh aborts the current command.
 401     return $1
 402 }
 403
 404 # Colorize stderr. Very useful when looking for errors. Thanks to
 405 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 406 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 407 # perfect and doesn't work with some interactive stderr output, but in those
 408 # cases the E alias can be used as workaround.
 409 exec 2>>(while read -r line; do
 410     printf '\e[91m%s\e[0m\n' "$line"
 411     print -n $'\0';
 412 done &)
 413
 414 # Load aliases and similar functions also used by other shells.
 415 if [[ -f ~/.shell/aliases ]]; then
 416     . ~/.shell/aliases
 417 fi
 418
 419 # Make sure aliases are expanded when using sudo.
 420 alias sudo='sudo '
 421
 422 # Global aliases for often used commands in the command line.
 423 alias -g E='2>&1'
 424 alias -g L='E | less'
 425 alias -g D='E | colordiff L'
 426 alias -g G='| grep'
 427 alias -g S='| sort'
 428 alias -g U='| uniq'
 429
 430 # Make going up directories simple.
 431 alias -g ...='../..'
 432 alias -g ....='../../..'
 433 alias -g .....='../../../..'
 434
 435 # If the window naming feature is used (see above) then use ".zsh" (leading
 436 # dot) as title name after running clear so it's clear to me that the window
 437 # is empty. I open so much windows that I don't know in which I have something
 438 # important. This helps me to remember which windows are empty (I run clear
 439 # after I finished my work in a window).
 440 if [[ -n $window_reset ]]; then
 441     alias clear='clear; window_reset=yes; window_precmd reset'
 442 fi
 443
 444 # Display all branches (except stash) in gitk but only 200 commits as this is
 445 # much faster. Also put in the background and disown. Thanks to sitaram in
 446 # #git on Freenode (2009-04-20 15:51).
 447 gitk() {
 448     command gitk \
 449         --max-count=200 \
 450         $(git rev-parse --symbolic-full-name --remotes --branches) \
 451         $@ &
 452     disown %command
 453 }
 454 # Same for tig (except the disown part as it's no GUI program).
 455 tig() {
 456     command tig \
 457         --max-count=200 \
 458         $(git rev-parse --symbolic-full-name --remotes --branches) \
 459         $@
 460 }
 461
 462
 463 # OS SPECIFIC SETTINGS
 464
 465 if [[ $(uname) == Linux ]]; then
 466     # Settings when creating Debian packages.
 467     DEBEMAIL=simon@ruderich.org
 468     export DEBEMAIL
 469     DEBFULLNAME="Simon Ruderich"
 470     export DEBFULLNAME
 471
 472 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 473     # Store the current clipboard in CLIPBOARD before every command so it can
 474     # be used in commands.
 475     os_darwin_preexec() {
 476         export CLIPBOARD="$(pbpaste)"
 477     }
 478     # Add the function as preexec hook.
 479     add-zsh-hook preexec os_darwin_preexec
 480
 481     # Initialize CLIPBOARD so it's available for completion directly after
 482     # startup.
 483     CLIPBOARD=""
 484     export CLIPBOARD
 485
 486     # Fetch current URL in clipboard with wget.
 487     alias wnc='wget --no-proxy $CLIPBOARD'
 488 fi
 489
 490
 491 # LOAD ADDITIONAL CONFIGURATION FILES
 492
 493 # Load rc file for current hostname (first part before a dot) or rc.local.
 494 source_config ~/.zsh host rc ${$(hostname)//.*/}
 495
 496
 497 # RUN COMMANDS
 498
 499 # If not already in screen reattach to a running session or create a new one.
 500 #
 501 # screen* is necessary as `screen` uses screen.linux for example for a linux
 502 # console which would otherwise cause an infinite loop.
 503 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 504     # Get running detached sessions.
 505     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 506     # Create a new session if none is running.
 507     if [[ -z $session ]]; then
 508         screen
 509     # Reattach to a running session.
 510     else
 511         screen -r $session
 512     fi
 513 fi
 514
 515
 516 source_debug "finished sourcing ~/.zsh/rc"
 517
 518 # vim: ft=zsh