zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 # MISCELLANEOUS SETTINGS
   5
   6 # Use Vi(m) style key bindings.
   7 bindkey -v
   8
   9 # Be paranoid, new files are readable/writable by me only.
  10 umask 077
  11
  12 # Make sure core dumps are created.
  13 ulimit -c unlimited
  14
  15 # Prevent overwriting existing files with '> filename', use '>| filename'
  16 # (or >!) instead.
  17 setopt noclobber
  18
  19 # Entering the name of a directory (if it's not a command) will automatically
  20 # cd to that directory.
  21 setopt autocd
  22
  23 # When entering a nonexistent command name automatically try to find a similar
  24 # one.
  25 setopt correct
  26
  27 # Enable zsh's extended glob abilities.
  28 setopt extendedglob
  29
  30 # Don't exit if <C-d> is pressed.
  31 setopt ignoreeof
  32
  33
  34 # HISTORY SETTINGS
  35
  36 # Use history and store it in ~/.zsh/history.
  37 HISTSIZE=1000
  38 SAVEHIST=1000
  39 HISTFILE=~/.zsh/history
  40 # Append to the history file instead of overwriting it and do it immediately
  41 # when a command is executed.
  42 setopt appendhistory
  43 setopt incappendhistory
  44 # If the same command is run multiple times store it only once in the history.
  45 setopt histignoredups
  46 # Vim like completions of previous executed commands.
  47 bindkey "^P" history-beginning-search-backward
  48 bindkey "^N" history-beginning-search-forward
  49
  50
  51 # PROMPT SETTINGS
  52
  53 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  54 autoload -Uz add-zsh-hook
  55
  56 # Use colorized output, necessary for prompts and completions.
  57 autoload -U colors && colors
  58
  59 # Set the default prompt. The current host and working directory is displayed,
  60 # the exit code of the last command if it wasn't 0, the number of running jobs
  61 # if not 0 and a + if this shell is running inside another shell.
  62 # The prompt is in green and blue to make easily detectable, the error exit
  63 # code in red and bold and the job count in yellow.
  64 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  65 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  66 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  67 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  68
  69 # Allow substitutions and expansions in the prompt, necessary for vcs_info.
  70 setopt promptsubst
  71 # Load vcs_info to display information about version control repositories.
  72 autoload -Uz vcs_info
  73 # Only look for git and mercurial repositories; the only I use.
  74 zstyle ':vcs_info:*' enable git hg
  75 # Set style of vcs_info display. The current branch (green) and vcs (blue) is
  76 # displayed. If there is an special action going on (merge, rebase) it's also
  77 # displayed (red).
  78 zstyle ':vcs_info:*' formats \
  79 "(%{${fg[green]}%}%b%{${fg[default]}%}:\
  80 %{${fg[blue]}%}%s%{${fg[default]}%})"
  81 zstyle ':vcs_info:*' actionformats \
  82 "(%{${fg[green]}%}%b%{${fg[default]}%}/\
  83 %{${fg[red]}%}%a%{${fg[default]}%}:\
  84 %{${fg[blue]}%}%s%{${fg[default]}%})"
  85 # Call vcs_info as precmd before every prompt.
  86 prompt_precmd() {
  87     vcs_info
  88 }
  89 add-zsh-hook precmd prompt_precmd
  90
  91 # Display the vcs information in the right prompt.
  92 RPROMPT='${vcs_info_msg_0_}'
  93
  94 # When screen is used set the name of the window to the currently running
  95 # program.
  96 #
  97 # When a program is started preexec() sets the window's name to it; when it
  98 # stops precmd() resets the windows' name to 'zsh'.
  99 if [[ $TERM == screen ]]; then
 100     # Set to a non empty value to reset the window name in the next precmd()
 101     # call.
 102     screen_name_reset=yes
 103
 104     screen_preexec() {
 105         # Get the application name excluding any arguments.
 106         local program_name=${1%% *}
 107
 108         # Ignore often used commands which are only running for a very short
 109         # time. This prevents a "blinking" name when it's changed to "cd" for
 110         # example and then some milliseconds later back to "zsh".
 111         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 112
 113         # Change my shortcuts so the real name of the program is displayed.
 114         case $program_name in
 115             e)
 116                 program_name=elinks
 117                 ;;
 118             g)
 119                 program_name=git
 120                 ;;
 121             m)
 122                 program_name=mutt
 123                 ;;
 124             v|vi)
 125                 program_name=vim
 126                 ;;
 127         esac
 128
 129         # Set the window name to the currently running program.
 130         print -n "\ek$program_name\e\\"
 131
 132         # Tell precmd() to reset the window name when the program stops.
 133         screen_name_reset=yes
 134     }
 135
 136     screen_precmd() {
 137         # Abort if no window name reset is necessary.
 138         [[ -z $screen_name_reset ]] && return
 139
 140         # Reset the window name to 'zsh'.
 141         print -n "\ekzsh\e\\"
 142
 143         # Just reset the name, so no screen reset necessary for the moment.
 144         screen_name_reset=
 145     }
 146
 147     # Add the preexec() and precmd() hooks.
 148     add-zsh-hook preexec screen_preexec
 149     add-zsh-hook precmd screen_precmd
 150 fi
 151
 152
 153 # COMPLETION SETTINGS
 154
 155 # Use new completion system.
 156 autoload -U compinit && compinit
 157 # Load the complist module which provides additions to completion lists
 158 # (coloring, scrollable).
 159 zmodload zsh/complist
 160 # Make sure the list of possible completions is displayed after pressing <TAB>
 161 # the first time.
 162 setopt nolistambiguous
 163 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 164 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 165 bindkey "^I" expand-or-complete-prefix
 166 # Use cache to speed up completions.
 167 zstyle ':completion:*' use-cache on
 168 zstyle ':completion:*' cache-path ~/.zsh/cache
 169 # Try uppercase if the currently typed string doesn't match. This allows
 170 # typing in lowercase most of the time and completion fixes the case.
 171 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 172 # Ignore completion functions.
 173 zstyle ':completion:*:functions' ignored-patterns '_*'
 174 # Ignore parent directory.
 175 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 176 # Use ls like colors for completions.
 177 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 178 # Make completion lists scrollable so "do you wish to see all n possibilities"
 179 # is no longer displayed.
 180 zstyle ':completion:*' list-prompt '%p'
 181 # When unsetting variables make sure every variable name is only suggested
 182 # once.
 183 zstyle ':completion:*:unset:*' ignore-line yes
 184 # When working with Mercurial and Git don't complete the same file multiple
 185 # times. Very useful when completing file names.
 186 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 187
 188
 189 # ALIAS AND FUNCTION SETTINGS
 190
 191 # Simplify calls to less, automatically redirects all output.
 192 alias -g L='2>&1 | less'
 193 # Simplify calls to colordiff, output is also piped through less.
 194 alias -g D='2>&1 | colordiff L'
 195 # Simplify calls to grep.
 196 alias -g G='| grep'
 197
 198 # Automatically use unified diffs.
 199 alias diff='diff -u'
 200
 201 # Display all files and use human readable sizes.
 202 alias du='du -sh'
 203
 204 # Multiple files given to Vim are opened in tabs.
 205 alias vim='vim -p'
 206
 207 # Shortcuts for often used programs.
 208 alias e='elinks'
 209 alias g='git'
 210 alias m='mutt'
 211 alias v='vim'
 212 alias vi='vim'
 213
 214 # Exit binding like in Vim; I sometimes confuse editor and shell.
 215 alias :q='exit'
 216
 217 # Edit the mercurial patch queue series file for the current mercurial
 218 # repository in Vim. Also change Vim's pwd to the patches directory so other
 219 # patches can easily be opened.
 220 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 221
 222 # Make going up directories simple.
 223 alias -g ...='../..'
 224 alias -g ....='../../..'
 225 alias -g .....='../../../..'
 226
 227 # Improved ls which displays the files in columns (-C), visualizes directories,
 228 # links and other special files (-F) and pages everything through less (L).
 229 #
 230 # If available use GNU ls with colorized output. If it isn't available use
 231 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 232 # pager.
 233 ls --color &> /dev/null
 234 if [[ $? -eq 0 ]]; then
 235     alias ls='ls --color'
 236 else
 237     alias ls='CLICOLOR_FORCE=1 ls -G'
 238 fi
 239 # Main ls function.
 240 function ls() {
 241     command ls -C -F $* L
 242 }
 243 # Helper function to list all files.
 244 function la() {
 245     ls -a $*
 246 }
 247 # Helper function to list all files in list format with access rights, etc.
 248 function ll() {
 249     la -l $*
 250 }
 251
 252 # If ^C is pressed while typing a command, add it to the history so it can be
 253 # easily retrieved later and then abort like ^C normally does. This is useful
 254 # when I want to abort an command to do something in between and then finish
 255 # typing the command.
 256 TRAPINT() {
 257     # Store the current buffer in the history.
 258     zle && print -s $BUFFER
 259
 260     # Return the default exit code so zsh aborts the current command.
 261     return $1
 262 }
 263
 264 # Display TODOs stored in ~/.todo if this file exists.
 265 todo() {
 266     if [[ -f ~/.todo ]]; then
 267         cat ~/.todo | $PAGER
 268     fi
 269 }
 270
 271
 272 # Load rc file for current OS.
 273 source_config ~/.zsh os rc $(uname) nolocal
 274 # Load rc file for current hostname (first part before a dot) or rc.local.
 275 source_config ~/.zsh host rc ${$(hostname)//.*/}