zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey -M viins 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -M viins -r '^[OA'
  45 bindkey -M viins -r '^[OB'
  46 bindkey -M viins -r '^[OC'
  47 bindkey -M viins -r '^[OD'
  48 bindkey -M viins -r '^[[A'
  49 bindkey -M viins -r '^[[B'
  50 bindkey -M viins -r '^[[C'
  51 bindkey -M viins -r '^[[D'
  52 # Also not in Vi mode.
  53 bindkey -M vicmd -r '^[OA'
  54 bindkey -M vicmd -r '^[OB'
  55 bindkey -M vicmd -r '^[OC'
  56 bindkey -M vicmd -r '^[OD'
  57 bindkey -M vicmd -r '^[[A'
  58 bindkey -M vicmd -r '^[[B'
  59 bindkey -M vicmd -r '^[[C'
  60 bindkey -M vicmd -r '^[[D'
  61
  62
  63 # FUNCTION SETTINGS
  64
  65 # Make sure every entry in $fpath is unique.
  66 typeset -U fpath
  67 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  68 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  69 if [[ -d ~/.zsh/functions/completion ]]; then
  70     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  71 fi
  72 # Set correct fpath to allow loading my functions (including completion
  73 # functions).
  74 fpath=(~/.zsh/functions $fpath)
  75 # Autoload my functions (except completion functions and hidden files). Thanks
  76 # to caphuso from the Zsh example files for this idea.
  77 if [[ -d ~/.zsh/functions ]]; then
  78     autoload ${fpath[1]}/^_*(^/:t)
  79 fi
  80
  81 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  82 # the moment only precmd(), preexec() and chpwd() are simulated.
  83 #
  84 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  85 # so the compatibility version is used there too.
  86 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  87     # Provide add-zsh-hook which was added in 4.3.4.
  88     fpath=(~/.zsh/functions/compatibility $fpath)
  89
  90     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  91     # arrays.
  92     function precmd() {
  93         for function in $precmd_functions; do
  94             $function $@
  95         done
  96     }
  97     function preexec() {
  98         for function in $preexec_functions; do
  99             $function $@
 100         done
 101     }
 102     function chpwd() {
 103         for function in $chpwd_functions; do
 104             $function $@
 105         done
 106     }
 107 fi
 108
 109 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
 110 autoload -Uz add-zsh-hook
 111
 112 # Load zmv (zsh move) which is powerful to rename files.
 113 autoload zmv
 114
 115
 116 # HISTORY SETTINGS
 117
 118 # Use history and store it in ~/.zsh/history.
 119 HISTSIZE=50000
 120 SAVEHIST=50000
 121 HISTFILE=~/.zsh/history
 122 # Append to the history file instead of overwriting it and do it immediately
 123 # when a command is executed.
 124 setopt appendhistory
 125 setopt incappendhistory
 126 # If the same command is run multiple times store it only once in the history.
 127 setopt histignoredups
 128 # Vim like completions of previous executed commands (also enter Vi-mode). If
 129 # called at the beginning it just recalls old commands (like cursor up), if
 130 # called after typing something, only lines starting with the typed are
 131 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 132 # on Freenode (2010-01-17 12:47) for the information how to a use function
 133 # with bindkey.
 134 zle -N my-vi-history-beginning-search-backward
 135 my-vi-history-beginning-search-backward() {
 136     local not_at_beginning_of_line
 137     if [[ $CURSOR -ne 0 ]]; then
 138         not_at_beginning_of_line=yes
 139     fi
 140
 141     zle history-beginning-search-backward
 142
 143     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 144     # this counters it).
 145     zle vi-cmd-mode
 146     if [[ -n $not_at_beginning_of_line ]]; then
 147         zle vi-forward-char
 148     fi
 149 }
 150 bindkey '^P' my-vi-history-beginning-search-backward
 151 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 152 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 153 # after calling ^P.
 154 bindkey -a '^N' history-beginning-search-forward
 155
 156
 157 # PROMPT SETTINGS
 158
 159 # Use colorized output, necessary for prompts and completions.
 160 autoload -U colors && colors
 161
 162 # Some shortcuts for colors.
 163 local red="%{${fg[red]}%}"
 164 local blue="%{${fg[blue]}%}"
 165 local green="%{${fg[green]}%}"
 166 local yellow="%{${fg[yellow]}%}"
 167 local default="%{${fg[default]}%}"
 168
 169 # Set the default prompt. The current host and working directory is displayed,
 170 # the exit code of the last command if it wasn't 0, the number of running jobs
 171 # if not 0.
 172 #
 173 # The prompt is in green and blue to make easily detectable, the error exit
 174 # code in red and bold and the job count in yellow.
 175 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 176 %(1j.$yellow%j$default.)%# \
 177 %(?..($red%B%?%b$default%) )"
 178
 179 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 180 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 181 # symbolic link to current checkout of Zsh's sources).
 182 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 183       -d ~/.zsh/functions/vcs_info ]]; then
 184     # Update fpath to allow loading the vcs_info functions.
 185     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 186        fpath=(~/.zsh/functions/vcs_info/
 187               ~/.zsh/functions/vcs_info/Backends
 188               $fpath)
 189     fi
 190
 191     # Allow substitutions and expansions in the prompt, necessary for
 192     # vcs_info.
 193     setopt promptsubst
 194     # Load vcs_info to display information about version control repositories.
 195     autoload -Uz vcs_info
 196     # Only look for git and mercurial repositories; the only I use.
 197     zstyle ':vcs_info:*' enable git hg
 198     # Check the repository for changes so they can be used in %u/%c (see
 199     # below). This comes with a speed penalty for bigger repositories.
 200     zstyle ':vcs_info:*' check-for-changes true
 201
 202     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 203     # is displayed. If there is an special action going on (merge, rebase)
 204     # it's also displayed (red). Also display if there are unstaged or staged
 205     # (%u/%c) changes.
 206     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 207           -d ~/.zsh/functions/vcs_info ]]; then
 208         zstyle ':vcs_info:*' formats \
 209             "($green%b%u%c$default:$blue%s$default)"
 210         zstyle ':vcs_info:*' actionformats \
 211             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 212     else
 213         # In older versions %u and %c are not defined yet and are not
 214         # correctly expanded.
 215         zstyle ':vcs_info:*' formats \
 216             "($green%b$default:$blue%s$default)"
 217         zstyle ':vcs_info:*' actionformats \
 218             "($green%b$default/$red%a$default:$blue%s$default)"
 219     fi
 220     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 221     # changes are detected in the repository; check-for-changes must be set to
 222     # true for this to work. Thanks to Bart Trojanowski
 223     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 224     # (2010-03-11 00:20).
 225     zstyle ':vcs_info:*' unstagedstr '¹'
 226     zstyle ':vcs_info:*' stagedstr   '²'
 227
 228     # Call vcs_info as precmd before every prompt.
 229     prompt_precmd() {
 230         vcs_info
 231     }
 232     add-zsh-hook precmd prompt_precmd
 233
 234     # Display the VCS information in the right prompt.
 235     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 236         RPROMPT='${vcs_info_msg_0_}'
 237     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 238     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 239     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 240     else
 241         RPROMPT='${vcs_info_msg_0_:- }'
 242     fi
 243 fi
 244
 245 unset red blue green yellow default
 246
 247 # When screen, xterm or rxvt is used set the name of the window to the
 248 # currently running program.
 249 #
 250 # When a program is started preexec() sets the window's name to it; when it
 251 # stops precmd() resets the window's name to 'zsh'.
 252 #
 253 # It works with screen, xterm and rxvt.
 254 #
 255 # If a command is run with sudo or if the shell is running as root then a ! is
 256 # added at the beginning of the command to make this clear. If a command is
 257 # running on a different computer with ssh a @ is added at the beginning. If
 258 # screen is running on the remote machine instead of @screen @:hostname
 259 # (hostname replaced by the machine's hostname) is displayed. This only works
 260 # if the .zshrc on the server also uses this command.
 261 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 262     # Is set to a non empty value to reset the window name in the next
 263     # precmd() call.
 264     window_reset=yes
 265     # Is set to a non empty value when the shell is running as root.
 266     if [[ $(id -u) -eq 0 ]]; then
 267         window_root=yes
 268     fi
 269
 270     window_preexec() {
 271         # Get the program name with its arguments.
 272         local program_name=$1
 273
 274         # When sudo is used use real program name instead, but with an
 275         # exclamation mark at the beginning (handled below).
 276         local program_sudo=
 277         if [[ $program_name == sudo* ]]; then
 278             program_name=${program_name#sudo }
 279             program_sudo=yes
 280         fi
 281         # Remove all arguments from the program name.
 282         program_name=${program_name%% *}
 283
 284         # Ignore often used commands which are only running for a very short
 285         # time. This prevents a "blinking" name when it's changed to "cd" for
 286         # example and then some milliseconds later back to "zsh".
 287         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 288
 289         # Change my shortcuts so the real name of the program is displayed.
 290         case $program_name in
 291             e)
 292                 program_name=elinks
 293                 ;;
 294             g)
 295                 program_name=git
 296                 ;;
 297             m)
 298                 program_name=mutt
 299                 ;;
 300             v|vi)
 301                 program_name=vim
 302                 ;;
 303         esac
 304
 305         # Add an exclamation mark at the beginning if running with sudo or if
 306         # running zsh as root.
 307         if [[ -n $program_sudo || -n $window_root ]]; then
 308             program_name=!$program_name
 309         fi
 310
 311         # Add an at mark at the beginning if running through ssh on a
 312         # different computer.
 313         if [[ -n $SSH_CONNECTION ]]; then
 314             program_name="@$program_name"
 315
 316             # If screen is running in SSH then display "@:hostname" as title
 317             # in the term/outer screen.
 318             if [[ $program_name == @screen ]]; then
 319                 program_name="@:${$(hostname)//.*/}"
 320             fi
 321         fi
 322
 323         # Set the window name to the currently running program.
 324         window_title "$program_name"
 325
 326         # Tell precmd() to reset the window name when the program stops.
 327         window_reset=yes
 328     }
 329
 330     window_precmd() {
 331         # Abort if no window name reset is necessary.
 332         [[ -z $window_reset ]] && return
 333
 334         # Reset the window name to 'zsh'.
 335         local name=zsh
 336         # If the function was called with an argument then reset the window
 337         # name to '.zsh' (used by clear alias).
 338         if [[ -n $1 ]]; then
 339             name=.zsh
 340         fi
 341
 342         # Prepend prefixes like in window_preexec().
 343         if [[ -n $SSH_CONNECTION ]]; then
 344             window_title "@$name"
 345         elif [[ -n $window_root ]]; then
 346             window_title "!$name"
 347         else
 348             window_title $name
 349         fi
 350
 351         # Just reset the name, so no screen reset necessary for the moment.
 352         window_reset=
 353     }
 354
 355     # Sets the window title. Works with screen, xterm and rxvt.
 356     if [[ $TERM == screen* ]]; then
 357         window_title() {
 358             print -n "\ek$1\e\\"
 359         }
 360     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 361         window_title() {
 362             print -n "\e]2;$1\e\\"
 363         }
 364     fi
 365
 366     # Add the preexec() and precmd() hooks.
 367     add-zsh-hook preexec window_preexec
 368     add-zsh-hook precmd window_precmd
 369 fi
 370
 371
 372 # COMPLETION SETTINGS
 373
 374 # Load the complist module which provides additions to completion lists
 375 # (coloring, scrollable).
 376 zmodload zsh/complist
 377 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 378 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 379 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 380 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 381
 382 # Use cache to speed up completions.
 383 zstyle ':completion:*' use-cache on
 384 zstyle ':completion:*' cache-path ~/.zsh/cache
 385
 386 # Complete arguments and fix spelling mistakes when possible.
 387 zstyle ':completion:*' completer _complete _match _correct _approximate
 388
 389 # Make sure the list of possible completions is displayed after pressing <TAB>
 390 # the first time.
 391 setopt nolistambiguous
 392 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 393 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 394 bindkey '^I' expand-or-complete-prefix
 395 # Try uppercase if the currently typed string doesn't match. This allows
 396 # typing in lowercase most of the time and completion fixes the case.
 397 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 398
 399 # Use ls like colors for completions.
 400 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 401
 402 # Make completion lists scrollable so "do you wish to see all n possibilities"
 403 # is no longer displayed.
 404 zstyle ':completion:*' list-prompt '%p'
 405 # Display group name (like 'external command', 'alias', etc.) when there are
 406 # multiple matches in bold.
 407 zstyle ':completion:*' format '    %B%d%b:'
 408 # Display different types of matches separately.
 409 zstyle ':completion:*' group-name ''
 410
 411 # Ignore completion functions.
 412 zstyle ':completion:*:functions' ignored-patterns '_*'
 413 # Ignore parent directory.
 414 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 415 # When unsetting variables make sure every variable name is only suggested
 416 # once.
 417 zstyle ':completion:*:unset:*' ignore-line yes
 418 # When working with Mercurial and Git don't complete the same file multiple
 419 # times. Very useful when completing file names.
 420 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 421
 422
 423 # CUSTOM ALIASES AND FUNCTIONS
 424
 425 # If ^C is pressed while typing a command, add it to the history so it can be
 426 # easily retrieved later and then abort like ^C normally does. This is useful
 427 # when I want to abort an command to do something in between and then finish
 428 # typing the command.
 429 #
 430 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 431 # starting with - don't cause errors.
 432 TRAPINT() {
 433     # Store the current buffer in the history.
 434     zle && print -s -- $BUFFER
 435
 436     # Return the default exit code so Zsh aborts the current command.
 437     return $1
 438 }
 439
 440 # Colorize stderr. Very useful when looking for errors. Thanks to
 441 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 442 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 443 # perfect and doesn't work with su and git for example, but it can handle most
 444 # interactive output quite well (even with no trailing new line) and in those
 445 # cases the E alias can be used as workaround.
 446 exec 2>>(while read -r -k -u 0 line; do
 447     printf '\e[91m%s\e[0m' "$line";
 448     print -n $'\0';
 449 done &)
 450
 451 # Load aliases and similar functions also used by other shells.
 452 if [[ -f ~/.shell/aliases ]]; then
 453     . ~/.shell/aliases
 454 fi
 455
 456 # Make sure aliases are expanded when using sudo.
 457 alias sudo='sudo '
 458
 459 # Global aliases for often used commands in the command line.
 460 alias -g E='2>&1'
 461 alias -g L='E | less'
 462 alias -g D='E | colordiff L'
 463 alias -g G='| grep'
 464 alias -g S='| sort'
 465 alias -g U='| uniq'
 466 alias -g H='| head'
 467 alias -g T='| tail'
 468
 469 # Make going up directories simple.
 470 alias -g ...='../..'
 471 alias -g ....='../../..'
 472 alias -g .....='../../../..'
 473
 474 # If the window naming feature is used (see above) then use ".zsh" (leading
 475 # dot) as title name after running clear so it's clear to me that the window
 476 # is empty. I open so much windows that I don't know in which I have something
 477 # important. This helps me to remember which windows are empty (I run clear
 478 # after I finished my work in a window).
 479 if [[ -n $window_reset ]]; then
 480     alias clear='clear; window_reset=yes; window_precmd reset'
 481 fi
 482
 483 # Display all branches (except stash) in gitk but only 200 commits as this is
 484 # much faster. Also put in the background and disown. Thanks to sitaram in
 485 # #git on Freenode (2009-04-20 15:51).
 486 gitk() {
 487     command gitk \
 488         --max-count=200 \
 489         $(git rev-parse --symbolic-full-name --remotes --branches) \
 490         $@ &
 491     disown %command
 492 }
 493 # Same for tig (except the disown part as it's no GUI program).
 494 tig() {
 495     command tig \
 496         --max-count=200 \
 497         $(git rev-parse --symbolic-full-name --remotes --branches) \
 498         $@
 499 }
 500
 501
 502 # OS SPECIFIC SETTINGS
 503
 504 if [[ $(uname) == Linux ]]; then
 505     # Settings when creating Debian packages.
 506     DEBEMAIL=simon@ruderich.org
 507     export DEBEMAIL
 508     DEBFULLNAME='Simon Ruderich'
 509     export DEBFULLNAME
 510
 511 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 512     # Store the current clipboard in CLIPBOARD before every command so it can
 513     # be used in commands.
 514     os_darwin_preexec() {
 515         export CLIPBOARD="$(pbpaste)"
 516     }
 517     # Add the function as preexec hook.
 518     add-zsh-hook preexec os_darwin_preexec
 519
 520     # Initialize CLIPBOARD so it's available for completion directly after
 521     # startup.
 522     CLIPBOARD=""
 523     export CLIPBOARD
 524
 525     # Fetch current URL in clipboard with wget.
 526     alias wnc='wget --no-proxy $CLIPBOARD'
 527 fi
 528
 529
 530 # LOAD ADDITIONAL CONFIGURATION FILES
 531
 532 # Load rc file for current hostname (first part before a dot) or rc.local.
 533 source_config ~/.zsh host rc ${$(hostname)//.*/}
 534
 535
 536 # RUN COMMANDS
 537
 538 # If not already in screen reattach to a running session or create a new one.
 539 #
 540 # screen* is necessary as `screen` uses screen.linux for example for a linux
 541 # console which would otherwise cause an infinite loop.
 542 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 543     # Get running detached sessions.
 544     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 545     # Create a new session if none is running.
 546     if [[ -z $session ]]; then
 547         screen
 548     # Reattach to a running session.
 549     else
 550         screen -r $session
 551     fi
 552 fi
 553
 554
 555 source_debug "finished sourcing ~/.zsh/rc"
 556
 557 # vim: ft=zsh