zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only lines starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a use function
  99 # with bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Some shortcuts for colors.
 129 local red="%{${fg[red]}%}"
 130 local blue="%{${fg[blue]}%}"
 131 local green="%{${fg[green]}%}"
 132 local yellow="%{${fg[yellow]}%}"
 133 local default="%{${fg[default]}%}"
 134
 135 # Set the default prompt. The current host and working directory is displayed,
 136 # the exit code of the last command if it wasn't 0, the number of running jobs
 137 # if not 0 and a + if this shell is running inside another shell.
 138 # The prompt is in green and blue to make easily detectable, the error exit
 139 # code in red and bold and the job count in yellow.
 140 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 141 %(1j.$yellow%j$default.)%# \
 142 %(?..($red%B%?%b$default%) )"
 143
 144 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 145 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 146 # symbolic link to current checkout of Zsh's sources).
 147 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 148       -d ~/.zsh/functions/vcs_info ]]; then
 149     # Update fpath to allow loading the VCS_Info functions.
 150     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 151        fpath=(~/.zsh/functions/vcs_info/
 152               ~/.zsh/functions/vcs_info/Backends
 153               $fpath)
 154     fi
 155
 156     # Allow substitutions and expansions in the prompt, necessary for
 157     # VCS_Info.
 158     setopt promptsubst
 159     # Load VCS_Info to display information about version control repositories.
 160     autoload -Uz vcs_info
 161     # Only look for git and mercurial repositories; the only I use.
 162     zstyle ':vcs_info:*' enable git hg
 163     # Check the repository for changes so they can be used in %u/%c (see
 164     # below). This comes with a speed penalty for bigger repositories.
 165     zstyle ':vcs_info:*' check-for-changes true
 166
 167     # Set style of VCS_Info display. The current branch (green) and VCS (blue)
 168     # is displayed. If there is an special action going on (merge, rebase)
 169     # it's also displayed (red). Also display if there are unstaged or staged
 170     # (%u/%c) changes.
 171     zstyle ':vcs_info:*' formats \
 172         "($green%b%u%c$default:$blue%s$default)"
 173     zstyle ':vcs_info:*' actionformats \
 174         "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 175     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 176     # changes are detected in the repository; check-for-changes must be set to
 177     # true for this to work. Thanks to Bart Trojanowski
 178     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 179     # (2010-03-11 00:20).
 180     zstyle ':vcs_info:*' unstagedstr '¹'
 181     zstyle ':vcs_info:*' stagedstr   '²'
 182
 183     # Call VCS_Info as precmd before every prompt.
 184     prompt_precmd() {
 185         vcs_info
 186     }
 187     add-zsh-hook precmd prompt_precmd
 188
 189     # Display the VCS information in the right prompt.
 190     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 191         RPROMPT='${vcs_info_msg_0_}'
 192     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 193     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 194     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 195     else
 196         RPROMPT='${vcs_info_msg_0_:- }'
 197     fi
 198 fi
 199
 200 unset red blue green yellow default
 201
 202 # When screen, xterm or rxvt is used set the name of the window to the
 203 # currently running program.
 204 #
 205 # When a program is started preexec() sets the window's name to it; when it
 206 # stops precmd() resets the window's name to 'zsh'.
 207 #
 208 # It works with screen, xterm and rxvt.
 209 #
 210 # If a command is run with sudo or if the shell is running as root then a ! is
 211 # added at the beginning of the command to make this clear. If a command is
 212 # running on a different computer with ssh a @ is added at the beginning. This
 213 # only works if the .zshrc on the server also uses this command.
 214 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 215     # Is set to a non empty value to reset the window name in the next
 216     # precmd() call.
 217     window_reset=yes
 218     # Is set to a non empty value when the shell is running as root.
 219     if [[ $(id -u) -eq 0 ]]; then
 220         window_root=yes
 221     fi
 222
 223     window_preexec() {
 224         # Get the program name with its arguments.
 225         local program_name=$1
 226
 227         # When sudo is used use real program name instead, but with an
 228         # exclamation mark at the beginning (handled below).
 229         local program_sudo=
 230         if [[ $program_name == sudo* ]]; then
 231             program_name=${program_name#sudo }
 232             program_sudo=yes
 233         fi
 234         # Remove all arguments from the program name.
 235         program_name=${program_name%% *}
 236
 237         # Ignore often used commands which are only running for a very short
 238         # time. This prevents a "blinking" name when it's changed to "cd" for
 239         # example and then some milliseconds later back to "zsh".
 240         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 241
 242         # Change my shortcuts so the real name of the program is displayed.
 243         case $program_name in
 244             e)
 245                 program_name=elinks
 246                 ;;
 247             g)
 248                 program_name=git
 249                 ;;
 250             m)
 251                 program_name=mutt
 252                 ;;
 253             v|vi)
 254                 program_name=vim
 255                 ;;
 256         esac
 257
 258         # Add an exclamation mark at the beginning if running with sudo or if
 259         # running zsh as root.
 260         if [[ -n $program_sudo || -n $window_root ]]; then
 261             program_name=!$program_name
 262         fi
 263
 264         # Add an at mark at the beginning if running through ssh on a
 265         # different computer.
 266         if [[ -n $SSH_CONNECTION ]]; then
 267             program_name="@$program_name"
 268         fi
 269
 270         # Set the window name to the currently running program.
 271         window_title "$program_name"
 272
 273         # Tell precmd() to reset the window name when the program stops.
 274         window_reset=yes
 275     }
 276
 277     window_precmd() {
 278         # Abort if no window name reset is necessary.
 279         [[ -z $window_reset ]] && return
 280
 281         # Reset the window name to 'zsh'.
 282         local name="zsh"
 283         # If the function was called with an argument then reset the window
 284         # name to '.zsh' (used by clear alias).
 285         if [[ -n $1 ]]; then
 286             name=".zsh"
 287         fi
 288
 289         # Prepend prefixes like in window_preexec().
 290         if [[ -n $SSH_CONNECTION ]]; then
 291             window_title "@$name"
 292         elif [[ -n $window_root ]]; then
 293             window_title "!$name"
 294         else
 295             window_title $name
 296         fi
 297
 298         # Just reset the name, so no screen reset necessary for the moment.
 299         window_reset=
 300     }
 301
 302     # Sets the window title. Works with screen, xterm and rxvt.
 303     window_title() {
 304         if [[ $TERM == screen* ]]; then
 305             print -n "\ek$1\e\\"
 306
 307         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 308             print -n "\e]2;$1\e\\"
 309         fi
 310     }
 311
 312     # Add the preexec() and precmd() hooks.
 313     add-zsh-hook preexec window_preexec
 314     add-zsh-hook precmd window_precmd
 315 fi
 316
 317
 318 # COMPLETION SETTINGS
 319
 320 # Load the complist module which provides additions to completion lists
 321 # (coloring, scrollable).
 322 zmodload zsh/complist
 323 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 324 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 325 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 326 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 327
 328 # Use cache to speed up completions.
 329 zstyle ':completion:*' use-cache on
 330 zstyle ':completion:*' cache-path ~/.zsh/cache
 331
 332 # Complete arguments and fix spelling mistakes when possible.
 333 zstyle ':completion:*' completer _complete _match _correct _approximate
 334
 335 # Make sure the list of possible completions is displayed after pressing <TAB>
 336 # the first time.
 337 setopt nolistambiguous
 338 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 339 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 340 bindkey "^I" expand-or-complete-prefix
 341 # Try uppercase if the currently typed string doesn't match. This allows
 342 # typing in lowercase most of the time and completion fixes the case.
 343 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 344
 345 # Use ls like colors for completions.
 346 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 347
 348 # Make completion lists scrollable so "do you wish to see all n possibilities"
 349 # is no longer displayed.
 350 zstyle ':completion:*' list-prompt '%p'
 351 # Display group name (like 'external command', 'alias', etc.) when there are
 352 # multiple matches in bold.
 353 zstyle ':completion:*' format '    %B%d%b:'
 354 # Display different types of matches separately.
 355 zstyle ':completion:*' group-name ''
 356
 357 # Ignore completion functions.
 358 zstyle ':completion:*:functions' ignored-patterns '_*'
 359 # Ignore parent directory.
 360 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 361 # When unsetting variables make sure every variable name is only suggested
 362 # once.
 363 zstyle ':completion:*:unset:*' ignore-line yes
 364 # When working with Mercurial and Git don't complete the same file multiple
 365 # times. Very useful when completing file names.
 366 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 367
 368
 369 # CUSTOM ALIASES AND FUNCTIONS
 370
 371 # If ^C is pressed while typing a command, add it to the history so it can be
 372 # easily retrieved later and then abort like ^C normally does. This is useful
 373 # when I want to abort an command to do something in between and then finish
 374 # typing the command.
 375 #
 376 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 377 # starting with - don't cause errors.
 378 TRAPINT() {
 379     # Store the current buffer in the history.
 380     zle && print -s -- $BUFFER
 381
 382     # Return the default exit code so zsh aborts the current command.
 383     return $1
 384 }
 385
 386 # Colorize stderr. Very useful when looking for errors. Thanks to
 387 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 388 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 389 # perfect and doesn't work with some interactive stderr output, but in those
 390 # cases the E alias can be used as workaround.
 391 exec 2>>(while read -r line; do
 392     printf '\e[91m%s\e[0m\n' "$line"
 393     print -n $'\0';
 394 done &)
 395
 396 # Load aliases and similar functions also used by other shells.
 397 if [[ -f ~/.shell/aliases ]]; then
 398     . ~/.shell/aliases
 399 fi
 400
 401 # Make sure aliases are expanded when using sudo.
 402 alias sudo='sudo '
 403
 404 # Global aliases for often used commands in the command line.
 405 alias -g E='2>&1'
 406 alias -g L='E | less'
 407 alias -g D='E | colordiff L'
 408 alias -g G='| grep'
 409 alias -g S='| sort'
 410 alias -g U='| uniq'
 411
 412 # Make going up directories simple.
 413 alias -g ...='../..'
 414 alias -g ....='../../..'
 415 alias -g .....='../../../..'
 416
 417 # If the window naming feature is used (see above) then use ".zsh" (leading
 418 # dot) as title name after running clear so it's clear to me that the window
 419 # is empty. I open so much windows that I don't know in which I have something
 420 # important. This helps me to remember which windows are empty (I run clear
 421 # after I finished my work in a window).
 422 if [[ -n $window_reset ]]; then
 423     alias clear='clear; window_reset=yes; window_precmd reset'
 424 fi
 425
 426 # Display all branches (except stash) in gitk but only 200 commits as this is
 427 # much faster. Also put in the background and disown. Thanks to sitaram in
 428 # #git on Freenode (2009-04-20 15:51).
 429 gitk() {
 430     command gitk \
 431         --max-count=200 \
 432         $(git rev-parse --symbolic-full-name --remotes --branches) \
 433         $@ &
 434     disown %command
 435 }
 436 # Same for tig (except the disown part as it's no GUI program).
 437 tig() {
 438     command tig \
 439         --max-count=200 \
 440         $(git rev-parse --symbolic-full-name --remotes --branches) \
 441         $@
 442 }
 443
 444
 445 # RUN COMMANDS
 446
 447 # If not already in screen reattach to a running session or create a new one.
 448 #
 449 # screen* is necessary as `screen` uses screen.linux for example for a linux
 450 # console which would otherwise cause an infinite loop.
 451 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 452     # Get running detached sessions.
 453     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 454     # Create a new session if none is running.
 455     if [[ -z $session ]]; then
 456         screen
 457     # Reattach to a running session.
 458     else
 459         screen -r $session
 460     fi
 461 fi
 462
 463
 464 # OS SPECIFIC SETTINGS
 465
 466 if [[ $(uname) == Linux ]]; then
 467     # Settings when creating Debian packages.
 468     DEBEMAIL=simon@ruderich.org
 469     export DEBEMAIL
 470     DEBFULLNAME="Simon Ruderich"
 471     export DEBFULLNAME
 472
 473 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 474     # Store the current clipboard in CLIPBOARD before every command so it can
 475     # be used in commands.
 476     os_darwin_preexec() {
 477         export CLIPBOARD="$(pbpaste)"
 478     }
 479     # Add the function as preexec hook.
 480     add-zsh-hook preexec os_darwin_preexec
 481
 482     # Initialize CLIPBOARD so it's available for completion directly after
 483     # startup.
 484     CLIPBOARD=""
 485     export CLIPBOARD
 486
 487     # Fetch current URL in clipboard with wget.
 488     alias wnc='wget --no-proxy $CLIPBOARD'
 489 fi
 490
 491
 492 # Load rc file for current hostname (first part before a dot) or rc.local.
 493 source_config ~/.zsh host rc ${$(hostname)//.*/}
 494
 495 source_debug "finished sourcing ~/.zsh/rc"
 496
 497 # vim: ft=zsh