zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Make sure every entry in $fpath is unique.
  36 typeset -U fpath
  37 # Set correct fpath to allow loading my functions (including completion
  38 # functions).
  39 fpath=(~/.zsh/functions $fpath)
  40 # Autoload my functions (except completion functions and hidden files). Thanks
  41 # to caphuso from the Zsh example files for this idea.
  42 autoload ${fpath[1]}/^_*(^/:t)
  43
  44 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  45 # the moment only precmd() and preexec() are simulated.
  46 #
  47 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  48 # so the compatibility version is used there too.
  49 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  50     # Provide add-zsh-hook which was added in 4.3.4.
  51     fpath=(~/.zsh/functions/compatibility $fpath)
  52
  53     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  54     function precmd() {
  55         for function in $precmd_functions; do
  56             $function $@
  57         done
  58     }
  59     function preexec() {
  60         for function in $preexec_functions; do
  61             $function $@
  62         done
  63     }
  64 fi
  65
  66 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  67 autoload -Uz add-zsh-hook
  68
  69
  70 # HISTORY SETTINGS
  71
  72 # Use history and store it in ~/.zsh/history.
  73 HISTSIZE=5000
  74 SAVEHIST=5000
  75 HISTFILE=~/.zsh/history
  76 # Append to the history file instead of overwriting it and do it immediately
  77 # when a command is executed.
  78 setopt appendhistory
  79 setopt incappendhistory
  80 # If the same command is run multiple times store it only once in the history.
  81 setopt histignoredups
  82 # Vim like completions of previous executed commands.
  83 bindkey "^P" history-beginning-search-backward
  84 bindkey "^N" history-beginning-search-forward
  85
  86
  87 # PROMPT SETTINGS
  88
  89 # Use colorized output, necessary for prompts and completions.
  90 autoload -U colors && colors
  91
  92 # Set the default prompt. The current host and working directory is displayed,
  93 # the exit code of the last command if it wasn't 0, the number of running jobs
  94 # if not 0 and a + if this shell is running inside another shell.
  95 # The prompt is in green and blue to make easily detectable, the error exit
  96 # code in red and bold and the job count in yellow.
  97 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  98 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  99 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 100 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 101
 102 # VCS_Info was added in 4.3.9.
 103 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 104     # Allow substitutions and expansions in the prompt, necessary for
 105     # vcs_info.
 106     setopt promptsubst
 107     # Load vcs_info to display information about version control repositories.
 108     autoload -Uz vcs_info
 109     # Only look for git and mercurial repositories; the only I use.
 110     zstyle ':vcs_info:*' enable git hg
 111     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 112     # is displayed. If there is an special action going on (merge, rebase)
 113     # it's also displayed (red).
 114     zstyle ':vcs_info:*' formats \
 115     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 116 %{${fg[blue]}%}%s%{${fg[default]}%})"
 117     zstyle ':vcs_info:*' actionformats \
 118     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 119 %{${fg[red]}%}%a%{${fg[default]}%}:\
 120 %{${fg[blue]}%}%s%{${fg[default]}%})"
 121     # Call vcs_info as precmd before every prompt.
 122     prompt_precmd() {
 123         vcs_info
 124     }
 125     add-zsh-hook precmd prompt_precmd
 126
 127     # Display the vcs information in the right prompt.
 128     RPROMPT='${vcs_info_msg_0_}'
 129 fi
 130
 131 # When screen or xterm is used set the name of the window to the currently
 132 # running program.
 133 #
 134 # When a program is started preexec() sets the window's name to it; when it
 135 # stops precmd() resets the windows' name to 'zsh'.
 136 #
 137 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 138 # and stumpwm is used (it's tested if stumpish is available) then the window
 139 # title is also set in stumpwm using stumpish.
 140 #
 141 # If a command is run with sudo or if the shell is running as root then a ! is
 142 # added at the beginning of the command to make this clear. If a command is
 143 # running on a different computer with ssh a @ is added at the beginning.
 144 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 145     # Set to a non empty value to reset the window name in the next precmd()
 146     # call.
 147     window_reset=yes
 148     # Set to a non empty value when the stump window manager is available.
 149     which stumpwm &> /dev/null
 150     if [[ $? -eq 0 ]]; then
 151         window_stumpwm=yes
 152     fi
 153     # Set to a non empty value when the shell is running as root.
 154     if [[ $(id -u) -eq 0 ]]; then
 155         window_root=yes
 156     fi
 157
 158     window_preexec() {
 159         # Get the program name with its arguments.
 160         local program_name=$1
 161
 162         # When sudo is used use real program name instead, but with an
 163         # exclamation mark at the beginning.
 164         local program_sudo=
 165         if [[ $program_name == sudo* ]]; then
 166             program_name=${program_name#sudo }
 167             program_sudo=yes
 168         fi
 169         # Remove all arguments from the program name.
 170         program_name=${program_name%% *}
 171
 172         # Ignore often used commands which are only running for a very short
 173         # time. This prevents a "blinking" name when it's changed to "cd" for
 174         # example and then some milliseconds later back to "zsh".
 175         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 176
 177         # Change my shortcuts so the real name of the program is displayed.
 178         case $program_name in
 179             e)
 180                 program_name=elinks
 181                 ;;
 182             g)
 183                 program_name=git
 184                 ;;
 185             m)
 186                 program_name=mutt
 187                 ;;
 188             v|vi)
 189                 program_name=vim
 190                 ;;
 191         esac
 192
 193         # Add an exclamation mark at the beginning if running with sudo or if
 194         # running zsh as root.
 195         if [[ $program_sudo == yes || $window_root == yes ]]; then
 196             program_name=!$program_name
 197         fi
 198
 199         # Add an at mark at the beginning if running ssh on a different
 200         # computer.
 201         if [[ -n $SSH_CONNECTION ]]; then
 202             program_name="@$program_name"
 203         fi
 204
 205         # Set the window name to the currently running program.
 206         window_title "$program_name"
 207
 208         # Tell precmd() to reset the window name when the program stops.
 209         window_reset=yes
 210     }
 211
 212     window_precmd() {
 213         # Abort if no window name reset is necessary.
 214         [[ -z $window_reset ]] && return
 215
 216         # Reset the window name to 'zsh'.
 217         if [[ -n $SSH_CONNECTION ]]; then
 218             window_title "@zsh"
 219         elif [[ $window_root == yes ]]; then
 220             window_title "!zsh"
 221         else
 222             window_title "zsh"
 223         fi
 224
 225         # Just reset the name, so no screen reset necessary for the moment.
 226         window_reset=
 227     }
 228
 229     # Sets the window title. Works with screen and xterm.
 230     window_title() {
 231         if [[ $TERM == screen* ]]; then
 232             print -n "\ek$1\e\\"
 233
 234             # Update window name in stumpwm if running screen in X11 and when
 235             # stumpwm is used.
 236             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 237                 echo "$1" | stumpish -e "title" > /dev/null
 238             fi
 239
 240         elif [[ $TERM == xterm* ]]; then
 241             print -n "\e]2;$1\e\\"
 242         fi
 243     }
 244
 245     # Add the preexec() and precmd() hooks.
 246     add-zsh-hook preexec window_preexec
 247     add-zsh-hook precmd window_precmd
 248 fi
 249
 250
 251 # COMPLETION SETTINGS
 252
 253 # Load the complist module which provides additions to completion lists
 254 # (coloring, scrollable).
 255 zmodload zsh/complist
 256 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 257 # cluttering of ~/.
 258 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 259
 260 # Use cache to speed up completions.
 261 zstyle ':completion:*' use-cache on
 262 zstyle ':completion:*' cache-path ~/.zsh/cache
 263
 264 # Complete arguments and fix spelling mistakes when possible.
 265 zstyle ':completion:*' completer _complete _match _correct _approximate
 266
 267 # Make sure the list of possible completions is displayed after pressing <TAB>
 268 # the first time.
 269 setopt nolistambiguous
 270 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 271 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 272 bindkey "^I" expand-or-complete-prefix
 273 # Try uppercase if the currently typed string doesn't match. This allows
 274 # typing in lowercase most of the time and completion fixes the case.
 275 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 276
 277 # Use ls like colors for completions.
 278 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 279
 280 # Make completion lists scrollable so "do you wish to see all n possibilities"
 281 # is no longer displayed.
 282 zstyle ':completion:*' list-prompt '%p'
 283 # Display group name (like 'external command', 'alias', etc.) when there are
 284 # multiple matches in bold.
 285 zstyle ':completion:*' format '    %B%d%b:'
 286 # Display different types of matches separately.
 287 zstyle ':completion:*' group-name ''
 288
 289 # Ignore completion functions.
 290 zstyle ':completion:*:functions' ignored-patterns '_*'
 291 # Ignore parent directory.
 292 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 293 # When unsetting variables make sure every variable name is only suggested
 294 # once.
 295 zstyle ':completion:*:unset:*' ignore-line yes
 296 # When working with Mercurial and Git don't complete the same file multiple
 297 # times. Very useful when completing file names.
 298 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 299
 300
 301 # CUSTOM ALIASES AND FUNCTIONS
 302
 303 # Make sure aliases are expanded when using sudo.
 304 alias sudo='sudo '
 305
 306 # Simplify calls to less, automatically redirects all output.
 307 alias -g L='2>&1 | less'
 308 # Simplify calls to colordiff, output is also piped through less.
 309 alias -g D='2>&1 | colordiff L'
 310 # Simplify calls to grep.
 311 alias -g G='| grep'
 312
 313 # Automatically use unified diffs.
 314 alias diff='diff -u'
 315
 316 # Display all files and use human readable sizes.
 317 alias du='du -sh'
 318
 319 # Use human readable sizes.
 320 alias df='df -h'
 321
 322 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 323 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 324     alias vim='vim -p'
 325 fi
 326
 327 # Shortcuts for often used programs.
 328 alias e='elinks'
 329 alias g='git'
 330 alias m='mutt'
 331 alias v='vim'
 332 alias vi='vim'
 333
 334 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 335 # shell.
 336 alias :q='echo "This is not Vim!" >&2'
 337
 338 # Edit the mercurial patch queue series file for the current mercurial
 339 # repository in Vim. Also change Vim's pwd to the patches directory so other
 340 # patches can easily be opened.
 341 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 342
 343 # Make going up directories simple.
 344 alias -g ...='../..'
 345 alias -g ....='../../..'
 346 alias -g .....='../../../..'
 347
 348 # Improved ls which displays the files in columns (-C), visualizes
 349 # directories, links and other special files (-F) and pages everything through
 350 # less (L).
 351 #
 352 # If available use GNU ls with colorized output. If it isn't available use
 353 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 354 # pager.
 355 ls --color &> /dev/null
 356 if [[ $? -eq 0 ]]; then
 357     alias ls='ls --color'
 358 else
 359     alias ls='CLICOLOR_FORCE=1 ls -G'
 360 fi
 361 # Main ls function.
 362 function ls() {
 363     command ls -C -F $* L
 364 }
 365 # Helper function to list all files.
 366 function la() {
 367     ls -a $*
 368 }
 369 # Helper function to list all files in list format with access rights, etc.
 370 function ll() {
 371     la -l $*
 372 }
 373
 374 # If ^C is pressed while typing a command, add it to the history so it can be
 375 # easily retrieved later and then abort like ^C normally does. This is useful
 376 # when I want to abort an command to do something in between and then finish
 377 # typing the command.
 378 TRAPINT() {
 379     # Store the current buffer in the history.
 380     zle && print -s $BUFFER
 381
 382     # Return the default exit code so zsh aborts the current command.
 383     return $1
 384 }
 385
 386 # Display TODOs stored in ~/.todo if this file exists.
 387 todo() {
 388     if [[ -f ~/.todo ]]; then
 389         cat ~/.todo | $PAGER
 390     fi
 391 }
 392
 393 # Colorize stderr. Very useful when looking for errors. Thanks to
 394 # http://gentoo-wiki.com/wiki/Zsh
 395 exec 2>>(while read line; do
 396     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 397
 398
 399 # RUN COMMANDS
 400
 401 # If not already in screen reattach to a running session or create a new one.
 402 #
 403 # screen* is necessary as `screen` uses screen.linux for example for a linux
 404 # console which would otherwise cause an infinite loop.
 405 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 406     # Create a new session if none is running.
 407     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 408         screen
 409     # Reattach to a running session.
 410     else
 411         screen -r
 412     fi
 413 fi
 414
 415
 416 # Load rc file for current OS.
 417 source_config ~/.zsh os rc $(uname) nolocal
 418 # Load rc file for current hostname (first part before a dot) or rc.local.
 419 source_config ~/.zsh host rc ${$(hostname)//.*/}
 420
 421 source_debug "finished sourcing ~/.zsh/rc"
 422
 423 # vim: ft=zsh