zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40
  41 # FUNCTION SETTINGS
  42
  43 # Make sure every entry in $fpath is unique.
  44 typeset -U fpath
  45 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  46 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  47 if [[ -d ~/.zsh/functions/completion ]]; then
  48     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  49 fi
  50 # Set correct fpath to allow loading my functions (including completion
  51 # functions).
  52 fpath=(~/.zsh/functions $fpath)
  53 # Autoload my functions (except completion functions and hidden files). Thanks
  54 # to caphuso from the Zsh example files for this idea.
  55 if [[ -d ~/.zsh/functions ]]; then
  56     autoload ${fpath[1]}/^_*(^/:t)
  57 fi
  58
  59 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  60 # the moment only precmd(), preexec() and chpwd() are simulated.
  61 #
  62 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  63 # so the compatibility version is used there too.
  64 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  65     # Provide add-zsh-hook which was added in 4.3.4.
  66     fpath=(~/.zsh/functions/compatibility $fpath)
  67
  68     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  69     # arrays.
  70     function precmd() {
  71         for function in $precmd_functions; do
  72             $function $@
  73         done
  74     }
  75     function preexec() {
  76         for function in $preexec_functions; do
  77             $function $@
  78         done
  79     }
  80     function chpwd() {
  81         for function in $chpwd_functions; do
  82             $function $@
  83         done
  84     }
  85 fi
  86
  87 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  88 autoload -Uz add-zsh-hook
  89
  90 # Load zmv (zsh move) which is powerful to rename files.
  91 autoload zmv
  92
  93
  94 # HISTORY SETTINGS
  95
  96 # Use history and store it in ~/.zsh/history.
  97 HISTSIZE=50000
  98 SAVEHIST=50000
  99 HISTFILE=~/.zsh/history
 100 # Append to the history file instead of overwriting it and do it immediately
 101 # when a command is executed.
 102 setopt appendhistory
 103 setopt incappendhistory
 104 # If the same command is run multiple times store it only once in the history.
 105 setopt histignoredups
 106 # Vim like completions of previous executed commands (also enter Vi-mode). If
 107 # called at the beginning it just recalls old commands (like cursor up), if
 108 # called after typing something, only lines starting with the typed are
 109 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 110 # on Freenode (2010-01-17 12:47) for the information how to a use function
 111 # with bindkey.
 112 zle -N my-vi-history-beginning-search-backward
 113 my-vi-history-beginning-search-backward() {
 114     local not_at_beginning_of_line
 115     if [[ $CURSOR -ne 0 ]]; then
 116         not_at_beginning_of_line=yes
 117     fi
 118
 119     zle history-beginning-search-backward
 120
 121     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 122     # this counters it).
 123     zle vi-cmd-mode
 124     if [[ -n $not_at_beginning_of_line ]]; then
 125         zle vi-forward-char
 126     fi
 127 }
 128 bindkey '^P' my-vi-history-beginning-search-backward
 129 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 130 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 131 # after calling ^P.
 132 bindkey -a '^N' history-beginning-search-forward
 133
 134
 135 # PROMPT SETTINGS
 136
 137 # Use colorized output, necessary for prompts and completions.
 138 autoload -U colors && colors
 139
 140 # Some shortcuts for colors.
 141 local red="%{${fg[red]}%}"
 142 local blue="%{${fg[blue]}%}"
 143 local green="%{${fg[green]}%}"
 144 local yellow="%{${fg[yellow]}%}"
 145 local default="%{${fg[default]}%}"
 146
 147 # Set the default prompt. The current host and working directory is displayed,
 148 # the exit code of the last command if it wasn't 0, the number of running jobs
 149 # if not 0.
 150 #
 151 # The prompt is in green and blue to make easily detectable, the error exit
 152 # code in red and bold and the job count in yellow.
 153 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 154 %(1j.$yellow%j$default.)%# \
 155 %(?..($red%B%?%b$default%) )"
 156
 157 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 158 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 159 # symbolic link to current checkout of Zsh's sources).
 160 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 161       -d ~/.zsh/functions/vcs_info ]]; then
 162     # Update fpath to allow loading the vcs_info functions.
 163     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 164        fpath=(~/.zsh/functions/vcs_info/
 165               ~/.zsh/functions/vcs_info/Backends
 166               $fpath)
 167     fi
 168
 169     # Allow substitutions and expansions in the prompt, necessary for
 170     # vcs_info.
 171     setopt promptsubst
 172     # Load vcs_info to display information about version control repositories.
 173     autoload -Uz vcs_info
 174     # Only look for git and mercurial repositories; the only I use.
 175     zstyle ':vcs_info:*' enable git hg
 176     # Check the repository for changes so they can be used in %u/%c (see
 177     # below). This comes with a speed penalty for bigger repositories.
 178     zstyle ':vcs_info:*' check-for-changes true
 179
 180     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 181     # is displayed. If there is an special action going on (merge, rebase)
 182     # it's also displayed (red). Also display if there are unstaged or staged
 183     # (%u/%c) changes.
 184     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 185           -d ~/.zsh/functions/vcs_info ]]; then
 186         zstyle ':vcs_info:*' formats \
 187             "($green%b%u%c$default:$blue%s$default)"
 188         zstyle ':vcs_info:*' actionformats \
 189             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 190     else
 191         # In older versions %u and %c are not defined yet and are not
 192         # correctly expanded.
 193         zstyle ':vcs_info:*' formats \
 194             "($green%b$default:$blue%s$default)"
 195         zstyle ':vcs_info:*' actionformats \
 196             "($green%b$default/$red%a$default:$blue%s$default)"
 197     fi
 198     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 199     # changes are detected in the repository; check-for-changes must be set to
 200     # true for this to work. Thanks to Bart Trojanowski
 201     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 202     # (2010-03-11 00:20).
 203     zstyle ':vcs_info:*' unstagedstr '¹'
 204     zstyle ':vcs_info:*' stagedstr   '²'
 205
 206     # Call vcs_info as precmd before every prompt.
 207     prompt_precmd() {
 208         vcs_info
 209     }
 210     add-zsh-hook precmd prompt_precmd
 211
 212     # Display the VCS information in the right prompt.
 213     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 214         RPROMPT='${vcs_info_msg_0_}'
 215     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 216     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 217     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 218     else
 219         RPROMPT='${vcs_info_msg_0_:- }'
 220     fi
 221 fi
 222
 223 unset red blue green yellow default
 224
 225 # When screen, xterm or rxvt is used set the name of the window to the
 226 # currently running program.
 227 #
 228 # When a program is started preexec() sets the window's name to it; when it
 229 # stops precmd() resets the window's name to 'zsh'.
 230 #
 231 # It works with screen, xterm and rxvt.
 232 #
 233 # If a command is run with sudo or if the shell is running as root then a ! is
 234 # added at the beginning of the command to make this clear. If a command is
 235 # running on a different computer with ssh a @ is added at the beginning. If
 236 # screen is running on the remote machine instead of @screen @:hostname
 237 # (hostname replaced by the machine's hostname) is displayed. This only works
 238 # if the .zshrc on the server also uses this command.
 239 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 240     # Is set to a non empty value to reset the window name in the next
 241     # precmd() call.
 242     window_reset=yes
 243     # Is set to a non empty value when the shell is running as root.
 244     if [[ $(id -u) -eq 0 ]]; then
 245         window_root=yes
 246     fi
 247
 248     window_preexec() {
 249         # Get the program name with its arguments.
 250         local program_name=$1
 251
 252         # When sudo is used use real program name instead, but with an
 253         # exclamation mark at the beginning (handled below).
 254         local program_sudo=
 255         if [[ $program_name == sudo* ]]; then
 256             program_name=${program_name#sudo }
 257             program_sudo=yes
 258         fi
 259         # Remove all arguments from the program name.
 260         program_name=${program_name%% *}
 261
 262         # Ignore often used commands which are only running for a very short
 263         # time. This prevents a "blinking" name when it's changed to "cd" for
 264         # example and then some milliseconds later back to "zsh".
 265         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 266
 267         # Change my shortcuts so the real name of the program is displayed.
 268         case $program_name in
 269             e)
 270                 program_name=elinks
 271                 ;;
 272             g)
 273                 program_name=git
 274                 ;;
 275             m)
 276                 program_name=mutt
 277                 ;;
 278             v|vi)
 279                 program_name=vim
 280                 ;;
 281         esac
 282
 283         # Add an exclamation mark at the beginning if running with sudo or if
 284         # running zsh as root.
 285         if [[ -n $program_sudo || -n $window_root ]]; then
 286             program_name=!$program_name
 287         fi
 288
 289         # Add an at mark at the beginning if running through ssh on a
 290         # different computer.
 291         if [[ -n $SSH_CONNECTION ]]; then
 292             program_name="@$program_name"
 293
 294             # If screen is running in SSH then display "@:hostname" as title
 295             # in the term/outer screen.
 296             if [[ $program_name == @screen ]]; then
 297                 program_name="@:${$(hostname)//.*/}"
 298             fi
 299         fi
 300
 301         # Set the window name to the currently running program.
 302         window_title "$program_name"
 303
 304         # Tell precmd() to reset the window name when the program stops.
 305         window_reset=yes
 306     }
 307
 308     window_precmd() {
 309         # Abort if no window name reset is necessary.
 310         [[ -z $window_reset ]] && return
 311
 312         # Reset the window name to 'zsh'.
 313         local name=zsh
 314         # If the function was called with an argument then reset the window
 315         # name to '.zsh' (used by clear alias).
 316         if [[ -n $1 ]]; then
 317             name=.zsh
 318         fi
 319
 320         # Prepend prefixes like in window_preexec().
 321         if [[ -n $SSH_CONNECTION ]]; then
 322             window_title "@$name"
 323         elif [[ -n $window_root ]]; then
 324             window_title "!$name"
 325         else
 326             window_title $name
 327         fi
 328
 329         # Just reset the name, so no screen reset necessary for the moment.
 330         window_reset=
 331     }
 332
 333     # Sets the window title. Works with screen, xterm and rxvt.
 334     if [[ $TERM == screen* ]]; then
 335         window_title() {
 336             print -n "\ek$1\e\\"
 337         }
 338     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 339         window_title() {
 340             print -n "\e]2;$1\e\\"
 341         }
 342     fi
 343
 344     # Add the preexec() and precmd() hooks.
 345     add-zsh-hook preexec window_preexec
 346     add-zsh-hook precmd window_precmd
 347 fi
 348
 349
 350 # COMPLETION SETTINGS
 351
 352 # Load the complist module which provides additions to completion lists
 353 # (coloring, scrollable).
 354 zmodload zsh/complist
 355 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 356 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 357 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 358 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 359
 360 # Use cache to speed up completions.
 361 zstyle ':completion:*' use-cache on
 362 zstyle ':completion:*' cache-path ~/.zsh/cache
 363
 364 # Complete arguments and fix spelling mistakes when possible.
 365 zstyle ':completion:*' completer _complete _match _correct _approximate
 366
 367 # Make sure the list of possible completions is displayed after pressing <TAB>
 368 # the first time.
 369 setopt nolistambiguous
 370 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 371 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 372 bindkey '^I' expand-or-complete-prefix
 373 # Try uppercase if the currently typed string doesn't match. This allows
 374 # typing in lowercase most of the time and completion fixes the case.
 375 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 376
 377 # Use ls like colors for completions.
 378 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 379
 380 # Make completion lists scrollable so "do you wish to see all n possibilities"
 381 # is no longer displayed.
 382 zstyle ':completion:*' list-prompt '%p'
 383 # Display group name (like 'external command', 'alias', etc.) when there are
 384 # multiple matches in bold.
 385 zstyle ':completion:*' format '    %B%d%b:'
 386 # Display different types of matches separately.
 387 zstyle ':completion:*' group-name ''
 388
 389 # Ignore completion functions.
 390 zstyle ':completion:*:functions' ignored-patterns '_*'
 391 # Ignore parent directory.
 392 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 393 # When unsetting variables make sure every variable name is only suggested
 394 # once.
 395 zstyle ':completion:*:unset:*' ignore-line yes
 396 # When working with Mercurial and Git don't complete the same file multiple
 397 # times. Very useful when completing file names.
 398 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 399
 400
 401 # CUSTOM ALIASES AND FUNCTIONS
 402
 403 # If ^C is pressed while typing a command, add it to the history so it can be
 404 # easily retrieved later and then abort like ^C normally does. This is useful
 405 # when I want to abort an command to do something in between and then finish
 406 # typing the command.
 407 #
 408 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 409 # starting with - don't cause errors.
 410 TRAPINT() {
 411     # Store the current buffer in the history.
 412     zle && print -s -- $BUFFER
 413
 414     # Return the default exit code so Zsh aborts the current command.
 415     return $1
 416 }
 417
 418 # Colorize stderr. Very useful when looking for errors. Thanks to
 419 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 420 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 421 # perfect and doesn't work with su and git for example, but it can handle most
 422 # interactive output quite well (even with no trailing new line) and in those
 423 # cases the E alias can be used as workaround.
 424 exec 2>>(while read -r -k -u 0 line; do
 425     printf '\e[91m%s\e[0m' "$line";
 426     print -n $'\0';
 427 done &)
 428
 429 # Load aliases and similar functions also used by other shells.
 430 if [[ -f ~/.shell/aliases ]]; then
 431     . ~/.shell/aliases
 432 fi
 433
 434 # Make sure aliases are expanded when using sudo.
 435 alias sudo='sudo '
 436
 437 # Global aliases for often used commands in the command line.
 438 alias -g E='2>&1'
 439 alias -g L='E | less'
 440 alias -g D='E | colordiff L'
 441 alias -g G='| grep'
 442 alias -g S='| sort'
 443 alias -g U='| uniq'
 444 alias -g H='| head'
 445 alias -g T='| tail'
 446
 447 # Make going up directories simple.
 448 alias -g ...='../..'
 449 alias -g ....='../../..'
 450 alias -g .....='../../../..'
 451
 452 # If the window naming feature is used (see above) then use ".zsh" (leading
 453 # dot) as title name after running clear so it's clear to me that the window
 454 # is empty. I open so much windows that I don't know in which I have something
 455 # important. This helps me to remember which windows are empty (I run clear
 456 # after I finished my work in a window).
 457 if [[ -n $window_reset ]]; then
 458     alias clear='clear; window_reset=yes; window_precmd reset'
 459 fi
 460
 461 # Display all branches (except stash) in gitk but only 200 commits as this is
 462 # much faster. Also put in the background and disown. Thanks to sitaram in
 463 # #git on Freenode (2009-04-20 15:51).
 464 gitk() {
 465     command gitk \
 466         --max-count=200 \
 467         $(git rev-parse --symbolic-full-name --remotes --branches) \
 468         $@ &
 469     disown %command
 470 }
 471 # Same for tig (except the disown part as it's no GUI program).
 472 tig() {
 473     command tig \
 474         --max-count=200 \
 475         $(git rev-parse --symbolic-full-name --remotes --branches) \
 476         $@
 477 }
 478
 479
 480 # OS SPECIFIC SETTINGS
 481
 482 if [[ $(uname) == Linux ]]; then
 483     # Settings when creating Debian packages.
 484     DEBEMAIL=simon@ruderich.org
 485     export DEBEMAIL
 486     DEBFULLNAME='Simon Ruderich'
 487     export DEBFULLNAME
 488
 489 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 490     # Store the current clipboard in CLIPBOARD before every command so it can
 491     # be used in commands.
 492     os_darwin_preexec() {
 493         export CLIPBOARD="$(pbpaste)"
 494     }
 495     # Add the function as preexec hook.
 496     add-zsh-hook preexec os_darwin_preexec
 497
 498     # Initialize CLIPBOARD so it's available for completion directly after
 499     # startup.
 500     CLIPBOARD=""
 501     export CLIPBOARD
 502
 503     # Fetch current URL in clipboard with wget.
 504     alias wnc='wget --no-proxy $CLIPBOARD'
 505 fi
 506
 507
 508 # LOAD ADDITIONAL CONFIGURATION FILES
 509
 510 # Load rc file for current hostname (first part before a dot) or rc.local.
 511 source_config ~/.zsh host rc ${$(hostname)//.*/}
 512
 513
 514 # RUN COMMANDS
 515
 516 # If not already in screen reattach to a running session or create a new one.
 517 #
 518 # screen* is necessary as `screen` uses screen.linux for example for a linux
 519 # console which would otherwise cause an infinite loop.
 520 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 521     # Get running detached sessions.
 522     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 523     # Create a new session if none is running.
 524     if [[ -z $session ]]; then
 525         screen
 526     # Reattach to a running session.
 527     else
 528         screen -r $session
 529     fi
 530 fi
 531
 532
 533 source_debug "finished sourcing ~/.zsh/rc"
 534
 535 # vim: ft=zsh