zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Set correct fpath to allow loading my functions (including completion
  36 # functions).
  37 fpath=(~/.zsh/functions $fpath)
  38 # Autoload my functions (except completion functions and hidden files). Thanks
  39 # to caphuso from the Zsh example files for this idea.
  40 autoload ${fpath[1]}/^_*(^/:t)
  41
  42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  43 # the moment only precmd() and preexec() are simulated.
  44 #
  45 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  46 # so the compatibility version is used there too.
  47 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  48     # Provide add-zsh-hook which was added in 4.3.4.
  49     fpath=(~/.zsh/functions/compatibility $fpath)
  50
  51     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  52     function precmd() {
  53         for function in $precmd_functions; do
  54             $function $@
  55         done
  56     }
  57     function preexec() {
  58         for function in $preexec_functions; do
  59             $function $@
  60         done
  61     }
  62 fi
  63
  64 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  65 autoload -Uz add-zsh-hook
  66
  67
  68 # HISTORY SETTINGS
  69
  70 # Use history and store it in ~/.zsh/history.
  71 HISTSIZE=5000
  72 SAVEHIST=5000
  73 HISTFILE=~/.zsh/history
  74 # Append to the history file instead of overwriting it and do it immediately
  75 # when a command is executed.
  76 setopt appendhistory
  77 setopt incappendhistory
  78 # If the same command is run multiple times store it only once in the history.
  79 setopt histignoredups
  80 # Vim like completions of previous executed commands.
  81 bindkey "^P" history-beginning-search-backward
  82 bindkey "^N" history-beginning-search-forward
  83
  84
  85 # PROMPT SETTINGS
  86
  87 # Use colorized output, necessary for prompts and completions.
  88 autoload -U colors && colors
  89
  90 # Set the default prompt. The current host and working directory is displayed,
  91 # the exit code of the last command if it wasn't 0, the number of running jobs
  92 # if not 0 and a + if this shell is running inside another shell.
  93 # The prompt is in green and blue to make easily detectable, the error exit
  94 # code in red and bold and the job count in yellow.
  95 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  96 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  97 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  98 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  99
 100 # VCS_Info was added in 4.3.9.
 101 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 102     # Allow substitutions and expansions in the prompt, necessary for
 103     # vcs_info.
 104     setopt promptsubst
 105     # Load vcs_info to display information about version control repositories.
 106     autoload -Uz vcs_info
 107     # Only look for git and mercurial repositories; the only I use.
 108     zstyle ':vcs_info:*' enable git hg
 109     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 110     # is displayed. If there is an special action going on (merge, rebase)
 111     # it's also displayed (red).
 112     zstyle ':vcs_info:*' formats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 114 %{${fg[blue]}%}%s%{${fg[default]}%})"
 115     zstyle ':vcs_info:*' actionformats \
 116     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 117 %{${fg[red]}%}%a%{${fg[default]}%}:\
 118 %{${fg[blue]}%}%s%{${fg[default]}%})"
 119     # Call vcs_info as precmd before every prompt.
 120     prompt_precmd() {
 121         vcs_info
 122     }
 123     add-zsh-hook precmd prompt_precmd
 124
 125     # Display the vcs information in the right prompt.
 126     RPROMPT='${vcs_info_msg_0_}'
 127 fi
 128
 129 # When screen or xterm is used set the name of the window to the currently
 130 # running program.
 131 #
 132 # When a program is started preexec() sets the window's name to it; when it
 133 # stops precmd() resets the windows' name to 'zsh'.
 134 #
 135 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 136 # and stumpwm is used (it's tested if stumpish is available) then the window
 137 # title is also set in stumpwm using stumpish.
 138 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 139     # Set to a non empty value to reset the window name in the next precmd()
 140     # call.
 141     window_reset=yes
 142     # Set to a non empty value when the stump window manager is available.
 143     which stumpwm &> /dev/null
 144     if [[ $? -eq 0 ]]; then
 145         window_stumpwm=yes
 146     fi
 147
 148     window_preexec() {
 149         # Get the program name with its arguments.
 150         local program_name=$1
 151         # When sudo is used use real program name instead, but with an
 152         # exclamation mark at the beginning.
 153         if [[ $program_name == sudo* ]]; then
 154             program_name=!${program_name#sudo }
 155         fi
 156         # Remove all arguments from the program name.
 157         program_name=${program_name%% *}
 158
 159         # Ignore often used commands which are only running for a very short
 160         # time. This prevents a "blinking" name when it's changed to "cd" for
 161         # example and then some milliseconds later back to "zsh".
 162         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 163
 164         # Change my shortcuts so the real name of the program is displayed.
 165         case $program_name in
 166             e)
 167                 program_name=elinks
 168                 ;;
 169             g)
 170                 program_name=git
 171                 ;;
 172             m)
 173                 program_name=mutt
 174                 ;;
 175             v|vi)
 176                 program_name=vim
 177                 ;;
 178         esac
 179
 180         # Set the window name to the currently running program.
 181         window_title "$program_name"
 182
 183         # Tell precmd() to reset the window name when the program stops.
 184         window_reset=yes
 185     }
 186
 187     window_precmd() {
 188         # Abort if no window name reset is necessary.
 189         [[ -z $window_reset ]] && return
 190
 191         # Reset the window name to 'zsh'.
 192         window_title "zsh"
 193
 194         # Just reset the name, so no screen reset necessary for the moment.
 195         window_reset=
 196     }
 197
 198     # Sets the window title. Works with screen and xterm.
 199     window_title() {
 200         if [[ $TERM == screen* ]]; then
 201             print -n "\ek$1\e\\"
 202
 203             # Update window name in stumpwm if running screen in X11 and when
 204             # stumpwm is used.
 205             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 206                 echo "$1" | stumpish -e "title" > /dev/null
 207             fi
 208
 209         elif [[ $TERM == xterm* ]]; then
 210             print -n "\e]2;$1\e\\"
 211         fi
 212     }
 213
 214     # Add the preexec() and precmd() hooks.
 215     add-zsh-hook preexec window_preexec
 216     add-zsh-hook precmd window_precmd
 217 fi
 218
 219
 220 # COMPLETION SETTINGS
 221
 222 # Load the complist module which provides additions to completion lists
 223 # (coloring, scrollable).
 224 zmodload zsh/complist
 225 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 226 # cluttering of ~/.
 227 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 228
 229 # Use cache to speed up completions.
 230 zstyle ':completion:*' use-cache on
 231 zstyle ':completion:*' cache-path ~/.zsh/cache
 232
 233 # Complete arguments and fix spelling mistakes when possible.
 234 zstyle ':completion:*' completer _complete _match _correct _approximate
 235
 236 # Make sure the list of possible completions is displayed after pressing <TAB>
 237 # the first time.
 238 setopt nolistambiguous
 239 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 240 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 241 bindkey "^I" expand-or-complete-prefix
 242 # Try uppercase if the currently typed string doesn't match. This allows
 243 # typing in lowercase most of the time and completion fixes the case.
 244 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 245
 246 # Use ls like colors for completions.
 247 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 248
 249 # Make completion lists scrollable so "do you wish to see all n possibilities"
 250 # is no longer displayed.
 251 zstyle ':completion:*' list-prompt '%p'
 252 # Display group name (like 'external command', 'alias', etc.) when there are
 253 # multiple matches in bold.
 254 zstyle ':completion:*' format '    %B%d%b:'
 255 # Display different types of matches separately.
 256 zstyle ':completion:*' group-name ''
 257
 258 # Ignore completion functions.
 259 zstyle ':completion:*:functions' ignored-patterns '_*'
 260 # Ignore parent directory.
 261 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 262 # When unsetting variables make sure every variable name is only suggested
 263 # once.
 264 zstyle ':completion:*:unset:*' ignore-line yes
 265 # When working with Mercurial and Git don't complete the same file multiple
 266 # times. Very useful when completing file names.
 267 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 268
 269
 270 # CUSTOM ALIASES AND FUNCTIONS
 271
 272 # Make sure aliases are expanded when using sudo.
 273 alias sudo='sudo '
 274
 275 # Simplify calls to less, automatically redirects all output.
 276 alias -g L='2>&1 | less'
 277 # Simplify calls to colordiff, output is also piped through less.
 278 alias -g D='2>&1 | colordiff L'
 279 # Simplify calls to grep.
 280 alias -g G='| grep'
 281
 282 # Automatically use unified diffs.
 283 alias diff='diff -u'
 284
 285 # Display all files and use human readable sizes.
 286 alias du='du -sh'
 287
 288 # Use human readable sizes.
 289 alias df='df -h'
 290
 291 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 292 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 293     alias vim='vim -p'
 294 fi
 295
 296 # Shortcuts for often used programs.
 297 alias e='elinks'
 298 alias g='git'
 299 alias m='mutt'
 300 alias v='vim'
 301 alias vi='vim'
 302
 303 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 304 # shell.
 305 alias :q='echo "This is not Vim!" >&2'
 306
 307 # Edit the mercurial patch queue series file for the current mercurial
 308 # repository in Vim. Also change Vim's pwd to the patches directory so other
 309 # patches can easily be opened.
 310 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 311
 312 # Make going up directories simple.
 313 alias -g ...='../..'
 314 alias -g ....='../../..'
 315 alias -g .....='../../../..'
 316
 317 # Improved ls which displays the files in columns (-C), visualizes
 318 # directories, links and other special files (-F) and pages everything through
 319 # less (L).
 320 #
 321 # If available use GNU ls with colorized output. If it isn't available use
 322 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 323 # pager.
 324 ls --color &> /dev/null
 325 if [[ $? -eq 0 ]]; then
 326     alias ls='ls --color'
 327 else
 328     alias ls='CLICOLOR_FORCE=1 ls -G'
 329 fi
 330 # Main ls function.
 331 function ls() {
 332     command ls -C -F $* L
 333 }
 334 # Helper function to list all files.
 335 function la() {
 336     ls -a $*
 337 }
 338 # Helper function to list all files in list format with access rights, etc.
 339 function ll() {
 340     la -l $*
 341 }
 342
 343 # If ^C is pressed while typing a command, add it to the history so it can be
 344 # easily retrieved later and then abort like ^C normally does. This is useful
 345 # when I want to abort an command to do something in between and then finish
 346 # typing the command.
 347 TRAPINT() {
 348     # Store the current buffer in the history.
 349     zle && print -s $BUFFER
 350
 351     # Return the default exit code so zsh aborts the current command.
 352     return $1
 353 }
 354
 355 # Display TODOs stored in ~/.todo if this file exists.
 356 todo() {
 357     if [[ -f ~/.todo ]]; then
 358         cat ~/.todo | $PAGER
 359     fi
 360 }
 361
 362 # Colorize stderr. Very useful when looking for errors. Thanks to
 363 # http://gentoo-wiki.com/wiki/Zsh
 364 exec 2>>(while read line; do
 365     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 366
 367
 368 # RUN COMMANDS
 369
 370 # If not already in screen reattach to a running session or create a new one.
 371 #
 372 # screen* is necessary as `screen` uses screen.linux for example for a linux
 373 # console which would otherwise cause an infinite loop.
 374 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 375     # Create a new session if none is running.
 376     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 377         screen
 378     # Reattach to a running session.
 379     else
 380         screen -r
 381     fi
 382 fi
 383
 384
 385 # Load rc file for current OS.
 386 source_config ~/.zsh os rc $(uname) nolocal
 387 # Load rc file for current hostname (first part before a dot) or rc.local.
 388 source_config ~/.zsh host rc ${$(hostname)//.*/}
 389
 390 source_debug "finished sourcing ~/.zsh/rc"
 391
 392 # vim: ft=zsh