zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Make sure every entry in $fpath is unique.
  36 typeset -U fpath
  37 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  38 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  39 if [[ -d ~/.zsh/functions/completion ]]; then
  40     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  41 fi
  42 # Set correct fpath to allow loading my functions (including completion
  43 # functions).
  44 fpath=(~/.zsh/functions $fpath)
  45 # Autoload my functions (except completion functions and hidden files). Thanks
  46 # to caphuso from the Zsh example files for this idea.
  47 autoload ${fpath[1]}/^_*(^/:t)
  48
  49 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  50 # the moment only precmd() and preexec() are simulated.
  51 #
  52 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  53 # so the compatibility version is used there too.
  54 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  55     # Provide add-zsh-hook which was added in 4.3.4.
  56     fpath=(~/.zsh/functions/compatibility $fpath)
  57
  58     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  59     function precmd() {
  60         for function in $precmd_functions; do
  61             $function $@
  62         done
  63     }
  64     function preexec() {
  65         for function in $preexec_functions; do
  66             $function $@
  67         done
  68     }
  69 fi
  70
  71 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  72 autoload -Uz add-zsh-hook
  73
  74
  75 # HISTORY SETTINGS
  76
  77 # Use history and store it in ~/.zsh/history.
  78 HISTSIZE=5000
  79 SAVEHIST=5000
  80 HISTFILE=~/.zsh/history
  81 # Append to the history file instead of overwriting it and do it immediately
  82 # when a command is executed.
  83 setopt appendhistory
  84 setopt incappendhistory
  85 # If the same command is run multiple times store it only once in the history.
  86 setopt histignoredups
  87 # Vim like completions of previous executed commands.
  88 bindkey "^P" history-beginning-search-backward
  89 bindkey "^N" history-beginning-search-forward
  90
  91
  92 # PROMPT SETTINGS
  93
  94 # Use colorized output, necessary for prompts and completions.
  95 autoload -U colors && colors
  96
  97 # Set the default prompt. The current host and working directory is displayed,
  98 # the exit code of the last command if it wasn't 0, the number of running jobs
  99 # if not 0 and a + if this shell is running inside another shell.
 100 # The prompt is in green and blue to make easily detectable, the error exit
 101 # code in red and bold and the job count in yellow.
 102 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 103 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 104 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 105 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 106
 107 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 108 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 109 # symbolic link to current checkout of Zsh's sources).
 110 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 111       -d ~/.zsh/functions/vcs_info ]]; then
 112     # Update fpath to allow loading the VCS_Info functions.
 113     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 114        fpath=(~/.zsh/functions/vcs_info/
 115               ~/.zsh/functions/vcs_info/Backends
 116               $fpath)
 117     fi
 118
 119     # Allow substitutions and expansions in the prompt, necessary for
 120     # vcs_info.
 121     setopt promptsubst
 122     # Load vcs_info to display information about version control repositories.
 123     autoload -Uz vcs_info
 124     # Only look for git and mercurial repositories; the only I use.
 125     zstyle ':vcs_info:*' enable git hg
 126     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 127     # is displayed. If there is an special action going on (merge, rebase)
 128     # it's also displayed (red).
 129     zstyle ':vcs_info:*' formats \
 130     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 131 %{${fg[blue]}%}%s%{${fg[default]}%})"
 132     zstyle ':vcs_info:*' actionformats \
 133     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 134 %{${fg[red]}%}%a%{${fg[default]}%}:\
 135 %{${fg[blue]}%}%s%{${fg[default]}%})"
 136     # Call vcs_info as precmd before every prompt.
 137     prompt_precmd() {
 138         vcs_info
 139     }
 140     add-zsh-hook precmd prompt_precmd
 141
 142     # Display the vcs information in the right prompt.
 143     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 144         RPROMPT='${vcs_info_msg_0_}'
 145     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 146     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 147     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 148     else
 149         RPROMPT='${vcs_info_msg_0_:- }'
 150     fi
 151 fi
 152
 153 # When screen or xterm is used set the name of the window to the currently
 154 # running program.
 155 #
 156 # When a program is started preexec() sets the window's name to it; when it
 157 # stops precmd() resets the windows' name to 'zsh'.
 158 #
 159 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 160 # and stumpwm is used (it's tested if stumpish is available) then the window
 161 # title is also set in stumpwm using stumpish.
 162 #
 163 # If a command is run with sudo or if the shell is running as root then a ! is
 164 # added at the beginning of the command to make this clear. If a command is
 165 # running on a different computer with ssh a @ is added at the beginning.
 166 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 167     # Set to a non empty value to reset the window name in the next precmd()
 168     # call.
 169     window_reset=yes
 170     # Set to a non empty value when the stump window manager is available.
 171     which stumpwm &> /dev/null
 172     if [[ $? -eq 0 ]]; then
 173         window_stumpwm=yes
 174     fi
 175     # Set to a non empty value when the shell is running as root.
 176     if [[ $(id -u) -eq 0 ]]; then
 177         window_root=yes
 178     fi
 179
 180     window_preexec() {
 181         # Get the program name with its arguments.
 182         local program_name=$1
 183
 184         # When sudo is used use real program name instead, but with an
 185         # exclamation mark at the beginning.
 186         local program_sudo=
 187         if [[ $program_name == sudo* ]]; then
 188             program_name=${program_name#sudo }
 189             program_sudo=yes
 190         fi
 191         # Remove all arguments from the program name.
 192         program_name=${program_name%% *}
 193
 194         # Ignore often used commands which are only running for a very short
 195         # time. This prevents a "blinking" name when it's changed to "cd" for
 196         # example and then some milliseconds later back to "zsh".
 197         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 198
 199         # Change my shortcuts so the real name of the program is displayed.
 200         case $program_name in
 201             e)
 202                 program_name=elinks
 203                 ;;
 204             g)
 205                 program_name=git
 206                 ;;
 207             m)
 208                 program_name=mutt
 209                 ;;
 210             v|vi)
 211                 program_name=vim
 212                 ;;
 213         esac
 214
 215         # Add an exclamation mark at the beginning if running with sudo or if
 216         # running zsh as root.
 217         if [[ -n $program_sudo || -n $window_root ]]; then
 218             program_name=!$program_name
 219         fi
 220
 221         # Add an at mark at the beginning if running ssh on a different
 222         # computer.
 223         if [[ -n $SSH_CONNECTION ]]; then
 224             program_name="@$program_name"
 225         fi
 226
 227         # Set the window name to the currently running program.
 228         window_title "$program_name"
 229
 230         # Tell precmd() to reset the window name when the program stops.
 231         window_reset=yes
 232     }
 233
 234     window_precmd() {
 235         # Abort if no window name reset is necessary.
 236         [[ -z $window_reset ]] && return
 237
 238         # Reset the window name to 'zsh'.
 239         if [[ -n $SSH_CONNECTION ]]; then
 240             window_title "@zsh"
 241         elif [[ -n $window_root ]]; then
 242             window_title "!zsh"
 243         else
 244             window_title "zsh"
 245         fi
 246
 247         # Just reset the name, so no screen reset necessary for the moment.
 248         window_reset=
 249     }
 250
 251     # Sets the window title. Works with screen and xterm.
 252     window_title() {
 253         if [[ $TERM == screen* ]]; then
 254             print -n "\ek$1\e\\"
 255
 256             # Update window name in stumpwm if running screen in X11 and when
 257             # stumpwm is used.
 258             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 259                 echo "$1" | stumpish -e "title" > /dev/null
 260             fi
 261
 262         elif [[ $TERM == xterm* ]]; then
 263             print -n "\e]2;$1\e\\"
 264         fi
 265     }
 266
 267     # Add the preexec() and precmd() hooks.
 268     add-zsh-hook preexec window_preexec
 269     add-zsh-hook precmd window_precmd
 270 fi
 271
 272
 273 # COMPLETION SETTINGS
 274
 275 # Load the complist module which provides additions to completion lists
 276 # (coloring, scrollable).
 277 zmodload zsh/complist
 278 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 279 # cluttering of ~/.
 280 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 281
 282 # Use cache to speed up completions.
 283 zstyle ':completion:*' use-cache on
 284 zstyle ':completion:*' cache-path ~/.zsh/cache
 285
 286 # Complete arguments and fix spelling mistakes when possible.
 287 zstyle ':completion:*' completer _complete _match _correct _approximate
 288
 289 # Make sure the list of possible completions is displayed after pressing <TAB>
 290 # the first time.
 291 setopt nolistambiguous
 292 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 293 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 294 bindkey "^I" expand-or-complete-prefix
 295 # Try uppercase if the currently typed string doesn't match. This allows
 296 # typing in lowercase most of the time and completion fixes the case.
 297 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 298
 299 # Use ls like colors for completions.
 300 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 301
 302 # Make completion lists scrollable so "do you wish to see all n possibilities"
 303 # is no longer displayed.
 304 zstyle ':completion:*' list-prompt '%p'
 305 # Display group name (like 'external command', 'alias', etc.) when there are
 306 # multiple matches in bold.
 307 zstyle ':completion:*' format '    %B%d%b:'
 308 # Display different types of matches separately.
 309 zstyle ':completion:*' group-name ''
 310
 311 # Ignore completion functions.
 312 zstyle ':completion:*:functions' ignored-patterns '_*'
 313 # Ignore parent directory.
 314 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 315 # When unsetting variables make sure every variable name is only suggested
 316 # once.
 317 zstyle ':completion:*:unset:*' ignore-line yes
 318 # When working with Mercurial and Git don't complete the same file multiple
 319 # times. Very useful when completing file names.
 320 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 321
 322
 323 # CUSTOM ALIASES AND FUNCTIONS
 324
 325 # Make sure aliases are expanded when using sudo.
 326 alias sudo='sudo '
 327
 328 # Global aliases for often used commands used in the command line.
 329 alias -g E='2>&1'
 330 alias -g L='E | less'
 331 alias -g D='E | colordiff L'
 332 alias -g G='| grep'
 333 alias -g S='| sort'
 334
 335 # Automatically use unified diffs.
 336 alias diff='diff -u'
 337
 338 # Display all files and use human readable sizes.
 339 alias du='du -sh'
 340
 341 # Use human readable sizes.
 342 alias df='df -h'
 343
 344 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 345 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 346     alias vim='vim -p'
 347 fi
 348
 349 # Shortcuts for often used programs.
 350 alias e='elinks'
 351 alias g='git'
 352 alias m='mutt'
 353 alias v='vim'
 354 alias vi='vim'
 355
 356 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 357 # shell.
 358 alias :q='echo "This is not Vim!" >&2'
 359
 360 # Edit the mercurial patch queue series file for the current mercurial
 361 # repository in Vim. Also change Vim's pwd to the patches directory so other
 362 # patches can easily be opened.
 363 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 364
 365 # Make going up directories simple.
 366 alias -g ...='../..'
 367 alias -g ....='../../..'
 368 alias -g .....='../../../..'
 369
 370 # Improved ls which displays the files in columns (-C), visualizes
 371 # directories, links and other special files (-F) and pages everything through
 372 # less (L).
 373 #
 374 # If available use GNU ls with colorized output. If it isn't available use
 375 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 376 # pager.
 377 ls --color &> /dev/null
 378 if [[ $? -eq 0 ]]; then
 379     alias ls='ls --color'
 380 else
 381     alias ls='CLICOLOR_FORCE=1 ls -G'
 382 fi
 383 # Main ls function.
 384 function ls() {
 385     command ls -C -F $* L
 386 }
 387 # Helper function to list all files.
 388 function la() {
 389     ls -a $*
 390 }
 391 # Helper function to list all files in list format with access rights, etc.
 392 function ll() {
 393     la -l $*
 394 }
 395
 396 # If ^C is pressed while typing a command, add it to the history so it can be
 397 # easily retrieved later and then abort like ^C normally does. This is useful
 398 # when I want to abort an command to do something in between and then finish
 399 # typing the command.
 400 TRAPINT() {
 401     # Store the current buffer in the history.
 402     zle && print -s $BUFFER
 403
 404     # Return the default exit code so zsh aborts the current command.
 405     return $1
 406 }
 407
 408 # Colorize stderr. Very useful when looking for errors. Thanks to
 409 # http://gentoo-wiki.com/wiki/Zsh
 410 exec 2>>(while read line; do
 411     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 412
 413
 414 # RUN COMMANDS
 415
 416 # If not already in screen reattach to a running session or create a new one.
 417 #
 418 # screen* is necessary as `screen` uses screen.linux for example for a linux
 419 # console which would otherwise cause an infinite loop.
 420 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 421     # Create a new session if none is running.
 422     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 423         screen
 424     # Reattach to a running session.
 425     else
 426         screen -r
 427     fi
 428 fi
 429
 430
 431 # Load rc file for current OS.
 432 source_config ~/.zsh os rc $(uname) nolocal
 433 # Load rc file for current hostname (first part before a dot) or rc.local.
 434 source_config ~/.zsh host rc ${$(hostname)//.*/}
 435
 436 source_debug "finished sourcing ~/.zsh/rc"
 437
 438 # vim: ft=zsh