zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Set correct fpath to allow loading my functions (including completion
  36 # functions).
  37 fpath=(~/.zsh/functions $fpath)
  38 # Autoload my functions (except completion functions and hidden files). Thanks
  39 # to caphuso from the Zsh example files for this idea.
  40 autoload ${fpath[1]}/^_*(^/:t)
  41
  42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  43 # the moment only precmd() and preexec() are simulated.
  44 if [[ $ZSH_VERSION != (4.3.<4->|4.<4->*|<5->*) ]]; then
  45     # Provide add-zsh-hook which was added in 4.3.4.
  46     fpath=($fpath ~/.zsh/functions/compatibility)
  47
  48     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  49     function precmd() {
  50         for function in $precmd_functions; do
  51             $function $@
  52         done
  53     }
  54     function preexec() {
  55         for function in $preexec_functions; do
  56             $function $@
  57         done
  58     }
  59 fi
  60
  61 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  62 autoload -Uz add-zsh-hook
  63
  64
  65 # HISTORY SETTINGS
  66
  67 # Use history and store it in ~/.zsh/history.
  68 HISTSIZE=5000
  69 SAVEHIST=5000
  70 HISTFILE=~/.zsh/history
  71 # Append to the history file instead of overwriting it and do it immediately
  72 # when a command is executed.
  73 setopt appendhistory
  74 setopt incappendhistory
  75 # If the same command is run multiple times store it only once in the history.
  76 setopt histignoredups
  77 # Vim like completions of previous executed commands.
  78 bindkey "^P" history-beginning-search-backward
  79 bindkey "^N" history-beginning-search-forward
  80
  81
  82 # PROMPT SETTINGS
  83
  84 # Use colorized output, necessary for prompts and completions.
  85 autoload -U colors && colors
  86
  87 # Set the default prompt. The current host and working directory is displayed,
  88 # the exit code of the last command if it wasn't 0, the number of running jobs
  89 # if not 0 and a + if this shell is running inside another shell.
  90 # The prompt is in green and blue to make easily detectable, the error exit
  91 # code in red and bold and the job count in yellow.
  92 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  93 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  94 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  95 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  96
  97 # VCS_Info was added in 4.3.9.
  98 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
  99     # Allow substitutions and expansions in the prompt, necessary for
 100     # vcs_info.
 101     setopt promptsubst
 102     # Load vcs_info to display information about version control repositories.
 103     autoload -Uz vcs_info
 104     # Only look for git and mercurial repositories; the only I use.
 105     zstyle ':vcs_info:*' enable git hg
 106     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 107     # is displayed. If there is an special action going on (merge, rebase)
 108     # it's also displayed (red).
 109     zstyle ':vcs_info:*' formats \
 110     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 111 %{${fg[blue]}%}%s%{${fg[default]}%})"
 112     zstyle ':vcs_info:*' actionformats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 114 %{${fg[red]}%}%a%{${fg[default]}%}:\
 115 %{${fg[blue]}%}%s%{${fg[default]}%})"
 116     # Call vcs_info as precmd before every prompt.
 117     prompt_precmd() {
 118         vcs_info
 119     }
 120     add-zsh-hook precmd prompt_precmd
 121
 122     # Display the vcs information in the right prompt.
 123     RPROMPT='${vcs_info_msg_0_}'
 124 fi
 125
 126 # When screen or xterm is used set the name of the window to the currently
 127 # running program.
 128 #
 129 # When a program is started preexec() sets the window's name to it; when it
 130 # stops precmd() resets the windows' name to 'zsh'.
 131 #
 132 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 133 # and stumpwm is used (it's tested if stumpish is available) then the window
 134 # title is also set in stumpwm using stumpish.
 135 if [[ $TERM == screen || $TERM == xterm* ]]; then
 136     # Set to a non empty value to reset the window name in the next precmd()
 137     # call.
 138     window_reset=yes
 139     # Set to a non empty value when the stump window manager is available.
 140     which stumpwm &> /dev/null
 141     if [[ $? -eq 0 ]]; then
 142         window_stumpwm=yes
 143     fi
 144
 145     window_preexec() {
 146         # Get the program name with its arguments.
 147         local program_name=$1
 148         # When sudo is used use real program name instead, but with an
 149         # exclamation mark at the beginning.
 150         if [[ $program_name == sudo* ]]; then
 151             program_name=!${program_name#sudo }
 152         fi
 153         # Remove all arguments from the program name.
 154         program_name=${program_name%% *}
 155
 156         # Ignore often used commands which are only running for a very short
 157         # time. This prevents a "blinking" name when it's changed to "cd" for
 158         # example and then some milliseconds later back to "zsh".
 159         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 160
 161         # Change my shortcuts so the real name of the program is displayed.
 162         case $program_name in
 163             e)
 164                 program_name=elinks
 165                 ;;
 166             g)
 167                 program_name=git
 168                 ;;
 169             m)
 170                 program_name=mutt
 171                 ;;
 172             v|vi)
 173                 program_name=vim
 174                 ;;
 175         esac
 176
 177         # Set the window name to the currently running program.
 178         window_title "$program_name"
 179
 180         # Tell precmd() to reset the window name when the program stops.
 181         window_reset=yes
 182     }
 183
 184     window_precmd() {
 185         # Abort if no window name reset is necessary.
 186         [[ -z $window_reset ]] && return
 187
 188         # Reset the window name to 'zsh'.
 189         window_title "zsh"
 190
 191         # Just reset the name, so no screen reset necessary for the moment.
 192         window_reset=
 193     }
 194
 195     # Sets the window title. Works with screen and xterm.
 196     window_title() {
 197         if [[ $TERM == screen ]]; then
 198             print -n "\ek$1\e\\"
 199
 200             # Update window name in stumpwm if running screen in X11 and when
 201             # stumpwm is used.
 202             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 203                 echo "$1" | stumpish -e "title" > /dev/null
 204             fi
 205
 206         elif [[ $TERM == xterm* ]]; then
 207             print -n "\e]2;$1\e\\"
 208         fi
 209     }
 210
 211     # Add the preexec() and precmd() hooks.
 212     add-zsh-hook preexec window_preexec
 213     add-zsh-hook precmd window_precmd
 214 fi
 215
 216
 217 # COMPLETION SETTINGS
 218
 219 # Load the complist module which provides additions to completion lists
 220 # (coloring, scrollable).
 221 zmodload zsh/complist
 222 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 223 # cluttering of ~/.
 224 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 225
 226 # Use cache to speed up completions.
 227 zstyle ':completion:*' use-cache on
 228 zstyle ':completion:*' cache-path ~/.zsh/cache
 229
 230 # Make sure the list of possible completions is displayed after pressing <TAB>
 231 # the first time.
 232 setopt nolistambiguous
 233 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 234 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 235 bindkey "^I" expand-or-complete-prefix
 236 # Try uppercase if the currently typed string doesn't match. This allows
 237 # typing in lowercase most of the time and completion fixes the case.
 238 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 239
 240 # Use ls like colors for completions.
 241 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 242
 243 # Make completion lists scrollable so "do you wish to see all n possibilities"
 244 # is no longer displayed.
 245 zstyle ':completion:*' list-prompt '%p'
 246
 247 # Ignore completion functions.
 248 zstyle ':completion:*:functions' ignored-patterns '_*'
 249 # Ignore parent directory.
 250 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 251 # When unsetting variables make sure every variable name is only suggested
 252 # once.
 253 zstyle ':completion:*:unset:*' ignore-line yes
 254 # When working with Mercurial and Git don't complete the same file multiple
 255 # times. Very useful when completing file names.
 256 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 257
 258
 259 # CUSTOM ALIASES AND FUNCTIONS
 260
 261 # Make sure aliases are expanded when using sudo.
 262 alias sudo='sudo '
 263
 264 # Simplify calls to less, automatically redirects all output.
 265 alias -g L='2>&1 | less'
 266 # Simplify calls to colordiff, output is also piped through less.
 267 alias -g D='2>&1 | colordiff L'
 268 # Simplify calls to grep.
 269 alias -g G='| grep'
 270
 271 # Automatically use unified diffs.
 272 alias diff='diff -u'
 273
 274 # Display all files and use human readable sizes.
 275 alias du='du -sh'
 276
 277 # Use human readable sizes.
 278 alias df='df -h'
 279
 280 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 281 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 282     alias vim='vim -p'
 283 fi
 284
 285 # Shortcuts for often used programs.
 286 alias e='elinks'
 287 alias g='git'
 288 alias m='mutt'
 289 alias v='vim'
 290 alias vi='vim'
 291
 292 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 293 # shell.
 294 alias :q='echo "This is not Vim!" >&2'
 295
 296 # Edit the mercurial patch queue series file for the current mercurial
 297 # repository in Vim. Also change Vim's pwd to the patches directory so other
 298 # patches can easily be opened.
 299 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 300
 301 # Make going up directories simple.
 302 alias -g ...='../..'
 303 alias -g ....='../../..'
 304 alias -g .....='../../../..'
 305
 306 # Improved ls which displays the files in columns (-C), visualizes
 307 # directories, links and other special files (-F) and pages everything through
 308 # less (L).
 309 #
 310 # If available use GNU ls with colorized output. If it isn't available use
 311 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 312 # pager.
 313 ls --color &> /dev/null
 314 if [[ $? -eq 0 ]]; then
 315     alias ls='ls --color'
 316 else
 317     alias ls='CLICOLOR_FORCE=1 ls -G'
 318 fi
 319 # Main ls function.
 320 function ls() {
 321     command ls -C -F $* L
 322 }
 323 # Helper function to list all files.
 324 function la() {
 325     ls -a $*
 326 }
 327 # Helper function to list all files in list format with access rights, etc.
 328 function ll() {
 329     la -l $*
 330 }
 331
 332 # If ^C is pressed while typing a command, add it to the history so it can be
 333 # easily retrieved later and then abort like ^C normally does. This is useful
 334 # when I want to abort an command to do something in between and then finish
 335 # typing the command.
 336 TRAPINT() {
 337     # Store the current buffer in the history.
 338     zle && print -s $BUFFER
 339
 340     # Return the default exit code so zsh aborts the current command.
 341     return $1
 342 }
 343
 344 # Display TODOs stored in ~/.todo if this file exists.
 345 todo() {
 346     if [[ -f ~/.todo ]]; then
 347         cat ~/.todo | $PAGER
 348     fi
 349 }
 350
 351 # Colorize stderr. Very useful when looking for errors. Thanks to
 352 # http://gentoo-wiki.com/wiki/Zsh
 353 exec 2>>(while read line; do
 354     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 355
 356
 357 # RUN COMMANDS
 358
 359 # If not already in screen reattach to a running session or create a new one.
 360 if [[ $TERM != 'screen' && $TERM != 'dumb' ]]; then
 361     # Create a new session if none is running.
 362     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 363         screen
 364     # Reattach to a running session.
 365     else
 366         screen -r
 367     fi
 368 fi
 369
 370
 371 # Load rc file for current OS.
 372 source_config ~/.zsh os rc $(uname) nolocal
 373 # Load rc file for current hostname (first part before a dot) or rc.local.
 374 source_config ~/.zsh host rc ${$(hostname)//.*/}
 375
 376 source_debug "finished sourcing ~/.zsh/rc"
 377
 378 # vim: ft=zsh