zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Set correct fpath to allow loading my functions (including completion
  36 # functions).
  37 fpath=(~/.zsh/functions $fpath)
  38 # Autoload my functions (except completion functions and hidden files). Thanks
  39 # to caphuso from the Zsh example files for this idea.
  40 autoload ${fpath[1]}/^_*(^/:t)
  41
  42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  43 # the moment only precmd() and preexec() are simulated.
  44 if [[ $ZSH_VERSION != (4.3.<4->|4.<4->*|<5->*) ]]; then
  45     # Provide add-zsh-hook which was added in 4.3.4.
  46     fpath=($fpath ~/.zsh/functions/compatibility)
  47
  48     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  49     function precmd() {
  50         for function in $precmd_functions; do
  51             $function $@
  52         done
  53     }
  54     function preexec() {
  55         for function in $preexec_functions; do
  56             $function $@
  57         done
  58     }
  59 fi
  60
  61 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  62 autoload -Uz add-zsh-hook
  63
  64
  65 # HISTORY SETTINGS
  66
  67 # Use history and store it in ~/.zsh/history.
  68 HISTSIZE=5000
  69 SAVEHIST=5000
  70 HISTFILE=~/.zsh/history
  71 # Append to the history file instead of overwriting it and do it immediately
  72 # when a command is executed.
  73 setopt appendhistory
  74 setopt incappendhistory
  75 # If the same command is run multiple times store it only once in the history.
  76 setopt histignoredups
  77 # Vim like completions of previous executed commands.
  78 bindkey "^P" history-beginning-search-backward
  79 bindkey "^N" history-beginning-search-forward
  80
  81
  82 # PROMPT SETTINGS
  83
  84 # Use colorized output, necessary for prompts and completions.
  85 autoload -U colors && colors
  86
  87 # Set the default prompt. The current host and working directory is displayed,
  88 # the exit code of the last command if it wasn't 0, the number of running jobs
  89 # if not 0 and a + if this shell is running inside another shell.
  90 # The prompt is in green and blue to make easily detectable, the error exit
  91 # code in red and bold and the job count in yellow.
  92 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  93 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  94 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  95 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  96
  97 # VCS_Info was added in 4.3.9.
  98 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
  99     # Allow substitutions and expansions in the prompt, necessary for
 100     # vcs_info.
 101     setopt promptsubst
 102     # Load vcs_info to display information about version control repositories.
 103     autoload -Uz vcs_info
 104     # Only look for git and mercurial repositories; the only I use.
 105     zstyle ':vcs_info:*' enable git hg
 106     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 107     # is displayed. If there is an special action going on (merge, rebase)
 108     # it's also displayed (red).
 109     zstyle ':vcs_info:*' formats \
 110     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 111 %{${fg[blue]}%}%s%{${fg[default]}%})"
 112     zstyle ':vcs_info:*' actionformats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 114 %{${fg[red]}%}%a%{${fg[default]}%}:\
 115 %{${fg[blue]}%}%s%{${fg[default]}%})"
 116     # Call vcs_info as precmd before every prompt.
 117     prompt_precmd() {
 118         vcs_info
 119     }
 120     add-zsh-hook precmd prompt_precmd
 121
 122     # Display the vcs information in the right prompt.
 123     RPROMPT='${vcs_info_msg_0_}'
 124 fi
 125
 126 # When screen or xterm is used set the name of the window to the currently
 127 # running program.
 128 #
 129 # When a program is started preexec() sets the window's name to it; when it
 130 # stops precmd() resets the windows' name to 'zsh'.
 131 if [[ $TERM == screen || $TERM == xterm* ]]; then
 132     # Set to a non empty value to reset the window name in the next precmd()
 133     # call.
 134     window_reset=yes
 135
 136     window_preexec() {
 137         # Get the program name with its arguments.
 138         local program_name=$1
 139         # When sudo is used use real program name instead, but with an
 140         # exclamation mark at the beginning.
 141         if [[ $program_name == sudo* ]]; then
 142             program_name=!${program_name#sudo }
 143         fi
 144         # Remove all arguments from the program name.
 145         program_name=${program_name%% *}
 146
 147         # Ignore often used commands which are only running for a very short
 148         # time. This prevents a "blinking" name when it's changed to "cd" for
 149         # example and then some milliseconds later back to "zsh".
 150         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 151
 152         # Change my shortcuts so the real name of the program is displayed.
 153         case $program_name in
 154             e)
 155                 program_name=elinks
 156                 ;;
 157             g)
 158                 program_name=git
 159                 ;;
 160             m)
 161                 program_name=mutt
 162                 ;;
 163             v|vi)
 164                 program_name=vim
 165                 ;;
 166         esac
 167
 168         # Set the window name to the currently running program.
 169         window_title "$program_name"
 170
 171         # Tell precmd() to reset the window name when the program stops.
 172         window_reset=yes
 173     }
 174
 175     window_precmd() {
 176         # Abort if no window name reset is necessary.
 177         [[ -z $window_reset ]] && return
 178
 179         # Reset the window name to 'zsh'.
 180         window_title "zsh"
 181
 182         # Just reset the name, so no screen reset necessary for the moment.
 183         window_reset=
 184     }
 185
 186     # Sets the window title. Works with screen and xterm.
 187     window_title() {
 188         if [[ $TERM == screen ]]; then
 189             print -n "\ek$1\e\\"
 190         elif [[ $TERM == xterm* ]]; then
 191             print -n "\e]2;$1\e\\"
 192         fi
 193     }
 194
 195     # Add the preexec() and precmd() hooks.
 196     add-zsh-hook preexec window_preexec
 197     add-zsh-hook precmd window_precmd
 198 fi
 199
 200
 201 # COMPLETION SETTINGS
 202
 203 # Load the complist module which provides additions to completion lists
 204 # (coloring, scrollable).
 205 zmodload zsh/complist
 206 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 207 # cluttering of ~/.
 208 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 209 # Make sure the list of possible completions is displayed after pressing <TAB>
 210 # the first time.
 211 setopt nolistambiguous
 212 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 213 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 214 bindkey "^I" expand-or-complete-prefix
 215 # Use cache to speed up completions.
 216 zstyle ':completion:*' use-cache on
 217 zstyle ':completion:*' cache-path ~/.zsh/cache
 218 # Try uppercase if the currently typed string doesn't match. This allows
 219 # typing in lowercase most of the time and completion fixes the case.
 220 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 221 # Ignore completion functions.
 222 zstyle ':completion:*:functions' ignored-patterns '_*'
 223 # Ignore parent directory.
 224 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 225 # Use ls like colors for completions.
 226 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 227 # Make completion lists scrollable so "do you wish to see all n possibilities"
 228 # is no longer displayed.
 229 zstyle ':completion:*' list-prompt '%p'
 230 # When unsetting variables make sure every variable name is only suggested
 231 # once.
 232 zstyle ':completion:*:unset:*' ignore-line yes
 233 # When working with Mercurial and Git don't complete the same file multiple
 234 # times. Very useful when completing file names.
 235 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 236
 237
 238 # CUSTOM ALIASES AND FUNCTIONS
 239
 240 # Make sure aliases are expanded when using sudo.
 241 alias sudo='sudo '
 242
 243 # Simplify calls to less, automatically redirects all output.
 244 alias -g L='2>&1 | less'
 245 # Simplify calls to colordiff, output is also piped through less.
 246 alias -g D='2>&1 | colordiff L'
 247 # Simplify calls to grep.
 248 alias -g G='| grep'
 249
 250 # Automatically use unified diffs.
 251 alias diff='diff -u'
 252
 253 # Display all files and use human readable sizes.
 254 alias du='du -sh'
 255
 256 # Use human readable sizes.
 257 alias df='df -h'
 258
 259 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 260 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 261     alias vim='vim -p'
 262 fi
 263
 264 # Shortcuts for often used programs.
 265 alias e='elinks'
 266 alias g='git'
 267 alias m='mutt'
 268 alias v='vim'
 269 alias vi='vim'
 270
 271 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 272 # shell.
 273 alias :q='echo "This is not Vim!" >&2'
 274
 275 # Edit the mercurial patch queue series file for the current mercurial
 276 # repository in Vim. Also change Vim's pwd to the patches directory so other
 277 # patches can easily be opened.
 278 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 279
 280 # Make going up directories simple.
 281 alias -g ...='../..'
 282 alias -g ....='../../..'
 283 alias -g .....='../../../..'
 284
 285 # Improved ls which displays the files in columns (-C), visualizes
 286 # directories, links and other special files (-F) and pages everything through
 287 # less (L).
 288 #
 289 # If available use GNU ls with colorized output. If it isn't available use
 290 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 291 # pager.
 292 ls --color &> /dev/null
 293 if [[ $? -eq 0 ]]; then
 294     alias ls='ls --color'
 295 else
 296     alias ls='CLICOLOR_FORCE=1 ls -G'
 297 fi
 298 # Main ls function.
 299 function ls() {
 300     command ls -C -F $* L
 301 }
 302 # Helper function to list all files.
 303 function la() {
 304     ls -a $*
 305 }
 306 # Helper function to list all files in list format with access rights, etc.
 307 function ll() {
 308     la -l $*
 309 }
 310
 311 # If ^C is pressed while typing a command, add it to the history so it can be
 312 # easily retrieved later and then abort like ^C normally does. This is useful
 313 # when I want to abort an command to do something in between and then finish
 314 # typing the command.
 315 TRAPINT() {
 316     # Store the current buffer in the history.
 317     zle && print -s $BUFFER
 318
 319     # Return the default exit code so zsh aborts the current command.
 320     return $1
 321 }
 322
 323 # Display TODOs stored in ~/.todo if this file exists.
 324 todo() {
 325     if [[ -f ~/.todo ]]; then
 326         cat ~/.todo | $PAGER
 327     fi
 328 }
 329
 330
 331 # RUN COMMANDS
 332
 333 # If not already in screen reattach to a running session or create a new one.
 334 if [[ $TERM != 'screen' && $TERM != 'dumb' ]]; then
 335     # Create a new session if none is running.
 336     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 337         screen
 338     # Reattach to a running session.
 339     else
 340         screen -r
 341     fi
 342 fi
 343
 344
 345 # Load rc file for current OS.
 346 source_config ~/.zsh os rc $(uname) nolocal
 347 # Load rc file for current hostname (first part before a dot) or rc.local.
 348 source_config ~/.zsh host rc ${$(hostname)//.*/}
 349
 350 source_debug "finished sourcing ~/.zsh/rc"
 351
 352 # vim: ft=zsh