zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Make sure every entry in $fpath is unique.
  36 typeset -U fpath
  37 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  38 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  39 if [[ -d ~/.zsh/functions/completion ]]; then
  40     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  41 fi
  42 # Set correct fpath to allow loading my functions (including completion
  43 # functions).
  44 fpath=(~/.zsh/functions $fpath)
  45 # Autoload my functions (except completion functions and hidden files). Thanks
  46 # to caphuso from the Zsh example files for this idea.
  47 autoload ${fpath[1]}/^_*(^/:t)
  48
  49 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  50 # the moment only precmd() and preexec() are simulated.
  51 #
  52 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  53 # so the compatibility version is used there too.
  54 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  55     # Provide add-zsh-hook which was added in 4.3.4.
  56     fpath=(~/.zsh/functions/compatibility $fpath)
  57
  58     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  59     function precmd() {
  60         for function in $precmd_functions; do
  61             $function $@
  62         done
  63     }
  64     function preexec() {
  65         for function in $preexec_functions; do
  66             $function $@
  67         done
  68     }
  69 fi
  70
  71 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  72 autoload -Uz add-zsh-hook
  73
  74
  75 # HISTORY SETTINGS
  76
  77 # Use history and store it in ~/.zsh/history.
  78 HISTSIZE=5000
  79 SAVEHIST=5000
  80 HISTFILE=~/.zsh/history
  81 # Append to the history file instead of overwriting it and do it immediately
  82 # when a command is executed.
  83 setopt appendhistory
  84 setopt incappendhistory
  85 # If the same command is run multiple times store it only once in the history.
  86 setopt histignoredups
  87 # Vim like completions of previous executed commands.
  88 bindkey "^P" history-beginning-search-backward
  89 bindkey "^N" history-beginning-search-forward
  90
  91
  92 # PROMPT SETTINGS
  93
  94 # Use colorized output, necessary for prompts and completions.
  95 autoload -U colors && colors
  96
  97 # Set the default prompt. The current host and working directory is displayed,
  98 # the exit code of the last command if it wasn't 0, the number of running jobs
  99 # if not 0 and a + if this shell is running inside another shell.
 100 # The prompt is in green and blue to make easily detectable, the error exit
 101 # code in red and bold and the job count in yellow.
 102 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
 103 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
 104 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 105 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 106
 107 # VCS_Info was added in 4.3.9.
 108 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 109     # Allow substitutions and expansions in the prompt, necessary for
 110     # vcs_info.
 111     setopt promptsubst
 112     # Load vcs_info to display information about version control repositories.
 113     autoload -Uz vcs_info
 114     # Only look for git and mercurial repositories; the only I use.
 115     zstyle ':vcs_info:*' enable git hg
 116     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 117     # is displayed. If there is an special action going on (merge, rebase)
 118     # it's also displayed (red).
 119     zstyle ':vcs_info:*' formats \
 120     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 121 %{${fg[blue]}%}%s%{${fg[default]}%})"
 122     zstyle ':vcs_info:*' actionformats \
 123     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 124 %{${fg[red]}%}%a%{${fg[default]}%}:\
 125 %{${fg[blue]}%}%s%{${fg[default]}%})"
 126     # Call vcs_info as precmd before every prompt.
 127     prompt_precmd() {
 128         vcs_info
 129     }
 130     add-zsh-hook precmd prompt_precmd
 131
 132     # Display the vcs information in the right prompt.
 133     RPROMPT='${vcs_info_msg_0_}'
 134 fi
 135
 136 # When screen or xterm is used set the name of the window to the currently
 137 # running program.
 138 #
 139 # When a program is started preexec() sets the window's name to it; when it
 140 # stops precmd() resets the windows' name to 'zsh'.
 141 #
 142 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 143 # and stumpwm is used (it's tested if stumpish is available) then the window
 144 # title is also set in stumpwm using stumpish.
 145 #
 146 # If a command is run with sudo or if the shell is running as root then a ! is
 147 # added at the beginning of the command to make this clear. If a command is
 148 # running on a different computer with ssh a @ is added at the beginning.
 149 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 150     # Set to a non empty value to reset the window name in the next precmd()
 151     # call.
 152     window_reset=yes
 153     # Set to a non empty value when the stump window manager is available.
 154     which stumpwm &> /dev/null
 155     if [[ $? -eq 0 ]]; then
 156         window_stumpwm=yes
 157     fi
 158     # Set to a non empty value when the shell is running as root.
 159     if [[ $(id -u) -eq 0 ]]; then
 160         window_root=yes
 161     fi
 162
 163     window_preexec() {
 164         # Get the program name with its arguments.
 165         local program_name=$1
 166
 167         # When sudo is used use real program name instead, but with an
 168         # exclamation mark at the beginning.
 169         local program_sudo=
 170         if [[ $program_name == sudo* ]]; then
 171             program_name=${program_name#sudo }
 172             program_sudo=yes
 173         fi
 174         # Remove all arguments from the program name.
 175         program_name=${program_name%% *}
 176
 177         # Ignore often used commands which are only running for a very short
 178         # time. This prevents a "blinking" name when it's changed to "cd" for
 179         # example and then some milliseconds later back to "zsh".
 180         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 181
 182         # Change my shortcuts so the real name of the program is displayed.
 183         case $program_name in
 184             e)
 185                 program_name=elinks
 186                 ;;
 187             g)
 188                 program_name=git
 189                 ;;
 190             m)
 191                 program_name=mutt
 192                 ;;
 193             v|vi)
 194                 program_name=vim
 195                 ;;
 196         esac
 197
 198         # Add an exclamation mark at the beginning if running with sudo or if
 199         # running zsh as root.
 200         if [[ -n $program_sudo || -n $window_root ]]; then
 201             program_name=!$program_name
 202         fi
 203
 204         # Add an at mark at the beginning if running ssh on a different
 205         # computer.
 206         if [[ -n $SSH_CONNECTION ]]; then
 207             program_name="@$program_name"
 208         fi
 209
 210         # Set the window name to the currently running program.
 211         window_title "$program_name"
 212
 213         # Tell precmd() to reset the window name when the program stops.
 214         window_reset=yes
 215     }
 216
 217     window_precmd() {
 218         # Abort if no window name reset is necessary.
 219         [[ -z $window_reset ]] && return
 220
 221         # Reset the window name to 'zsh'.
 222         if [[ -n $SSH_CONNECTION ]]; then
 223             window_title "@zsh"
 224         elif [[ -n $window_root ]]; then
 225             window_title "!zsh"
 226         else
 227             window_title "zsh"
 228         fi
 229
 230         # Just reset the name, so no screen reset necessary for the moment.
 231         window_reset=
 232     }
 233
 234     # Sets the window title. Works with screen and xterm.
 235     window_title() {
 236         if [[ $TERM == screen* ]]; then
 237             print -n "\ek$1\e\\"
 238
 239             # Update window name in stumpwm if running screen in X11 and when
 240             # stumpwm is used.
 241             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 242                 echo "$1" | stumpish -e "title" > /dev/null
 243             fi
 244
 245         elif [[ $TERM == xterm* ]]; then
 246             print -n "\e]2;$1\e\\"
 247         fi
 248     }
 249
 250     # Add the preexec() and precmd() hooks.
 251     add-zsh-hook preexec window_preexec
 252     add-zsh-hook precmd window_precmd
 253 fi
 254
 255
 256 # COMPLETION SETTINGS
 257
 258 # Load the complist module which provides additions to completion lists
 259 # (coloring, scrollable).
 260 zmodload zsh/complist
 261 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 262 # cluttering of ~/.
 263 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 264
 265 # Use cache to speed up completions.
 266 zstyle ':completion:*' use-cache on
 267 zstyle ':completion:*' cache-path ~/.zsh/cache
 268
 269 # Complete arguments and fix spelling mistakes when possible.
 270 zstyle ':completion:*' completer _complete _match _correct _approximate
 271
 272 # Make sure the list of possible completions is displayed after pressing <TAB>
 273 # the first time.
 274 setopt nolistambiguous
 275 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 276 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 277 bindkey "^I" expand-or-complete-prefix
 278 # Try uppercase if the currently typed string doesn't match. This allows
 279 # typing in lowercase most of the time and completion fixes the case.
 280 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 281
 282 # Use ls like colors for completions.
 283 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 284
 285 # Make completion lists scrollable so "do you wish to see all n possibilities"
 286 # is no longer displayed.
 287 zstyle ':completion:*' list-prompt '%p'
 288 # Display group name (like 'external command', 'alias', etc.) when there are
 289 # multiple matches in bold.
 290 zstyle ':completion:*' format '    %B%d%b:'
 291 # Display different types of matches separately.
 292 zstyle ':completion:*' group-name ''
 293
 294 # Ignore completion functions.
 295 zstyle ':completion:*:functions' ignored-patterns '_*'
 296 # Ignore parent directory.
 297 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 298 # When unsetting variables make sure every variable name is only suggested
 299 # once.
 300 zstyle ':completion:*:unset:*' ignore-line yes
 301 # When working with Mercurial and Git don't complete the same file multiple
 302 # times. Very useful when completing file names.
 303 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 304
 305
 306 # CUSTOM ALIASES AND FUNCTIONS
 307
 308 # Make sure aliases are expanded when using sudo.
 309 alias sudo='sudo '
 310
 311 # Redirect stderr to stdout.
 312 alias -g E='2>&1'
 313
 314 # Simplify calls to less, automatically redirects all output.
 315 alias -g L='E | less'
 316 # Simplify calls to colordiff, output is also piped through less.
 317 alias -g D='E | colordiff L'
 318 # Simplify calls to grep.
 319 alias -g G='| grep'
 320 # Simplify calls to sort.
 321 alias -g S='| sort'
 322
 323 # Automatically use unified diffs.
 324 alias diff='diff -u'
 325
 326 # Display all files and use human readable sizes.
 327 alias du='du -sh'
 328
 329 # Use human readable sizes.
 330 alias df='df -h'
 331
 332 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 333 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 334     alias vim='vim -p'
 335 fi
 336
 337 # Shortcuts for often used programs.
 338 alias e='elinks'
 339 alias g='git'
 340 alias m='mutt'
 341 alias v='vim'
 342 alias vi='vim'
 343
 344 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 345 # shell.
 346 alias :q='echo "This is not Vim!" >&2'
 347
 348 # Edit the mercurial patch queue series file for the current mercurial
 349 # repository in Vim. Also change Vim's pwd to the patches directory so other
 350 # patches can easily be opened.
 351 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 352
 353 # Make going up directories simple.
 354 alias -g ...='../..'
 355 alias -g ....='../../..'
 356 alias -g .....='../../../..'
 357
 358 # Improved ls which displays the files in columns (-C), visualizes
 359 # directories, links and other special files (-F) and pages everything through
 360 # less (L).
 361 #
 362 # If available use GNU ls with colorized output. If it isn't available use
 363 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 364 # pager.
 365 ls --color &> /dev/null
 366 if [[ $? -eq 0 ]]; then
 367     alias ls='ls --color'
 368 else
 369     alias ls='CLICOLOR_FORCE=1 ls -G'
 370 fi
 371 # Main ls function.
 372 function ls() {
 373     command ls -C -F $* L
 374 }
 375 # Helper function to list all files.
 376 function la() {
 377     ls -a $*
 378 }
 379 # Helper function to list all files in list format with access rights, etc.
 380 function ll() {
 381     la -l $*
 382 }
 383
 384 # If ^C is pressed while typing a command, add it to the history so it can be
 385 # easily retrieved later and then abort like ^C normally does. This is useful
 386 # when I want to abort an command to do something in between and then finish
 387 # typing the command.
 388 TRAPINT() {
 389     # Store the current buffer in the history.
 390     zle && print -s $BUFFER
 391
 392     # Return the default exit code so zsh aborts the current command.
 393     return $1
 394 }
 395
 396 # Display TODOs stored in ~/.todo if this file exists.
 397 todo() {
 398     if [[ -f ~/.todo ]]; then
 399         cat ~/.todo | $PAGER
 400     fi
 401 }
 402
 403 # Colorize stderr. Very useful when looking for errors. Thanks to
 404 # http://gentoo-wiki.com/wiki/Zsh
 405 exec 2>>(while read line; do
 406     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 407
 408
 409 # RUN COMMANDS
 410
 411 # If not already in screen reattach to a running session or create a new one.
 412 #
 413 # screen* is necessary as `screen` uses screen.linux for example for a linux
 414 # console which would otherwise cause an infinite loop.
 415 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 416     # Create a new session if none is running.
 417     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 418         screen
 419     # Reattach to a running session.
 420     else
 421         screen -r
 422     fi
 423 fi
 424
 425
 426 # Load rc file for current OS.
 427 source_config ~/.zsh os rc $(uname) nolocal
 428 # Load rc file for current hostname (first part before a dot) or rc.local.
 429 source_config ~/.zsh host rc ${$(hostname)//.*/}
 430
 431 source_debug "finished sourcing ~/.zsh/rc"
 432
 433 # vim: ft=zsh