]> ruderich.org/simon Gitweb - config/dotfiles.git/blob - zsh/rc
zsh: Fix 62d757146f6bcf1f4951059769239db024144812.
[config/dotfiles.git] / zsh / rc
1 # Zsh configuration file.
2
3
4 source_debug "sourcing ~/.zsh/rc"
5
6 # MISCELLANEOUS SETTINGS
7
8 # Use Vi(m) style key bindings.
9 bindkey -v
10
11 # Be paranoid, new files are readable/writable by me only.
12 umask 077
13
14 # Prevent overwriting existing files with '> filename', use '>| filename'
15 # (or >!) instead.
16 setopt noclobber
17
18 # Entering the name of a directory (if it's not a command) will automatically
19 # cd to that directory.
20 setopt autocd
21
22 # When entering a nonexistent command name automatically try to find a similar
23 # one.
24 setopt correct
25
26 # Enable zsh's extended glob abilities.
27 setopt extendedglob
28
29 # Don't exit if <C-d> is pressed.
30 setopt ignoreeof
31
32
33 # FUNCTION SETTINGS
34
35 # Set correct fpath to allow loading my functions (including completion
36 # functions).
37 fpath=(~/.zsh/functions $fpath)
38 # Autoload my functions (except completion functions and hidden files). Thanks
39 # to caphuso from the Zsh example files for this idea.
40 autoload ${fpath[1]}/^_*(^/:t)
41
42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
43 # the moment only precmd() and preexec() are simulated.
44 #
45 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
46 # so the compatibility version is used there too.
47 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
48     # Provide add-zsh-hook which was added in 4.3.4.
49     fpath=(~/.zsh/functions/compatibility $fpath)
50
51     # Run all functions defined in the ${precmd,preexec}_functions arrays.
52     function precmd() {
53         for function in $precmd_functions; do
54             $function $@
55         done
56     }
57     function preexec() {
58         for function in $preexec_functions; do
59             $function $@
60         done
61     }
62 fi
63
64 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
65 autoload -Uz add-zsh-hook
66
67
68 # HISTORY SETTINGS
69
70 # Use history and store it in ~/.zsh/history.
71 HISTSIZE=5000
72 SAVEHIST=5000
73 HISTFILE=~/.zsh/history
74 # Append to the history file instead of overwriting it and do it immediately
75 # when a command is executed.
76 setopt appendhistory
77 setopt incappendhistory
78 # If the same command is run multiple times store it only once in the history.
79 setopt histignoredups
80 # Vim like completions of previous executed commands.
81 bindkey "^P" history-beginning-search-backward
82 bindkey "^N" history-beginning-search-forward
83
84
85 # PROMPT SETTINGS
86
87 # Use colorized output, necessary for prompts and completions.
88 autoload -U colors && colors
89
90 # Set the default prompt. The current host and working directory is displayed,
91 # the exit code of the last command if it wasn't 0, the number of running jobs
92 # if not 0 and a + if this shell is running inside another shell.
93 # The prompt is in green and blue to make easily detectable, the error exit
94 # code in red and bold and the job count in yellow.
95 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
96 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
97 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
98 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
99
100 # VCS_Info was added in 4.3.9.
101 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
102     # Allow substitutions and expansions in the prompt, necessary for
103     # vcs_info.
104     setopt promptsubst
105     # Load vcs_info to display information about version control repositories.
106     autoload -Uz vcs_info
107     # Only look for git and mercurial repositories; the only I use.
108     zstyle ':vcs_info:*' enable git hg
109     # Set style of vcs_info display. The current branch (green) and vcs (blue)
110     # is displayed. If there is an special action going on (merge, rebase)
111     # it's also displayed (red).
112     zstyle ':vcs_info:*' formats \
113     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
114 %{${fg[blue]}%}%s%{${fg[default]}%})"
115     zstyle ':vcs_info:*' actionformats \
116     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
117 %{${fg[red]}%}%a%{${fg[default]}%}:\
118 %{${fg[blue]}%}%s%{${fg[default]}%})"
119     # Call vcs_info as precmd before every prompt.
120     prompt_precmd() {
121         vcs_info
122     }
123     add-zsh-hook precmd prompt_precmd
124
125     # Display the vcs information in the right prompt.
126     RPROMPT='${vcs_info_msg_0_}'
127 fi
128
129 # When screen or xterm is used set the name of the window to the currently
130 # running program.
131 #
132 # When a program is started preexec() sets the window's name to it; when it
133 # stops precmd() resets the windows' name to 'zsh'.
134 #
135 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
136 # and stumpwm is used (it's tested if stumpish is available) then the window
137 # title is also set in stumpwm using stumpish.
138 if [[ $TERM == screen* || $TERM == xterm* ]]; then
139     # Set to a non empty value to reset the window name in the next precmd()
140     # call.
141     window_reset=yes
142     # Set to a non empty value when the stump window manager is available.
143     which stumpwm &> /dev/null
144     if [[ $? -eq 0 ]]; then
145         window_stumpwm=yes
146     fi
147
148     window_preexec() {
149         # Get the program name with its arguments.
150         local program_name=$1
151
152         # When sudo is used use real program name instead, but with an
153         # exclamation mark at the beginning.
154         local program_sudo=
155         if [[ $program_name == sudo* ]]; then
156             program_name=${program_name#sudo }
157             program_sudo=yes
158         fi
159         # Remove all arguments from the program name.
160         program_name=${program_name%% *}
161
162         # Ignore often used commands which are only running for a very short
163         # time. This prevents a "blinking" name when it's changed to "cd" for
164         # example and then some milliseconds later back to "zsh".
165         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
166
167         # Change my shortcuts so the real name of the program is displayed.
168         case $program_name in
169             e)
170                 program_name=elinks
171                 ;;
172             g)
173                 program_name=git
174                 ;;
175             m)
176                 program_name=mutt
177                 ;;
178             v|vi)
179                 program_name=vim
180                 ;;
181         esac
182
183         # Add an exclamation mark at the beginning if running with sudo.
184         if [[ $program_sudo == yes ]]; then
185             program_name=!$program_name
186         fi
187
188         # Add an at mark at the beginning if running ssh on a different
189         # computer.
190         if [[ -n $SSH_CONNECTION ]]; then
191             program_name="@$program_name"
192         fi
193
194         # Set the window name to the currently running program.
195         window_title "$program_name"
196
197         # Tell precmd() to reset the window name when the program stops.
198         window_reset=yes
199     }
200
201     window_precmd() {
202         # Abort if no window name reset is necessary.
203         [[ -z $window_reset ]] && return
204
205         # Reset the window name to 'zsh'.
206         if [[ -n $SSH_CONNECTION ]]; then
207             window_title "@zsh"
208         else
209             window_title "zsh"
210         fi
211
212         # Just reset the name, so no screen reset necessary for the moment.
213         window_reset=
214     }
215
216     # Sets the window title. Works with screen and xterm.
217     window_title() {
218         if [[ $TERM == screen* ]]; then
219             print -n "\ek$1\e\\"
220
221             # Update window name in stumpwm if running screen in X11 and when
222             # stumpwm is used.
223             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
224                 echo "$1" | stumpish -e "title" > /dev/null
225             fi
226
227         elif [[ $TERM == xterm* ]]; then
228             print -n "\e]2;$1\e\\"
229         fi
230     }
231
232     # Add the preexec() and precmd() hooks.
233     add-zsh-hook preexec window_preexec
234     add-zsh-hook precmd window_precmd
235 fi
236
237
238 # COMPLETION SETTINGS
239
240 # Load the complist module which provides additions to completion lists
241 # (coloring, scrollable).
242 zmodload zsh/complist
243 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
244 # cluttering of ~/.
245 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
246
247 # Use cache to speed up completions.
248 zstyle ':completion:*' use-cache on
249 zstyle ':completion:*' cache-path ~/.zsh/cache
250
251 # Complete arguments and fix spelling mistakes when possible.
252 zstyle ':completion:*' completer _complete _match _correct _approximate
253
254 # Make sure the list of possible completions is displayed after pressing <TAB>
255 # the first time.
256 setopt nolistambiguous
257 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
258 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
259 bindkey "^I" expand-or-complete-prefix
260 # Try uppercase if the currently typed string doesn't match. This allows
261 # typing in lowercase most of the time and completion fixes the case.
262 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
263
264 # Use ls like colors for completions.
265 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
266
267 # Make completion lists scrollable so "do you wish to see all n possibilities"
268 # is no longer displayed.
269 zstyle ':completion:*' list-prompt '%p'
270 # Display group name (like 'external command', 'alias', etc.) when there are
271 # multiple matches in bold.
272 zstyle ':completion:*' format '    %B%d%b:'
273 # Display different types of matches separately.
274 zstyle ':completion:*' group-name ''
275
276 # Ignore completion functions.
277 zstyle ':completion:*:functions' ignored-patterns '_*'
278 # Ignore parent directory.
279 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
280 # When unsetting variables make sure every variable name is only suggested
281 # once.
282 zstyle ':completion:*:unset:*' ignore-line yes
283 # When working with Mercurial and Git don't complete the same file multiple
284 # times. Very useful when completing file names.
285 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
286
287
288 # CUSTOM ALIASES AND FUNCTIONS
289
290 # Make sure aliases are expanded when using sudo.
291 alias sudo='sudo '
292
293 # Simplify calls to less, automatically redirects all output.
294 alias -g L='2>&1 | less'
295 # Simplify calls to colordiff, output is also piped through less.
296 alias -g D='2>&1 | colordiff L'
297 # Simplify calls to grep.
298 alias -g G='| grep'
299
300 # Automatically use unified diffs.
301 alias diff='diff -u'
302
303 # Display all files and use human readable sizes.
304 alias du='du -sh'
305
306 # Use human readable sizes.
307 alias df='df -h'
308
309 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
310 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
311     alias vim='vim -p'
312 fi
313
314 # Shortcuts for often used programs.
315 alias e='elinks'
316 alias g='git'
317 alias m='mutt'
318 alias v='vim'
319 alias vi='vim'
320
321 # I sometimes confuse editor and shell, print a warning to prevent I exit the
322 # shell.
323 alias :q='echo "This is not Vim!" >&2'
324
325 # Edit the mercurial patch queue series file for the current mercurial
326 # repository in Vim. Also change Vim's pwd to the patches directory so other
327 # patches can easily be opened.
328 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
329
330 # Make going up directories simple.
331 alias -g ...='../..'
332 alias -g ....='../../..'
333 alias -g .....='../../../..'
334
335 # Improved ls which displays the files in columns (-C), visualizes
336 # directories, links and other special files (-F) and pages everything through
337 # less (L).
338 #
339 # If available use GNU ls with colorized output. If it isn't available use
340 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
341 # pager.
342 ls --color &> /dev/null
343 if [[ $? -eq 0 ]]; then
344     alias ls='ls --color'
345 else
346     alias ls='CLICOLOR_FORCE=1 ls -G'
347 fi
348 # Main ls function.
349 function ls() {
350     command ls -C -F $* L
351 }
352 # Helper function to list all files.
353 function la() {
354     ls -a $*
355 }
356 # Helper function to list all files in list format with access rights, etc.
357 function ll() {
358     la -l $*
359 }
360
361 # If ^C is pressed while typing a command, add it to the history so it can be
362 # easily retrieved later and then abort like ^C normally does. This is useful
363 # when I want to abort an command to do something in between and then finish
364 # typing the command.
365 TRAPINT() {
366     # Store the current buffer in the history.
367     zle && print -s $BUFFER
368
369     # Return the default exit code so zsh aborts the current command.
370     return $1
371 }
372
373 # Display TODOs stored in ~/.todo if this file exists.
374 todo() {
375     if [[ -f ~/.todo ]]; then
376         cat ~/.todo | $PAGER
377     fi
378 }
379
380 # Colorize stderr. Very useful when looking for errors. Thanks to
381 # http://gentoo-wiki.com/wiki/Zsh
382 exec 2>>(while read line; do
383     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
384
385
386 # RUN COMMANDS
387
388 # If not already in screen reattach to a running session or create a new one.
389 #
390 # screen* is necessary as `screen` uses screen.linux for example for a linux
391 # console which would otherwise cause an infinite loop.
392 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
393     # Create a new session if none is running.
394     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
395         screen
396     # Reattach to a running session.
397     else
398         screen -r
399     fi
400 fi
401
402
403 # Load rc file for current OS.
404 source_config ~/.zsh os rc $(uname) nolocal
405 # Load rc file for current hostname (first part before a dot) or rc.local.
406 source_config ~/.zsh host rc ${$(hostname)//.*/}
407
408 source_debug "finished sourcing ~/.zsh/rc"
409
410 # vim: ft=zsh