zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Set correct fpath to allow loading my functions (including completion
  36 # functions).
  37 fpath=(~/.zsh/functions $fpath)
  38 # Autoload my functions (except completion functions and hidden files). Thanks
  39 # to caphuso from the Zsh example files for this idea.
  40 autoload ${fpath[1]}/^_*(^/:t)
  41
  42 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  43 # the moment only precmd() and preexec() are simulated.
  44 if [[ $ZSH_VERSION != (4.3.<4->|4.<4->*|<5->*) ]]; then
  45     # Provide add-zsh-hook which was added in 4.3.4.
  46     fpath=($fpath ~/.zsh/functions/compatibility)
  47
  48     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  49     function precmd() {
  50         for function in $precmd_functions; do
  51             $function $@
  52         done
  53     }
  54     function preexec() {
  55         for function in $preexec_functions; do
  56             $function $@
  57         done
  58     }
  59 fi
  60
  61 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  62 autoload -Uz add-zsh-hook
  63
  64
  65 # HISTORY SETTINGS
  66
  67 # Use history and store it in ~/.zsh/history.
  68 HISTSIZE=5000
  69 SAVEHIST=5000
  70 HISTFILE=~/.zsh/history
  71 # Append to the history file instead of overwriting it and do it immediately
  72 # when a command is executed.
  73 setopt appendhistory
  74 setopt incappendhistory
  75 # If the same command is run multiple times store it only once in the history.
  76 setopt histignoredups
  77 # Vim like completions of previous executed commands.
  78 bindkey "^P" history-beginning-search-backward
  79 bindkey "^N" history-beginning-search-forward
  80
  81
  82 # PROMPT SETTINGS
  83
  84 # Use colorized output, necessary for prompts and completions.
  85 autoload -U colors && colors
  86
  87 # Set the default prompt. The current host and working directory is displayed,
  88 # the exit code of the last command if it wasn't 0, the number of running jobs
  89 # if not 0 and a + if this shell is running inside another shell.
  90 # The prompt is in green and blue to make easily detectable, the error exit
  91 # code in red and bold and the job count in yellow.
  92 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  93 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  94 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  95 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  96
  97 # VCS_Info was added in 4.3.9.
  98 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
  99     # Allow substitutions and expansions in the prompt, necessary for
 100     # vcs_info.
 101     setopt promptsubst
 102     # Load vcs_info to display information about version control repositories.
 103     autoload -Uz vcs_info
 104     # Only look for git and mercurial repositories; the only I use.
 105     zstyle ':vcs_info:*' enable git hg
 106     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 107     # is displayed. If there is an special action going on (merge, rebase)
 108     # it's also displayed (red).
 109     zstyle ':vcs_info:*' formats \
 110     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 111 %{${fg[blue]}%}%s%{${fg[default]}%})"
 112     zstyle ':vcs_info:*' actionformats \
 113     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 114 %{${fg[red]}%}%a%{${fg[default]}%}:\
 115 %{${fg[blue]}%}%s%{${fg[default]}%})"
 116     # Call vcs_info as precmd before every prompt.
 117     prompt_precmd() {
 118         vcs_info
 119     }
 120     add-zsh-hook precmd prompt_precmd
 121
 122     # Display the vcs information in the right prompt.
 123     RPROMPT='${vcs_info_msg_0_}'
 124 fi
 125
 126 # When screen is used set the name of the window to the currently running
 127 # program.
 128 #
 129 # When a program is started preexec() sets the window's name to it; when it
 130 # stops precmd() resets the windows' name to 'zsh'.
 131 if [[ $TERM == screen ]]; then
 132     # Set to a non empty value to reset the window name in the next precmd()
 133     # call.
 134     screen_name_reset=yes
 135
 136     screen_preexec() {
 137         # Get the program name with its arguments.
 138         local program_name=$1
 139         # When sudo is used use real program name instead, but with an
 140         # exclamation mark at the beginning.
 141         if [[ $program_name == sudo* ]]; then
 142             program_name=!${program_name#sudo }
 143         fi
 144         # Remove all arguments from the program name.
 145         program_name=${program_name%% *}
 146
 147         # Ignore often used commands which are only running for a very short
 148         # time. This prevents a "blinking" name when it's changed to "cd" for
 149         # example and then some milliseconds later back to "zsh".
 150         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 151
 152         # Change my shortcuts so the real name of the program is displayed.
 153         case $program_name in
 154             e)
 155                 program_name=elinks
 156                 ;;
 157             g)
 158                 program_name=git
 159                 ;;
 160             m)
 161                 program_name=mutt
 162                 ;;
 163             v|vi)
 164                 program_name=vim
 165                 ;;
 166         esac
 167
 168         # Set the window name to the currently running program.
 169         print -n "\ek$program_name\e\\"
 170
 171         # Tell precmd() to reset the window name when the program stops.
 172         screen_name_reset=yes
 173     }
 174
 175     screen_precmd() {
 176         # Abort if no window name reset is necessary.
 177         [[ -z $screen_name_reset ]] && return
 178
 179         # Reset the window name to 'zsh'.
 180         print -n "\ekzsh\e\\"
 181
 182         # Just reset the name, so no screen reset necessary for the moment.
 183         screen_name_reset=
 184     }
 185
 186     # Add the preexec() and precmd() hooks.
 187     add-zsh-hook preexec screen_preexec
 188     add-zsh-hook precmd screen_precmd
 189 fi
 190
 191
 192 # COMPLETION SETTINGS
 193
 194 # Load the complist module which provides additions to completion lists
 195 # (coloring, scrollable).
 196 zmodload zsh/complist
 197 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 198 # cluttering of ~/.
 199 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 200 # Make sure the list of possible completions is displayed after pressing <TAB>
 201 # the first time.
 202 setopt nolistambiguous
 203 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 204 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 205 bindkey "^I" expand-or-complete-prefix
 206 # Use cache to speed up completions.
 207 zstyle ':completion:*' use-cache on
 208 zstyle ':completion:*' cache-path ~/.zsh/cache
 209 # Try uppercase if the currently typed string doesn't match. This allows
 210 # typing in lowercase most of the time and completion fixes the case.
 211 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 212 # Ignore completion functions.
 213 zstyle ':completion:*:functions' ignored-patterns '_*'
 214 # Ignore parent directory.
 215 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 216 # Use ls like colors for completions.
 217 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 218 # Make completion lists scrollable so "do you wish to see all n possibilities"
 219 # is no longer displayed.
 220 zstyle ':completion:*' list-prompt '%p'
 221 # When unsetting variables make sure every variable name is only suggested
 222 # once.
 223 zstyle ':completion:*:unset:*' ignore-line yes
 224 # When working with Mercurial and Git don't complete the same file multiple
 225 # times. Very useful when completing file names.
 226 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 227
 228
 229 # CUSTOM ALIASES AND FUNCTIONS
 230
 231 # Simplify calls to less, automatically redirects all output.
 232 alias -g L='2>&1 | less'
 233 # Simplify calls to colordiff, output is also piped through less.
 234 alias -g D='2>&1 | colordiff L'
 235 # Simplify calls to grep.
 236 alias -g G='| grep'
 237
 238 # Automatically use unified diffs.
 239 alias diff='diff -u'
 240
 241 # Display all files and use human readable sizes.
 242 alias du='du -sh'
 243
 244 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 245 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 246     alias vim='vim -p'
 247 fi
 248
 249 # Shortcuts for often used programs.
 250 alias e='elinks'
 251 alias g='git'
 252 alias m='mutt'
 253 alias v='vim'
 254 alias vi='vim'
 255
 256 # Exit binding like in Vim; I sometimes confuse editor and shell.
 257 alias :q='exit'
 258
 259 # Edit the mercurial patch queue series file for the current mercurial
 260 # repository in Vim. Also change Vim's pwd to the patches directory so other
 261 # patches can easily be opened.
 262 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 263
 264 # Make going up directories simple.
 265 alias -g ...='../..'
 266 alias -g ....='../../..'
 267 alias -g .....='../../../..'
 268
 269 # Improved ls which displays the files in columns (-C), visualizes directories,
 270 # links and other special files (-F) and pages everything through less (L).
 271 #
 272 # If available use GNU ls with colorized output. If it isn't available use
 273 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 274 # pager.
 275 ls --color &> /dev/null
 276 if [[ $? -eq 0 ]]; then
 277     alias ls='ls --color'
 278 else
 279     alias ls='CLICOLOR_FORCE=1 ls -G'
 280 fi
 281 # Main ls function.
 282 function ls() {
 283     command ls -C -F $* L
 284 }
 285 # Helper function to list all files.
 286 function la() {
 287     ls -a $*
 288 }
 289 # Helper function to list all files in list format with access rights, etc.
 290 function ll() {
 291     la -l $*
 292 }
 293
 294 # If ^C is pressed while typing a command, add it to the history so it can be
 295 # easily retrieved later and then abort like ^C normally does. This is useful
 296 # when I want to abort an command to do something in between and then finish
 297 # typing the command.
 298 TRAPINT() {
 299     # Store the current buffer in the history.
 300     zle && print -s $BUFFER
 301
 302     # Return the default exit code so zsh aborts the current command.
 303     return $1
 304 }
 305
 306 # Display TODOs stored in ~/.todo if this file exists.
 307 todo() {
 308     if [[ -f ~/.todo ]]; then
 309         cat ~/.todo | $PAGER
 310     fi
 311 }
 312
 313
 314 # Load rc file for current OS.
 315 source_config ~/.zsh os rc $(uname) nolocal
 316 # Load rc file for current hostname (first part before a dot) or rc.local.
 317 source_config ~/.zsh host rc ${$(hostname)//.*/}
 318
 319 source_debug "finished sourcing ~/.zsh/rc"