zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 # MISCELLANEOUS SETTINGS
   5
   6 # Use Vi(m) style key bindings.
   7 bindkey -v
   8
   9 # Be paranoid, new files are readable/writable by me only.
  10 umask 077
  11
  12 # Make sure core dumps are created.
  13 ulimit -c unlimited
  14
  15 # Prevent overwriting existing files with '> filename', use '>| filename'
  16 # (or >!) instead.
  17 setopt noclobber
  18
  19 # Entering the name of a directory (if it's not a command) will automatically
  20 # cd to that directory.
  21 setopt autocd
  22
  23 # When entering a nonexistent command name automatically try to find a similar
  24 # one.
  25 setopt correct
  26
  27 # Enable zsh's extended glob abilities.
  28 setopt extendedglob
  29
  30 # Don't exit if <C-d> is pressed.
  31 setopt ignoreeof
  32
  33
  34 # HISTORY SETTINGS
  35
  36 # Use history and store it in ~/.zsh/history.
  37 HISTSIZE=1000
  38 SAVEHIST=1000
  39 HISTFILE=~/.zsh/history
  40 # Append to the history file instead of overwriting it and do it immediately
  41 # when a command is executed.
  42 setopt appendhistory
  43 setopt incappendhistory
  44 # If the same command is run multiple times store it only once in the history.
  45 setopt histignoredups
  46 # Vim like completions of previous executed commands.
  47 bindkey "^P" history-beginning-search-backward
  48 bindkey "^N" history-beginning-search-forward
  49
  50
  51 # PROMPT SETTINGS
  52
  53 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  54 autoload -Uz add-zsh-hook
  55
  56 # Use colorized output, necessary for prompts and completions.
  57 autoload -U colors && colors
  58
  59 # Set the default prompt. The current host and working directory is displayed,
  60 # the exit code of the last command if it wasn't 0, the number of running jobs
  61 # if not 0 and a + if this shell is running inside another shell.
  62 # The prompt is in green and blue to make easily detectable, the error exit
  63 # code in red and bold and the job count in yellow.
  64 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  65 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  66 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  67 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  68
  69 # VCS_Info was added in 4.3.9.
  70 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
  71     # Allow substitutions and expansions in the prompt, necessary for
  72     # vcs_info.
  73     setopt promptsubst
  74     # Load vcs_info to display information about version control repositories.
  75     autoload -Uz vcs_info
  76     # Only look for git and mercurial repositories; the only I use.
  77     zstyle ':vcs_info:*' enable git hg
  78     # Set style of vcs_info display. The current branch (green) and vcs (blue)
  79     # is displayed. If there is an special action going on (merge, rebase)
  80     # it's also displayed (red).
  81     zstyle ':vcs_info:*' formats \
  82     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
  83 %{${fg[blue]}%}%s%{${fg[default]}%})"
  84     zstyle ':vcs_info:*' actionformats \
  85     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
  86 %{${fg[red]}%}%a%{${fg[default]}%}:\
  87 %{${fg[blue]}%}%s%{${fg[default]}%})"
  88     # Call vcs_info as precmd before every prompt.
  89     prompt_precmd() {
  90         vcs_info
  91     }
  92     add-zsh-hook precmd prompt_precmd
  93
  94     # Display the vcs information in the right prompt.
  95     RPROMPT='${vcs_info_msg_0_}'
  96 fi
  97
  98 # When screen is used set the name of the window to the currently running
  99 # program.
 100 #
 101 # When a program is started preexec() sets the window's name to it; when it
 102 # stops precmd() resets the windows' name to 'zsh'.
 103 if [[ $TERM == screen ]]; then
 104     # Set to a non empty value to reset the window name in the next precmd()
 105     # call.
 106     screen_name_reset=yes
 107
 108     screen_preexec() {
 109         # Get the application name excluding any arguments.
 110         local program_name=${1%% *}
 111
 112         # Ignore often used commands which are only running for a very short
 113         # time. This prevents a "blinking" name when it's changed to "cd" for
 114         # example and then some milliseconds later back to "zsh".
 115         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 116
 117         # Change my shortcuts so the real name of the program is displayed.
 118         case $program_name in
 119             e)
 120                 program_name=elinks
 121                 ;;
 122             g)
 123                 program_name=git
 124                 ;;
 125             m)
 126                 program_name=mutt
 127                 ;;
 128             v|vi)
 129                 program_name=vim
 130                 ;;
 131         esac
 132
 133         # Set the window name to the currently running program.
 134         print -n "\ek$program_name\e\\"
 135
 136         # Tell precmd() to reset the window name when the program stops.
 137         screen_name_reset=yes
 138     }
 139
 140     screen_precmd() {
 141         # Abort if no window name reset is necessary.
 142         [[ -z $screen_name_reset ]] && return
 143
 144         # Reset the window name to 'zsh'.
 145         print -n "\ekzsh\e\\"
 146
 147         # Just reset the name, so no screen reset necessary for the moment.
 148         screen_name_reset=
 149     }
 150
 151     # Add the preexec() and precmd() hooks.
 152     add-zsh-hook preexec screen_preexec
 153     add-zsh-hook precmd screen_precmd
 154 fi
 155
 156
 157 # COMPLETION SETTINGS
 158
 159 # Use new completion system.
 160 autoload -U compinit && compinit
 161 # Load the complist module which provides additions to completion lists
 162 # (coloring, scrollable).
 163 zmodload zsh/complist
 164 # Make sure the list of possible completions is displayed after pressing <TAB>
 165 # the first time.
 166 setopt nolistambiguous
 167 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 168 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 169 bindkey "^I" expand-or-complete-prefix
 170 # Use cache to speed up completions.
 171 zstyle ':completion:*' use-cache on
 172 zstyle ':completion:*' cache-path ~/.zsh/cache
 173 # Try uppercase if the currently typed string doesn't match. This allows
 174 # typing in lowercase most of the time and completion fixes the case.
 175 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 176 # Ignore completion functions.
 177 zstyle ':completion:*:functions' ignored-patterns '_*'
 178 # Ignore parent directory.
 179 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 180 # Use ls like colors for completions.
 181 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 182 # Make completion lists scrollable so "do you wish to see all n possibilities"
 183 # is no longer displayed.
 184 zstyle ':completion:*' list-prompt '%p'
 185 # When unsetting variables make sure every variable name is only suggested
 186 # once.
 187 zstyle ':completion:*:unset:*' ignore-line yes
 188 # When working with Mercurial and Git don't complete the same file multiple
 189 # times. Very useful when completing file names.
 190 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 191
 192
 193 # ALIAS AND FUNCTION SETTINGS
 194
 195 # Simplify calls to less, automatically redirects all output.
 196 alias -g L='2>&1 | less'
 197 # Simplify calls to colordiff, output is also piped through less.
 198 alias -g D='2>&1 | colordiff L'
 199 # Simplify calls to grep.
 200 alias -g G='| grep'
 201
 202 # Automatically use unified diffs.
 203 alias diff='diff -u'
 204
 205 # Display all files and use human readable sizes.
 206 alias du='du -sh'
 207
 208 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 209 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 210     alias vim='vim -p'
 211 fi
 212
 213 # Shortcuts for often used programs.
 214 alias e='elinks'
 215 alias g='git'
 216 alias m='mutt'
 217 alias v='vim'
 218 alias vi='vim'
 219
 220 # Exit binding like in Vim; I sometimes confuse editor and shell.
 221 alias :q='exit'
 222
 223 # Edit the mercurial patch queue series file for the current mercurial
 224 # repository in Vim. Also change Vim's pwd to the patches directory so other
 225 # patches can easily be opened.
 226 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 227
 228 # Make going up directories simple.
 229 alias -g ...='../..'
 230 alias -g ....='../../..'
 231 alias -g .....='../../../..'
 232
 233 # Improved ls which displays the files in columns (-C), visualizes directories,
 234 # links and other special files (-F) and pages everything through less (L).
 235 #
 236 # If available use GNU ls with colorized output. If it isn't available use
 237 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 238 # pager.
 239 ls --color &> /dev/null
 240 if [[ $? -eq 0 ]]; then
 241     alias ls='ls --color'
 242 else
 243     alias ls='CLICOLOR_FORCE=1 ls -G'
 244 fi
 245 # Main ls function.
 246 function ls() {
 247     command ls -C -F $* L
 248 }
 249 # Helper function to list all files.
 250 function la() {
 251     ls -a $*
 252 }
 253 # Helper function to list all files in list format with access rights, etc.
 254 function ll() {
 255     la -l $*
 256 }
 257
 258 # If ^C is pressed while typing a command, add it to the history so it can be
 259 # easily retrieved later and then abort like ^C normally does. This is useful
 260 # when I want to abort an command to do something in between and then finish
 261 # typing the command.
 262 TRAPINT() {
 263     # Store the current buffer in the history.
 264     zle && print -s $BUFFER
 265
 266     # Return the default exit code so zsh aborts the current command.
 267     return $1
 268 }
 269
 270 # Display TODOs stored in ~/.todo if this file exists.
 271 todo() {
 272     if [[ -f ~/.todo ]]; then
 273         cat ~/.todo | $PAGER
 274     fi
 275 }
 276
 277
 278 # Load rc file for current OS.
 279 source_config ~/.zsh os rc $(uname) nolocal
 280 # Load rc file for current hostname (first part before a dot) or rc.local.
 281 source_config ~/.zsh host rc ${$(hostname)//.*/}