zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Disable beeps.
  15 setopt nobeep
  16
  17 # Prevent overwriting existing files with '> filename', use '>| filename'
  18 # (or >!) instead.
  19 setopt noclobber
  20
  21 # Entering the name of a directory (if it's not a command) will automatically
  22 # cd to that directory.
  23 setopt autocd
  24
  25 # When entering a nonexistent command name automatically try to find a similar
  26 # one.
  27 setopt correct
  28
  29 # Enable zsh's extended glob abilities.
  30 setopt extendedglob
  31
  32 # Don't exit if <C-d> is pressed.
  33 setopt ignoreeof
  34
  35
  36 # FUNCTION SETTINGS
  37
  38 # Make sure every entry in $fpath is unique.
  39 typeset -U fpath
  40 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  41 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  42 if [[ -d ~/.zsh/functions/completion ]]; then
  43     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  44 fi
  45 # Set correct fpath to allow loading my functions (including completion
  46 # functions).
  47 fpath=(~/.zsh/functions $fpath)
  48 # Autoload my functions (except completion functions and hidden files). Thanks
  49 # to caphuso from the Zsh example files for this idea.
  50 if [[ -d ~/.zsh/functions ]]; then
  51     autoload ${fpath[1]}/^_*(^/:t)
  52 fi
  53
  54 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  55 # the moment only precmd() and preexec() are simulated.
  56 #
  57 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  58 # so the compatibility version is used there too.
  59 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  60     # Provide add-zsh-hook which was added in 4.3.4.
  61     fpath=(~/.zsh/functions/compatibility $fpath)
  62
  63     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  64     function precmd() {
  65         for function in $precmd_functions; do
  66             $function $@
  67         done
  68     }
  69     function preexec() {
  70         for function in $preexec_functions; do
  71             $function $@
  72         done
  73     }
  74 fi
  75
  76 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  77 autoload -Uz add-zsh-hook
  78
  79 # Load zmv (zsh move) which is powerful to rename files.
  80 autoload zmv
  81
  82 # HISTORY SETTINGS
  83
  84 # Use history and store it in ~/.zsh/history.
  85 HISTSIZE=50000
  86 SAVEHIST=50000
  87 HISTFILE=~/.zsh/history
  88 # Append to the history file instead of overwriting it and do it immediately
  89 # when a command is executed.
  90 setopt appendhistory
  91 setopt incappendhistory
  92 # If the same command is run multiple times store it only once in the history.
  93 setopt histignoredups
  94 # Vim like completions of previous executed commands (also enter Vi-mode). If
  95 # called at the beginning it just recalls old commands (like cursor up), if
  96 # called after typing something only lines starting with the typed are
  97 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
  98 # on Freenode (2010-01-17 12:47) for the information how to a use function
  99 # with bindkey.
 100 zle -N my-vi-history-beginning-search-backward
 101 my-vi-history-beginning-search-backward() {
 102     local not_at_beginning_of_line
 103     if [[ $CURSOR -ne 0 ]]; then
 104         not_at_beginning_of_line=yes
 105     fi
 106
 107     zle history-beginning-search-backward
 108
 109     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 110     # this counters it).
 111     zle vi-cmd-mode
 112     if [[ -n $not_at_beginning_of_line ]]; then
 113         zle vi-forward-char
 114     fi
 115 }
 116 bindkey "^P" my-vi-history-beginning-search-backward
 117 bindkey -a "^P" history-beginning-search-backward # binding for Vi-mode
 118 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 119 # after calling ^P.
 120 bindkey -a "^N" history-beginning-search-forward
 121
 122
 123 # PROMPT SETTINGS
 124
 125 # Use colorized output, necessary for prompts and completions.
 126 autoload -U colors && colors
 127
 128 # Some shortcuts for colors.
 129 local red="%{${fg[red]}%}"
 130 local blue="%{${fg[blue]}%}"
 131 local green="%{${fg[green]}%}"
 132 local yellow="%{${fg[yellow]}%}"
 133 local default="%{${fg[default]}%}"
 134
 135 # Set the default prompt. The current host and working directory is displayed,
 136 # the exit code of the last command if it wasn't 0, the number of running jobs
 137 # if not 0 and a + if this shell is running inside another shell.
 138 # The prompt is in green and blue to make easily detectable, the error exit
 139 # code in red and bold and the job count in yellow.
 140 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 141 %(1j.$yellow%j$default.)%# \
 142 %(?..($red%B%?%b$default%) )"
 143
 144 # VCS_Info was added in 4.3.9 but it works in earlier versions too. So load it
 145 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 146 # symbolic link to current checkout of Zsh's sources).
 147 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 148       -d ~/.zsh/functions/vcs_info ]]; then
 149     # Update fpath to allow loading the VCS_Info functions.
 150     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 151        fpath=(~/.zsh/functions/vcs_info/
 152               ~/.zsh/functions/vcs_info/Backends
 153               $fpath)
 154     fi
 155
 156     # Allow substitutions and expansions in the prompt, necessary for
 157     # VCS_info.
 158     setopt promptsubst
 159     # Load VCS_info to display information about version control repositories.
 160     autoload -Uz vcs_info
 161     # Only look for git and mercurial repositories; the only I use.
 162     zstyle ':vcs_info:*' enable git hg
 163     # Check the repository for changes so they can be used in %u/%c (see
 164     # below). This comes with a speed penalty for bigger repositories.
 165     zstyle ':vcs_info:*' check-for-changes true
 166
 167     # Set style of VCS_info display. The current branch (green) and VCS (blue)
 168     # is displayed. If there is an special action going on (merge, rebase)
 169     # it's also displayed (red).
 170     zstyle ':vcs_info:*' formats \
 171         "($green%b%u%c$default:$blue%s$default)"
 172     zstyle ':vcs_info:*' actionformats \
 173         "($green%b$default/$red%a$default:$blue%s$default)"
 174     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 175     # changes are detected in the repository; check-for-changes must be set to
 176     # true for this to work. Thanks to Bart Trojanowski
 177     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 178     # (2010-03-11 00:20).
 179     zstyle ':vcs_info:*' unstagedstr '¹'
 180     zstyle ':vcs_info:*' stagedstr   '²'
 181
 182     # Call VCS_info as precmd before every prompt.
 183     prompt_precmd() {
 184         vcs_info
 185     }
 186     add-zsh-hook precmd prompt_precmd
 187
 188     # Display the VCS information in the right prompt.
 189     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 190         RPROMPT='${vcs_info_msg_0_}'
 191     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 192     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 193     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 194     else
 195         RPROMPT='${vcs_info_msg_0_:- }'
 196     fi
 197 fi
 198
 199 unset red blue green yellow default
 200
 201 # When screen, xterm or rxvt is used set the name of the window to the
 202 # currently running program.
 203 #
 204 # When a program is started preexec() sets the window's name to it; when it
 205 # stops precmd() resets the window's name to 'zsh'.
 206 #
 207 # It works with screen, xterm and rxvt.
 208 #
 209 # If a command is run with sudo or if the shell is running as root then a ! is
 210 # added at the beginning of the command to make this clear. If a command is
 211 # running on a different computer with ssh a @ is added at the beginning. This
 212 # only works if the .zshrc on the server also uses this command.
 213 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 214     # Is set to a non empty value to reset the window name in the next
 215     # precmd() call.
 216     window_reset=yes
 217     # Is set to a non empty value when the shell is running as root.
 218     if [[ $(id -u) -eq 0 ]]; then
 219         window_root=yes
 220     fi
 221
 222     window_preexec() {
 223         # Get the program name with its arguments.
 224         local program_name=$1
 225
 226         # When sudo is used use real program name instead, but with an
 227         # exclamation mark at the beginning (handled below).
 228         local program_sudo=
 229         if [[ $program_name == sudo* ]]; then
 230             program_name=${program_name#sudo }
 231             program_sudo=yes
 232         fi
 233         # Remove all arguments from the program name.
 234         program_name=${program_name%% *}
 235
 236         # Ignore often used commands which are only running for a very short
 237         # time. This prevents a "blinking" name when it's changed to "cd" for
 238         # example and then some milliseconds later back to "zsh".
 239         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 240
 241         # Change my shortcuts so the real name of the program is displayed.
 242         case $program_name in
 243             e)
 244                 program_name=elinks
 245                 ;;
 246             g)
 247                 program_name=git
 248                 ;;
 249             m)
 250                 program_name=mutt
 251                 ;;
 252             v|vi)
 253                 program_name=vim
 254                 ;;
 255         esac
 256
 257         # Add an exclamation mark at the beginning if running with sudo or if
 258         # running zsh as root.
 259         if [[ -n $program_sudo || -n $window_root ]]; then
 260             program_name=!$program_name
 261         fi
 262
 263         # Add an at mark at the beginning if running through ssh on a
 264         # different computer.
 265         if [[ -n $SSH_CONNECTION ]]; then
 266             program_name="@$program_name"
 267         fi
 268
 269         # Set the window name to the currently running program.
 270         window_title "$program_name"
 271
 272         # Tell precmd() to reset the window name when the program stops.
 273         window_reset=yes
 274     }
 275
 276     window_precmd() {
 277         # Abort if no window name reset is necessary.
 278         [[ -z $window_reset ]] && return
 279
 280         # Reset the window name to 'zsh'.
 281         local name="zsh"
 282         # If the function was called with an argument then reset the window
 283         # name to '.zsh' (used by clear alias).
 284         if [[ -n $1 ]]; then
 285             name=".zsh"
 286         fi
 287
 288         # Prepend prefixes like in window_preexec().
 289         if [[ -n $SSH_CONNECTION ]]; then
 290             window_title "@$name"
 291         elif [[ -n $window_root ]]; then
 292             window_title "!$name"
 293         else
 294             window_title $name
 295         fi
 296
 297         # Just reset the name, so no screen reset necessary for the moment.
 298         window_reset=
 299     }
 300
 301     # Sets the window title. Works with screen, xterm and rxvt.
 302     window_title() {
 303         if [[ $TERM == screen* ]]; then
 304             print -n "\ek$1\e\\"
 305
 306         elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 307             print -n "\e]2;$1\e\\"
 308         fi
 309     }
 310
 311     # Add the preexec() and precmd() hooks.
 312     add-zsh-hook preexec window_preexec
 313     add-zsh-hook precmd window_precmd
 314 fi
 315
 316
 317 # COMPLETION SETTINGS
 318
 319 # Load the complist module which provides additions to completion lists
 320 # (coloring, scrollable).
 321 zmodload zsh/complist
 322 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 323 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 324 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 325 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 326
 327 # Use cache to speed up completions.
 328 zstyle ':completion:*' use-cache on
 329 zstyle ':completion:*' cache-path ~/.zsh/cache
 330
 331 # Complete arguments and fix spelling mistakes when possible.
 332 zstyle ':completion:*' completer _complete _match _correct _approximate
 333
 334 # Make sure the list of possible completions is displayed after pressing <TAB>
 335 # the first time.
 336 setopt nolistambiguous
 337 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 338 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 339 bindkey "^I" expand-or-complete-prefix
 340 # Try uppercase if the currently typed string doesn't match. This allows
 341 # typing in lowercase most of the time and completion fixes the case.
 342 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 343
 344 # Use ls like colors for completions.
 345 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 346
 347 # Make completion lists scrollable so "do you wish to see all n possibilities"
 348 # is no longer displayed.
 349 zstyle ':completion:*' list-prompt '%p'
 350 # Display group name (like 'external command', 'alias', etc.) when there are
 351 # multiple matches in bold.
 352 zstyle ':completion:*' format '    %B%d%b:'
 353 # Display different types of matches separately.
 354 zstyle ':completion:*' group-name ''
 355
 356 # Ignore completion functions.
 357 zstyle ':completion:*:functions' ignored-patterns '_*'
 358 # Ignore parent directory.
 359 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 360 # When unsetting variables make sure every variable name is only suggested
 361 # once.
 362 zstyle ':completion:*:unset:*' ignore-line yes
 363 # When working with Mercurial and Git don't complete the same file multiple
 364 # times. Very useful when completing file names.
 365 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 366
 367
 368 # CUSTOM ALIASES AND FUNCTIONS
 369
 370 # If ^C is pressed while typing a command, add it to the history so it can be
 371 # easily retrieved later and then abort like ^C normally does. This is useful
 372 # when I want to abort an command to do something in between and then finish
 373 # typing the command.
 374 #
 375 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 376 # starting with - don't cause errors.
 377 TRAPINT() {
 378     # Store the current buffer in the history.
 379     zle && print -s -- $BUFFER
 380
 381     # Return the default exit code so zsh aborts the current command.
 382     return $1
 383 }
 384
 385 # Colorize stderr. Very useful when looking for errors. Thanks to
 386 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 387 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 388 # perfect and doesn't work with some interactive stderr output, but in those
 389 # cases the E alias can be used as workaround.
 390 exec 2>>(while read -r line; do
 391     printf '\e[91m%s\e[0m\n' "$line"
 392     print -n $'\0';
 393 done &)
 394
 395 # Load aliases and similar functions also used by other shells.
 396 if [[ -f ~/.shell/aliases ]]; then
 397     . ~/.shell/aliases
 398 fi
 399
 400 # Make sure aliases are expanded when using sudo.
 401 alias sudo='sudo '
 402
 403 # Global aliases for often used commands in the command line.
 404 alias -g E='2>&1'
 405 alias -g L='E | less'
 406 alias -g D='E | colordiff L'
 407 alias -g G='| grep'
 408 alias -g S='| sort'
 409 alias -g U='| uniq'
 410
 411 # Make going up directories simple.
 412 alias -g ...='../..'
 413 alias -g ....='../../..'
 414 alias -g .....='../../../..'
 415
 416 # If the window naming feature is used (see above) then use ".zsh" (leading
 417 # dot) as title name after running clear so it's clear to me that the window
 418 # is empty. I open so much windows that I don't know in which I have something
 419 # important. This helps me to remember which windows are empty (I run clear
 420 # after I finished my work in a window).
 421 if [[ -n $window_reset ]]; then
 422     alias clear='clear; window_reset=yes; window_precmd reset'
 423 fi
 424
 425 # Display all branches (except stash) in gitk but only 200 commits as this is
 426 # much faster. Also put in the background and disown. Thanks to sitaram in
 427 # #git on Freenode (2009-04-20 15:51).
 428 gitk() {
 429     command gitk \
 430         --max-count=200 \
 431         $(git rev-parse --symbolic-full-name --remotes --branches) \
 432         $@ &
 433     disown %command
 434 }
 435 # Same for tig (except the disown part as it's no GUI program).
 436 tig() {
 437     command tig \
 438         --max-count=200 \
 439         $(git rev-parse --symbolic-full-name --remotes --branches) \
 440         $@
 441 }
 442
 443
 444 # RUN COMMANDS
 445
 446 # If not already in screen reattach to a running session or create a new one.
 447 #
 448 # screen* is necessary as `screen` uses screen.linux for example for a linux
 449 # console which would otherwise cause an infinite loop.
 450 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 451     # Get running detached sessions.
 452     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 453     # Create a new session if none is running.
 454     if [[ -z $session ]]; then
 455         screen
 456     # Reattach to a running session.
 457     else
 458         screen -r $session
 459     fi
 460 fi
 461
 462
 463 # OS SPECIFIC SETTINGS
 464
 465 if [[ $(uname) == Linux ]]; then
 466     # Settings when creating Debian packages.
 467     DEBEMAIL=simon@ruderich.org
 468     export DEBEMAIL
 469     DEBFULLNAME="Simon Ruderich"
 470     export DEBFULLNAME
 471
 472 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 473     # Store the current clipboard in CLIPBOARD before every command so it can
 474     # be used in commands.
 475     os_darwin_preexec() {
 476         export CLIPBOARD="$(pbpaste)"
 477     }
 478     # Add the function as preexec hook.
 479     add-zsh-hook preexec os_darwin_preexec
 480
 481     # Initialize CLIPBOARD so it's available for completion directly after
 482     # startup.
 483     CLIPBOARD=""
 484     export CLIPBOARD
 485
 486     # Fetch current URL in clipboard with wget.
 487     alias wnc='wget --no-proxy $CLIPBOARD'
 488 fi
 489
 490
 491 # Load rc file for current hostname (first part before a dot) or rc.local.
 492 source_config ~/.zsh host rc ${$(hostname)//.*/}
 493
 494 source_debug "finished sourcing ~/.zsh/rc"
 495
 496 # vim: ft=zsh