zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Use Vi(m) style key bindings.
   9 bindkey -v
  10
  11 # Be paranoid, new files are readable/writable by me only.
  12 umask 077
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # FUNCTION SETTINGS
  34
  35 # Make sure every entry in $fpath is unique.
  36 typeset -U fpath
  37 # Set correct fpath to allow loading my functions (including completion
  38 # functions).
  39 fpath=(~/.zsh/functions $fpath)
  40 # Autoload my functions (except completion functions and hidden files). Thanks
  41 # to caphuso from the Zsh example files for this idea.
  42 autoload ${fpath[1]}/^_*(^/:t)
  43
  44 # Simulate hooks using _functions arrays for Zsh versions older then 4.3.4. At
  45 # the moment only precmd() and preexec() are simulated.
  46 #
  47 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  48 # so the compatibility version is used there too.
  49 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  50     # Provide add-zsh-hook which was added in 4.3.4.
  51     fpath=(~/.zsh/functions/compatibility $fpath)
  52
  53     # Run all functions defined in the ${precmd,preexec}_functions arrays.
  54     function precmd() {
  55         for function in $precmd_functions; do
  56             $function $@
  57         done
  58     }
  59     function preexec() {
  60         for function in $preexec_functions; do
  61             $function $@
  62         done
  63     }
  64 fi
  65
  66 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  67 autoload -Uz add-zsh-hook
  68
  69
  70 # HISTORY SETTINGS
  71
  72 # Use history and store it in ~/.zsh/history.
  73 HISTSIZE=5000
  74 SAVEHIST=5000
  75 HISTFILE=~/.zsh/history
  76 # Append to the history file instead of overwriting it and do it immediately
  77 # when a command is executed.
  78 setopt appendhistory
  79 setopt incappendhistory
  80 # If the same command is run multiple times store it only once in the history.
  81 setopt histignoredups
  82 # Vim like completions of previous executed commands.
  83 bindkey "^P" history-beginning-search-backward
  84 bindkey "^N" history-beginning-search-forward
  85
  86
  87 # PROMPT SETTINGS
  88
  89 # Use colorized output, necessary for prompts and completions.
  90 autoload -U colors && colors
  91
  92 # Set the default prompt. The current host and working directory is displayed,
  93 # the exit code of the last command if it wasn't 0, the number of running jobs
  94 # if not 0 and a + if this shell is running inside another shell.
  95 # The prompt is in green and blue to make easily detectable, the error exit
  96 # code in red and bold and the job count in yellow.
  97 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  98 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  99 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
 100 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
 101
 102 # VCS_Info was added in 4.3.9.
 103 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 104     # Allow substitutions and expansions in the prompt, necessary for
 105     # vcs_info.
 106     setopt promptsubst
 107     # Load vcs_info to display information about version control repositories.
 108     autoload -Uz vcs_info
 109     # Only look for git and mercurial repositories; the only I use.
 110     zstyle ':vcs_info:*' enable git hg
 111     # Set style of vcs_info display. The current branch (green) and vcs (blue)
 112     # is displayed. If there is an special action going on (merge, rebase)
 113     # it's also displayed (red).
 114     zstyle ':vcs_info:*' formats \
 115     "(%{${fg[green]}%}%b%{${fg[default]}%}:\
 116 %{${fg[blue]}%}%s%{${fg[default]}%})"
 117     zstyle ':vcs_info:*' actionformats \
 118     "(%{${fg[green]}%}%b%{${fg[default]}%}/\
 119 %{${fg[red]}%}%a%{${fg[default]}%}:\
 120 %{${fg[blue]}%}%s%{${fg[default]}%})"
 121     # Call vcs_info as precmd before every prompt.
 122     prompt_precmd() {
 123         vcs_info
 124     }
 125     add-zsh-hook precmd prompt_precmd
 126
 127     # Display the vcs information in the right prompt.
 128     RPROMPT='${vcs_info_msg_0_}'
 129 fi
 130
 131 # When screen or xterm is used set the name of the window to the currently
 132 # running program.
 133 #
 134 # When a program is started preexec() sets the window's name to it; when it
 135 # stops precmd() resets the windows' name to 'zsh'.
 136 #
 137 # It works with screen and xterm. If screen is running in X11 (DISPLAY is set)
 138 # and stumpwm is used (it's tested if stumpish is available) then the window
 139 # title is also set in stumpwm using stumpish.
 140 if [[ $TERM == screen* || $TERM == xterm* ]]; then
 141     # Set to a non empty value to reset the window name in the next precmd()
 142     # call.
 143     window_reset=yes
 144     # Set to a non empty value when the stump window manager is available.
 145     which stumpwm &> /dev/null
 146     if [[ $? -eq 0 ]]; then
 147         window_stumpwm=yes
 148     fi
 149     # Set to a non empty value when the shell is running as root.
 150     if [[ $(id -u) -eq 0 ]]; then
 151         window_root=yes
 152     fi
 153
 154     window_preexec() {
 155         # Get the program name with its arguments.
 156         local program_name=$1
 157
 158         # When sudo is used use real program name instead, but with an
 159         # exclamation mark at the beginning.
 160         local program_sudo=
 161         if [[ $program_name == sudo* ]]; then
 162             program_name=${program_name#sudo }
 163             program_sudo=yes
 164         fi
 165         # Remove all arguments from the program name.
 166         program_name=${program_name%% *}
 167
 168         # Ignore often used commands which are only running for a very short
 169         # time. This prevents a "blinking" name when it's changed to "cd" for
 170         # example and then some milliseconds later back to "zsh".
 171         [[ $program_name == (cd*|ls|la|ll|clear) ]] && return
 172
 173         # Change my shortcuts so the real name of the program is displayed.
 174         case $program_name in
 175             e)
 176                 program_name=elinks
 177                 ;;
 178             g)
 179                 program_name=git
 180                 ;;
 181             m)
 182                 program_name=mutt
 183                 ;;
 184             v|vi)
 185                 program_name=vim
 186                 ;;
 187         esac
 188
 189         # Add an exclamation mark at the beginning if running with sudo or if
 190         # running zsh as root.
 191         if [[ $program_sudo == yes || $window_root == yes ]]; then
 192             program_name=!$program_name
 193         fi
 194
 195         # Add an at mark at the beginning if running ssh on a different
 196         # computer.
 197         if [[ -n $SSH_CONNECTION ]]; then
 198             program_name="@$program_name"
 199         fi
 200
 201         # Set the window name to the currently running program.
 202         window_title "$program_name"
 203
 204         # Tell precmd() to reset the window name when the program stops.
 205         window_reset=yes
 206     }
 207
 208     window_precmd() {
 209         # Abort if no window name reset is necessary.
 210         [[ -z $window_reset ]] && return
 211
 212         # Reset the window name to 'zsh'.
 213         if [[ -n $SSH_CONNECTION ]]; then
 214             window_title "@zsh"
 215         elif [[ $window_root == yes ]]; then
 216             window_title "!zsh"
 217         else
 218             window_title "zsh"
 219         fi
 220
 221         # Just reset the name, so no screen reset necessary for the moment.
 222         window_reset=
 223     }
 224
 225     # Sets the window title. Works with screen and xterm.
 226     window_title() {
 227         if [[ $TERM == screen* ]]; then
 228             print -n "\ek$1\e\\"
 229
 230             # Update window name in stumpwm if running screen in X11 and when
 231             # stumpwm is used.
 232             if [[ -n $DISPLAY && -n $window_stumpwm ]]; then
 233                 echo "$1" | stumpish -e "title" > /dev/null
 234             fi
 235
 236         elif [[ $TERM == xterm* ]]; then
 237             print -n "\e]2;$1\e\\"
 238         fi
 239     }
 240
 241     # Add the preexec() and precmd() hooks.
 242     add-zsh-hook preexec window_preexec
 243     add-zsh-hook precmd window_precmd
 244 fi
 245
 246
 247 # COMPLETION SETTINGS
 248
 249 # Load the complist module which provides additions to completion lists
 250 # (coloring, scrollable).
 251 zmodload zsh/complist
 252 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 253 # cluttering of ~/.
 254 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 255
 256 # Use cache to speed up completions.
 257 zstyle ':completion:*' use-cache on
 258 zstyle ':completion:*' cache-path ~/.zsh/cache
 259
 260 # Complete arguments and fix spelling mistakes when possible.
 261 zstyle ':completion:*' completer _complete _match _correct _approximate
 262
 263 # Make sure the list of possible completions is displayed after pressing <TAB>
 264 # the first time.
 265 setopt nolistambiguous
 266 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 267 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 268 bindkey "^I" expand-or-complete-prefix
 269 # Try uppercase if the currently typed string doesn't match. This allows
 270 # typing in lowercase most of the time and completion fixes the case.
 271 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 272
 273 # Use ls like colors for completions.
 274 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 275
 276 # Make completion lists scrollable so "do you wish to see all n possibilities"
 277 # is no longer displayed.
 278 zstyle ':completion:*' list-prompt '%p'
 279 # Display group name (like 'external command', 'alias', etc.) when there are
 280 # multiple matches in bold.
 281 zstyle ':completion:*' format '    %B%d%b:'
 282 # Display different types of matches separately.
 283 zstyle ':completion:*' group-name ''
 284
 285 # Ignore completion functions.
 286 zstyle ':completion:*:functions' ignored-patterns '_*'
 287 # Ignore parent directory.
 288 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 289 # When unsetting variables make sure every variable name is only suggested
 290 # once.
 291 zstyle ':completion:*:unset:*' ignore-line yes
 292 # When working with Mercurial and Git don't complete the same file multiple
 293 # times. Very useful when completing file names.
 294 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 295
 296
 297 # CUSTOM ALIASES AND FUNCTIONS
 298
 299 # Make sure aliases are expanded when using sudo.
 300 alias sudo='sudo '
 301
 302 # Simplify calls to less, automatically redirects all output.
 303 alias -g L='2>&1 | less'
 304 # Simplify calls to colordiff, output is also piped through less.
 305 alias -g D='2>&1 | colordiff L'
 306 # Simplify calls to grep.
 307 alias -g G='| grep'
 308
 309 # Automatically use unified diffs.
 310 alias diff='diff -u'
 311
 312 # Display all files and use human readable sizes.
 313 alias du='du -sh'
 314
 315 # Use human readable sizes.
 316 alias df='df -h'
 317
 318 # Multiple files given to Vim are opened in tabs, supported since Vim 7.
 319 if [[ ${${${(f)"$(vim --version)"}[1]#VIM - Vi IMproved }%% *} == 7* ]]; then
 320     alias vim='vim -p'
 321 fi
 322
 323 # Shortcuts for often used programs.
 324 alias e='elinks'
 325 alias g='git'
 326 alias m='mutt'
 327 alias v='vim'
 328 alias vi='vim'
 329
 330 # I sometimes confuse editor and shell, print a warning to prevent I exit the
 331 # shell.
 332 alias :q='echo "This is not Vim!" >&2'
 333
 334 # Edit the mercurial patch queue series file for the current mercurial
 335 # repository in Vim. Also change Vim's pwd to the patches directory so other
 336 # patches can easily be opened.
 337 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 338
 339 # Make going up directories simple.
 340 alias -g ...='../..'
 341 alias -g ....='../../..'
 342 alias -g .....='../../../..'
 343
 344 # Improved ls which displays the files in columns (-C), visualizes
 345 # directories, links and other special files (-F) and pages everything through
 346 # less (L).
 347 #
 348 # If available use GNU ls with colorized output. If it isn't available use
 349 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 350 # pager.
 351 ls --color &> /dev/null
 352 if [[ $? -eq 0 ]]; then
 353     alias ls='ls --color'
 354 else
 355     alias ls='CLICOLOR_FORCE=1 ls -G'
 356 fi
 357 # Main ls function.
 358 function ls() {
 359     command ls -C -F $* L
 360 }
 361 # Helper function to list all files.
 362 function la() {
 363     ls -a $*
 364 }
 365 # Helper function to list all files in list format with access rights, etc.
 366 function ll() {
 367     la -l $*
 368 }
 369
 370 # If ^C is pressed while typing a command, add it to the history so it can be
 371 # easily retrieved later and then abort like ^C normally does. This is useful
 372 # when I want to abort an command to do something in between and then finish
 373 # typing the command.
 374 TRAPINT() {
 375     # Store the current buffer in the history.
 376     zle && print -s $BUFFER
 377
 378     # Return the default exit code so zsh aborts the current command.
 379     return $1
 380 }
 381
 382 # Display TODOs stored in ~/.todo if this file exists.
 383 todo() {
 384     if [[ -f ~/.todo ]]; then
 385         cat ~/.todo | $PAGER
 386     fi
 387 }
 388
 389 # Colorize stderr. Very useful when looking for errors. Thanks to
 390 # http://gentoo-wiki.com/wiki/Zsh
 391 exec 2>>(while read line; do
 392     print '\e[91m'${(q)line}'\e[0m' > /dev/tty; print -n $'\0'; done &)
 393
 394
 395 # RUN COMMANDS
 396
 397 # If not already in screen reattach to a running session or create a new one.
 398 #
 399 # screen* is necessary as `screen` uses screen.linux for example for a linux
 400 # console which would otherwise cause an infinite loop.
 401 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 402     # Create a new session if none is running.
 403     if [[ $(screen -list | grep "Detached" | wc -l) == 0 ]]; then
 404         screen
 405     # Reattach to a running session.
 406     else
 407         screen -r
 408     fi
 409 fi
 410
 411
 412 # Load rc file for current OS.
 413 source_config ~/.zsh os rc $(uname) nolocal
 414 # Load rc file for current hostname (first part before a dot) or rc.local.
 415 source_config ~/.zsh host rc ${$(hostname)//.*/}
 416
 417 source_debug "finished sourcing ~/.zsh/rc"
 418
 419 # vim: ft=zsh