zsh/rc: Disable Mercurial support for vcs_info.

[config/dotfiles.git] / zsh / rc

diff --git a/zsh/rc b/zsh/rc
index c6691783224feb182fc95edfc7f521d98fbad12b..8b5a333ccdbbf066c53f68bc5a69e96c31612c6b 100644 (file)
--- a/zsh/rc
+++ b/zsh/rc
@@ -1,6 +1,6 @@
 # Zsh configuration file.
 
-# Copyright (C) 2011-2012  Simon Ruderich
+# Copyright (C) 2011-2013  Simon Ruderich
 #
 # This file is free software: you can redistribute it and/or modify
 # it under the terms of the GNU General Public License as published by
@@ -85,8 +85,7 @@ setopt ignoreeof
 # Use Vi(m) style key bindings.
 bindkey -v
 
-# Use jj and jk to exit insert mode.
-bindkey 'jj' vi-cmd-mode
+# Use jk to exit insert mode (jj is too slow).
 bindkey 'jk' vi-cmd-mode
 
 # I don't need the arrow keys, I use ^N and ^P for this (see below).
@@ -221,8 +220,8 @@ if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
 
     # Load vcs_info to display information about version control repositories.
     autoload -Uz vcs_info
-    # Only look for git and mercurial repositories; the only I use.
-    zstyle ':vcs_info:*' enable git hg
+    # Only look for certain VCS.
+    zstyle ':vcs_info:*' enable git
     # Check the repository for changes so they can be used in %u/%c (see
     # below). This comes with a speed penalty for bigger repositories.
     zstyle ':vcs_info:*' check-for-changes yes
@@ -234,10 +233,10 @@ if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
           -d ~/.zsh/functions/vcs_info ]]; then
         zstyle ':vcs_info:*' formats \
-            "(${green}%b%u%c${default}:${blue}%s${default})" \
+            "(${green}%b%u%c${default}:${blue}%s${default}%m)" \
             "${green}%u%c${default}"
         zstyle ':vcs_info:*' actionformats \
-            "(${green}%b%u%c${default}/${red}%a${default}:${blue}%s${default})" \
+            "(${green}%b%u%c${default}/${red}%a${default}:${blue}%s${default}%m)" \
             "${green}%u%c${default}"
     else
         # In older versions %u and %c are not defined yet and are not
@@ -288,6 +287,26 @@ if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
         esac
     }
 
+    # Display number of WIP stashes (this excludes manually named commits
+    # which might be used for something else), thanks to
+    # http://eseth.org/2010/git-in-zsh.html (viewed on 2013-04-27) for the
+    # idea to display the stash count.
+    function +vi-git-stashes() {
+        if [[ -s ${hook_com[base]/.git/refs/stash} ]]; then
+            local -a stashes
+            # Thanks to Valodim in #zsh on Freenode (2013-07-01 14:14 CEST)
+            # for the solution to "grep" the output with (M) and :#(...).
+            stashes=( ${(M)${(f)"$(git stash list 2>/dev/null)"}:#(*WIP*)} )
+
+            if [[ ${#stashes} -gt 0 ]]; then
+                hook_com[misc]+=" ${yellow}${#stashes}s${default}"
+            fi
+        fi
+    }
+
+    # Apply hooks to Git.
+    zstyle ':vcs_info:git*+set-message:*' hooks git-stashes
+
     # Must run vcs_info when changing directories.
     prompt_chpwd() {
         zshrc_force_run_vcs_info=1
@@ -884,6 +903,17 @@ exec 2>>(while read -r -k -u 0 line; do
     print -n $'\0'
 done &)
 
+# Display possible log messages from ~/.xinitrc (if `xmessage` wasn't
+# installed). No race condition as xinitrc has finished before a shell is
+# executed and only one shell is started on login.
+if [[ -f ~/.xinitrc.errors ]]; then
+    echo "${fg_bold[red]}xinitrc failed!${fg_bold[default]}"
+    echo
+    cat ~/.xinitrc.errors
+    rm ~/.xinitrc.errors
+    echo
+fi
+
 # Run the following programs every 4 hours (and when zsh starts).
 PERIOD=14400
 periodic() {
@@ -894,6 +924,63 @@ periodic() {
 }
 
 
+# RESTART SETTINGS
+
+zmodload -F zsh/stat b:zstat
+
+# Remember startup time. Used to perform automatic restarts when ~/.zshrc is
+# modified.
+zshrc_startup_time=$EPOCHSECONDS
+
+# Automatically restart Zsh if ~/.zshrc was modified.
+zshrc_restart_precmd() {
+    local stat
+    if ! zstat -A stat +mtime ~/.zshrc; then
+        return
+    fi
+
+    # ~/.zshrc wasn't modified, nothing to do.
+    if [[ $stat -le $zshrc_startup_time ]]; then
+        return
+    fi
+
+    local startup
+    strftime -s startup '%Y-%m-%d %H:%M:%S' "$zshrc_startup_time"
+
+    echo -n "${fg[magenta]}"
+    echo -n "~/.zshrc modified since startup ($startup) ... "
+    echo -n "${fg[default]}"
+
+    if [[ -n $zshrc_disable_restart ]]; then
+        echo 'automatic restart disabled.'
+        return
+    fi
+
+    # Don't exec if we have background processes because execing will let us
+    # lose control over them.
+    if [[ ${#${(k)jobstates}} -ne 0 ]]; then
+        echo 'active background jobs!'
+        return
+    fi
+
+    # Try to start a new interactive shell. If it fails, something is wrong.
+    # Don't kill our current session by execing it.
+    zsh -i -c 'exit 42'
+    if [[ $? -ne 42 ]]; then
+        echo -n "${fg_bold[red]}"
+        echo 'failed to start new zsh!'
+        echo -n "${fg_bold[default]}"
+        return
+    fi
+
+    echo 'restarting zsh.'
+    echo
+
+    exec zsh
+}
+precmd_functions+=(zshrc_restart_precmd)
+
+
 source_debug '. ~/.zsh/rc (done)'
 
 # vim: ft=zsh