bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2021  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.12';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 sub split_line {
 345     my ($line) = @_;
 346
 347     my @work = ($line);
 348     foreach my $delim (';', '&&', '||') {
 349         my @x;
 350         foreach (@work) {
 351             push @x, Text::ParseWords::parse_line(qr/\Q$delim\E/, 1, $_);
 352         }
 353         @work = @x;
 354     }
 355
 356     return map {
 357         # Ensure newline at the line end - necessary for
 358         # correct parsing later.
 359         $_ =~ s/\s+$//;
 360         $_ .= "\n";
 361     } @work;
 362 }
 363
 364 sub error_flags {
 365     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 366
 367     # Get string value of qr//-escaped regexps and if requested rename them.
 368     my @missing_flags = map {
 369             $flag_renames_ref->{$_}
 370         } @{$missing_flags_ref};
 371
 372     my $flags = join ' ', @missing_flags;
 373     printf '%d:', $number if defined $number;
 374     printf '%s (%s)%s %s',
 375            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 376            $line;
 377
 378     return;
 379 }
 380 sub error_non_verbose_build {
 381     my ($line, $number) = @_;
 382
 383     printf '%d:', $number if defined $number;
 384     printf '%s%s %s',
 385            error_color('NONVERBOSE BUILD', 'red'),
 386            error_color(':', 'yellow'),
 387            $line;
 388
 389     return;
 390 }
 391 sub error_invalid_cmake {
 392     my ($version) = @_;
 393
 394     printf "%s%s %s\n",
 395             error_color('INVALID CMAKE', 'red'),
 396             error_color(':', 'yellow'),
 397             $version;
 398
 399     return;
 400 }
 401 sub error_hardening_wrapper {
 402     printf "%s%s %s\n",
 403             error_color('HARDENING WRAPPER', 'red'),
 404             error_color(':', 'yellow'),
 405             'no checks possible, aborting';
 406
 407     return;
 408 }
 409 sub error_color {
 410     my ($message, $color) = @_;
 411
 412     if ($option_color) {
 413         return Term::ANSIColor::colored($message, $color);
 414     } else {
 415         return $message;
 416     }
 417 }
 418
 419 sub any_flags_used {
 420     my ($line, @flags) = @_;
 421
 422     foreach my $flag (@flags) {
 423         return 1 if $line =~ /$flag/;
 424     }
 425
 426     return 0;
 427 }
 428 sub all_flags_used {
 429     my ($line, $missing_flags_ref, @flags) = @_;
 430
 431     my @missing_flags = ();
 432     foreach my $flag (@flags) {
 433         if (not $line =~ /$flag/) {
 434             push @missing_flags, $flag;
 435         }
 436     }
 437
 438     return 1 if scalar @missing_flags == 0;
 439
 440     @{$missing_flags_ref} = @missing_flags;
 441     return 0;
 442 }
 443 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 444 # $good_flag is present.
 445 sub flag_overwritten {
 446     my ($line, $good_flag, $bad_flags) = @_;
 447
 448     if (not any_flags_used($line, @{$bad_flags})) {
 449         return 0;
 450     }
 451
 452     my $bad_pos = 0;
 453     foreach my $flag (@{$bad_flags}) {
 454         while ($line =~ /$flag/g) {
 455             if ($bad_pos < $+[0]) {
 456                 $bad_pos = $+[0];
 457             }
 458         }
 459     }
 460     my $good_pos = 0;
 461     while ($line =~ /$good_flag/g) {
 462         $good_pos = $+[0];
 463     }
 464     if ($good_pos > $bad_pos) {
 465         return 0;
 466     }
 467     return 1;
 468 }
 469
 470 sub cppflags_fortify_broken {
 471     my ($line, $missing_flags) = @_;
 472
 473     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 474     my $fortify_source = $def_cppflags_fortify[0];
 475
 476     # Some build systems enable/disable fortify source multiple times, check
 477     # the final result.
 478     if (not flag_overwritten($line,
 479                              $fortify_source,
 480                              \@def_cppflags_fortify_bad)) {
 481         return 0;
 482     }
 483     push @{$missing_flags}, $fortify_source;
 484     return 1;
 485 }
 486
 487 sub cflags_stack_broken {
 488     my ($line, $missing_flags, $strong) = @_;
 489
 490     my $flag = $strong ? $def_cflags_stack_strong[0]
 491                        : $def_cflags_stack[0];
 492
 493     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 494         return 0;
 495     }
 496     push @{$missing_flags}, $flag;
 497     return 1;
 498 }
 499
 500 # Modifies $missing_flags_ref array.
 501 sub pic_pie_conflict {
 502     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 503
 504     return 0 if not $pie;
 505     return 0 if not any_flags_used($line, @def_ldflags_pic);
 506
 507     my %flags = map { $_ => 1 } @flags_pie;
 508
 509     # Remove all PIE flags from @missing_flags as they are not required with
 510     # -fPIC.
 511     my @result = grep {
 512         not exists $flags{$_}
 513     } @{$missing_flags_ref};
 514     @{$missing_flags_ref} = @result;
 515
 516     # We got a conflict when no flags are left, thus only PIE flags were
 517     # missing. If other flags were missing abort because the conflict is not
 518     # the problem.
 519     return scalar @result == 0;
 520 }
 521
 522 sub is_non_verbose_build {
 523     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 524
 525     if ($line =~ /$libtool_regex/o) {
 526         # libtool's --silent hides the real compiler flags.
 527         if ($line =~ /\s--silent/) {
 528             return 1;
 529         # If --silent is not present, skip this line as some compiler flags
 530         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 531         # internally. libtool displays the real compiler command on the next
 532         # line, so the flags are checked as usual.
 533         } else {
 534             ${$skip_ref} = 1;
 535             return 0;
 536         }
 537     }
 538
 539     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 540                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 541                 or $line =~ /^\s*[][\/0-9 ]*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 542                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 543                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 544         return 0;
 545     }
 546
 547     # False positives.
 548     #
 549     # C++ compiler setting.
 550     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 551     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 552     # "Compiling" non binary files.
 553     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
 554     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 555     # "Compiling" with no file name.
 556     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 557         # $file_extension_regex may need spaces around the filename.
 558         return 0 if not " $1 " =~ /$file_extension_regex/o;
 559     }
 560
 561     my $file = $1;
 562
 563     # On the first pass we only check if this line is verbose or not.
 564     return 1 if not defined $input_ref;
 565
 566     # Second pass, we have access to the next lines.
 567     ${$skip_ref} = 0;
 568
 569     # CMake and other build systems print the non-verbose messages also when
 570     # building verbose. If a compiler and the file name occurs in the next
 571     # lines, treat it as verbose build.
 572     if (defined $file) {
 573         # Get filename, we can't use the complete path as only parts of it are
 574         # used in the real compiler command.
 575         $file =~ m{/([^/\s]+)$};
 576         $file = $1;
 577
 578         for (my $i = 1; $i <= $line_count; $i++) {
 579             my $next_line = $input_ref->[$line_offset + $i];
 580             last unless defined $next_line;
 581
 582             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 583                 # Not a non-verbose line, but we still have to skip the
 584                 # current line as it doesn't contain any compiler commands.
 585                 ${$skip_ref} = 1;
 586                 return 0;
 587             }
 588         }
 589     }
 590
 591     return 1;
 592 }
 593
 594 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 595 sub remove_flags {
 596     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 597
 598     my %removes = map { $_ => 1 } @flags;
 599     foreach my $flags (@{$flag_refs_ref}) {
 600         @{$flags} = grep {
 601             # Flag found as string.
 602             not exists $removes{$_}
 603             # Flag found as string representation of regexp.
 604                 and (not defined $flag_renames_ref->{$_}
 605                         or not exists $removes{$flag_renames_ref->{$_}})
 606         } @{$flags};
 607     }
 608
 609     return;
 610 }
 611
 612 # Modifies $flag_renames_ref hash.
 613 sub compile_flag_regexp {
 614     my ($flag_renames_ref, @flags) = @_;
 615
 616     my @result = ();
 617     foreach my $flag (@flags) {
 618         # Compile flag regexp for faster execution.
 619         my $regex = qr/\s(['"]?)$flag\1(?:\s|\\)/;
 620
 621         # Store flag name in replacement string for correct flags in messages
 622         # with qr//ed flag regexps.
 623         $flag_renames_ref->{$regex}
 624             = (exists $flag_renames_ref->{$flag})
 625                 ? $flag_renames_ref->{$flag}
 626                 : $flag;
 627
 628         push @result, $regex;
 629     }
 630     return @result;
 631 }
 632
 633 # Does any extension in @extensions exist in %{$extensions_ref}?
 634 sub extension_found {
 635     my ($extensions_ref, @extensions) = @_;
 636
 637     foreach my $extension (@extensions) {
 638         if (exists $extensions_ref->{$extension}) {
 639             return 1;
 640         }
 641     }
 642     return 0;
 643 }
 644
 645
 646 # MAIN
 647
 648 # Parse command line arguments.
 649 my $option_help             = 0;
 650 my $option_version          = 0;
 651 my $option_pie              = 0;
 652 my $option_bindnow          = 0;
 653 my @option_ignore_arch      = ();
 654 my @option_ignore_flag      = ();
 655 my @option_ignore_arch_flag = ();
 656 my @option_ignore_line      = ();
 657 my @option_ignore_arch_line = ();
 658 my $option_all              = 0;
 659 my $option_arch             = undef;
 660 my $option_buildd           = 0;
 661 my $option_debian           = 0;
 662    $option_color            = 0;
 663 my $option_line_numbers     = 0;
 664 if (not Getopt::Long::GetOptions(
 665             'help|h|?'           => \$option_help,
 666             'version'            => \$option_version,
 667             # Hardening options.
 668             'pie'                => \$option_pie,
 669             'bindnow'            => \$option_bindnow,
 670             'all'                => \$option_all,
 671             # Ignore.
 672             'ignore-arch=s'      => \@option_ignore_arch,
 673             'ignore-flag=s'      => \@option_ignore_flag,
 674             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 675             'ignore-line=s'      => \@option_ignore_line,
 676             'ignore-arch-line=s' => \@option_ignore_arch_line,
 677             # Misc.
 678             'color'              => \$option_color,
 679             'arch=s'             => \$option_arch,
 680             'buildd'             => \$option_buildd,
 681             'debian'             => \$option_debian,
 682             'line-numbers'       => \$option_line_numbers,
 683         )) {
 684     require Pod::Usage;
 685     Pod::Usage::pod2usage(2);
 686 }
 687 if ($option_help) {
 688     require Pod::Usage;
 689     Pod::Usage::pod2usage(1);
 690 }
 691 if ($option_version) {
 692     print <<"EOF";
 693 blhc $VERSION  Copyright (C) 2012-2021  Simon Ruderich
 694
 695 This program is free software: you can redistribute it and/or modify
 696 it under the terms of the GNU General Public License as published by
 697 the Free Software Foundation, either version 3 of the License, or
 698 (at your option) any later version.
 699
 700 This program is distributed in the hope that it will be useful,
 701 but WITHOUT ANY WARRANTY; without even the implied warranty of
 702 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 703 GNU General Public License for more details.
 704
 705 You should have received a copy of the GNU General Public License
 706 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 707 EOF
 708     exit 0;
 709 }
 710
 711 # Arguments missing.
 712 if (scalar @ARGV == 0) {
 713     require Pod::Usage;
 714     Pod::Usage::pod2usage(2);
 715 }
 716
 717 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 718 # installed on Debian's buildds.
 719 if (not $option_buildd) {
 720     require Term::ANSIColor;
 721 }
 722
 723 if ($option_all) {
 724     $option_pie     = 1;
 725     $option_bindnow = 1;
 726 }
 727
 728 # Precompiled ignores for faster lookup.
 729 my %option_ignore_arch_flag = ();
 730 my %option_ignore_arch_line = ();
 731
 732 # Strip flags which should be ignored.
 733 if (scalar @option_ignore_flag > 0) {
 734     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 735 }
 736 # Same for arch specific ignore flags, but only prepare here.
 737 if (scalar @option_ignore_arch_flag > 0) {
 738     foreach my $ignore (@option_ignore_arch_flag) {
 739         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 740
 741         if (not $ignore_arch or not $ignore_flag) {
 742             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 743                         . '("arch:flag" expected)' . "\n", $ignore;
 744             require Pod::Usage;
 745             Pod::Usage::pod2usage(2);
 746         }
 747
 748         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 749     }
 750 }
 751
 752 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 753 # faster with this.
 754 foreach my $flags (@flag_refs_all) {
 755     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 756 }
 757
 758 # Precompile ignore line regexps, also anchor at beginning and end of line.
 759 # Additional entries are also extracted from the build log, see below.
 760 foreach my $ignore (@option_ignore_line) {
 761     $ignore = qr/^$ignore$/;
 762 }
 763 # Same for arch specific ignore lines.
 764 if (scalar @option_ignore_arch_line > 0) {
 765     foreach my $ignore (@option_ignore_arch_line) {
 766         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 767
 768         if (not $ignore_arch or not $ignore_line) {
 769             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 770                         . '("arch:line" expected)' . "\n", $ignore;
 771             require Pod::Usage;
 772             Pod::Usage::pod2usage(2);
 773         }
 774
 775         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 776     }
 777 }
 778
 779 # Final exit code.
 780 my $exit = 0;
 781
 782 FILE:
 783 foreach my $file (@ARGV) {
 784     print "checking '$file'...\n" if scalar @ARGV > 1;
 785
 786     -f $file or die "No such file: $file";
 787
 788     open my $fh, '<', $file or die $!;
 789
 790     # Architecture of this file.
 791     my $arch = $option_arch;
 792
 793     # Hardening options. Not all architectures support all hardening options.
 794     my $harden_format  = 1;
 795     my $harden_fortify = 1;
 796     my $harden_stack   = 1;
 797     my $harden_stack_strong = 1;
 798     my $harden_relro   = 1;
 799     my $harden_bindnow = $option_bindnow; # defaults to 0
 800     my $harden_pie     = $option_pie;     # defaults to 0
 801
 802     # Number of parallel jobs to prevent false positives when detecting
 803     # non-verbose builds. As not all jobs declare the number of parallel jobs
 804     # use a large enough default.
 805     my $parallel = 10;
 806
 807     # Don't check for PIE flags if automatically applied by the compiler. Only
 808     # used in buildd and Debian mode.
 809     my $disable_harden_pie = 0;
 810     if ($option_debian) {
 811         $disable_harden_pie = 1;
 812     }
 813
 814     my $number = 0;
 815     while (my $line = <$fh>) {
 816         $number++;
 817
 818         # Detect architecture automatically unless overridden. For buildd logs
 819         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 820         # build logs which aren't built (wrong architecture, build error,
 821         # etc.).
 822         if (not $arch) {
 823             if (index($line, 'Build Architecture: ') == 0) {
 824                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 825             # For old logs (sbuild << 0.63.0-1).
 826             } elsif (index($line, 'Architecture: ') == 0) {
 827                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 828             }
 829         }
 830
 831         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 832         # check for hardening flags in buildd mode if an older dpkg-dev is
 833         # used. Default flags (-g -O2) are still checked.
 834         #
 835         # Packages which were built before 1.16.1 but used their own hardening
 836         # flags are not checked.
 837         #
 838         # Strong stack protector is used since dpkg 1.17.11.
 839         #
 840         # Recent GCC versions automatically use PIE (only on supported
 841         # architectures) and dpkg respects this properly since 1.18.15 and
 842         # doesn't pass PIE flags manually.
 843         if ($option_buildd
 844                 and index($line, 'Toolchain package versions: ') == 0) {
 845             require Dpkg::Version;
 846
 847             my $disable = 1;
 848             my $disable_strong = 1;
 849
 850             if ($line =~ /\bdpkg-dev_(\S+)/) {
 851                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 852                     $disable = 0;
 853                 }
 854                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 855                     $disable_strong = 0;
 856                 }
 857                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 858                     $disable_harden_pie = 1;
 859                 }
 860             }
 861
 862             if ($disable) {
 863                 $harden_format  = 0;
 864                 $harden_fortify = 0;
 865                 $harden_stack   = 0;
 866                 $harden_relro   = 0;
 867                 $harden_bindnow = 0;
 868                 $harden_pie     = 0;
 869             }
 870             if ($disable_strong) {
 871                 $harden_stack_strong = 0;
 872             }
 873         }
 874
 875         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 876         # this was later dropped because upstream rejected the patch. Thus
 877         # build logs with these versions will have fortify hardening flags
 878         # enabled, even though they may be not correctly set and are missing
 879         # when build with later CMake versions. Thanks to Aron Xu for letting
 880         # me know.
 881         if (index($line, 'Package versions: ') == 0
 882                 and $line =~ /\bcmake_(\S+)/
 883                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 884             if (not $option_buildd) {
 885                 error_invalid_cmake($1);
 886                 $exit |= $exit_code{invalid_cmake};
 887             } else {
 888                 print "$buildd_tag{invalid_cmake}|$1|\n";
 889             }
 890         }
 891
 892         # Debian's build daemons use "Filtered Build-Depends:" (or just
 893         # "Build-Depends:" in older versions) for the build dependencies, but
 894         # pbuilder uses "Depends:"; support both.
 895         if (index($line, 'Filtered Build-Depends: ') == 0
 896                 or index($line, 'Build-Depends: ') == 0
 897                 or index($line, 'Depends: ') == 0) {
 898             # If hardening wrapper is used (wraps calls to gcc and adds
 899             # hardening flags automatically) we can't perform any checks,
 900             # abort.
 901             if ($line =~ /\bhardening-wrapper\b/) {
 902                 if (not $option_buildd) {
 903                     error_hardening_wrapper();
 904                     $exit |= $exit_code{hardening_wrapper};
 905                 } else {
 906                     print "$buildd_tag{hardening_wrapper}||\n";
 907                 }
 908                 next FILE;
 909             }
 910         }
 911
 912         # This flags is not always available, but if it is use it.
 913         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 914             $parallel = $1 * 2;
 915         }
 916
 917         # We skip over unimportant lines at the beginning of the log to
 918         # prevent false positives.
 919         last if index($line, 'dpkg-buildpackage: ') == 0;
 920     }
 921
 922     # Input lines, contain only the lines with compiler commands.
 923     my @input = ();
 924     # Non-verbose lines in the input. Used to reduce calls to
 925     # is_non_verbose_build() (which is quite slow) in the second loop when
 926     # it's already clear if a line is non-verbose or not.
 927     my @input_nonverbose = ();
 928     # Input line number.
 929     my @input_number = ();
 930
 931     my $continuation = 0;
 932     my $complete_line = undef;
 933     my $non_verbose;
 934     while (my $line = <$fh>) {
 935         $number++;
 936
 937         # And stop at the end of the build log. Package details (reported by
 938         # the buildd logs) are not important for us. This also prevents false
 939         # positives.
 940         last if index($line, 'Build finished at ') == 0
 941                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 942
 943         if (not $continuation) {
 944             $non_verbose = 0;
 945         }
 946
 947         # Detect architecture automatically unless overridden.
 948         if (not $arch
 949                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 950             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 951         # Older versions of dpkg-buildpackage
 952         } elsif (not $arch
 953                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 954             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 955
 956             # Old buildd logs use e.g. "host architecture is alpha", remove
 957             # the "is", otherwise debarch_to_debtriplet() will not detect the
 958             # architecture.
 959             if (index($arch, 'is ') == 0) {
 960                 $arch = substr $arch, 3;
 961             }
 962         }
 963
 964         # Permit dynamic excludes from within the build log to ignore false
 965         # positives. Cannot use a separate config file as we often only have
 966         # the build log itself.
 967         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
 968             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
 969             push @option_ignore_line, qr/^$ignore$/;
 970             next;
 971         }
 972
 973         next if $line =~ /^\s*#/;
 974         # Ignore compiler warnings for now.
 975         next if $line =~ /$warning_regex/o;
 976
 977         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 978             # Remove all ANSI color sequences which are sometimes used in
 979             # non-verbose builds.
 980             $line = Term::ANSIColor::colorstrip($line);
 981             # Also strip '\0xf' (delete previous character), used by Elinks'
 982             # build system.
 983             $line =~ s/\x0f//g;
 984             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 985             # what it does).
 986             $line =~ s/\033\(B//g;
 987         }
 988
 989         # Check if this line indicates a non verbose build.
 990         my $skip = 0;
 991         $non_verbose |= is_non_verbose_build($line, \$skip);
 992         next if $skip;
 993
 994         # Treat each command as a single line so we don't ignore valid
 995         # commands when handling false positives. split_line() is slow, only
 996         # use it when necessary.
 997         my @line = ($line !~ /(?:;|&&|\|\|)/)
 998                  ? ($line)
 999                  : split_line($line);
1000         foreach my $line (@line) {
1001             if ($continuation) {
1002                 $continuation = 0;
1003
1004                 # Join lines, but leave the "\" in place so it's clear where
1005                 # the original line break was.
1006                 chomp $complete_line;
1007                 $complete_line .= ' ' . $line;
1008             }
1009             # Line continuation, line ends with "\".
1010             if ($line =~ /\\$/) {
1011                 $continuation = 1;
1012                 # Start line continuation.
1013                 if (not defined $complete_line) {
1014                     $complete_line = $line;
1015                 }
1016                 next;
1017             }
1018
1019             # Use the complete line if a line continuation occurred.
1020             if (defined $complete_line) {
1021                 $line = $complete_line;
1022                 $complete_line = undef;
1023             }
1024
1025             my $noenv = $line;
1026             # Strip (basic) environment variables for compiler detection. This
1027             # prevents false positives when environment variables contain
1028             # compiler binaries. Nested quotes, command substitution, etc. is
1029             # not supported.
1030             $noenv =~ s/^
1031                 \s*
1032                 (?:
1033                     [a-zA-Z_]+          # environment variable name
1034                     =
1035                     (?:
1036                         [^\s"'\$`\\]+   # non-quoted string
1037                         |
1038                         '[^"'\$`\\]*'   # single-quoted string
1039                         |
1040                         "[^"'\$`\\]*"   # double-quoted string
1041                     )
1042                     \s+
1043                 )*
1044             //x;
1045             # Ignore lines with no compiler commands.
1046             next if not $non_verbose
1047                     and not $noenv =~ /$cc_regex_normal/o;
1048             # Ignore lines with no filenames with extensions. May miss some
1049             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1050             # a problem as the log will most likely contain other non-verbose
1051             # commands which are detected.
1052             next if not $non_verbose
1053                     and not $line =~ /$file_extension_regex/o;
1054
1055             # Ignore false positives.
1056             #
1057             # `./configure` output.
1058             next if not $non_verbose
1059                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1060             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1061                                 [Cc]ompiler[\s.]*:?\s+
1062                                 /x;
1063             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1064                                 \s*=\s*$cc_regex_full
1065                                 # optional compiler options, don't allow
1066                                 # "everything" here to prevent false negatives
1067                                 \s*(?:\s-\S+)*\s*$}xo;
1068             # `echo` is never a compiler command
1069             next if $line =~ /^\s*echo\s/;
1070             # Ignore calls to `make` because they can contain environment
1071             # variables which look like compiler commands, e.g. CC=).
1072             next if $line =~ /^\s*make\s/;
1073             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1074             # line (or similar for other architectures) which gets recognized
1075             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1076             # C++ files. No hardening flags are relevant during this step,
1077             # thus ignore `moc-qt*` lines. The resulting files will be
1078             # compiled in a separate step (and therefore checked).
1079             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1080                                \s.+\s
1081                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1082                                \s}x;
1083             # Ignore false positives when the line contains only CC=gcc but no
1084             # other gcc command.
1085             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1086                 my $before = $1;
1087                 my $after  = $2;
1088                 next if     not $before =~ /$cc_regex_normal/o
1089                         and not $after  =~ /$cc_regex_normal/o;
1090             }
1091             # Ignore false positives caused by gcc -v. It outputs a line
1092             # looking like a normal compiler line but which is sometimes
1093             # missing hardening flags, although the normal compiler line
1094             # contains them.
1095             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1096                                    [0-9.]+/cc1(?:plus)?}xo;
1097             # Ignore false positive with `rm` which may remove files which
1098             # look like a compiler executable thus causing the line to be
1099             # treated as a normal compiler line.
1100             next if $line =~ m{^\s*rm\s+};
1101             next if $line =~ m{^\s*dwz\s+};
1102             # Some build systems emit "gcc > file".
1103             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1104             # Hex output may contain "cc".
1105             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1106             # Meson build output
1107             next if $line =~ /^C\+\+ linker for the host machine: /;
1108             # Embedded `gcc -print-*` commands
1109             next if $line =~ /`$cc_regex_normal\s*[^`]*-print-\S+`/;
1110             # cmake checking for compiler flags without setting CPPFLAGS
1111             next if $line =~ m{^\s*/usr/(bin|lib)/(ccache/)?c\+\+ -dM -E -c /usr/share/cmake-\S+/Modules/CMakeCXXCompilerABI\.cpp};
1112
1113             # Check if additional hardening options were used. Used to ensure
1114             # they are used for the complete build.
1115             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1116                                                          @def_ldflags_pie);
1117             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1118
1119             push @input, $line;
1120             push @input_nonverbose, $non_verbose;
1121             push @input_number, $number if $option_line_numbers;
1122         }
1123     }
1124
1125     close $fh or die $!;
1126
1127     # Ignore arch if requested.
1128     if (scalar @option_ignore_arch > 0 and $arch) {
1129         foreach my $ignore (@option_ignore_arch) {
1130             if ($arch eq $ignore) {
1131                 print "ignoring architecture '$arch'\n";
1132                 next FILE;
1133             }
1134         }
1135     }
1136
1137     if (scalar @input == 0) {
1138         if (not $option_buildd) {
1139             print "No compiler commands!\n";
1140             $exit |= $exit_code{no_compiler_commands};
1141         } else {
1142             print "$buildd_tag{no_compiler_commands}||\n";
1143         }
1144         next FILE;
1145     }
1146
1147     if ($option_buildd) {
1148         $statistics{commands} += scalar @input;
1149     }
1150
1151     # Option or auto detected.
1152     if ($arch) {
1153         # The following was partially copied from dpkg-dev 1.20.5
1154         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1155         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1156         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1157         # licensed under GPL version 2 or later. Keep it in sync.
1158
1159         require Dpkg::Arch;
1160         my ($os, $cpu);
1161         # Recent dpkg versions use a quadruplet for arch. Support both.
1162         eval {
1163             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1164         };
1165         if ($@) {
1166             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1167         }
1168
1169         my %builtin_pie_arch = map { $_ => 1 } qw(
1170             amd64
1171             arm64
1172             armel
1173             armhf
1174             hurd-i386
1175             i386
1176             kfreebsd-amd64
1177             kfreebsd-i386
1178             mips
1179             mipsel
1180             mips64el
1181             powerpc
1182             ppc64
1183             ppc64el
1184             riscv64
1185             s390x
1186             sparc
1187             sparc64
1188         );
1189
1190         # Disable unsupported hardening options.
1191         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1192                 or $cpu =~ /^(?:hppa|avr32)$/) {
1193             $harden_pie = 0;
1194         }
1195         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1196             $harden_stack = 0;
1197             $harden_stack_strong = 0;
1198         }
1199         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1200             $harden_relro   = 0;
1201             $harden_bindnow = 0;
1202         }
1203
1204         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1205             $harden_pie = 0;
1206         }
1207     }
1208
1209     # Default values.
1210     my @cflags   = @def_cflags;
1211     my @cxxflags = @def_cxxflags;
1212     my @cppflags = @def_cppflags;
1213     my @ldflags  = @def_ldflags;
1214     # Check the specified hardening options, same order as dpkg-buildflags.
1215     if ($harden_pie) {
1216         @cflags   = (@cflags,   @def_cflags_pie);
1217         @cxxflags = (@cxxflags, @def_cflags_pie);
1218         @ldflags  = (@ldflags,  @def_ldflags_pie);
1219     }
1220     if ($harden_stack_strong) {
1221         @cflags   = (@cflags,   @def_cflags_stack_strong);
1222         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1223     } elsif ($harden_stack) {
1224         @cflags   = (@cflags,   @def_cflags_stack);
1225         @cxxflags = (@cxxflags, @def_cflags_stack);
1226     }
1227     if ($harden_fortify) {
1228         @cflags   = (@cflags,   @def_cflags_fortify);
1229         @cxxflags = (@cxxflags, @def_cflags_fortify);
1230         @cppflags = (@cppflags, @def_cppflags_fortify);
1231     }
1232     if ($harden_format) {
1233         @cflags   = (@cflags,   @def_cflags_format);
1234         @cxxflags = (@cxxflags, @def_cflags_format);
1235     }
1236     if ($harden_relro) {
1237         @ldflags = (@ldflags, @def_ldflags_relro);
1238     }
1239     if ($harden_bindnow) {
1240         @ldflags = (@ldflags, @def_ldflags_bindnow);
1241     }
1242
1243     # Ada doesn't support format hardening flags, see #680117 for more
1244     # information. Same for fortran.
1245     my @cflags_backup;
1246     my @cflags_noformat = grep {
1247         my $ok = 1;
1248         foreach my $flag (@def_cflags_format) {
1249             $ok = 0 if $_ eq $flag;
1250         }
1251         $ok;
1252     } @cflags;
1253
1254     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1255     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1256     # as long as @def_cppflags_fortify contains only one variable.
1257     if (scalar @def_cppflags_fortify == 0) {
1258         $harden_fortify = 0;
1259     }
1260
1261     # Ignore flags for this arch if requested.
1262     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1263         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1264
1265         remove_flags(\@local_flag_refs,
1266                      \%flag_renames,
1267                      @{$option_ignore_arch_flag{$arch}});
1268     }
1269
1270     my @ignore_line = @option_ignore_line;
1271     # Ignore lines for this arch if requested.
1272     if ($arch and exists $option_ignore_arch_line{$arch}) {
1273         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1274     }
1275
1276 LINE:
1277     for (my $i = 0; $i < scalar @input; $i++) {
1278         my $line = $input[$i];
1279
1280         # Ignore line if requested.
1281         foreach my $ignore (@ignore_line) {
1282             next LINE if $line =~ /$ignore/;
1283         }
1284
1285         my $skip = 0;
1286         if ($input_nonverbose[$i]
1287                 and is_non_verbose_build($line, \$skip,
1288                                          \@input, $i, $parallel)) {
1289             if (not $option_buildd) {
1290                 error_non_verbose_build($line, $input_number[$i]);
1291                 $exit |= $exit_code{non_verbose_build};
1292             } else {
1293                 $statistics{commands_nonverbose}++;
1294             }
1295             next;
1296         }
1297         # Even if it's a verbose build, we might have to skip this line (see
1298         # is_non_verbose_build()).
1299         next if $skip;
1300
1301         my $orig_line = $line;
1302
1303         # Remove everything until and including the compiler command. Makes
1304         # checks easier and faster.
1305         $line =~ s/^.*?$cc_regex//o;
1306         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1307         # the brace and similar characters at the line end.
1308         $line =~ s/['")]+$//;
1309
1310         # Skip unnecessary tests when only preprocessing.
1311         my $flag_preprocess = 0;
1312
1313         my $dependency = 0;
1314         my $preprocess = 0;
1315         my $compile    = 0;
1316         my $link       = 0;
1317
1318         # Preprocess, compile, assemble.
1319         if ($line =~ /\s(-E|-S|-c)\b/) {
1320             $preprocess      = 1;
1321             $flag_preprocess = 1 if $1 eq '-E';
1322             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1323         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1324         # -MT -MQ) are always used with -M/-MM.
1325         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1326             $dependency = 1;
1327         # Otherwise assume we are linking.
1328         } else {
1329             $link = 1;
1330         }
1331
1332         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1333         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1334             $dependency      = 0;
1335             $flag_preprocess = 0;
1336         }
1337
1338         # Dependency generation for Makefiles, no preprocessing or other flags
1339         # needed.
1340         next if $dependency;
1341
1342         # Get all file extensions on this line.
1343         my @extensions = $line =~ /$file_extension_regex/go;
1344         # Ignore all unknown extensions to speedup the search below.
1345         @extensions = grep { exists $extension{$_} } @extensions;
1346
1347         # These file types don't require preprocessing.
1348         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1349             $preprocess = 0;
1350         }
1351         # These file types require preprocessing.
1352         if (extension_found(\%extensions_preprocess, @extensions)) {
1353             # Prevent false positives with "libtool: link: g++ -include test.h
1354             # .." compiler lines.
1355             if ($orig_line !~ /$libtool_link_regex/o) {
1356                 $preprocess = 1;
1357             }
1358         }
1359
1360         if (not $flag_preprocess) {
1361             # If there are source files then it's compiling/linking in one
1362             # step and we must check both. We only check for source files
1363             # here, because header files cause too many false positives.
1364             if (extension_found(\%extensions_compile_link, @extensions)) {
1365                 # Assembly files don't need CFLAGS.
1366                 if (not extension_found(\%extensions_compile, @extensions)
1367                         and extension_found(\%extensions_no_compile, @extensions)) {
1368                     $compile = 0;
1369                 # But the rest does.
1370                 } else {
1371                     $compile = 1;
1372                 }
1373             # No compilable extensions found, either linking or compiling
1374             # header flags.
1375             #
1376             # If there are also no object files we are just compiling headers
1377             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1378             # to our liberal checks for compiler lines, this also reduces the
1379             # number of false positives considerably.
1380             } elsif ($link
1381                     and not extension_found(\%extensions_object, @extensions)) {
1382                 $link = 0;
1383             }
1384         }
1385
1386         my $compile_cpp = 0;
1387         my $restore_cflags = 0;
1388         # Assume CXXFLAGS are required when a C++ file is specified in the
1389         # compiler line.
1390         if ($compile
1391                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1392             $compile     = 0;
1393             $compile_cpp = 1;
1394         # Ada needs special CFLAGS
1395         } elsif (extension_found(\%extensions_ada, @extensions)) {
1396             $restore_cflags = 1;
1397             $preprocess = 0; # Ada uses no CPPFLAGS
1398             @cflags_backup = @cflags;
1399             @cflags        = @cflags_noformat;
1400         # Same for fortran
1401         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1402             $restore_cflags = 1;
1403             @cflags_backup = @cflags;
1404             @cflags        = @cflags_noformat;
1405         }
1406
1407         if ($option_buildd) {
1408             $statistics{preprocess}++  if $preprocess;
1409             $statistics{compile}++     if $compile;
1410             $statistics{compile_cpp}++ if $compile_cpp;
1411             $statistics{link}++        if $link;
1412         }
1413
1414         # Check if there are flags indicating a debug build. If that's true,
1415         # skip the check for -O2. This prevents fortification, but that's fine
1416         # for a debug build.
1417         if (any_flags_used($line, @def_cflags_debug)) {
1418             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1419             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1420         }
1421
1422         # Check hardening flags.
1423         my @missing;
1424         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1425                     or (($harden_stack or $harden_stack_strong)
1426                         and cflags_stack_broken($line, \@missing,
1427                                                 $harden_stack_strong)))
1428                 # Libraries linked with -fPIC don't have to (and can't) be
1429                 # linked with -fPIE as well. It's no error if only PIE flags
1430                 # are missing.
1431                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1432                 # Assume dpkg-buildflags returns the correct flags.
1433                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1434             if (not $option_buildd) {
1435                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1436                             $input[$i], $input_number[$i]);
1437                 $exit |= $exit_code{flags_missing};
1438             } else {
1439                 $statistics{compile_missing}++;
1440             }
1441         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1442                 # Libraries linked with -fPIC don't have to (and can't) be
1443                 # linked with -fPIE as well. It's no error if only PIE flags
1444                 # are missing.
1445                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1446                 # Assume dpkg-buildflags returns the correct flags.
1447                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1448             if (not $option_buildd) {
1449                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1450                             $input[$i], $input_number[$i]);
1451                 $exit |= $exit_code{flags_missing};
1452             } else {
1453                 $statistics{compile_cpp_missing}++;
1454             }
1455         }
1456         if ($preprocess
1457                 and (not all_flags_used($line, \@missing, @cppflags)
1458                     # The fortify flag might be overwritten, detect that.
1459                      or ($harden_fortify
1460                          and cppflags_fortify_broken($line, \@missing)))
1461                 # Assume dpkg-buildflags returns the correct flags.
1462                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1463             if (not $option_buildd) {
1464                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1465                             $input[$i], $input_number[$i]);
1466                 $exit |= $exit_code{flags_missing};
1467             } else {
1468                 $statistics{preprocess_missing}++;
1469             }
1470         }
1471         if ($link and not all_flags_used($line, \@missing, @ldflags)
1472                 # Same here, -fPIC conflicts with -fPIE.
1473                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1474                 # Assume dpkg-buildflags returns the correct flags.
1475                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1476             if (not $option_buildd) {
1477                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1478                             $input[$i], $input_number[$i]);
1479                 $exit |= $exit_code{flags_missing};
1480             } else {
1481                 $statistics{link_missing}++;
1482             }
1483         }
1484
1485         # Restore normal CFLAGS.
1486         if ($restore_cflags) {
1487             @cflags = @cflags_backup;
1488         }
1489     }
1490 }
1491
1492 # Print statistics for buildd mode, only output in this mode.
1493 if ($option_buildd) {
1494     my @warning;
1495
1496     if ($statistics{preprocess_missing}) {
1497         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1498                                $statistics{preprocess_missing},
1499                                $statistics{preprocess};
1500     }
1501     if ($statistics{compile_missing}) {
1502         push @warning, sprintf 'CFLAGS %d (of %d)',
1503                                $statistics{compile_missing},
1504                                $statistics{compile};
1505     }
1506     if ($statistics{compile_cpp_missing}) {
1507         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1508                                $statistics{compile_cpp_missing},
1509                                $statistics{compile_cpp};
1510     }
1511     if ($statistics{link_missing}) {
1512         push @warning, sprintf 'LDFLAGS %d (of %d)',
1513                                $statistics{link_missing},
1514                                $statistics{link};
1515     }
1516     if (scalar @warning) {
1517         local $" = ', '; # array join string
1518         print "$buildd_tag{flags_missing}|@warning missing|\n";
1519     }
1520
1521     if ($statistics{commands_nonverbose}) {
1522         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1523                $statistics{commands_nonverbose},
1524                $statistics{commands},
1525     }
1526 }
1527
1528
1529 exit $exit;
1530
1531
1532 __END__
1533
1534 =head1 NAME
1535
1536 blhc - build log hardening check, checks build logs for missing hardening flags
1537
1538 =head1 SYNOPSIS
1539
1540 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1541
1542 =head1 DESCRIPTION
1543
1544 blhc is a small tool which checks build logs for missing hardening flags. It's
1545 licensed under the GPL 3 or later.
1546
1547 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1548 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1549 official buildd build logs)) to help maintainers detect missing hardening
1550 flags in their packages.
1551
1552 Only gcc is detected as compiler at the moment. If other compilers support
1553 hardening flags as well, please report them.
1554
1555 If there's no output, no flags are missing and the build log is fine.
1556
1557 See F<README> for details about performed checks, auto-detection and
1558 limitations.
1559
1560 =head1 FALSE POSITIVES
1561
1562 To suppress false positives you can embed the following string in the build
1563 log:
1564
1565     blhc: ignore-line-regexp: REGEXP
1566
1567 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1568 ignored.
1569
1570 Please use this feature sparingly so that missing flags are not overlooked. If
1571 you find false positives which affect more packages please report a bug.
1572
1573 To generate this string simply use echo in C<debian/rules>; make sure to use @
1574 to suppress the echo command itself as it could also trigger a false positive.
1575 If the build process takes a long time edit the C<.build> file in place and
1576 tweak the ignore string until B<blhc --all --debian package.build> no longer
1577 reports any false positives.
1578
1579 =head1 OPTIONS
1580
1581 =over 8
1582
1583 =item B<--all>
1584
1585 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1586 auto detected.
1587
1588 =item B<--arch> I<architecture>
1589
1590 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1591 disables hardening flags not available on this architecture. Is detected
1592 automatically if dpkg-buildpackage is used.
1593
1594 =item B<--bindnow>
1595
1596 Force check for all +bindnow hardening flags. By default it's auto detected.
1597
1598 =item B<--buildd>
1599
1600 Special mode for buildds when automatically parsing log files. The following
1601 changes are in effect:
1602
1603 =over 2
1604
1605 =item *
1606
1607 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1608 possible tags.
1609
1610 =item *
1611
1612 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1613 detected).
1614
1615 =item *
1616
1617 Don't require Term::ANSIColor.
1618
1619 =item *
1620
1621 Return exit code 0, unless there was a error (-I, -W messages don't count as
1622 error).
1623
1624 =back
1625
1626 =item B<--debian>
1627
1628 Apply Debian-specific settings. At the moment this only disables checking for
1629 PIE which is automatically applied by Debian's GCC and no longer requires a
1630 compiler command line argument.
1631
1632 =item B<--color>
1633
1634 Use colored (ANSI) output for warning messages.
1635
1636 =item B<--line-numbers>
1637
1638 Display line numbers.
1639
1640 =item B<--ignore-arch> I<arch>
1641
1642 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1643
1644 Used to prevent false positives. This option can be specified multiple times.
1645
1646 =item B<--ignore-arch-flag> I<arch>:I<flag>
1647
1648 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1649
1650 =item B<--ignore-arch-line> I<arch>:I<line>
1651
1652 Like B<--ignore-line>, but only ignore line on I<arch>.
1653
1654 =item B<--ignore-flag> I<flag>
1655
1656 Don't print an error when the specific flag is missing in a compiler line.
1657 I<flag> is a string.
1658
1659 Used to prevent false positives. This option can be specified multiple times.
1660
1661 =item B<--ignore-line> I<regex>
1662
1663 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1664 at the beginning and end of the line to prevent false negatives.
1665
1666 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1667 warnings (which have line continuation resolved).
1668
1669 Used to prevent false positives. This option can be specified multiple times.
1670
1671 =item B<--pie>
1672
1673 Force check for all +pie hardening flags. By default it's auto detected.
1674
1675 =item B<-h -? --help>
1676
1677 Print available options.
1678
1679 =item B<--version>
1680
1681 Print version number and license.
1682
1683 =back
1684
1685 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1686 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1687 all other commands as well.
1688
1689 =head1 EXAMPLES
1690
1691 Normal usage, parse a single log file.
1692
1693     blhc path/to/log/file
1694
1695 If there's no output, no flags are missing and the build log is fine.
1696
1697 Parse multiple log files. The exit code is ORed over all files.
1698
1699     blhc path/to/directory/with/log/files/*
1700
1701 Don't treat missing C<-g> as error:
1702
1703     blhc --ignore-flag -g path/to/log/file
1704
1705 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1706
1707     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1708
1709 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1710 false positive.
1711
1712     blhc --ignore-line '\./script gcc file' path/to/log/file
1713
1714 Ignore lines matching C<./script gcc file> somewhere in the line.
1715
1716     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1717
1718 Use blhc with pbuilder.
1719
1720     pbuilder path/to/package.dsc | tee path/log/file
1721     blhc path/to/file || echo flags missing
1722
1723 Assume this build log was created on a Debian system and thus don't warn about
1724 missing PIE flags if the current architecture injects them automatically (this
1725 is enabled in buildd mode per default). C<--arch> is necessary if the build
1726 log contains no architecture information as written by dpkg-buildpackage.
1727
1728     blhc --debian --all --arch=amd64 path/to/log/file
1729
1730 =head1 BUILDD TAGS
1731
1732 The following tags are used in I<--buildd> mode. In braces the additional data
1733 which is displayed.
1734
1735 =over 2
1736
1737 =item B<I-hardening-wrapper-used>
1738
1739 The package uses hardening-wrapper which intercepts calls to gcc and adds
1740 hardening flags. The build log doesn't contain any hardening flags and thus
1741 can't be checked by blhc.
1742
1743 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1744
1745 Build log contains lines which hide the real compiler flags. For example:
1746
1747     CC test-a.c
1748     CC test-b.c
1749     CC test-c.c
1750     LD test
1751
1752 Most of the time either C<export V=1> or C<export verbose=1> in
1753 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1754 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1755 patched to remove the C<@>s hiding the real compiler commands.
1756
1757 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1758
1759 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1760
1761 =item B<I-invalid-cmake-used> (version)
1762
1763 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1764 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1765 patch was rejected by upstream and later reverted in Debian. Thus those two
1766 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1767 handle them (for example by passing them to CFLAGS). To prevent false
1768 negatives just blacklist those two versions.
1769
1770 =item B<I-no-compiler-commands>
1771
1772 No compiler commands were detected. Either the log contains none or they were
1773 not correctly detected by blhc (please report the bug in this case).
1774
1775 =back
1776
1777 =head1 EXIT STATUS
1778
1779 The exit status is a "bit mask", each listed status is ORed when the error
1780 condition occurs to get the result.
1781
1782 =over 4
1783
1784 =item B<0>
1785
1786 Success.
1787
1788 =item B<1>
1789
1790 No compiler commands were found.
1791
1792 =item B<2>
1793
1794 Invalid arguments/options given to blhc.
1795
1796 =item B<4>
1797
1798 Non verbose build.
1799
1800 =item B<8>
1801
1802 Missing hardening flags.
1803
1804 =item B<16>
1805
1806 Hardening wrapper detected, no tests performed.
1807
1808 =item B<32>
1809
1810 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1811 TAGS"> for a detailed explanation.
1812
1813 =back
1814
1815 =head1 AUTHOR
1816
1817 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1818
1819 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1820 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1821
1822 =head1 LICENSE AND COPYRIGHT
1823
1824 Copyright (C) 2012-2020 by Simon Ruderich
1825
1826 This program is free software: you can redistribute it and/or modify
1827 it under the terms of the GNU General Public License as published by
1828 the Free Software Foundation, either version 3 of the License, or
1829 (at your option) any later version.
1830
1831 This program is distributed in the hope that it will be useful,
1832 but WITHOUT ANY WARRANTY; without even the implied warranty of
1833 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1834 GNU General Public License for more details.
1835
1836 You should have received a copy of the GNU General Public License
1837 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1838
1839 =head1 SEE ALSO
1840
1841 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1842
1843 =cut