bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2020  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.12';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 sub error_flags {
 345     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 346
 347     # Get string value of qr//-escaped regexps and if requested rename them.
 348     my @missing_flags = map {
 349             $flag_renames_ref->{$_}
 350         } @{$missing_flags_ref};
 351
 352     my $flags = join ' ', @missing_flags;
 353     printf '%d:', $number if defined $number;
 354     printf '%s (%s)%s %s',
 355            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 356            $line;
 357
 358     return;
 359 }
 360 sub error_non_verbose_build {
 361     my ($line, $number) = @_;
 362
 363     printf '%d:', $number if defined $number;
 364     printf '%s%s %s',
 365            error_color('NONVERBOSE BUILD', 'red'),
 366            error_color(':', 'yellow'),
 367            $line;
 368
 369     return;
 370 }
 371 sub error_invalid_cmake {
 372     my ($version) = @_;
 373
 374     printf "%s%s %s\n",
 375             error_color('INVALID CMAKE', 'red'),
 376             error_color(':', 'yellow'),
 377             $version;
 378
 379     return;
 380 }
 381 sub error_hardening_wrapper {
 382     printf "%s%s %s\n",
 383             error_color('HARDENING WRAPPER', 'red'),
 384             error_color(':', 'yellow'),
 385             'no checks possible, aborting';
 386
 387     return;
 388 }
 389 sub error_color {
 390     my ($message, $color) = @_;
 391
 392     if ($option_color) {
 393         return Term::ANSIColor::colored($message, $color);
 394     } else {
 395         return $message;
 396     }
 397 }
 398
 399 sub any_flags_used {
 400     my ($line, @flags) = @_;
 401
 402     foreach my $flag (@flags) {
 403         return 1 if $line =~ /$flag/;
 404     }
 405
 406     return 0;
 407 }
 408 sub all_flags_used {
 409     my ($line, $missing_flags_ref, @flags) = @_;
 410
 411     my @missing_flags = ();
 412     foreach my $flag (@flags) {
 413         if (not $line =~ /$flag/) {
 414             push @missing_flags, $flag;
 415         }
 416     }
 417
 418     return 1 if scalar @missing_flags == 0;
 419
 420     @{$missing_flags_ref} = @missing_flags;
 421     return 0;
 422 }
 423 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 424 # $good_flag is present.
 425 sub flag_overwritten {
 426     my ($line, $good_flag, $bad_flags) = @_;
 427
 428     if (not any_flags_used($line, @{$bad_flags})) {
 429         return 0;
 430     }
 431
 432     my $bad_pos = 0;
 433     foreach my $flag (@{$bad_flags}) {
 434         while ($line =~ /$flag/g) {
 435             if ($bad_pos < $+[0]) {
 436                 $bad_pos = $+[0];
 437             }
 438         }
 439     }
 440     my $good_pos = 0;
 441     while ($line =~ /$good_flag/g) {
 442         $good_pos = $+[0];
 443     }
 444     if ($good_pos > $bad_pos) {
 445         return 0;
 446     }
 447     return 1;
 448 }
 449
 450 sub cppflags_fortify_broken {
 451     my ($line, $missing_flags) = @_;
 452
 453     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 454     my $fortify_source = $def_cppflags_fortify[0];
 455
 456     # Some build systems enable/disable fortify source multiple times, check
 457     # the final result.
 458     if (not flag_overwritten($line,
 459                              $fortify_source,
 460                              \@def_cppflags_fortify_bad)) {
 461         return 0;
 462     }
 463     push @{$missing_flags}, $fortify_source;
 464     return 1;
 465 }
 466
 467 sub cflags_stack_broken {
 468     my ($line, $missing_flags, $strong) = @_;
 469
 470     my $flag = $strong ? $def_cflags_stack_strong[0]
 471                        : $def_cflags_stack[0];
 472
 473     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 474         return 0;
 475     }
 476     push @{$missing_flags}, $flag;
 477     return 1;
 478 }
 479
 480 # Modifies $missing_flags_ref array.
 481 sub pic_pie_conflict {
 482     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 483
 484     return 0 if not $pie;
 485     return 0 if not any_flags_used($line, @def_ldflags_pic);
 486
 487     my %flags = map { $_ => 1 } @flags_pie;
 488
 489     # Remove all PIE flags from @missing_flags as they are not required with
 490     # -fPIC.
 491     my @result = grep {
 492         not exists $flags{$_}
 493     } @{$missing_flags_ref};
 494     @{$missing_flags_ref} = @result;
 495
 496     # We got a conflict when no flags are left, thus only PIE flags were
 497     # missing. If other flags were missing abort because the conflict is not
 498     # the problem.
 499     return scalar @result == 0;
 500 }
 501
 502 sub is_non_verbose_build {
 503     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 504
 505     if ($line =~ /$libtool_regex/o) {
 506         # libtool's --silent hides the real compiler flags.
 507         if ($line =~ /\s--silent/) {
 508             return 1;
 509         # If --silent is not present, skip this line as some compiler flags
 510         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 511         # internally. libtool displays the real compiler command on the next
 512         # line, so the flags are checked as usual.
 513         } else {
 514             ${$skip_ref} = 1;
 515             return 0;
 516         }
 517     }
 518
 519     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 520                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 521                 or $line =~ /^\s*[][\/0-9 ]*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 522                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 523                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 524         return 0;
 525     }
 526
 527     # False positives.
 528     #
 529     # C++ compiler setting.
 530     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 531     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 532     # "Compiling" non binary files.
 533     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
 534     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 535     # "Compiling" with no file name.
 536     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 537         # $file_extension_regex may need spaces around the filename.
 538         return 0 if not " $1 " =~ /$file_extension_regex/o;
 539     }
 540
 541     my $file = $1;
 542
 543     # On the first pass we only check if this line is verbose or not.
 544     return 1 if not defined $input_ref;
 545
 546     # Second pass, we have access to the next lines.
 547     ${$skip_ref} = 0;
 548
 549     # CMake and other build systems print the non-verbose messages also when
 550     # building verbose. If a compiler and the file name occurs in the next
 551     # lines, treat it as verbose build.
 552     if (defined $file) {
 553         # Get filename, we can't use the complete path as only parts of it are
 554         # used in the real compiler command.
 555         $file =~ m{/([^/\s]+)$};
 556         $file = $1;
 557
 558         for (my $i = 1; $i <= $line_count; $i++) {
 559             my $next_line = $input_ref->[$line_offset + $i];
 560             last unless defined $next_line;
 561
 562             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 563                 # Not a non-verbose line, but we still have to skip the
 564                 # current line as it doesn't contain any compiler commands.
 565                 ${$skip_ref} = 1;
 566                 return 0;
 567             }
 568         }
 569     }
 570
 571     return 1;
 572 }
 573
 574 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 575 sub remove_flags {
 576     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 577
 578     my %removes = map { $_ => 1 } @flags;
 579     foreach my $flags (@{$flag_refs_ref}) {
 580         @{$flags} = grep {
 581             # Flag found as string.
 582             not exists $removes{$_}
 583             # Flag found as string representation of regexp.
 584                 and (not defined $flag_renames_ref->{$_}
 585                         or not exists $removes{$flag_renames_ref->{$_}})
 586         } @{$flags};
 587     }
 588
 589     return;
 590 }
 591
 592 # Modifies $flag_renames_ref hash.
 593 sub compile_flag_regexp {
 594     my ($flag_renames_ref, @flags) = @_;
 595
 596     my @result = ();
 597     foreach my $flag (@flags) {
 598         # Compile flag regexp for faster execution.
 599         my $regex = qr/\s$flag(?:\s|\\)/;
 600
 601         # Store flag name in replacement string for correct flags in messages
 602         # with qr//ed flag regexps.
 603         $flag_renames_ref->{$regex}
 604             = (exists $flag_renames_ref->{$flag})
 605                 ? $flag_renames_ref->{$flag}
 606                 : $flag;
 607
 608         push @result, $regex;
 609     }
 610     return @result;
 611 }
 612
 613 # Does any extension in @extensions exist in %{$extensions_ref}?
 614 sub extension_found {
 615     my ($extensions_ref, @extensions) = @_;
 616
 617     foreach my $extension (@extensions) {
 618         if (exists $extensions_ref->{$extension}) {
 619             return 1;
 620         }
 621     }
 622     return 0;
 623 }
 624
 625
 626 # MAIN
 627
 628 # Parse command line arguments.
 629 my $option_help             = 0;
 630 my $option_version          = 0;
 631 my $option_pie              = 0;
 632 my $option_bindnow          = 0;
 633 my @option_ignore_arch      = ();
 634 my @option_ignore_flag      = ();
 635 my @option_ignore_arch_flag = ();
 636 my @option_ignore_line      = ();
 637 my @option_ignore_arch_line = ();
 638 my $option_all              = 0;
 639 my $option_arch             = undef;
 640 my $option_buildd           = 0;
 641 my $option_debian           = 0;
 642    $option_color            = 0;
 643 my $option_line_numbers     = 0;
 644 if (not Getopt::Long::GetOptions(
 645             'help|h|?'           => \$option_help,
 646             'version'            => \$option_version,
 647             # Hardening options.
 648             'pie'                => \$option_pie,
 649             'bindnow'            => \$option_bindnow,
 650             'all'                => \$option_all,
 651             # Ignore.
 652             'ignore-arch=s'      => \@option_ignore_arch,
 653             'ignore-flag=s'      => \@option_ignore_flag,
 654             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 655             'ignore-line=s'      => \@option_ignore_line,
 656             'ignore-arch-line=s' => \@option_ignore_arch_line,
 657             # Misc.
 658             'color'              => \$option_color,
 659             'arch=s'             => \$option_arch,
 660             'buildd'             => \$option_buildd,
 661             'debian'             => \$option_debian,
 662             'line-numbers'       => \$option_line_numbers,
 663         )) {
 664     require Pod::Usage;
 665     Pod::Usage::pod2usage(2);
 666 }
 667 if ($option_help) {
 668     require Pod::Usage;
 669     Pod::Usage::pod2usage(1);
 670 }
 671 if ($option_version) {
 672     print <<"EOF";
 673 blhc $VERSION  Copyright (C) 2012-2020  Simon Ruderich
 674
 675 This program is free software: you can redistribute it and/or modify
 676 it under the terms of the GNU General Public License as published by
 677 the Free Software Foundation, either version 3 of the License, or
 678 (at your option) any later version.
 679
 680 This program is distributed in the hope that it will be useful,
 681 but WITHOUT ANY WARRANTY; without even the implied warranty of
 682 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 683 GNU General Public License for more details.
 684
 685 You should have received a copy of the GNU General Public License
 686 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 687 EOF
 688     exit 0;
 689 }
 690
 691 # Arguments missing.
 692 if (scalar @ARGV == 0) {
 693     require Pod::Usage;
 694     Pod::Usage::pod2usage(2);
 695 }
 696
 697 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 698 # installed on Debian's buildds.
 699 if (not $option_buildd) {
 700     require Term::ANSIColor;
 701 }
 702
 703 if ($option_all) {
 704     $option_pie     = 1;
 705     $option_bindnow = 1;
 706 }
 707
 708 # Precompiled ignores for faster lookup.
 709 my %option_ignore_arch_flag = ();
 710 my %option_ignore_arch_line = ();
 711
 712 # Strip flags which should be ignored.
 713 if (scalar @option_ignore_flag > 0) {
 714     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 715 }
 716 # Same for arch specific ignore flags, but only prepare here.
 717 if (scalar @option_ignore_arch_flag > 0) {
 718     foreach my $ignore (@option_ignore_arch_flag) {
 719         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 720
 721         if (not $ignore_arch or not $ignore_flag) {
 722             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 723                         . '("arch:flag" expected)' . "\n", $ignore;
 724             require Pod::Usage;
 725             Pod::Usage::pod2usage(2);
 726         }
 727
 728         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 729     }
 730 }
 731
 732 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 733 # faster with this.
 734 foreach my $flags (@flag_refs_all) {
 735     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 736 }
 737
 738 # Precompile ignore line regexps, also anchor at beginning and end of line.
 739 # Additional entries are also extracted from the build log, see below.
 740 foreach my $ignore (@option_ignore_line) {
 741     $ignore = qr/^$ignore$/;
 742 }
 743 # Same for arch specific ignore lines.
 744 if (scalar @option_ignore_arch_line > 0) {
 745     foreach my $ignore (@option_ignore_arch_line) {
 746         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 747
 748         if (not $ignore_arch or not $ignore_line) {
 749             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 750                         . '("arch:line" expected)' . "\n", $ignore;
 751             require Pod::Usage;
 752             Pod::Usage::pod2usage(2);
 753         }
 754
 755         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 756     }
 757 }
 758
 759 # Final exit code.
 760 my $exit = 0;
 761
 762 FILE:
 763 foreach my $file (@ARGV) {
 764     print "checking '$file'...\n" if scalar @ARGV > 1;
 765
 766     -f $file or die "No such file: $file";
 767
 768     open my $fh, '<', $file or die $!;
 769
 770     # Architecture of this file.
 771     my $arch = $option_arch;
 772
 773     # Hardening options. Not all architectures support all hardening options.
 774     my $harden_format  = 1;
 775     my $harden_fortify = 1;
 776     my $harden_stack   = 1;
 777     my $harden_stack_strong = 1;
 778     my $harden_relro   = 1;
 779     my $harden_bindnow = $option_bindnow; # defaults to 0
 780     my $harden_pie     = $option_pie;     # defaults to 0
 781
 782     # Number of parallel jobs to prevent false positives when detecting
 783     # non-verbose builds. As not all jobs declare the number of parallel jobs
 784     # use a large enough default.
 785     my $parallel = 10;
 786
 787     # Don't check for PIE flags if automatically applied by the compiler. Only
 788     # used in buildd and Debian mode.
 789     my $disable_harden_pie = 0;
 790     if ($option_debian) {
 791         $disable_harden_pie = 1;
 792     }
 793
 794     my $number = 0;
 795     while (my $line = <$fh>) {
 796         $number++;
 797
 798         # Detect architecture automatically unless overridden. For buildd logs
 799         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 800         # build logs which aren't built (wrong architecture, build error,
 801         # etc.).
 802         if (not $arch) {
 803             if (index($line, 'Build Architecture: ') == 0) {
 804                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 805             # For old logs (sbuild << 0.63.0-1).
 806             } elsif (index($line, 'Architecture: ') == 0) {
 807                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 808             }
 809         }
 810
 811         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 812         # check for hardening flags in buildd mode if an older dpkg-dev is
 813         # used. Default flags (-g -O2) are still checked.
 814         #
 815         # Packages which were built before 1.16.1 but used their own hardening
 816         # flags are not checked.
 817         #
 818         # Strong stack protector is used since dpkg 1.17.11.
 819         #
 820         # Recent GCC versions automatically use PIE (only on supported
 821         # architectures) and dpkg respects this properly since 1.18.15 and
 822         # doesn't pass PIE flags manually.
 823         if ($option_buildd
 824                 and index($line, 'Toolchain package versions: ') == 0) {
 825             require Dpkg::Version;
 826
 827             my $disable = 1;
 828             my $disable_strong = 1;
 829
 830             if ($line =~ /\bdpkg-dev_(\S+)/) {
 831                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 832                     $disable = 0;
 833                 }
 834                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 835                     $disable_strong = 0;
 836                 }
 837                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 838                     $disable_harden_pie = 1;
 839                 }
 840             }
 841
 842             if ($disable) {
 843                 $harden_format  = 0;
 844                 $harden_fortify = 0;
 845                 $harden_stack   = 0;
 846                 $harden_relro   = 0;
 847                 $harden_bindnow = 0;
 848                 $harden_pie     = 0;
 849             }
 850             if ($disable_strong) {
 851                 $harden_stack_strong = 0;
 852             }
 853         }
 854
 855         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 856         # this was later dropped because upstream rejected the patch. Thus
 857         # build logs with these versions will have fortify hardening flags
 858         # enabled, even though they may be not correctly set and are missing
 859         # when build with later CMake versions. Thanks to Aron Xu for letting
 860         # me know.
 861         if (index($line, 'Package versions: ') == 0
 862                 and $line =~ /\bcmake_(\S+)/
 863                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 864             if (not $option_buildd) {
 865                 error_invalid_cmake($1);
 866                 $exit |= $exit_code{invalid_cmake};
 867             } else {
 868                 print "$buildd_tag{invalid_cmake}|$1|\n";
 869             }
 870         }
 871
 872         # Debian's build daemons use "Filtered Build-Depends:" (or just
 873         # "Build-Depends:" in older versions) for the build dependencies, but
 874         # pbuilder uses "Depends:"; support both.
 875         if (index($line, 'Filtered Build-Depends: ') == 0
 876                 or index($line, 'Build-Depends: ') == 0
 877                 or index($line, 'Depends: ') == 0) {
 878             # If hardening wrapper is used (wraps calls to gcc and adds
 879             # hardening flags automatically) we can't perform any checks,
 880             # abort.
 881             if ($line =~ /\bhardening-wrapper\b/) {
 882                 if (not $option_buildd) {
 883                     error_hardening_wrapper();
 884                     $exit |= $exit_code{hardening_wrapper};
 885                 } else {
 886                     print "$buildd_tag{hardening_wrapper}||\n";
 887                 }
 888                 next FILE;
 889             }
 890         }
 891
 892         # This flags is not always available, but if it is use it.
 893         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 894             $parallel = $1 * 2;
 895         }
 896
 897         # We skip over unimportant lines at the beginning of the log to
 898         # prevent false positives.
 899         last if index($line, 'dpkg-buildpackage: ') == 0;
 900     }
 901
 902     # Input lines, contain only the lines with compiler commands.
 903     my @input = ();
 904     # Non-verbose lines in the input. Used to reduce calls to
 905     # is_non_verbose_build() (which is quite slow) in the second loop when
 906     # it's already clear if a line is non-verbose or not.
 907     my @input_nonverbose = ();
 908     # Input line number.
 909     my @input_number = ();
 910
 911     my $continuation = 0;
 912     my $complete_line = undef;
 913     my $non_verbose;
 914     while (my $line = <$fh>) {
 915         $number++;
 916
 917         # And stop at the end of the build log. Package details (reported by
 918         # the buildd logs) are not important for us. This also prevents false
 919         # positives.
 920         last if index($line, 'Build finished at ') == 0
 921                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 922
 923         if (not $continuation) {
 924             $non_verbose = 0;
 925         }
 926
 927         # Detect architecture automatically unless overridden.
 928         if (not $arch
 929                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 930             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 931         # Older versions of dpkg-buildpackage
 932         } elsif (not $arch
 933                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 934             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 935
 936             # Old buildd logs use e.g. "host architecture is alpha", remove
 937             # the "is", otherwise debarch_to_debtriplet() will not detect the
 938             # architecture.
 939             if (index($arch, 'is ') == 0) {
 940                 $arch = substr $arch, 3;
 941             }
 942         }
 943
 944         # Permit dynamic excludes from within the build log to ignore false
 945         # positives. Cannot use a separate config file as we often only have
 946         # the build log itself.
 947         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
 948             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
 949             push @option_ignore_line, qr/^$ignore$/;
 950             next;
 951         }
 952
 953         next if $line =~ /^\s*#/;
 954         # Ignore compiler warnings for now.
 955         next if $line =~ /$warning_regex/o;
 956
 957         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 958             # Remove all ANSI color sequences which are sometimes used in
 959             # non-verbose builds.
 960             $line = Term::ANSIColor::colorstrip($line);
 961             # Also strip '\0xf' (delete previous character), used by Elinks'
 962             # build system.
 963             $line =~ s/\x0f//g;
 964             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 965             # what it does).
 966             $line =~ s/\033\(B//g;
 967         }
 968
 969         # Check if this line indicates a non verbose build.
 970         my $skip = 0;
 971         $non_verbose |= is_non_verbose_build($line, \$skip);
 972         next if $skip;
 973
 974         # One line may contain multiple commands (";"). Treat each one as
 975         # single line. parse_line() is slow, only use it when necessary.
 976         my @line = (index($line, ';') == -1)
 977                  ? ($line)
 978                  : map {
 979                        # Ensure newline at the line end - necessary for
 980                        # correct parsing later.
 981                        $_ =~ s/\s+$//;
 982                        $_ .= "\n";
 983                    } Text::ParseWords::parse_line(';', 1, $line);
 984         foreach my $line (@line) {
 985             if ($continuation) {
 986                 $continuation = 0;
 987
 988                 # Join lines, but leave the "\" in place so it's clear where
 989                 # the original line break was.
 990                 chomp $complete_line;
 991                 $complete_line .= ' ' . $line;
 992             }
 993             # Line continuation, line ends with "\".
 994             if ($line =~ /\\$/) {
 995                 $continuation = 1;
 996                 # Start line continuation.
 997                 if (not defined $complete_line) {
 998                     $complete_line = $line;
 999                 }
1000                 next;
1001             }
1002
1003             # Use the complete line if a line continuation occurred.
1004             if (defined $complete_line) {
1005                 $line = $complete_line;
1006                 $complete_line = undef;
1007             }
1008
1009             # Ignore lines with no compiler commands.
1010             next if not $non_verbose
1011                     and not $line =~ /$cc_regex_normal/o;
1012             # Ignore lines with no filenames with extensions. May miss some
1013             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1014             # a problem as the log will most likely contain other non-verbose
1015             # commands which are detected.
1016             next if not $non_verbose
1017                     and not $line =~ /$file_extension_regex/o;
1018
1019             # Ignore false positives.
1020             #
1021             # `./configure` output.
1022             next if not $non_verbose
1023                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1024             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1025                                 [Cc]ompiler[\s.]*:?\s+
1026                                 /x;
1027             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1028                                 \s*=\s*$cc_regex_full
1029                                 # optional compiler options, don't allow
1030                                 # "everything" here to prevent false negatives
1031                                 \s*(?:\s-\S+)*\s*$}xo;
1032             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1033             # line (or similar for other architectures) which gets recognized
1034             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1035             # C++ files. No hardening flags are relevant during this step,
1036             # thus ignore `moc-qt*` lines. The resulting files will be
1037             # compiled in a separate step (and therefore checked).
1038             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1039                                \s.+\s
1040                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1041                                \s}x;
1042             # Ignore false positives when the line contains only CC=gcc but no
1043             # other gcc command.
1044             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1045                 my $before = $1;
1046                 my $after  = $2;
1047                 next if     not $before =~ /$cc_regex_normal/o
1048                         and not $after  =~ /$cc_regex_normal/o;
1049             }
1050             # Ignore false positives caused by gcc -v. It outputs a line
1051             # looking like a normal compiler line but which is sometimes
1052             # missing hardening flags, although the normal compiler line
1053             # contains them.
1054             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1055                                    [0-9.]+/cc1(?:plus)?}xo;
1056             # Ignore false positive with `rm` which may remove files which
1057             # look like a compiler executable thus causing the line to be
1058             # treated as a normal compiler line.
1059             next if $line =~ m{^\s*rm\s+};
1060             next if $line =~ m{^\s*dwz\s+};
1061             # Some build systems emit "gcc > file".
1062             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1063             # Hex output may contain "cc".
1064             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1065             # Meson build output
1066             next if $line =~ /^C\+\+ linker for the host machine: /;
1067             # Embedded `gcc -print-*` commands
1068             next if $line =~ /`$cc_regex_normal\s*[^`]*-print-\S+`/;
1069
1070             # Check if additional hardening options were used. Used to ensure
1071             # they are used for the complete build.
1072             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1073                                                          @def_ldflags_pie);
1074             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1075
1076             push @input, $line;
1077             push @input_nonverbose, $non_verbose;
1078             push @input_number, $number if $option_line_numbers;
1079         }
1080     }
1081
1082     close $fh or die $!;
1083
1084     # Ignore arch if requested.
1085     if (scalar @option_ignore_arch > 0 and $arch) {
1086         foreach my $ignore (@option_ignore_arch) {
1087             if ($arch eq $ignore) {
1088                 print "ignoring architecture '$arch'\n";
1089                 next FILE;
1090             }
1091         }
1092     }
1093
1094     if (scalar @input == 0) {
1095         if (not $option_buildd) {
1096             print "No compiler commands!\n";
1097             $exit |= $exit_code{no_compiler_commands};
1098         } else {
1099             print "$buildd_tag{no_compiler_commands}||\n";
1100         }
1101         next FILE;
1102     }
1103
1104     if ($option_buildd) {
1105         $statistics{commands} += scalar @input;
1106     }
1107
1108     # Option or auto detected.
1109     if ($arch) {
1110         # The following was partially copied from dpkg-dev 1.20.5
1111         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1112         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1113         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1114         # licensed under GPL version 2 or later. Keep it in sync.
1115
1116         require Dpkg::Arch;
1117         my ($os, $cpu);
1118         # Recent dpkg versions use a quadruplet for arch. Support both.
1119         eval {
1120             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1121         };
1122         if ($@) {
1123             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1124         }
1125
1126         my %builtin_pie_arch = map { $_ => 1 } qw(
1127             amd64
1128             arm64
1129             armel
1130             armhf
1131             hurd-i386
1132             i386
1133             kfreebsd-amd64
1134             kfreebsd-i386
1135             mips
1136             mipsel
1137             mips64el
1138             powerpc
1139             ppc64
1140             ppc64el
1141             riscv64
1142             s390x
1143             sparc
1144             sparc64
1145         );
1146
1147         # Disable unsupported hardening options.
1148         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1149                 or $cpu =~ /^(?:hppa|avr32)$/) {
1150             $harden_pie = 0;
1151         }
1152         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1153             $harden_stack = 0;
1154             $harden_stack_strong = 0;
1155         }
1156         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1157             $harden_relro   = 0;
1158             $harden_bindnow = 0;
1159         }
1160
1161         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1162             $harden_pie = 0;
1163         }
1164     }
1165
1166     # Default values.
1167     my @cflags   = @def_cflags;
1168     my @cxxflags = @def_cxxflags;
1169     my @cppflags = @def_cppflags;
1170     my @ldflags  = @def_ldflags;
1171     # Check the specified hardening options, same order as dpkg-buildflags.
1172     if ($harden_pie) {
1173         @cflags   = (@cflags,   @def_cflags_pie);
1174         @cxxflags = (@cxxflags, @def_cflags_pie);
1175         @ldflags  = (@ldflags,  @def_ldflags_pie);
1176     }
1177     if ($harden_stack_strong) {
1178         @cflags   = (@cflags,   @def_cflags_stack_strong);
1179         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1180     } elsif ($harden_stack) {
1181         @cflags   = (@cflags,   @def_cflags_stack);
1182         @cxxflags = (@cxxflags, @def_cflags_stack);
1183     }
1184     if ($harden_fortify) {
1185         @cflags   = (@cflags,   @def_cflags_fortify);
1186         @cxxflags = (@cxxflags, @def_cflags_fortify);
1187         @cppflags = (@cppflags, @def_cppflags_fortify);
1188     }
1189     if ($harden_format) {
1190         @cflags   = (@cflags,   @def_cflags_format);
1191         @cxxflags = (@cxxflags, @def_cflags_format);
1192     }
1193     if ($harden_relro) {
1194         @ldflags = (@ldflags, @def_ldflags_relro);
1195     }
1196     if ($harden_bindnow) {
1197         @ldflags = (@ldflags, @def_ldflags_bindnow);
1198     }
1199
1200     # Ada doesn't support format hardening flags, see #680117 for more
1201     # information. Same for fortran.
1202     my @cflags_backup;
1203     my @cflags_noformat = grep {
1204         my $ok = 1;
1205         foreach my $flag (@def_cflags_format) {
1206             $ok = 0 if $_ eq $flag;
1207         }
1208         $ok;
1209     } @cflags;
1210
1211     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1212     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1213     # as long as @def_cppflags_fortify contains only one variable.
1214     if (scalar @def_cppflags_fortify == 0) {
1215         $harden_fortify = 0;
1216     }
1217
1218     # Ignore flags for this arch if requested.
1219     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1220         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1221
1222         remove_flags(\@local_flag_refs,
1223                      \%flag_renames,
1224                      @{$option_ignore_arch_flag{$arch}});
1225     }
1226
1227     my @ignore_line = @option_ignore_line;
1228     # Ignore lines for this arch if requested.
1229     if ($arch and exists $option_ignore_arch_line{$arch}) {
1230         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1231     }
1232
1233 LINE:
1234     for (my $i = 0; $i < scalar @input; $i++) {
1235         my $line = $input[$i];
1236
1237         # Ignore line if requested.
1238         foreach my $ignore (@ignore_line) {
1239             next LINE if $line =~ /$ignore/;
1240         }
1241
1242         my $skip = 0;
1243         if ($input_nonverbose[$i]
1244                 and is_non_verbose_build($line, \$skip,
1245                                          \@input, $i, $parallel)) {
1246             if (not $option_buildd) {
1247                 error_non_verbose_build($line, $input_number[$i]);
1248                 $exit |= $exit_code{non_verbose_build};
1249             } else {
1250                 $statistics{commands_nonverbose}++;
1251             }
1252             next;
1253         }
1254         # Even if it's a verbose build, we might have to skip this line (see
1255         # is_non_verbose_build()).
1256         next if $skip;
1257
1258         my $orig_line = $line;
1259
1260         # Remove everything until and including the compiler command. Makes
1261         # checks easier and faster.
1262         $line =~ s/^.*?$cc_regex//o;
1263         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1264         # the brace and similar characters at the line end.
1265         $line =~ s/['")]+$//;
1266
1267         # Skip unnecessary tests when only preprocessing.
1268         my $flag_preprocess = 0;
1269
1270         my $dependency = 0;
1271         my $preprocess = 0;
1272         my $compile    = 0;
1273         my $link       = 0;
1274
1275         # Preprocess, compile, assemble.
1276         if ($line =~ /\s(-E|-S|-c)\b/) {
1277             $preprocess      = 1;
1278             $flag_preprocess = 1 if $1 eq '-E';
1279             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1280         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1281         # -MT -MQ) are always used with -M/-MM.
1282         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1283             $dependency = 1;
1284         # Otherwise assume we are linking.
1285         } else {
1286             $link = 1;
1287         }
1288
1289         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1290         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1291             $dependency      = 0;
1292             $flag_preprocess = 0;
1293         }
1294
1295         # Dependency generation for Makefiles, no preprocessing or other flags
1296         # needed.
1297         next if $dependency;
1298
1299         # Get all file extensions on this line.
1300         my @extensions = $line =~ /$file_extension_regex/go;
1301         # Ignore all unknown extensions to speedup the search below.
1302         @extensions = grep { exists $extension{$_} } @extensions;
1303
1304         # These file types don't require preprocessing.
1305         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1306             $preprocess = 0;
1307         }
1308         # These file types require preprocessing.
1309         if (extension_found(\%extensions_preprocess, @extensions)) {
1310             # Prevent false positives with "libtool: link: g++ -include test.h
1311             # .." compiler lines.
1312             if ($orig_line !~ /$libtool_link_regex/o) {
1313                 $preprocess = 1;
1314             }
1315         }
1316
1317         if (not $flag_preprocess) {
1318             # If there are source files then it's compiling/linking in one
1319             # step and we must check both. We only check for source files
1320             # here, because header files cause too many false positives.
1321             if (extension_found(\%extensions_compile_link, @extensions)) {
1322                 # Assembly files don't need CFLAGS.
1323                 if (not extension_found(\%extensions_compile, @extensions)
1324                         and extension_found(\%extensions_no_compile, @extensions)) {
1325                     $compile = 0;
1326                 # But the rest does.
1327                 } else {
1328                     $compile = 1;
1329                 }
1330             # No compilable extensions found, either linking or compiling
1331             # header flags.
1332             #
1333             # If there are also no object files we are just compiling headers
1334             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1335             # to our liberal checks for compiler lines, this also reduces the
1336             # number of false positives considerably.
1337             } elsif ($link
1338                     and not extension_found(\%extensions_object, @extensions)) {
1339                 $link = 0;
1340             }
1341         }
1342
1343         my $compile_cpp = 0;
1344         my $restore_cflags = 0;
1345         # Assume CXXFLAGS are required when a C++ file is specified in the
1346         # compiler line.
1347         if ($compile
1348                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1349             $compile     = 0;
1350             $compile_cpp = 1;
1351         # Ada needs special CFLAGS
1352         } elsif (extension_found(\%extensions_ada, @extensions)) {
1353             $restore_cflags = 1;
1354             $preprocess = 0; # Ada uses no CPPFLAGS
1355             @cflags_backup = @cflags;
1356             @cflags        = @cflags_noformat;
1357         # Same for fortran
1358         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1359             $restore_cflags = 1;
1360             @cflags_backup = @cflags;
1361             @cflags        = @cflags_noformat;
1362         }
1363
1364         if ($option_buildd) {
1365             $statistics{preprocess}++  if $preprocess;
1366             $statistics{compile}++     if $compile;
1367             $statistics{compile_cpp}++ if $compile_cpp;
1368             $statistics{link}++        if $link;
1369         }
1370
1371         # Check if there are flags indicating a debug build. If that's true,
1372         # skip the check for -O2. This prevents fortification, but that's fine
1373         # for a debug build.
1374         if (any_flags_used($line, @def_cflags_debug)) {
1375             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1376             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1377         }
1378
1379         # Check hardening flags.
1380         my @missing;
1381         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1382                     or (($harden_stack or $harden_stack_strong)
1383                         and cflags_stack_broken($line, \@missing,
1384                                                 $harden_stack_strong)))
1385                 # Libraries linked with -fPIC don't have to (and can't) be
1386                 # linked with -fPIE as well. It's no error if only PIE flags
1387                 # are missing.
1388                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1389                 # Assume dpkg-buildflags returns the correct flags.
1390                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1391             if (not $option_buildd) {
1392                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1393                             $input[$i], $input_number[$i]);
1394                 $exit |= $exit_code{flags_missing};
1395             } else {
1396                 $statistics{compile_missing}++;
1397             }
1398         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1399                 # Libraries linked with -fPIC don't have to (and can't) be
1400                 # linked with -fPIE as well. It's no error if only PIE flags
1401                 # are missing.
1402                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1403                 # Assume dpkg-buildflags returns the correct flags.
1404                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1405             if (not $option_buildd) {
1406                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1407                             $input[$i], $input_number[$i]);
1408                 $exit |= $exit_code{flags_missing};
1409             } else {
1410                 $statistics{compile_cpp_missing}++;
1411             }
1412         }
1413         if ($preprocess
1414                 and (not all_flags_used($line, \@missing, @cppflags)
1415                     # The fortify flag might be overwritten, detect that.
1416                      or ($harden_fortify
1417                          and cppflags_fortify_broken($line, \@missing)))
1418                 # Assume dpkg-buildflags returns the correct flags.
1419                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1420             if (not $option_buildd) {
1421                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1422                             $input[$i], $input_number[$i]);
1423                 $exit |= $exit_code{flags_missing};
1424             } else {
1425                 $statistics{preprocess_missing}++;
1426             }
1427         }
1428         if ($link and not all_flags_used($line, \@missing, @ldflags)
1429                 # Same here, -fPIC conflicts with -fPIE.
1430                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1431                 # Assume dpkg-buildflags returns the correct flags.
1432                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1433             if (not $option_buildd) {
1434                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1435                             $input[$i], $input_number[$i]);
1436                 $exit |= $exit_code{flags_missing};
1437             } else {
1438                 $statistics{link_missing}++;
1439             }
1440         }
1441
1442         # Restore normal CFLAGS.
1443         if ($restore_cflags) {
1444             @cflags = @cflags_backup;
1445         }
1446     }
1447 }
1448
1449 # Print statistics for buildd mode, only output in this mode.
1450 if ($option_buildd) {
1451     my @warning;
1452
1453     if ($statistics{preprocess_missing}) {
1454         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1455                                $statistics{preprocess_missing},
1456                                $statistics{preprocess};
1457     }
1458     if ($statistics{compile_missing}) {
1459         push @warning, sprintf 'CFLAGS %d (of %d)',
1460                                $statistics{compile_missing},
1461                                $statistics{compile};
1462     }
1463     if ($statistics{compile_cpp_missing}) {
1464         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1465                                $statistics{compile_cpp_missing},
1466                                $statistics{compile_cpp};
1467     }
1468     if ($statistics{link_missing}) {
1469         push @warning, sprintf 'LDFLAGS %d (of %d)',
1470                                $statistics{link_missing},
1471                                $statistics{link};
1472     }
1473     if (scalar @warning) {
1474         local $" = ', '; # array join string
1475         print "$buildd_tag{flags_missing}|@warning missing|\n";
1476     }
1477
1478     if ($statistics{commands_nonverbose}) {
1479         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1480                $statistics{commands_nonverbose},
1481                $statistics{commands},
1482     }
1483 }
1484
1485
1486 exit $exit;
1487
1488
1489 __END__
1490
1491 =head1 NAME
1492
1493 blhc - build log hardening check, checks build logs for missing hardening flags
1494
1495 =head1 SYNOPSIS
1496
1497 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1498
1499 =head1 DESCRIPTION
1500
1501 blhc is a small tool which checks build logs for missing hardening flags. It's
1502 licensed under the GPL 3 or later.
1503
1504 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1505 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1506 official buildd build logs)) to help maintainers detect missing hardening
1507 flags in their packages.
1508
1509 Only gcc is detected as compiler at the moment. If other compilers support
1510 hardening flags as well, please report them.
1511
1512 If there's no output, no flags are missing and the build log is fine.
1513
1514 See F<README> for details about performed checks, auto-detection and
1515 limitations.
1516
1517 =head1 FALSE POSITIVES
1518
1519 To suppress false positives you can embed the following string in the build
1520 log:
1521
1522     blhc: ignore-line-regexp: REGEXP
1523
1524 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1525 ignored.
1526
1527 Please use this feature sparingly so that missing flags are not overlooked. If
1528 you find false positives which affect more packages please report a bug.
1529
1530 To generate this string simply use echo in C<debian/rules>; make sure to use @
1531 to suppress the echo command itself as it could also trigger a false positive.
1532
1533 =head1 OPTIONS
1534
1535 =over 8
1536
1537 =item B<--all>
1538
1539 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1540 auto detected.
1541
1542 =item B<--arch> I<architecture>
1543
1544 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1545 disables hardening flags not available on this architecture. Is detected
1546 automatically if dpkg-buildpackage is used.
1547
1548 =item B<--bindnow>
1549
1550 Force check for all +bindnow hardening flags. By default it's auto detected.
1551
1552 =item B<--buildd>
1553
1554 Special mode for buildds when automatically parsing log files. The following
1555 changes are in effect:
1556
1557 =over 2
1558
1559 =item *
1560
1561 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1562 possible tags.
1563
1564 =item *
1565
1566 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1567 detected).
1568
1569 =item *
1570
1571 Don't require Term::ANSIColor.
1572
1573 =item *
1574
1575 Return exit code 0, unless there was a error (-I, -W messages don't count as
1576 error).
1577
1578 =back
1579
1580 =item B<--debian>
1581
1582 Apply Debian-specific settings. At the moment this only disables checking for
1583 PIE which is automatically applied by Debian's GCC and no longer requires a
1584 compiler command line argument.
1585
1586 =item B<--color>
1587
1588 Use colored (ANSI) output for warning messages.
1589
1590 =item B<--line-numbers>
1591
1592 Display line numbers.
1593
1594 =item B<--ignore-arch> I<arch>
1595
1596 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1597
1598 Used to prevent false positives. This option can be specified multiple times.
1599
1600 =item B<--ignore-arch-flag> I<arch>:I<flag>
1601
1602 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1603
1604 =item B<--ignore-arch-line> I<arch>:I<line>
1605
1606 Like B<--ignore-line>, but only ignore line on I<arch>.
1607
1608 =item B<--ignore-flag> I<flag>
1609
1610 Don't print an error when the specific flag is missing in a compiler line.
1611 I<flag> is a string.
1612
1613 Used to prevent false positives. This option can be specified multiple times.
1614
1615 =item B<--ignore-line> I<regex>
1616
1617 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1618 at the beginning and end of the line to prevent false negatives.
1619
1620 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1621 warnings (which have line continuation resolved).
1622
1623 Used to prevent false positives. This option can be specified multiple times.
1624
1625 =item B<--pie>
1626
1627 Force check for all +pie hardening flags. By default it's auto detected.
1628
1629 =item B<-h -? --help>
1630
1631 Print available options.
1632
1633 =item B<--version>
1634
1635 Print version number and license.
1636
1637 =back
1638
1639 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1640 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1641 all other commands as well.
1642
1643 =head1 EXAMPLES
1644
1645 Normal usage, parse a single log file.
1646
1647     blhc path/to/log/file
1648
1649 If there's no output, no flags are missing and the build log is fine.
1650
1651 Parse multiple log files. The exit code is ORed over all files.
1652
1653     blhc path/to/directory/with/log/files/*
1654
1655 Don't treat missing C<-g> as error:
1656
1657     blhc --ignore-flag -g path/to/log/file
1658
1659 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1660
1661     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1662
1663 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1664 false positive.
1665
1666     blhc --ignore-line '\./script gcc file' path/to/log/file
1667
1668 Ignore lines matching C<./script gcc file> somewhere in the line.
1669
1670     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1671
1672 Use blhc with pbuilder.
1673
1674     pbuilder path/to/package.dsc | tee path/log/file
1675     blhc path/to/file || echo flags missing
1676
1677 Assume this build log was created on a Debian system and thus don't warn about
1678 missing PIE flags if the current architecture injects them automatically (this
1679 is enabled in buildd mode per default). C<--arch> is necessary if the build
1680 log contains no architecture information as written by dpkg-buildpackage.
1681
1682     blhc --debian --all --arch=amd64 path/to/log/file
1683
1684 =head1 BUILDD TAGS
1685
1686 The following tags are used in I<--buildd> mode. In braces the additional data
1687 which is displayed.
1688
1689 =over 2
1690
1691 =item B<I-hardening-wrapper-used>
1692
1693 The package uses hardening-wrapper which intercepts calls to gcc and adds
1694 hardening flags. The build log doesn't contain any hardening flags and thus
1695 can't be checked by blhc.
1696
1697 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1698
1699 Build log contains lines which hide the real compiler flags. For example:
1700
1701     CC test-a.c
1702     CC test-b.c
1703     CC test-c.c
1704     LD test
1705
1706 Most of the time either C<export V=1> or C<export verbose=1> in
1707 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1708 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1709 patched to remove the C<@>s hiding the real compiler commands.
1710
1711 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1712
1713 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1714
1715 =item B<I-invalid-cmake-used> (version)
1716
1717 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1718 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1719 patch was rejected by upstream and later reverted in Debian. Thus those two
1720 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1721 handle them (for example by passing them to CFLAGS). To prevent false
1722 negatives just blacklist those two versions.
1723
1724 =item B<I-no-compiler-commands>
1725
1726 No compiler commands were detected. Either the log contains none or they were
1727 not correctly detected by blhc (please report the bug in this case).
1728
1729 =back
1730
1731 =head1 EXIT STATUS
1732
1733 The exit status is a "bit mask", each listed status is ORed when the error
1734 condition occurs to get the result.
1735
1736 =over 4
1737
1738 =item B<0>
1739
1740 Success.
1741
1742 =item B<1>
1743
1744 No compiler commands were found.
1745
1746 =item B<2>
1747
1748 Invalid arguments/options given to blhc.
1749
1750 =item B<4>
1751
1752 Non verbose build.
1753
1754 =item B<8>
1755
1756 Missing hardening flags.
1757
1758 =item B<16>
1759
1760 Hardening wrapper detected, no tests performed.
1761
1762 =item B<32>
1763
1764 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1765 TAGS"> for a detailed explanation.
1766
1767 =back
1768
1769 =head1 AUTHOR
1770
1771 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1772
1773 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1774 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1775
1776 =head1 LICENSE AND COPYRIGHT
1777
1778 Copyright (C) 2012-2020 by Simon Ruderich
1779
1780 This program is free software: you can redistribute it and/or modify
1781 it under the terms of the GNU General Public License as published by
1782 the Free Software Foundation, either version 3 of the License, or
1783 (at your option) any later version.
1784
1785 This program is distributed in the hope that it will be useful,
1786 but WITHOUT ANY WARRANTY; without even the implied warranty of
1787 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1788 GNU General Public License for more details.
1789
1790 You should have received a copy of the GNU General Public License
1791 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1792
1793 =head1 SEE ALSO
1794
1795 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1796
1797 =cut