bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2013  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.04';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 180 # real regexps below for better execution speed).
 181 my @def_cflags = (
 182     '-g',
 183     '-O(?:2|3)',
 184 );
 185 my @def_cflags_format = (
 186     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 187     '-Werror=format-security', # implies -Wformat-security
 188 );
 189 my @def_cflags_fortify = (
 190     # fortify needs at least -O1, but -O2 is recommended anyway
 191 );
 192 my @def_cflags_stack = (
 193     '-fstack-protector',
 194     '--param[= ]ssp-buffer-size=4',
 195 );
 196 my @def_cflags_pie = (
 197     '-fPIE',
 198 );
 199 my @def_cxxflags = (
 200     @def_cflags,
 201 );
 202 # @def_cxxflags_* is the same as @def_cflags_*.
 203 my @def_cppflags = ();
 204 my @def_cppflags_fortify = (
 205     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 206     # If you add another flag fix hack below (search for "Hack to fix").
 207 );
 208 my @def_cppflags_fortify_bad = (
 209     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 210     '-U_FORTIFY_SOURCE',
 211     '-D_FORTIFY_SOURCE=0',
 212     '-D_FORTIFY_SOURCE=1',
 213 );
 214 my @def_ldflags = ();
 215 my @def_ldflags_relro = (
 216     '-Wl,(?:-z,)?relro',
 217 );
 218 my @def_ldflags_bindnow = (
 219     '-Wl,(?:-z,)?now',
 220 );
 221 my @def_ldflags_pie = (
 222     '-fPIE',
 223     '-pie',
 224 );
 225 my @def_ldflags_pic = (
 226     '-fPIC',
 227     '-fpic',
 228     '-shared',
 229 );
 230 # References to all flags checked by the flag checker.
 231 my @flag_refs = (
 232     \@def_cflags,
 233     \@def_cflags_format,
 234     \@def_cflags_fortify,
 235     \@def_cflags_stack,
 236     \@def_cflags_pie,
 237     \@def_cxxflags,
 238     \@def_cppflags,
 239     \@def_cppflags_fortify,
 240     \@def_ldflags,
 241     \@def_ldflags_relro,
 242     \@def_ldflags_bindnow,
 243     \@def_ldflags_pie,
 244 );
 245 # References to all used flags.
 246 my @flag_refs_all = (
 247     @flag_refs,
 248     \@def_cppflags_fortify_bad,
 249     \@def_ldflags_pic,
 250 );
 251 # Renaming rules for the output so the regex parts are not visible. Also
 252 # stores string values of flag regexps above, see compile_flag_regexp().
 253 my %flag_renames = (
 254     '-O(?:2|3)'                    => '-O2',
 255     '-Wformat(?:=2)?'              => '-Wformat',
 256     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 257     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 258     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 259 );
 260
 261 my %exit_code = (
 262     no_compiler_commands => 1 << 0,
 263     # used by POD::Usage => 1 << 1,
 264     non_verbose_build    => 1 << 2,
 265     flags_missing        => 1 << 3,
 266     hardening_wrapper    => 1 << 4,
 267     invalid_cmake        => 1 << 5,
 268 );
 269
 270 my %buildd_tag = (
 271     no_compiler_commands => 'I-no-compiler-commands',
 272     non_verbose_build    => 'W-compiler-flags-hidden',
 273     flags_missing        => 'W-dpkg-buildflags-missing',
 274     hardening_wrapper    => 'I-hardening-wrapper-used',
 275     invalid_cmake        => 'I-invalid-cmake-used',
 276 );
 277
 278 # Statistics of missing flags and non-verbose build commands. Used for
 279 # $option_buildd.
 280 my %statistics = (
 281     preprocess          => 0,
 282     preprocess_missing  => 0,
 283     compile             => 0,
 284     compile_missing     => 0,
 285     compile_cpp         => 0,
 286     compile_cpp_missing => 0,
 287     link                => 0,
 288     link_missing        => 0,
 289     commands            => 0,
 290     commands_nonverbose => 0,
 291 );
 292
 293 # Use colored (ANSI) output?
 294 my $option_color;
 295
 296
 297 # FUNCTIONS
 298
 299 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 300 sub array_equal {
 301     my ($first_ref, $second_ref) = @_;
 302
 303     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 304
 305     my $length = scalar @{$first_ref};
 306     for (my $i = 0; $i < $length; $i++) {
 307         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 308     }
 309
 310     return 1;
 311 }
 312
 313 sub error_flags {
 314     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 315
 316     # Get string value of qr//-escaped regexps and if requested rename them.
 317     my @missing_flags = map {
 318             $flag_renames_ref->{$_}
 319         } @{$missing_flags_ref};
 320
 321     my $flags = join ' ', @missing_flags;
 322     printf '%s (%s)%s %s',
 323            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 324            $line;
 325
 326     return;
 327 }
 328 sub error_non_verbose_build {
 329     my ($line) = @_;
 330
 331     printf '%s%s %s',
 332            error_color('NONVERBOSE BUILD', 'red'),
 333            error_color(':', 'yellow'),
 334            $line;
 335
 336     return;
 337 }
 338 sub error_invalid_cmake {
 339     my ($version) = @_;
 340
 341     printf "%s%s %s\n",
 342             error_color('INVALID CMAKE', 'red'),
 343             error_color(':', 'yellow'),
 344             $version;
 345
 346     return;
 347 }
 348 sub error_hardening_wrapper {
 349     printf "%s%s %s\n",
 350             error_color('HARDENING WRAPPER', 'red'),
 351             error_color(':', 'yellow'),
 352             'no checks possible, aborting';
 353
 354     return;
 355 }
 356 sub error_color {
 357     my ($message, $color) = @_;
 358
 359     if ($option_color) {
 360         return Term::ANSIColor::colored($message, $color);
 361     } else {
 362         return $message;
 363     }
 364 }
 365
 366 sub any_flags_used {
 367     my ($line, @flags) = @_;
 368
 369     foreach my $flag (@flags) {
 370         return 1 if $line =~ /$flag/;
 371     }
 372
 373     return 0;
 374 }
 375 sub all_flags_used {
 376     my ($line, $missing_flags_ref, @flags) = @_;
 377
 378     my @missing_flags = ();
 379     foreach my $flag (@flags) {
 380         if (not $line =~ /$flag/) {
 381             push @missing_flags, $flag;
 382         }
 383     }
 384
 385     return 1 if scalar @missing_flags == 0;
 386
 387     @{$missing_flags_ref} = @missing_flags;
 388     return 0;
 389 }
 390
 391 sub cppflags_fortify_broken {
 392     my ($line, $missing_flags) = @_;
 393
 394     # This doesn't take the position into account, but is a simple solution.
 395     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 396     # is wrong anyway.
 397
 398     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 399         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 400         push @{$missing_flags}, $def_cppflags_fortify[0];
 401         return 1;
 402     }
 403
 404     return 0;
 405 }
 406
 407 # Modifies $missing_flags_ref array.
 408 sub pic_pie_conflict {
 409     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 410
 411     return 0 if not $pie;
 412     return 0 if not any_flags_used($line, @def_ldflags_pic);
 413
 414     my %flags = map { $_ => 1 } @flags_pie;
 415
 416     # Remove all PIE flags from @missing_flags as they are not required with
 417     # -fPIC.
 418     my @result = grep {
 419         not exists $flags{$_}
 420     } @{$missing_flags_ref};
 421     @{$missing_flags_ref} = @result;
 422
 423     # We got a conflict when no flags are left, thus only PIE flags were
 424     # missing. If other flags were missing abort because the conflict is not
 425     # the problem.
 426     return scalar @result == 0;
 427 }
 428
 429 sub is_non_verbose_build {
 430     my ($line, $next_line, $skip_ref) = @_;
 431
 432     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 433                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 434                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 435                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 436                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 437         return 0;
 438     }
 439
 440     # False positives.
 441     #
 442     # C++ compiler setting.
 443     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 444     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 445     # "Compiling" with no file name.
 446     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 447         # $file_extension_regex may need spaces around the filename.
 448         return 0 if not " $1 " =~ /$file_extension_regex/o;
 449     }
 450
 451     my $file = $1;
 452
 453     # On the first pass we only check if this line is verbose or not.
 454     return 1 if not defined $next_line;
 455
 456     # Second pass, we have access to the next line.
 457     ${$skip_ref} = 0;
 458
 459     # CMake and other build systems print the non-verbose messages also when
 460     # building verbose. If a compiler and the file name occurs in the next
 461     # line, treat it as verbose build.
 462     if (defined $file) {
 463         # Get filename, we can't use the complete path as only parts of it are
 464         # used in the real compiler command.
 465         $file =~ m{/([^/\s]+)$};
 466         $file = $1;
 467
 468         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 469             # Not a non-verbose line, but we still have to skip the current line
 470             # as it doesn't contain any compiler commands.
 471             ${$skip_ref} = 1;
 472             return 0;
 473         }
 474     }
 475
 476     return 1;
 477 }
 478
 479 # Remove @flags from $flag_refs_ref, and $flag_renames_ref.
 480 sub remove_flags {
 481     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 482
 483     my %removes = map { $_ => 1 } @flags;
 484     foreach my $flags (@{$flag_refs_ref}) {
 485         @{$flags} = grep {
 486             # Flag found as string.
 487             not exists $removes{$_}
 488             # Flag found as string representation of regexp.
 489                 and (not defined $flag_renames_ref->{$_}
 490                         or not exists $removes{$flag_renames_ref->{$_}})
 491         } @{$flags};
 492     }
 493
 494     return;
 495 }
 496
 497 # Modifies $flag_renames_ref hash.
 498 sub compile_flag_regexp {
 499     my ($flag_renames_ref, @flags) = @_;
 500
 501     my @result = ();
 502     foreach my $flag (@flags) {
 503         # Store flag name in replacement string for correct flags in messages
 504         # with qr//ed flag regexps.
 505         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 506             = (exists $flag_renames_ref->{$flag})
 507                 ? $flag_renames_ref->{$flag}
 508                 : $flag;
 509
 510         # Compile flag regexp for faster execution.
 511         push @result, qr/\s$flag(?:\s|\\)/;
 512     }
 513     return @result;
 514 }
 515
 516 # Does any extension in @extensions exist in %{$extensions_ref}?
 517 sub extension_found {
 518     my ($extensions_ref, @extensions) = @_;
 519
 520     foreach my $extension (@extensions) {
 521         if (exists $extensions_ref->{$extension}) {
 522             return 1;
 523         }
 524     }
 525     return 0;
 526 }
 527
 528
 529 # MAIN
 530
 531 # Parse command line arguments.
 532 my $option_help             = 0;
 533 my $option_version          = 0;
 534 my $option_pie              = 0;
 535 my $option_bindnow          = 0;
 536 my @option_ignore_arch      = ();
 537 my @option_ignore_flag      = ();
 538 my @option_ignore_arch_flag = ();
 539 my @option_ignore_line      = ();
 540 my @option_ignore_arch_line = ();
 541 my $option_all              = 0;
 542 my $option_arch             = undef;
 543 my $option_buildd           = 0;
 544    $option_color            = 0;
 545 if (not Getopt::Long::GetOptions(
 546             'help|h|?'           => \$option_help,
 547             'version'            => \$option_version,
 548             # Hardening options.
 549             'pie'                => \$option_pie,
 550             'bindnow'            => \$option_bindnow,
 551             'all'                => \$option_all,
 552             # Ignore.
 553             'ignore-arch=s'      => \@option_ignore_arch,
 554             'ignore-flag=s'      => \@option_ignore_flag,
 555             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 556             'ignore-line=s'      => \@option_ignore_line,
 557             'ignore-arch-line=s' => \@option_ignore_arch_line,
 558             # Misc.
 559             'color'              => \$option_color,
 560             'arch=s'             => \$option_arch,
 561             'buildd'             => \$option_buildd,
 562         )) {
 563     require Pod::Usage;
 564     Pod::Usage::pod2usage(2);
 565 }
 566 if ($option_help) {
 567     require Pod::Usage;
 568     Pod::Usage::pod2usage(1);
 569 }
 570 if ($option_version) {
 571     print "blhc $VERSION  Copyright (C) 2012-2013  Simon Ruderich
 572
 573 This program is free software: you can redistribute it and/or modify
 574 it under the terms of the GNU General Public License as published by
 575 the Free Software Foundation, either version 3 of the License, or
 576 (at your option) any later version.
 577
 578 This program is distributed in the hope that it will be useful,
 579 but WITHOUT ANY WARRANTY; without even the implied warranty of
 580 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 581 GNU General Public License for more details.
 582
 583 You should have received a copy of the GNU General Public License
 584 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 585 ";
 586     exit 0;
 587 }
 588
 589 # Arguments missing.
 590 if (scalar @ARGV == 0) {
 591     require Pod::Usage;
 592     Pod::Usage::pod2usage(2);
 593 }
 594
 595 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 596 # installed on Debian's buildds.
 597 if (not $option_buildd) {
 598     require Term::ANSIColor;
 599 }
 600
 601 if ($option_all) {
 602     $option_pie     = 1;
 603     $option_bindnow = 1;
 604 }
 605
 606 # Precompiled ignores for faster lookup.
 607 my %option_ignore_arch_flag = ();
 608 my %option_ignore_arch_line = ();
 609
 610 # Strip flags which should be ignored.
 611 if (scalar @option_ignore_flag > 0) {
 612     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 613 }
 614 # Same for arch specific ignore flags, but only prepare here.
 615 if (scalar @option_ignore_arch_flag > 0) {
 616     foreach my $ignore (@option_ignore_arch_flag) {
 617         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 618
 619         if (not $ignore_arch or not $ignore_flag) {
 620             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 621                         . '("arch:flag" expected)' . "\n", $ignore;
 622             require Pod::Usage;
 623             Pod::Usage::pod2usage(2);
 624         }
 625
 626         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 627     }
 628 }
 629
 630 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 631 # faster with this.
 632 foreach my $flags (@flag_refs_all) {
 633     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 634 }
 635
 636 # Precompile ignore line regexps, also anchor at beginning and end of line.
 637 foreach my $ignore (@option_ignore_line) {
 638     $ignore = qr/^$ignore$/;
 639 }
 640 # Same for arch specific ignore lines.
 641 if (scalar @option_ignore_arch_line > 0) {
 642     foreach my $ignore (@option_ignore_arch_line) {
 643         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 644
 645         if (not $ignore_arch or not $ignore_line) {
 646             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 647                         . '("arch:line" expected)' . "\n", $ignore;
 648             require Pod::Usage;
 649             Pod::Usage::pod2usage(2);
 650         }
 651
 652         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 653     }
 654 }
 655
 656 # Final exit code.
 657 my $exit = 0;
 658
 659 FILE:
 660 foreach my $file (@ARGV) {
 661     print "checking '$file'...\n" if scalar @ARGV > 1;
 662
 663     -f $file or die "No such file: $file";
 664
 665     open my $fh, '<', $file or die $!;
 666
 667     # Architecture of this file.
 668     my $arch = $option_arch;
 669
 670     # Hardening options. Not all architectures support all hardening options.
 671     my $harden_format  = 1;
 672     my $harden_fortify = 1;
 673     my $harden_stack   = 1;
 674     my $harden_relro   = 1;
 675     my $harden_bindnow = $option_bindnow; # defaults to 0
 676     my $harden_pie     = $option_pie;     # defaults to 0
 677
 678     # Does this build log use ada? Ada also uses gcc as compiler but uses
 679     # different CFLAGS. But only perform ada checks if an ada compiler used
 680     # for performance reasons.
 681     my $ada = 0;
 682
 683     while (my $line = <$fh>) {
 684         # Detect architecture automatically unless overridden. For buildd logs
 685         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 686         # build logs which aren't built (wrong architecture, build error,
 687         # etc.).
 688         if (not $arch and index($line, 'Architecture: ') == 0) {
 689             $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 690         }
 691
 692         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 693         # check for hardening flags in buildd mode if an older dpkg-dev is
 694         # used. Default flags (-g -O2) are still checked.
 695         #
 696         # Packages which were built before 1.16.1 but used their own hardening
 697         # flags are not checked.
 698         if ($option_buildd
 699                 and index($line, 'Toolchain package versions: ') == 0) {
 700             require Dpkg::Version;
 701             if (not $line =~ /\bdpkg-dev_(\S+)/
 702                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 703                 $harden_format  = 0;
 704                 $harden_fortify = 0;
 705                 $harden_stack   = 0;
 706                 $harden_relro   = 0;
 707                 $harden_bindnow = 0;
 708                 $harden_pie     = 0;
 709             }
 710         }
 711
 712         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 713         # this was later dropped because upstream rejected the patch. Thus
 714         # build logs with these versions will have fortify hardening flags
 715         # enabled, even though they may be not correctly set and are missing
 716         # when build with later CMake versions. Thanks to Aron Xu for letting
 717         # me know.
 718         if (index($line, 'Package versions: ') == 0
 719                 and $line =~ /\bcmake_(\S+)/
 720                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 721             if (not $option_buildd) {
 722                 error_invalid_cmake($1);
 723                 $exit |= $exit_code{invalid_cmake};
 724             } else {
 725                 print "$buildd_tag{invalid_cmake}|$1|\n";
 726             }
 727         }
 728
 729         # Debian's build daemons use Build-Depends: for the build
 730         # dependencies, but pbuilder just uses Depends:; support both.
 731         if (index($line, 'Build-Depends: ') == 0
 732                 or index($line, 'Depends: ') == 0) {
 733             # If hardening wrapper is used (wraps calls to gcc and adds
 734             # hardening flags automatically) we can't perform any checks,
 735             # abort.
 736             if ($line =~ /\bhardening-wrapper\b/) {
 737                 if (not $option_buildd) {
 738                     error_hardening_wrapper();
 739                     $exit |= $exit_code{hardening_wrapper};
 740                 } else {
 741                     print "$buildd_tag{hardening_wrapper}||\n";
 742                 }
 743                 next FILE;
 744             }
 745
 746             # Ada compiler.
 747             if ($line =~ /\bgnat\b/) {
 748                 $ada = 1;
 749             }
 750         }
 751
 752         # We skip over unimportant lines at the beginning of the log to
 753         # prevent false positives.
 754         last if index($line, 'dpkg-buildpackage: ') == 0;
 755     }
 756
 757     # Input lines, contain only the lines with compiler commands.
 758     my @input = ();
 759     # Non-verbose lines in the input. Used to reduce calls to
 760     # is_non_verbose_build() (which is quite slow) in the second loop when
 761     # it's already clear if a line is non-verbose or not.
 762     my @input_nonverbose = ();
 763
 764     my $continuation = 0;
 765     my $complete_line = undef;
 766     while (my $line = <$fh>) {
 767         # And stop at the end of the build log. Package details (reported by
 768         # the buildd logs) are not important for us. This also prevents false
 769         # positives.
 770         last if index($line, 'Build finished at ') == 0
 771                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 772
 773         # Detect architecture automatically unless overridden.
 774         if (not $arch
 775                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 776             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 777
 778             # Old buildd logs use e.g. "host architecture is alpha", remove
 779             # the "is", otherwise debarch_to_debtriplet() will not detect the
 780             # architecture.
 781             if (index($arch, 'is ') == 0) {
 782                 $arch = substr $arch, 3;
 783             }
 784         }
 785
 786         # Ignore compiler warnings for now.
 787         next if $line =~ /$warning_regex/o;
 788
 789         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 790             # Remove all ANSI color sequences which are sometimes used in
 791             # non-verbose builds.
 792             $line = Term::ANSIColor::colorstrip($line);
 793             # Also strip '\0xf' (delete previous character), used by Elinks'
 794             # build system.
 795             $line =~ s/\x0f//g;
 796             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 797             # what it does).
 798             $line =~ s/\033\(B//g;
 799         }
 800
 801         # Check if this line indicates a non verbose build.
 802         my $non_verbose = is_non_verbose_build($line);
 803
 804         # One line may contain multiple commands (";"). Treat each one as
 805         # single line. parse_line() is slow, only use it when necessary.
 806         my @line = (index($line, ';') == -1)
 807                  ? ($line)
 808                  : map {
 809                        # Ensure newline at the line end - necessary for
 810                        # correct parsing later.
 811                        $_ =~ s/\s+$//;
 812                        $_ .= "\n";
 813                    } Text::ParseWords::parse_line(';', 1, $line);
 814         foreach my $line (@line) {
 815             if ($continuation) {
 816                 $continuation = 0;
 817
 818                 # Join lines, but leave the "\" in place so it's clear where
 819                 # the original line break was.
 820                 chomp $complete_line;
 821                 $complete_line .= ' ' . $line;
 822             }
 823             # Line continuation, line ends with "\".
 824             if ($line =~ /\\$/) {
 825                 $continuation = 1;
 826                 # Start line continuation.
 827                 if (not defined $complete_line) {
 828                     $complete_line = $line;
 829                 }
 830                 next;
 831             }
 832
 833             # Use the complete line if a line continuation occurred.
 834             if (defined $complete_line) {
 835                 $line = $complete_line;
 836                 $complete_line = undef;
 837             }
 838
 839             # Ignore lines with no compiler commands.
 840             next if not $non_verbose
 841                     and not $line =~ /$cc_regex_normal/o;
 842             # Ignore lines with no filenames with extensions. May miss some
 843             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 844             # a problem as the log will most likely contain other non-verbose
 845             # commands which are detected.
 846             next if not $non_verbose
 847                     and not $line =~ /$file_extension_regex/o;
 848
 849             # Ignore false positives.
 850             #
 851             # `./configure` output.
 852             next if not $non_verbose
 853                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 854             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 855                                 [Cc]ompiler[\s.]*:?\s+
 856                                 /x;
 857             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 858                                 \s*=\s*$cc_regex_full
 859                                 # optional compiler options, don't allow
 860                                 # "everything" here to prevent false negatives
 861                                 \s*(?:\s-\S+)*\s*$}xo;
 862             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 863             # line (or similar for other architectures) which gets recognized
 864             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 865             # C++ files. No hardening flags are relevant during this step,
 866             # thus ignore `moc-qt*` lines. The resulting files will be
 867             # compiled in a separate step (and therefore checked).
 868             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 869                                \s.+\s
 870                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 871                                \s}x;
 872             # Ignore false positives when the line contains only CC=gcc but no
 873             # other gcc command.
 874             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 875                 my $before = $1;
 876                 my $after  = $2;
 877                 next if     not $before =~ /$cc_regex_normal/o
 878                         and not $after  =~ /$cc_regex_normal/o;
 879             }
 880
 881             # Check if additional hardening options were used. Used to ensure
 882             # they are used for the complete build.
 883             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 884                                                          @def_ldflags_pie);
 885             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 886
 887             push @input, $line;
 888             push @input_nonverbose, $non_verbose;
 889         }
 890     }
 891
 892     close $fh or die $!;
 893
 894     # Ignore arch if requested.
 895     if (scalar @option_ignore_arch > 0 and $arch) {
 896         foreach my $ignore (@option_ignore_arch) {
 897             if ($arch eq $ignore) {
 898                 print "ignoring architecture '$arch'\n";
 899                 next FILE;
 900             }
 901         }
 902     }
 903
 904     if (scalar @input == 0) {
 905         if (not $option_buildd) {
 906             print "No compiler commands!\n";
 907             $exit |= $exit_code{no_compiler_commands};
 908         } else {
 909             print "$buildd_tag{no_compiler_commands}||\n";
 910         }
 911         next FILE;
 912     }
 913
 914     if ($option_buildd) {
 915         $statistics{commands} += scalar @input;
 916     }
 917
 918     # Option or auto detected.
 919     if ($arch) {
 920         # The following was partially copied from dpkg-dev 1.16.4.3
 921         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 922         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 923         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 924         # later. Keep it in sync.
 925
 926         require Dpkg::Arch;
 927         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 928
 929         # Disable unsupported hardening options.
 930         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 931             $harden_stack = 0;
 932         }
 933         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 934             $harden_relro   = 0;
 935             $harden_bindnow = 0;
 936         }
 937     }
 938
 939     # Default values.
 940     my @cflags   = @def_cflags;
 941     my @cxxflags = @def_cxxflags;
 942     my @cppflags = @def_cppflags;
 943     my @ldflags  = @def_ldflags;
 944     # Check the specified hardening options, same order as dpkg-buildflags.
 945     if ($harden_pie) {
 946         @cflags   = (@cflags,   @def_cflags_pie);
 947         @cxxflags = (@cxxflags, @def_cflags_pie);
 948         @ldflags  = (@ldflags,  @def_ldflags_pie);
 949     }
 950     if ($harden_stack) {
 951         @cflags   = (@cflags,   @def_cflags_stack);
 952         @cxxflags = (@cxxflags, @def_cflags_stack);
 953     }
 954     if ($harden_fortify) {
 955         @cflags   = (@cflags,   @def_cflags_fortify);
 956         @cxxflags = (@cxxflags, @def_cflags_fortify);
 957         @cppflags = (@cppflags, @def_cppflags_fortify);
 958     }
 959     if ($harden_format) {
 960         @cflags   = (@cflags,   @def_cflags_format);
 961         @cxxflags = (@cxxflags, @def_cflags_format);
 962     }
 963     if ($harden_relro) {
 964         @ldflags = (@ldflags, @def_ldflags_relro);
 965     }
 966     if ($harden_bindnow) {
 967         @ldflags = (@ldflags, @def_ldflags_bindnow);
 968     }
 969
 970     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 971     my @cflags_backup;
 972     # Ada CFLAGS.
 973     my @cflags_ada = @cflags;
 974     # Ada doesn't support format hardening flags, see #680117 for more
 975     # information. Filter them out if ada is used.
 976     if ($ada and $harden_format) {
 977         @cflags_ada = grep {
 978             my $ok = 1;
 979             foreach my $flag (@def_cflags_format) {
 980                 $ok = 0 if $_ eq $flag;
 981             }
 982             $ok;
 983         } @cflags;
 984     }
 985
 986     # Hack to fix cppflags_fortify_broken() if --ignore-flag
 987     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
 988     # as long as @def_cppflags_fortify contains only one variable.
 989     if (scalar @def_cppflags_fortify == 0) {
 990         $harden_fortify = 0;
 991     }
 992
 993     # Ignore flags for this arch if requested.
 994     if ($arch and exists $option_ignore_arch_flag{$arch}) {
 995         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
 996
 997         remove_flags(\@local_flag_refs,
 998                      \%flag_renames,
 999                      @{$option_ignore_arch_flag{$arch}});
1000     }
1001
1002     my @ignore_line = @option_ignore_line;
1003     # Ignore lines for this arch if requested.
1004     if ($arch and exists $option_ignore_arch_line{$arch}) {
1005         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1006     }
1007
1008 LINE:
1009     for (my $i = 0; $i < scalar @input; $i++) {
1010         my $line = $input[$i];
1011
1012         # Ignore line if requested.
1013         foreach my $ignore (@ignore_line) {
1014             next LINE if $line =~ /$ignore/;
1015         }
1016
1017         my $skip = 0;
1018         if ($input_nonverbose[$i]
1019                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1020             if (not $option_buildd) {
1021                 error_non_verbose_build($line);
1022                 $exit |= $exit_code{non_verbose_build};
1023             } else {
1024                 $statistics{commands_nonverbose}++;
1025             }
1026             next;
1027         }
1028         # Even if it's a verbose build, we might have to skip this line (see
1029         # is_non_verbose_build()).
1030         next if $skip;
1031
1032         # Remove everything until and including the compiler command. Makes
1033         # checks easier and faster.
1034         $line =~ s/^.*?$cc_regex//o;
1035         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1036         # the brace and similar characters at the line end.
1037         $line =~ s/['")]+$//;
1038
1039         # Skip unnecessary tests when only preprocessing.
1040         my $flag_preprocess = 0;
1041
1042         my $dependency = 0;
1043         my $preprocess = 0;
1044         my $compile    = 0;
1045         my $link       = 0;
1046
1047         # Preprocess, compile, assemble.
1048         if ($line =~ /\s(-E|-S|-c)\b/) {
1049             $preprocess      = 1;
1050             $flag_preprocess = 1 if $1 eq '-E';
1051             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1052         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1053         # -MT -MQ) are always used with -M/-MM.
1054         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1055             $dependency = 1;
1056         # Otherwise assume we are linking.
1057         } else {
1058             $link = 1;
1059         }
1060
1061         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1062         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1063             $dependency      = 0;
1064             $flag_preprocess = 0;
1065         }
1066
1067         # Dependency generation for Makefiles, no preprocessing or other flags
1068         # needed.
1069         next if $dependency;
1070
1071         # Get all file extensions on this line.
1072         my @extensions = $line =~ /$file_extension_regex/go;
1073         # Ignore all unknown extensions to speedup the search below.
1074         @extensions = grep { exists $extension{$_} } @extensions;
1075
1076         # These file types don't require preprocessing.
1077         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1078             $preprocess = 0;
1079         }
1080         # These file types require preprocessing.
1081         if (extension_found(\%extensions_preprocess, @extensions)) {
1082             $preprocess = 1;
1083         }
1084
1085         if (not $flag_preprocess) {
1086             # If there are source files then it's compiling/linking in one
1087             # step and we must check both. We only check for source files
1088             # here, because header files cause too many false positives.
1089             if (extension_found(\%extensions_compile_link, @extensions)) {
1090                 # Assembly files don't need CFLAGS.
1091                 if (not extension_found(\%extensions_compile, @extensions)
1092                         and extension_found(\%extensions_no_compile, @extensions)) {
1093                     $compile = 0;
1094                 # But the rest does.
1095                 } else {
1096                     $compile = 1;
1097                 }
1098             # No compilable extensions found, either linking or compiling
1099             # header flags.
1100             #
1101             # If there are also no object files we are just compiling headers
1102             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1103             # to our liberal checks for compiler lines, this also reduces the
1104             # number of false positives considerably.
1105             } elsif ($link
1106                     and not extension_found(\%extensions_object, @extensions)) {
1107                 $link = 0;
1108             }
1109         }
1110
1111         my $compile_cpp = 0;
1112         my $compile_ada = 0;
1113         # Assume CXXFLAGS are required when a C++ file is specified in the
1114         # compiler line.
1115         if ($compile
1116                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1117             $compile     = 0;
1118             $compile_cpp = 1;
1119         # Ada needs special CFLAGS, use them if only ada files are compiled.
1120         } elsif ($ada
1121                     and $compile
1122                     and array_equal(\@extensions,
1123                                     \@source_no_preprocess_compile_ada)) {
1124             $compile_ada = 1;
1125             @cflags_backup = @cflags;
1126             @cflags        = @cflags_ada;
1127         }
1128
1129         if ($option_buildd) {
1130             $statistics{preprocess}++  if $preprocess;
1131             $statistics{compile}++     if $compile;
1132             $statistics{compile_cpp}++ if $compile_cpp;
1133             $statistics{link}++        if $link;
1134         }
1135
1136         # Check hardening flags.
1137         my @missing;
1138         if ($compile and not all_flags_used($line, \@missing, @cflags)
1139                 # Libraries linked with -fPIC don't have to (and can't) be
1140                 # linked with -fPIE as well. It's no error if only PIE flags
1141                 # are missing.
1142                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1143                 # Assume dpkg-buildflags returns the correct flags.
1144                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1145             if (not $option_buildd) {
1146                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1147                 $exit |= $exit_code{flags_missing};
1148             } else {
1149                 $statistics{compile_missing}++;
1150             }
1151         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1152                 # Libraries linked with -fPIC don't have to (and can't) be
1153                 # linked with -fPIE as well. It's no error if only PIE flags
1154                 # are missing.
1155                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1156                 # Assume dpkg-buildflags returns the correct flags.
1157                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1158             if (not $option_buildd) {
1159                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1160                 $exit |= $exit_code{flags_missing};
1161             } else {
1162                 $statistics{compile_cpp_missing}++;
1163             }
1164         }
1165         if ($preprocess
1166                 and (not all_flags_used($line, \@missing, @cppflags)
1167                     # The fortify flag might be overwritten, detect that.
1168                      or ($harden_fortify
1169                          and cppflags_fortify_broken($line, \@missing)))
1170                 # Assume dpkg-buildflags returns the correct flags.
1171                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1172             if (not $option_buildd) {
1173                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1174                 $exit |= $exit_code{flags_missing};
1175             } else {
1176                 $statistics{preprocess_missing}++;
1177             }
1178         }
1179         if ($link and not all_flags_used($line, \@missing, @ldflags)
1180                 # Same here, -fPIC conflicts with -fPIE.
1181                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1182                 # Assume dpkg-buildflags returns the correct flags.
1183                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1184             if (not $option_buildd) {
1185                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1186                 $exit |= $exit_code{flags_missing};
1187             } else {
1188                 $statistics{link_missing}++;
1189             }
1190         }
1191
1192         # Restore normal CFLAGS.
1193         if ($compile_ada) {
1194             @cflags = @cflags_backup;
1195         }
1196     }
1197 }
1198
1199 # Print statistics for buildd mode, only output in this mode.
1200 if ($option_buildd) {
1201     my @warning;
1202
1203     if ($statistics{preprocess_missing}) {
1204         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1205                                $statistics{preprocess_missing},
1206                                $statistics{preprocess};
1207     }
1208     if ($statistics{compile_missing}) {
1209         push @warning, sprintf 'CFLAGS %d (of %d)',
1210                                $statistics{compile_missing},
1211                                $statistics{compile};
1212     }
1213     if ($statistics{compile_cpp_missing}) {
1214         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1215                                $statistics{compile_cpp_missing},
1216                                $statistics{compile_cpp};
1217     }
1218     if ($statistics{link_missing}) {
1219         push @warning, sprintf 'LDFLAGS %d (of %d)',
1220                                $statistics{link_missing},
1221                                $statistics{link};
1222     }
1223     if (scalar @warning) {
1224         local $" = ', '; # array join string
1225         print "$buildd_tag{flags_missing}|@warning missing|\n";
1226     }
1227
1228     if ($statistics{commands_nonverbose}) {
1229         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1230                $statistics{commands_nonverbose},
1231                $statistics{commands},
1232     }
1233 }
1234
1235
1236 exit $exit;
1237
1238
1239 __END__
1240
1241 =head1 NAME
1242
1243 blhc - build log hardening check, checks build logs for missing hardening flags
1244
1245 =head1 SYNOPSIS
1246
1247 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1248
1249 =head1 DESCRIPTION
1250
1251 blhc is a small tool which checks build logs for missing hardening flags. It's
1252 licensed under the GPL 3 or later.
1253
1254 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1255 tools using dpkg-buildpackage like pbuilder or the official buildd build logs)
1256 to help maintainers detect missing hardening flags in their packages.
1257
1258 Only gcc is detected as compiler at the moment. If other compilers support
1259 hardening flags as well, please report them.
1260
1261 If there's no output, no flags are missing and the build log is fine.
1262
1263 =head1 OPTIONS
1264
1265 =over 8
1266
1267 =item B<--all>
1268
1269 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1270 auto detected.
1271
1272 =item B<--arch> I<architecture>
1273
1274 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1275 disables hardening flags not available on this architecture. Is detected
1276 automatically if dpkg-buildpackage is used.
1277
1278 =item B<--bindnow>
1279
1280 Force check for all +bindnow hardening flags. By default it's auto detected.
1281
1282 =item B<--buildd>
1283
1284 Special mode for buildds when automatically parsing log files. The following
1285 changes are in effect:
1286
1287 =over 2
1288
1289 =item *
1290
1291 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1292 possible tags.
1293
1294 =item *
1295
1296 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1297 detected).
1298
1299 =item *
1300
1301 Don't require Term::ANSIColor.
1302
1303 =item *
1304
1305 Return exit code 0, unless there was a error (-I, -W messages don't count as
1306 error).
1307
1308 =back
1309
1310 =item B<--color>
1311
1312 Use colored (ANSI) output for warning messages.
1313
1314 =item B<--ignore-arch> I<arch>
1315
1316 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1317
1318 Used to prevent false positives. This option can be specified multiple times.
1319
1320 =item B<--ignore-arch-flag> I<arch>:I<flag>
1321
1322 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1323
1324 =item B<--ignore-arch-line> I<arch>:I<line>
1325
1326 Like B<--ignore-line>, but only ignore line on I<arch>.
1327
1328 =item B<--ignore-flag> I<flag>
1329
1330 Don't print an error when the specific flag is missing in a compiler line.
1331 I<flag> is a string.
1332
1333 Used to prevent false positives. This option can be specified multiple times.
1334
1335 =item B<--ignore-line> I<regex>
1336
1337 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1338 at the beginning and end of the line to prevent false negatives.
1339
1340 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1341 warnings (which have line continuation resolved).
1342
1343 Used to prevent false positives. This option can be specified multiple times.
1344
1345 =item B<--pie>
1346
1347 Force check for all +pie hardening flags. By default it's auto detected.
1348
1349 =item B<-h -? --help>
1350
1351 Print available options.
1352
1353 =item B<--version>
1354
1355 Print version number and license.
1356
1357 =back
1358
1359 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1360 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1361 all other commands as well.
1362
1363 =head1 EXAMPLES
1364
1365 Normal usage, parse a single log file.
1366
1367     blhc path/to/log/file
1368
1369 If there's no output, no flags are missing and the build log is fine.
1370
1371 Parse multiple log files. The exit code is ORed over all files.
1372
1373     blhc path/to/directory/with/log/files/*
1374
1375 Don't treat missing C<-g> as error:
1376
1377     blhc --ignore-flag -g path/to/log/file
1378
1379 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1380
1381     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1382
1383 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1384 false positive.
1385
1386     blhc --ignore-line '\./script gcc file' path/to/log/file
1387
1388 Ignore lines matching C<./script gcc file> somewhere in the line.
1389
1390     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1391
1392 Use blhc with pbuilder.
1393
1394     pbuilder path/to/package.dsc | tee path/log/file
1395     blhc path/to/file || echo flags missing
1396
1397 =head1 BUILDD TAGS
1398
1399 The following tags are used in I<--buildd> mode. In braces the additional data
1400 which is displayed.
1401
1402 =over 2
1403
1404 =item B<I-hardening-wrapper-used>
1405
1406 The package uses hardening-wrapper which intercepts calls to gcc and adds
1407 hardening flags. The build log doesn't contain any hardening flags and thus
1408 can't be checked by blhc.
1409
1410 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1411
1412 Build log contains lines which hide the real compiler flags. For example:
1413
1414     CC test-a.c
1415     CC test-b.c
1416     CC test-c.c
1417     LD test
1418
1419 Most of the time either C<export V=1> or C<export verbose=1> in
1420 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1421 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1422 patched to remove the C<@>s hiding the real compiler commands.
1423
1424 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1425
1426 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1427
1428 =item B<I-invalid-cmake-used> (version)
1429
1430 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1431 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1432 patch was rejected by upstream and later reverted in Debian. Thus those two
1433 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1434 handle them (for example by passing them to CFLAGS). To prevent false
1435 negatives just blacklist those two versions.
1436
1437 =item B<I-no-compiler-commands>
1438
1439 No compiler commands were detected. Either the log contains none or they were
1440 not correctly detected by blhc (please report the bug in this case).
1441
1442 =back
1443
1444 =head1 EXIT STATUS
1445
1446 The exit status is a "bit mask", each listed status is ORed when the error
1447 condition occurs to get the result.
1448
1449 =over 4
1450
1451 =item B<0>
1452
1453 Success.
1454
1455 =item B<1>
1456
1457 No compiler commands were found.
1458
1459 =item B<2>
1460
1461 Invalid arguments/options given to blhc.
1462
1463 =item B<4>
1464
1465 Non verbose build.
1466
1467 =item B<8>
1468
1469 Missing hardening flags.
1470
1471 =item B<16>
1472
1473 Hardening wrapper detected, no tests performed.
1474
1475 =item B<32>
1476
1477 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1478 TAGS"> for a detailed explanation.
1479
1480 =back
1481
1482 =head1 AUTHOR
1483
1484 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1485
1486 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1487 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1488
1489 =head1 LICENSE AND COPYRIGHT
1490
1491 Copyright (C) 2012-2013 by Simon Ruderich
1492
1493 This program is free software: you can redistribute it and/or modify
1494 it under the terms of the GNU General Public License as published by
1495 the Free Software Foundation, either version 3 of the License, or
1496 (at your option) any later version.
1497
1498 This program is distributed in the hope that it will be useful,
1499 but WITHOUT ANY WARRANTY; without even the implied warranty of
1500 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1501 GNU General Public License for more details.
1502
1503 You should have received a copy of the GNU General Public License
1504 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1505
1506 =head1 SEE ALSO
1507
1508 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1509
1510 =cut