Detect non-verbose commands in waf builds
[blhc/blhc.git] / bin / blhc
1 #!/usr/bin/perl
2
3 # Build log hardening check, checks build logs for missing hardening flags.
4
5 # Copyright (C) 2012-2020  Simon Ruderich
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20
21 use strict;
22 use warnings;
23
24 use Getopt::Long ();
25 use Text::ParseWords ();
26
27 our $VERSION = '0.11';
28
29
30 # CONSTANTS/VARIABLES
31
32 # Regex to catch compiler commands.
33 my $cc_regex = qr/
34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
35     (?<!\.)                # ignore file names, e.g. "test.gcc"
36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
38     /x;
39 # Full regex which matches the complete compiler name. Used in a few places to
40 # prevent false negatives.
41 my $cc_regex_full_prefix = qr/
42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
43     /x;
44 my $cc_regex_full = qr/
45     (?:$cc_regex_full_prefix-)?
46     $cc_regex
47     /x;
48 # Regex to check if a line contains a compiler command.
49 my $cc_regex_normal = qr/
50     \b$cc_regex(?:\s|\\)
51     /x;
52 # Regex to catch (GCC) compiler warnings.
53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
54 # Regex to catch libtool commands and not lines which show commands executed
55 # by libtool (e.g. libtool: link: ...).
56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
57 my $libtool_link_regex = qr/\blibtool: link: /;
58
59 # List of source file extensions which require preprocessing.
60 my @source_preprocess_compile_cpp = (
61     # C++
62     qw( cc cp cxx cpp CPP c++ C ),
63     # Objective-C++
64     qw( mm M ),
65 );
66 my @source_preprocess_compile_fortran = (
67     # Fortran
68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
69 );
70 my @source_preprocess_compile = (
71     # C
72     qw( c ),
73     # Objective-C
74     qw( m ),
75     # (Objective-)C++
76     @source_preprocess_compile_cpp,
77     # Fortran
78     @source_preprocess_compile_fortran,
79 );
80 my @source_preprocess_no_compile = (
81     # Assembly
82     qw( S sx ),
83 );
84 my @source_preprocess = (
85     @source_preprocess_compile,
86     @source_preprocess_no_compile,
87 );
88 # List of source file extensions which don't require preprocessing.
89 my @source_no_preprocess_compile_cpp = (
90     # C++
91     qw( ii ),
92     # Objective-C++
93     qw( mii ),
94 );
95 my @source_no_preprocess_compile_ada = (
96     # Ada source
97     qw( ada ),
98     # Ada body
99     qw( adb ),
100 );
101 my @source_no_preprocess_compile_fortran = (
102     # Fortran
103     qw( f for ftn f90 f95 f03 f08 ),
104 );
105 my @source_no_preprocess_compile = (
106     # C
107     qw( i ),
108     # (Objective-)C++
109     @source_no_preprocess_compile_cpp,
110     # Objective-C
111     qw( mi ),
112     # Fortran
113     @source_no_preprocess_compile_fortran,
114     # Ada
115     @source_no_preprocess_compile_ada,
116 );
117 my @source_no_preprocess_no_compile_ada = (
118     # Ada specification
119     qw( ads ),
120 );
121 my @source_no_preprocess_no_compile = (
122     # Assembly
123     qw( s ),
124     # Ada
125     @source_no_preprocess_no_compile_ada,
126 );
127 my @source_no_preprocess = (
128     @source_no_preprocess_compile,
129     @source_no_preprocess_no_compile,
130 );
131 # List of header file extensions which require preprocessing.
132 my @header_preprocess = (
133     # C, C++, Objective-C, Objective-C++
134     qw( h ),
135     # C++
136     qw( hh H hp hxx hpp HPP h++ tcc ),
137 );
138 # Object files.
139 my @object = (
140     # Normal object files.
141     qw ( o ),
142     # Libtool object files.
143     qw ( lo la ),
144     # Dynamic libraries. bzip2 uses .sho.
145     qw ( so sho ),
146     # Static libraries.
147     qw ( a ),
148 );
149
150 # Hashes for fast extensions lookup to check if a file falls in one of these
151 # categories.
152 my %extensions_no_preprocess = map { $_ => 1 } (
153     # There's no @header_no_preprocess.
154     @source_no_preprocess,
155 );
156 my %extensions_preprocess = map { $_ => 1 } (
157     @header_preprocess,
158     @source_preprocess,
159 );
160 my %extensions_compile_link = map { $_ => 1 } (
161     @source_preprocess,
162     @source_no_preprocess,
163 );
164 my %extensions_compile = map { $_ => 1 } (
165     @source_preprocess_compile,
166     @source_no_preprocess_compile,
167 );
168 my %extensions_no_compile = map { $_ => 1 } (
169     @source_preprocess_no_compile,
170     @source_no_preprocess_no_compile,
171 );
172 my %extensions_compile_cpp = map { $_ => 1 } (
173     @source_preprocess_compile_cpp,
174     @source_no_preprocess_compile_cpp,
175 );
176 my %extensions_ada = map { $_ => 1 } (
177     @source_no_preprocess_compile_ada,
178     @source_no_preprocess_no_compile_ada,
179 );
180 my %extensions_fortran = map { $_ => 1 } (
181     @source_no_preprocess_compile_fortran,
182     @source_preprocess_compile_fortran,
183 );
184 my %extensions_object = map { $_ => 1 } (
185     @object,
186 );
187 my %extension = map { $_ => 1 } (
188     @source_no_preprocess,
189     @header_preprocess,
190     @source_preprocess,
191     @object,
192 );
193
194 # Regexp to match file extensions.
195 my $file_extension_regex = qr/
196     \s
197     \S+             # Filename without extension.
198     \.
199     ([^\/\\.,;:\s]+)# File extension.
200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
201                     # word characters at the end and because \b matches double
202                     # extensions (like .cpp.o). Works always as all lines are
203                     # terminated with "\n".
204     /x;
205
206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
207 # real regexps below for better execution speed).
208 my @def_cflags = (
209     '-g',
210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
211 );
212 my @def_cflags_debug = (
213     # These flags indicate a debug build which disables checks for -O2.
214     '-O0',
215     '-Og',
216 );
217 my @def_cflags_format = (
218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
219     '-Werror=format-security', # implies -Wformat-security
220 );
221 my @def_cflags_fortify = (
222     # fortify needs at least -O1, but -O2 is recommended anyway
223 );
224 my @def_cflags_stack = (
225     '-fstack-protector', # keep first, used by cflags_stack_broken()
226     '--param[= ]ssp-buffer-size=4',
227 );
228 my @def_cflags_stack_strong = (
229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
230 );
231 my @def_cflags_stack_bad = (
232     # Blacklist all stack protector options for simplicity.
233     '-fno-stack-protector',
234     '-fno-stack-protector-all',
235     '-fno-stack-protector-strong',
236 );
237 my @def_cflags_pie = (
238     '-fPIE',
239 );
240 my @def_cxxflags = (
241     @def_cflags,
242 );
243 # @def_cxxflags_* is the same as @def_cflags_*.
244 my @def_cppflags = ();
245 my @def_cppflags_fortify = (
246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
247     # If you add another flag fix hack below (search for "Hack to fix") and
248     # $def_cppflags_fortify[0].
249 );
250 my @def_cppflags_fortify_bad = (
251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
252     '-U_FORTIFY_SOURCE',
253     '-D_FORTIFY_SOURCE=0',
254     '-D_FORTIFY_SOURCE=1',
255 );
256 my @def_ldflags = ();
257 my @def_ldflags_relro = (
258     '-Wl,(?:-z,)?relro',
259 );
260 my @def_ldflags_bindnow = (
261     '-Wl,(?:-z,)?now',
262 );
263 my @def_ldflags_pie = (
264     '-fPIE',
265     '-pie',
266 );
267 my @def_ldflags_pic = (
268     '-fPIC',
269     '-fpic',
270     '-shared',
271 );
272 # References to all flags checked by the flag checker.
273 my @flag_refs = (
274     \@def_cflags,
275     \@def_cflags_format,
276     \@def_cflags_fortify,
277     \@def_cflags_stack,
278     \@def_cflags_stack_strong,
279     \@def_cflags_stack_bad,
280     \@def_cflags_pie,
281     \@def_cxxflags,
282     \@def_cppflags,
283     \@def_cppflags_fortify,
284     \@def_ldflags,
285     \@def_ldflags_relro,
286     \@def_ldflags_bindnow,
287     \@def_ldflags_pie,
288 );
289 # References to all used flags.
290 my @flag_refs_all = (
291     @flag_refs,
292     \@def_cflags_debug,
293     \@def_cppflags_fortify_bad,
294     \@def_ldflags_pic,
295 );
296 # Renaming rules for the output so the regex parts are not visible. Also
297 # stores string values of flag regexps above, see compile_flag_regexp().
298 my %flag_renames = (
299     '-O(?:2|3)'                    => '-O2',
300     '-Wformat(?:=2)?'              => '-Wformat',
301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
304 );
305
306 my %exit_code = (
307     no_compiler_commands => 1 << 0,
308     # used by POD::Usage => 1 << 1,
309     non_verbose_build    => 1 << 2,
310     flags_missing        => 1 << 3,
311     hardening_wrapper    => 1 << 4,
312     invalid_cmake        => 1 << 5,
313 );
314
315 my %buildd_tag = (
316     no_compiler_commands => 'I-no-compiler-commands',
317     non_verbose_build    => 'W-compiler-flags-hidden',
318     flags_missing        => 'W-dpkg-buildflags-missing',
319     hardening_wrapper    => 'I-hardening-wrapper-used',
320     invalid_cmake        => 'I-invalid-cmake-used',
321 );
322
323 # Statistics of missing flags and non-verbose build commands. Used for
324 # $option_buildd.
325 my %statistics = (
326     preprocess          => 0,
327     preprocess_missing  => 0,
328     compile             => 0,
329     compile_missing     => 0,
330     compile_cpp         => 0,
331     compile_cpp_missing => 0,
332     link                => 0,
333     link_missing        => 0,
334     commands            => 0,
335     commands_nonverbose => 0,
336 );
337
338 # Use colored (ANSI) output?
339 my $option_color;
340
341
342 # FUNCTIONS
343
344 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
345 sub array_equal {
346     my ($first_ref, $second_ref) = @_;
347
348     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
349
350     my $length = scalar @{$first_ref};
351     for (my $i = 0; $i < $length; $i++) {
352         return 0 if $first_ref->[$i] ne $second_ref->[$i];
353     }
354
355     return 1;
356 }
357
358 sub error_flags {
359     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
360
361     # Get string value of qr//-escaped regexps and if requested rename them.
362     my @missing_flags = map {
363             $flag_renames_ref->{$_}
364         } @{$missing_flags_ref};
365
366     my $flags = join ' ', @missing_flags;
367     printf '%d:', $number if defined $number;
368     printf '%s (%s)%s %s',
369            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
370            $line;
371
372     return;
373 }
374 sub error_non_verbose_build {
375     my ($line, $number) = @_;
376
377     printf '%d:', $number if defined $number;
378     printf '%s%s %s',
379            error_color('NONVERBOSE BUILD', 'red'),
380            error_color(':', 'yellow'),
381            $line;
382
383     return;
384 }
385 sub error_invalid_cmake {
386     my ($version) = @_;
387
388     printf "%s%s %s\n",
389             error_color('INVALID CMAKE', 'red'),
390             error_color(':', 'yellow'),
391             $version;
392
393     return;
394 }
395 sub error_hardening_wrapper {
396     printf "%s%s %s\n",
397             error_color('HARDENING WRAPPER', 'red'),
398             error_color(':', 'yellow'),
399             'no checks possible, aborting';
400
401     return;
402 }
403 sub error_color {
404     my ($message, $color) = @_;
405
406     if ($option_color) {
407         return Term::ANSIColor::colored($message, $color);
408     } else {
409         return $message;
410     }
411 }
412
413 sub any_flags_used {
414     my ($line, @flags) = @_;
415
416     foreach my $flag (@flags) {
417         return 1 if $line =~ /$flag/;
418     }
419
420     return 0;
421 }
422 sub all_flags_used {
423     my ($line, $missing_flags_ref, @flags) = @_;
424
425     my @missing_flags = ();
426     foreach my $flag (@flags) {
427         if (not $line =~ /$flag/) {
428             push @missing_flags, $flag;
429         }
430     }
431
432     return 1 if scalar @missing_flags == 0;
433
434     @{$missing_flags_ref} = @missing_flags;
435     return 0;
436 }
437 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
438 # $good_flag is present.
439 sub flag_overwritten {
440     my ($line, $good_flag, $bad_flags) = @_;
441
442     if (not any_flags_used($line, @{$bad_flags})) {
443         return 0;
444     }
445
446     my $bad_pos = 0;
447     foreach my $flag (@{$bad_flags}) {
448         while ($line =~ /$flag/g) {
449             if ($bad_pos < $+[0]) {
450                 $bad_pos = $+[0];
451             }
452         }
453     }
454     my $good_pos = 0;
455     while ($line =~ /$good_flag/g) {
456         $good_pos = $+[0];
457     }
458     if ($good_pos > $bad_pos) {
459         return 0;
460     }
461     return 1;
462 }
463
464 sub cppflags_fortify_broken {
465     my ($line, $missing_flags) = @_;
466
467     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
468     my $fortify_source = $def_cppflags_fortify[0];
469
470     # Some build systems enable/disable fortify source multiple times, check
471     # the final result.
472     if (not flag_overwritten($line,
473                              $fortify_source,
474                              \@def_cppflags_fortify_bad)) {
475         return 0;
476     }
477     push @{$missing_flags}, $fortify_source;
478     return 1;
479 }
480
481 sub cflags_stack_broken {
482     my ($line, $missing_flags, $strong) = @_;
483
484     my $flag = $strong ? $def_cflags_stack_strong[0]
485                        : $def_cflags_stack[0];
486
487     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
488         return 0;
489     }
490     push @{$missing_flags}, $flag;
491     return 1;
492 }
493
494 # Modifies $missing_flags_ref array.
495 sub pic_pie_conflict {
496     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
497
498     return 0 if not $pie;
499     return 0 if not any_flags_used($line, @def_ldflags_pic);
500
501     my %flags = map { $_ => 1 } @flags_pie;
502
503     # Remove all PIE flags from @missing_flags as they are not required with
504     # -fPIC.
505     my @result = grep {
506         not exists $flags{$_}
507     } @{$missing_flags_ref};
508     @{$missing_flags_ref} = @result;
509
510     # We got a conflict when no flags are left, thus only PIE flags were
511     # missing. If other flags were missing abort because the conflict is not
512     # the problem.
513     return scalar @result == 0;
514 }
515
516 sub is_non_verbose_build {
517     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
518
519     if ($line =~ /$libtool_regex/o) {
520         # libtool's --silent hides the real compiler flags.
521         if ($line =~ /\s--silent/) {
522             return 1;
523         # If --silent is not present, skip this line as some compiler flags
524         # might be missing (e.g. -fPIE) which are handled correctly by libtool
525         # internally. libtool displays the real compiler command on the next
526         # line, so the flags are checked as usual.
527         } else {
528             ${$skip_ref} = 1;
529             return 0;
530         }
531     }
532
533     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
534                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
535                 or $line =~ /^\s*[][\/0-9 ]*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
536                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
537                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
538         return 0;
539     }
540
541     # False positives.
542     #
543     # C++ compiler setting.
544     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
545     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
546     # "Compiling" non binary files.
547     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
548     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
549     # "Compiling" with no file name.
550     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
551         # $file_extension_regex may need spaces around the filename.
552         return 0 if not " $1 " =~ /$file_extension_regex/o;
553     }
554
555     my $file = $1;
556
557     # On the first pass we only check if this line is verbose or not.
558     return 1 if not defined $input_ref;
559
560     # Second pass, we have access to the next lines.
561     ${$skip_ref} = 0;
562
563     # CMake and other build systems print the non-verbose messages also when
564     # building verbose. If a compiler and the file name occurs in the next
565     # lines, treat it as verbose build.
566     if (defined $file) {
567         # Get filename, we can't use the complete path as only parts of it are
568         # used in the real compiler command.
569         $file =~ m{/([^/\s]+)$};
570         $file = $1;
571
572         for (my $i = 1; $i <= $line_count; $i++) {
573             my $next_line = $input_ref->[$line_offset + $i];
574             last unless defined $next_line;
575
576             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
577                 # Not a non-verbose line, but we still have to skip the
578                 # current line as it doesn't contain any compiler commands.
579                 ${$skip_ref} = 1;
580                 return 0;
581             }
582         }
583     }
584
585     return 1;
586 }
587
588 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
589 sub remove_flags {
590     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
591
592     my %removes = map { $_ => 1 } @flags;
593     foreach my $flags (@{$flag_refs_ref}) {
594         @{$flags} = grep {
595             # Flag found as string.
596             not exists $removes{$_}
597             # Flag found as string representation of regexp.
598                 and (not defined $flag_renames_ref->{$_}
599                         or not exists $removes{$flag_renames_ref->{$_}})
600         } @{$flags};
601     }
602
603     return;
604 }
605
606 # Modifies $flag_renames_ref hash.
607 sub compile_flag_regexp {
608     my ($flag_renames_ref, @flags) = @_;
609
610     my @result = ();
611     foreach my $flag (@flags) {
612         # Compile flag regexp for faster execution.
613         my $regex = qr/\s$flag(?:\s|\\)/;
614
615         # Store flag name in replacement string for correct flags in messages
616         # with qr//ed flag regexps.
617         $flag_renames_ref->{$regex}
618             = (exists $flag_renames_ref->{$flag})
619                 ? $flag_renames_ref->{$flag}
620                 : $flag;
621
622         push @result, $regex;
623     }
624     return @result;
625 }
626
627 # Does any extension in @extensions exist in %{$extensions_ref}?
628 sub extension_found {
629     my ($extensions_ref, @extensions) = @_;
630
631     foreach my $extension (@extensions) {
632         if (exists $extensions_ref->{$extension}) {
633             return 1;
634         }
635     }
636     return 0;
637 }
638
639
640 # MAIN
641
642 # Parse command line arguments.
643 my $option_help             = 0;
644 my $option_version          = 0;
645 my $option_pie              = 0;
646 my $option_bindnow          = 0;
647 my @option_ignore_arch      = ();
648 my @option_ignore_flag      = ();
649 my @option_ignore_arch_flag = ();
650 my @option_ignore_line      = ();
651 my @option_ignore_arch_line = ();
652 my $option_all              = 0;
653 my $option_arch             = undef;
654 my $option_buildd           = 0;
655 my $option_debian           = 0;
656    $option_color            = 0;
657 my $option_line_numbers     = 0;
658 if (not Getopt::Long::GetOptions(
659             'help|h|?'           => \$option_help,
660             'version'            => \$option_version,
661             # Hardening options.
662             'pie'                => \$option_pie,
663             'bindnow'            => \$option_bindnow,
664             'all'                => \$option_all,
665             # Ignore.
666             'ignore-arch=s'      => \@option_ignore_arch,
667             'ignore-flag=s'      => \@option_ignore_flag,
668             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
669             'ignore-line=s'      => \@option_ignore_line,
670             'ignore-arch-line=s' => \@option_ignore_arch_line,
671             # Misc.
672             'color'              => \$option_color,
673             'arch=s'             => \$option_arch,
674             'buildd'             => \$option_buildd,
675             'debian'             => \$option_debian,
676             'line-numbers'       => \$option_line_numbers,
677         )) {
678     require Pod::Usage;
679     Pod::Usage::pod2usage(2);
680 }
681 if ($option_help) {
682     require Pod::Usage;
683     Pod::Usage::pod2usage(1);
684 }
685 if ($option_version) {
686     print <<"EOF";
687 blhc $VERSION  Copyright (C) 2012-2020  Simon Ruderich
688
689 This program is free software: you can redistribute it and/or modify
690 it under the terms of the GNU General Public License as published by
691 the Free Software Foundation, either version 3 of the License, or
692 (at your option) any later version.
693
694 This program is distributed in the hope that it will be useful,
695 but WITHOUT ANY WARRANTY; without even the implied warranty of
696 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
697 GNU General Public License for more details.
698
699 You should have received a copy of the GNU General Public License
700 along with this program.  If not, see <http://www.gnu.org/licenses/>.
701 EOF
702     exit 0;
703 }
704
705 # Arguments missing.
706 if (scalar @ARGV == 0) {
707     require Pod::Usage;
708     Pod::Usage::pod2usage(2);
709 }
710
711 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
712 # installed on Debian's buildds.
713 if (not $option_buildd) {
714     require Term::ANSIColor;
715 }
716
717 if ($option_all) {
718     $option_pie     = 1;
719     $option_bindnow = 1;
720 }
721
722 # Precompiled ignores for faster lookup.
723 my %option_ignore_arch_flag = ();
724 my %option_ignore_arch_line = ();
725
726 # Strip flags which should be ignored.
727 if (scalar @option_ignore_flag > 0) {
728     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
729 }
730 # Same for arch specific ignore flags, but only prepare here.
731 if (scalar @option_ignore_arch_flag > 0) {
732     foreach my $ignore (@option_ignore_arch_flag) {
733         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
734
735         if (not $ignore_arch or not $ignore_flag) {
736             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
737                         . '("arch:flag" expected)' . "\n", $ignore;
738             require Pod::Usage;
739             Pod::Usage::pod2usage(2);
740         }
741
742         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
743     }
744 }
745
746 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
747 # faster with this.
748 foreach my $flags (@flag_refs_all) {
749     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
750 }
751
752 # Precompile ignore line regexps, also anchor at beginning and end of line.
753 # Additional entries are also extracted from the build log, see below.
754 foreach my $ignore (@option_ignore_line) {
755     $ignore = qr/^$ignore$/;
756 }
757 # Same for arch specific ignore lines.
758 if (scalar @option_ignore_arch_line > 0) {
759     foreach my $ignore (@option_ignore_arch_line) {
760         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
761
762         if (not $ignore_arch or not $ignore_line) {
763             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
764                         . '("arch:line" expected)' . "\n", $ignore;
765             require Pod::Usage;
766             Pod::Usage::pod2usage(2);
767         }
768
769         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
770     }
771 }
772
773 # Final exit code.
774 my $exit = 0;
775
776 FILE:
777 foreach my $file (@ARGV) {
778     print "checking '$file'...\n" if scalar @ARGV > 1;
779
780     -f $file or die "No such file: $file";
781
782     open my $fh, '<', $file or die $!;
783
784     # Architecture of this file.
785     my $arch = $option_arch;
786
787     # Hardening options. Not all architectures support all hardening options.
788     my $harden_format  = 1;
789     my $harden_fortify = 1;
790     my $harden_stack   = 1;
791     my $harden_stack_strong = 1;
792     my $harden_relro   = 1;
793     my $harden_bindnow = $option_bindnow; # defaults to 0
794     my $harden_pie     = $option_pie;     # defaults to 0
795
796     # Number of parallel jobs to prevent false positives when detecting
797     # non-verbose builds. As not all jobs declare the number of parallel jobs
798     # use a large enough default.
799     my $parallel = 10;
800
801     # Don't check for PIE flags if automatically applied by the compiler. Only
802     # used in buildd and Debian mode.
803     my $disable_harden_pie = 0;
804     if ($option_debian) {
805         $disable_harden_pie = 1;
806     }
807
808     my $number = 0;
809     while (my $line = <$fh>) {
810         $number++;
811
812         # Detect architecture automatically unless overridden. For buildd logs
813         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
814         # build logs which aren't built (wrong architecture, build error,
815         # etc.).
816         if (not $arch) {
817             if (index($line, 'Build Architecture: ') == 0) {
818                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
819             # For old logs (sbuild << 0.63.0-1).
820             } elsif (index($line, 'Architecture: ') == 0) {
821                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
822             }
823         }
824
825         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
826         # check for hardening flags in buildd mode if an older dpkg-dev is
827         # used. Default flags (-g -O2) are still checked.
828         #
829         # Packages which were built before 1.16.1 but used their own hardening
830         # flags are not checked.
831         #
832         # Strong stack protector is used since dpkg 1.17.11.
833         #
834         # Recent GCC versions automatically use PIE (only on supported
835         # architectures) and dpkg respects this properly since 1.18.15 and
836         # doesn't pass PIE flags manually.
837         if ($option_buildd
838                 and index($line, 'Toolchain package versions: ') == 0) {
839             require Dpkg::Version;
840
841             my $disable = 1;
842             my $disable_strong = 1;
843
844             if ($line =~ /\bdpkg-dev_(\S+)/) {
845                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
846                     $disable = 0;
847                 }
848                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
849                     $disable_strong = 0;
850                 }
851                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
852                     $disable_harden_pie = 1;
853                 }
854             }
855
856             if ($disable) {
857                 $harden_format  = 0;
858                 $harden_fortify = 0;
859                 $harden_stack   = 0;
860                 $harden_relro   = 0;
861                 $harden_bindnow = 0;
862                 $harden_pie     = 0;
863             }
864             if ($disable_strong) {
865                 $harden_stack_strong = 0;
866             }
867         }
868
869         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
870         # this was later dropped because upstream rejected the patch. Thus
871         # build logs with these versions will have fortify hardening flags
872         # enabled, even though they may be not correctly set and are missing
873         # when build with later CMake versions. Thanks to Aron Xu for letting
874         # me know.
875         if (index($line, 'Package versions: ') == 0
876                 and $line =~ /\bcmake_(\S+)/
877                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
878             if (not $option_buildd) {
879                 error_invalid_cmake($1);
880                 $exit |= $exit_code{invalid_cmake};
881             } else {
882                 print "$buildd_tag{invalid_cmake}|$1|\n";
883             }
884         }
885
886         # Debian's build daemons use "Filtered Build-Depends:" (or just
887         # "Build-Depends:" in older versions) for the build dependencies, but
888         # pbuilder uses "Depends:"; support both.
889         if (index($line, 'Filtered Build-Depends: ') == 0
890                 or index($line, 'Build-Depends: ') == 0
891                 or index($line, 'Depends: ') == 0) {
892             # If hardening wrapper is used (wraps calls to gcc and adds
893             # hardening flags automatically) we can't perform any checks,
894             # abort.
895             if ($line =~ /\bhardening-wrapper\b/) {
896                 if (not $option_buildd) {
897                     error_hardening_wrapper();
898                     $exit |= $exit_code{hardening_wrapper};
899                 } else {
900                     print "$buildd_tag{hardening_wrapper}||\n";
901                 }
902                 next FILE;
903             }
904         }
905
906         # This flags is not always available, but if it is use it.
907         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
908             $parallel = $1 * 2;
909         }
910
911         # We skip over unimportant lines at the beginning of the log to
912         # prevent false positives.
913         last if index($line, 'dpkg-buildpackage: ') == 0;
914     }
915
916     # Input lines, contain only the lines with compiler commands.
917     my @input = ();
918     # Non-verbose lines in the input. Used to reduce calls to
919     # is_non_verbose_build() (which is quite slow) in the second loop when
920     # it's already clear if a line is non-verbose or not.
921     my @input_nonverbose = ();
922     # Input line number.
923     my @input_number = ();
924
925     my $continuation = 0;
926     my $complete_line = undef;
927     my $non_verbose;
928     while (my $line = <$fh>) {
929         $number++;
930
931         # And stop at the end of the build log. Package details (reported by
932         # the buildd logs) are not important for us. This also prevents false
933         # positives.
934         last if index($line, 'Build finished at ') == 0
935                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
936
937         if (not $continuation) {
938             $non_verbose = 0;
939         }
940
941         # Detect architecture automatically unless overridden.
942         if (not $arch
943                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
944             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
945         # Older versions of dpkg-buildpackage
946         } elsif (not $arch
947                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
948             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
949
950             # Old buildd logs use e.g. "host architecture is alpha", remove
951             # the "is", otherwise debarch_to_debtriplet() will not detect the
952             # architecture.
953             if (index($arch, 'is ') == 0) {
954                 $arch = substr $arch, 3;
955             }
956         }
957
958         # Permit dynamic excludes from within the build log to ignore false
959         # positives. Cannot use a separate config file as we often only have
960         # the build log itself.
961         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
962             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
963             push @option_ignore_line, qr/^$ignore$/;
964             next;
965         }
966
967         next if $line =~ /^\s*#/;
968         # Ignore compiler warnings for now.
969         next if $line =~ /$warning_regex/o;
970
971         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
972             # Remove all ANSI color sequences which are sometimes used in
973             # non-verbose builds.
974             $line = Term::ANSIColor::colorstrip($line);
975             # Also strip '\0xf' (delete previous character), used by Elinks'
976             # build system.
977             $line =~ s/\x0f//g;
978             # And "ESC(B" which seems to be used on armhf and hurd (not sure
979             # what it does).
980             $line =~ s/\033\(B//g;
981         }
982
983         # Check if this line indicates a non verbose build.
984         my $skip = 0;
985         $non_verbose |= is_non_verbose_build($line, \$skip);
986         next if $skip;
987
988         # One line may contain multiple commands (";"). Treat each one as
989         # single line. parse_line() is slow, only use it when necessary.
990         my @line = (index($line, ';') == -1)
991                  ? ($line)
992                  : map {
993                        # Ensure newline at the line end - necessary for
994                        # correct parsing later.
995                        $_ =~ s/\s+$//;
996                        $_ .= "\n";
997                    } Text::ParseWords::parse_line(';', 1, $line);
998         foreach my $line (@line) {
999             if ($continuation) {
1000                 $continuation = 0;
1001
1002                 # Join lines, but leave the "\" in place so it's clear where
1003                 # the original line break was.
1004                 chomp $complete_line;
1005                 $complete_line .= ' ' . $line;
1006             }
1007             # Line continuation, line ends with "\".
1008             if ($line =~ /\\$/) {
1009                 $continuation = 1;
1010                 # Start line continuation.
1011                 if (not defined $complete_line) {
1012                     $complete_line = $line;
1013                 }
1014                 next;
1015             }
1016
1017             # Use the complete line if a line continuation occurred.
1018             if (defined $complete_line) {
1019                 $line = $complete_line;
1020                 $complete_line = undef;
1021             }
1022
1023             # Ignore lines with no compiler commands.
1024             next if not $non_verbose
1025                     and not $line =~ /$cc_regex_normal/o;
1026             # Ignore lines with no filenames with extensions. May miss some
1027             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1028             # a problem as the log will most likely contain other non-verbose
1029             # commands which are detected.
1030             next if not $non_verbose
1031                     and not $line =~ /$file_extension_regex/o;
1032
1033             # Ignore false positives.
1034             #
1035             # `./configure` output.
1036             next if not $non_verbose
1037                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1038             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1039                                 [Cc]ompiler[\s.]*:?\s+
1040                                 /x;
1041             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1042                                 \s*=\s*$cc_regex_full
1043                                 # optional compiler options, don't allow
1044                                 # "everything" here to prevent false negatives
1045                                 \s*(?:\s-\S+)*\s*$}xo;
1046             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1047             # line (or similar for other architectures) which gets recognized
1048             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1049             # C++ files. No hardening flags are relevant during this step,
1050             # thus ignore `moc-qt*` lines. The resulting files will be
1051             # compiled in a separate step (and therefore checked).
1052             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1053                                \s.+\s
1054                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1055                                \s}x;
1056             # Ignore false positives when the line contains only CC=gcc but no
1057             # other gcc command.
1058             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1059                 my $before = $1;
1060                 my $after  = $2;
1061                 next if     not $before =~ /$cc_regex_normal/o
1062                         and not $after  =~ /$cc_regex_normal/o;
1063             }
1064             # Ignore false positives caused by gcc -v. It outputs a line
1065             # looking like a normal compiler line but which is sometimes
1066             # missing hardening flags, although the normal compiler line
1067             # contains them.
1068             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1069                                    [0-9.]+/cc1(?:plus)?}xo;
1070             # Ignore false positive with `rm` which may remove files which
1071             # look like a compiler executable thus causing the line to be
1072             # treated as a normal compiler line.
1073             next if $line =~ m{^\s*rm\s+};
1074             next if $line =~ m{^\s*dwz\s+};
1075             # Some build systems emit "gcc > file".
1076             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1077             # Hex output may contain "cc".
1078             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1079             # Meson build output
1080             next if $line =~ /^C\+\+ linker for the host machine: /;
1081             # Embedded `gcc -print-*` commands
1082             next if $line =~ /`$cc_regex_normal\s*[^`]*-print-\S+`/;
1083
1084             # Check if additional hardening options were used. Used to ensure
1085             # they are used for the complete build.
1086             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1087                                                          @def_ldflags_pie);
1088             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1089
1090             push @input, $line;
1091             push @input_nonverbose, $non_verbose;
1092             push @input_number, $number if $option_line_numbers;
1093         }
1094     }
1095
1096     close $fh or die $!;
1097
1098     # Ignore arch if requested.
1099     if (scalar @option_ignore_arch > 0 and $arch) {
1100         foreach my $ignore (@option_ignore_arch) {
1101             if ($arch eq $ignore) {
1102                 print "ignoring architecture '$arch'\n";
1103                 next FILE;
1104             }
1105         }
1106     }
1107
1108     if (scalar @input == 0) {
1109         if (not $option_buildd) {
1110             print "No compiler commands!\n";
1111             $exit |= $exit_code{no_compiler_commands};
1112         } else {
1113             print "$buildd_tag{no_compiler_commands}||\n";
1114         }
1115         next FILE;
1116     }
1117
1118     if ($option_buildd) {
1119         $statistics{commands} += scalar @input;
1120     }
1121
1122     # Option or auto detected.
1123     if ($arch) {
1124         # The following was partially copied from dpkg-dev 1.20.5
1125         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1126         # copyright RaphaĆ«l Hertzog <hertzog@debian.org>, Guillem Jover
1127         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1128         # licensed under GPL version 2 or later. Keep it in sync.
1129
1130         require Dpkg::Arch;
1131         my ($os, $cpu);
1132         # Recent dpkg versions use a quadruplet for arch. Support both.
1133         eval {
1134             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1135         };
1136         if ($@) {
1137             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1138         }
1139
1140         my %builtin_pie_arch = map { $_ => 1 } qw(
1141             amd64
1142             arm64
1143             armel
1144             armhf
1145             hurd-i386
1146             i386
1147             kfreebsd-amd64
1148             kfreebsd-i386
1149             mips
1150             mipsel
1151             mips64el
1152             powerpc
1153             ppc64
1154             ppc64el
1155             riscv64
1156             s390x
1157             sparc
1158             sparc64
1159         );
1160
1161         # Disable unsupported hardening options.
1162         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1163                 or $cpu =~ /^(?:hppa|avr32)$/) {
1164             $harden_pie = 0;
1165         }
1166         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1167             $harden_stack = 0;
1168             $harden_stack_strong = 0;
1169         }
1170         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1171             $harden_relro   = 0;
1172             $harden_bindnow = 0;
1173         }
1174
1175         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1176             $harden_pie = 0;
1177         }
1178     }
1179
1180     # Default values.
1181     my @cflags   = @def_cflags;
1182     my @cxxflags = @def_cxxflags;
1183     my @cppflags = @def_cppflags;
1184     my @ldflags  = @def_ldflags;
1185     # Check the specified hardening options, same order as dpkg-buildflags.
1186     if ($harden_pie) {
1187         @cflags   = (@cflags,   @def_cflags_pie);
1188         @cxxflags = (@cxxflags, @def_cflags_pie);
1189         @ldflags  = (@ldflags,  @def_ldflags_pie);
1190     }
1191     if ($harden_stack_strong) {
1192         @cflags   = (@cflags,   @def_cflags_stack_strong);
1193         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1194     } elsif ($harden_stack) {
1195         @cflags   = (@cflags,   @def_cflags_stack);
1196         @cxxflags = (@cxxflags, @def_cflags_stack);
1197     }
1198     if ($harden_fortify) {
1199         @cflags   = (@cflags,   @def_cflags_fortify);
1200         @cxxflags = (@cxxflags, @def_cflags_fortify);
1201         @cppflags = (@cppflags, @def_cppflags_fortify);
1202     }
1203     if ($harden_format) {
1204         @cflags   = (@cflags,   @def_cflags_format);
1205         @cxxflags = (@cxxflags, @def_cflags_format);
1206     }
1207     if ($harden_relro) {
1208         @ldflags = (@ldflags, @def_ldflags_relro);
1209     }
1210     if ($harden_bindnow) {
1211         @ldflags = (@ldflags, @def_ldflags_bindnow);
1212     }
1213
1214     # Ada doesn't support format hardening flags, see #680117 for more
1215     # information. Same for fortran.
1216     my @cflags_backup;
1217     my @cflags_noformat = grep {
1218         my $ok = 1;
1219         foreach my $flag (@def_cflags_format) {
1220             $ok = 0 if $_ eq $flag;
1221         }
1222         $ok;
1223     } @cflags;
1224
1225     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1226     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1227     # as long as @def_cppflags_fortify contains only one variable.
1228     if (scalar @def_cppflags_fortify == 0) {
1229         $harden_fortify = 0;
1230     }
1231
1232     # Ignore flags for this arch if requested.
1233     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1234         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1235
1236         remove_flags(\@local_flag_refs,
1237                      \%flag_renames,
1238                      @{$option_ignore_arch_flag{$arch}});
1239     }
1240
1241     my @ignore_line = @option_ignore_line;
1242     # Ignore lines for this arch if requested.
1243     if ($arch and exists $option_ignore_arch_line{$arch}) {
1244         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1245     }
1246
1247 LINE:
1248     for (my $i = 0; $i < scalar @input; $i++) {
1249         my $line = $input[$i];
1250
1251         # Ignore line if requested.
1252         foreach my $ignore (@ignore_line) {
1253             next LINE if $line =~ /$ignore/;
1254         }
1255
1256         my $skip = 0;
1257         if ($input_nonverbose[$i]
1258                 and is_non_verbose_build($line, \$skip,
1259                                          \@input, $i, $parallel)) {
1260             if (not $option_buildd) {
1261                 error_non_verbose_build($line, $input_number[$i]);
1262                 $exit |= $exit_code{non_verbose_build};
1263             } else {
1264                 $statistics{commands_nonverbose}++;
1265             }
1266             next;
1267         }
1268         # Even if it's a verbose build, we might have to skip this line (see
1269         # is_non_verbose_build()).
1270         next if $skip;
1271
1272         my $orig_line = $line;
1273
1274         # Remove everything until and including the compiler command. Makes
1275         # checks easier and faster.
1276         $line =~ s/^.*?$cc_regex//o;
1277         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1278         # the brace and similar characters at the line end.
1279         $line =~ s/['")]+$//;
1280
1281         # Skip unnecessary tests when only preprocessing.
1282         my $flag_preprocess = 0;
1283
1284         my $dependency = 0;
1285         my $preprocess = 0;
1286         my $compile    = 0;
1287         my $link       = 0;
1288
1289         # Preprocess, compile, assemble.
1290         if ($line =~ /\s(-E|-S|-c)\b/) {
1291             $preprocess      = 1;
1292             $flag_preprocess = 1 if $1 eq '-E';
1293             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1294         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1295         # -MT -MQ) are always used with -M/-MM.
1296         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1297             $dependency = 1;
1298         # Otherwise assume we are linking.
1299         } else {
1300             $link = 1;
1301         }
1302
1303         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1304         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1305             $dependency      = 0;
1306             $flag_preprocess = 0;
1307         }
1308
1309         # Dependency generation for Makefiles, no preprocessing or other flags
1310         # needed.
1311         next if $dependency;
1312
1313         # Get all file extensions on this line.
1314         my @extensions = $line =~ /$file_extension_regex/go;
1315         # Ignore all unknown extensions to speedup the search below.
1316         @extensions = grep { exists $extension{$_} } @extensions;
1317
1318         # These file types don't require preprocessing.
1319         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1320             $preprocess = 0;
1321         }
1322         # These file types require preprocessing.
1323         if (extension_found(\%extensions_preprocess, @extensions)) {
1324             # Prevent false positives with "libtool: link: g++ -include test.h
1325             # .." compiler lines.
1326             if ($orig_line !~ /$libtool_link_regex/o) {
1327                 $preprocess = 1;
1328             }
1329         }
1330
1331         if (not $flag_preprocess) {
1332             # If there are source files then it's compiling/linking in one
1333             # step and we must check both. We only check for source files
1334             # here, because header files cause too many false positives.
1335             if (extension_found(\%extensions_compile_link, @extensions)) {
1336                 # Assembly files don't need CFLAGS.
1337                 if (not extension_found(\%extensions_compile, @extensions)
1338                         and extension_found(\%extensions_no_compile, @extensions)) {
1339                     $compile = 0;
1340                 # But the rest does.
1341                 } else {
1342                     $compile = 1;
1343                 }
1344             # No compilable extensions found, either linking or compiling
1345             # header flags.
1346             #
1347             # If there are also no object files we are just compiling headers
1348             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1349             # to our liberal checks for compiler lines, this also reduces the
1350             # number of false positives considerably.
1351             } elsif ($link
1352                     and not extension_found(\%extensions_object, @extensions)) {
1353                 $link = 0;
1354             }
1355         }
1356
1357         my $compile_cpp = 0;
1358         my $restore_cflags = 0;
1359         # Assume CXXFLAGS are required when a C++ file is specified in the
1360         # compiler line.
1361         if ($compile
1362                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1363             $compile     = 0;
1364             $compile_cpp = 1;
1365         # Ada needs special CFLAGS
1366         } elsif (extension_found(\%extensions_ada, @extensions)) {
1367             $restore_cflags = 1;
1368             $preprocess = 0; # Ada uses no CPPFLAGS
1369             @cflags_backup = @cflags;
1370             @cflags        = @cflags_noformat;
1371         # Same for fortran
1372         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1373             $restore_cflags = 1;
1374             @cflags_backup = @cflags;
1375             @cflags        = @cflags_noformat;
1376         }
1377
1378         if ($option_buildd) {
1379             $statistics{preprocess}++  if $preprocess;
1380             $statistics{compile}++     if $compile;
1381             $statistics{compile_cpp}++ if $compile_cpp;
1382             $statistics{link}++        if $link;
1383         }
1384
1385         # Check if there are flags indicating a debug build. If that's true,
1386         # skip the check for -O2. This prevents fortification, but that's fine
1387         # for a debug build.
1388         if (any_flags_used($line, @def_cflags_debug)) {
1389             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1390             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1391         }
1392
1393         # Check hardening flags.
1394         my @missing;
1395         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1396                     or (($harden_stack or $harden_stack_strong)
1397                         and cflags_stack_broken($line, \@missing,
1398                                                 $harden_stack_strong)))
1399                 # Libraries linked with -fPIC don't have to (and can't) be
1400                 # linked with -fPIE as well. It's no error if only PIE flags
1401                 # are missing.
1402                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1403                 # Assume dpkg-buildflags returns the correct flags.
1404                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1405             if (not $option_buildd) {
1406                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1407                             $input[$i], $input_number[$i]);
1408                 $exit |= $exit_code{flags_missing};
1409             } else {
1410                 $statistics{compile_missing}++;
1411             }
1412         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1413                 # Libraries linked with -fPIC don't have to (and can't) be
1414                 # linked with -fPIE as well. It's no error if only PIE flags
1415                 # are missing.
1416                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1417                 # Assume dpkg-buildflags returns the correct flags.
1418                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1419             if (not $option_buildd) {
1420                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1421                             $input[$i], $input_number[$i]);
1422                 $exit |= $exit_code{flags_missing};
1423             } else {
1424                 $statistics{compile_cpp_missing}++;
1425             }
1426         }
1427         if ($preprocess
1428                 and (not all_flags_used($line, \@missing, @cppflags)
1429                     # The fortify flag might be overwritten, detect that.
1430                      or ($harden_fortify
1431                          and cppflags_fortify_broken($line, \@missing)))
1432                 # Assume dpkg-buildflags returns the correct flags.
1433                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1434             if (not $option_buildd) {
1435                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1436                             $input[$i], $input_number[$i]);
1437                 $exit |= $exit_code{flags_missing};
1438             } else {
1439                 $statistics{preprocess_missing}++;
1440             }
1441         }
1442         if ($link and not all_flags_used($line, \@missing, @ldflags)
1443                 # Same here, -fPIC conflicts with -fPIE.
1444                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1445                 # Assume dpkg-buildflags returns the correct flags.
1446                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1447             if (not $option_buildd) {
1448                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1449                             $input[$i], $input_number[$i]);
1450                 $exit |= $exit_code{flags_missing};
1451             } else {
1452                 $statistics{link_missing}++;
1453             }
1454         }
1455
1456         # Restore normal CFLAGS.
1457         if ($restore_cflags) {
1458             @cflags = @cflags_backup;
1459         }
1460     }
1461 }
1462
1463 # Print statistics for buildd mode, only output in this mode.
1464 if ($option_buildd) {
1465     my @warning;
1466
1467     if ($statistics{preprocess_missing}) {
1468         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1469                                $statistics{preprocess_missing},
1470                                $statistics{preprocess};
1471     }
1472     if ($statistics{compile_missing}) {
1473         push @warning, sprintf 'CFLAGS %d (of %d)',
1474                                $statistics{compile_missing},
1475                                $statistics{compile};
1476     }
1477     if ($statistics{compile_cpp_missing}) {
1478         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1479                                $statistics{compile_cpp_missing},
1480                                $statistics{compile_cpp};
1481     }
1482     if ($statistics{link_missing}) {
1483         push @warning, sprintf 'LDFLAGS %d (of %d)',
1484                                $statistics{link_missing},
1485                                $statistics{link};
1486     }
1487     if (scalar @warning) {
1488         local $" = ', '; # array join string
1489         print "$buildd_tag{flags_missing}|@warning missing|\n";
1490     }
1491
1492     if ($statistics{commands_nonverbose}) {
1493         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1494                $statistics{commands_nonverbose},
1495                $statistics{commands},
1496     }
1497 }
1498
1499
1500 exit $exit;
1501
1502
1503 __END__
1504
1505 =head1 NAME
1506
1507 blhc - build log hardening check, checks build logs for missing hardening flags
1508
1509 =head1 SYNOPSIS
1510
1511 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1512
1513 =head1 DESCRIPTION
1514
1515 blhc is a small tool which checks build logs for missing hardening flags. It's
1516 licensed under the GPL 3 or later.
1517
1518 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1519 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1520 official buildd build logs)) to help maintainers detect missing hardening
1521 flags in their packages.
1522
1523 Only gcc is detected as compiler at the moment. If other compilers support
1524 hardening flags as well, please report them.
1525
1526 If there's no output, no flags are missing and the build log is fine.
1527
1528 See F<README> for details about performed checks, auto-detection and
1529 limitations.
1530
1531 =head1 FALSE POSITIVES
1532
1533 To suppress false positives you can embed the following string in the build
1534 log:
1535
1536     blhc: ignore-line-regexp: REGEXP
1537
1538 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1539 ignored.
1540
1541 Please use this feature sparingly so that missing flags are not overlooked. If
1542 you find false positives which affect more packages please report a bug.
1543
1544 To generate this string simply use echo in C<debian/rules>; make sure to use @
1545 to suppress the echo command itself as it could also trigger a false positive.
1546
1547 =head1 OPTIONS
1548
1549 =over 8
1550
1551 =item B<--all>
1552
1553 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1554 auto detected.
1555
1556 =item B<--arch> I<architecture>
1557
1558 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1559 disables hardening flags not available on this architecture. Is detected
1560 automatically if dpkg-buildpackage is used.
1561
1562 =item B<--bindnow>
1563
1564 Force check for all +bindnow hardening flags. By default it's auto detected.
1565
1566 =item B<--buildd>
1567
1568 Special mode for buildds when automatically parsing log files. The following
1569 changes are in effect:
1570
1571 =over 2
1572
1573 =item *
1574
1575 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1576 possible tags.
1577
1578 =item *
1579
1580 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1581 detected).
1582
1583 =item *
1584
1585 Don't require Term::ANSIColor.
1586
1587 =item *
1588
1589 Return exit code 0, unless there was a error (-I, -W messages don't count as
1590 error).
1591
1592 =back
1593
1594 =item B<--debian>
1595
1596 Apply Debian-specific settings. At the moment this only disables checking for
1597 PIE which is automatically applied by Debian's GCC and no longer requires a
1598 compiler command line argument.
1599
1600 =item B<--color>
1601
1602 Use colored (ANSI) output for warning messages.
1603
1604 =item B<--line-numbers>
1605
1606 Display line numbers.
1607
1608 =item B<--ignore-arch> I<arch>
1609
1610 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1611
1612 Used to prevent false positives. This option can be specified multiple times.
1613
1614 =item B<--ignore-arch-flag> I<arch>:I<flag>
1615
1616 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1617
1618 =item B<--ignore-arch-line> I<arch>:I<line>
1619
1620 Like B<--ignore-line>, but only ignore line on I<arch>.
1621
1622 =item B<--ignore-flag> I<flag>
1623
1624 Don't print an error when the specific flag is missing in a compiler line.
1625 I<flag> is a string.
1626
1627 Used to prevent false positives. This option can be specified multiple times.
1628
1629 =item B<--ignore-line> I<regex>
1630
1631 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1632 at the beginning and end of the line to prevent false negatives.
1633
1634 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1635 warnings (which have line continuation resolved).
1636
1637 Used to prevent false positives. This option can be specified multiple times.
1638
1639 =item B<--pie>
1640
1641 Force check for all +pie hardening flags. By default it's auto detected.
1642
1643 =item B<-h -? --help>
1644
1645 Print available options.
1646
1647 =item B<--version>
1648
1649 Print version number and license.
1650
1651 =back
1652
1653 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1654 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1655 all other commands as well.
1656
1657 =head1 EXAMPLES
1658
1659 Normal usage, parse a single log file.
1660
1661     blhc path/to/log/file
1662
1663 If there's no output, no flags are missing and the build log is fine.
1664
1665 Parse multiple log files. The exit code is ORed over all files.
1666
1667     blhc path/to/directory/with/log/files/*
1668
1669 Don't treat missing C<-g> as error:
1670
1671     blhc --ignore-flag -g path/to/log/file
1672
1673 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1674
1675     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1676
1677 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1678 false positive.
1679
1680     blhc --ignore-line '\./script gcc file' path/to/log/file
1681
1682 Ignore lines matching C<./script gcc file> somewhere in the line.
1683
1684     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1685
1686 Use blhc with pbuilder.
1687
1688     pbuilder path/to/package.dsc | tee path/log/file
1689     blhc path/to/file || echo flags missing
1690
1691 Assume this build log was created on a Debian system and thus don't warn about
1692 missing PIE flags if the current architecture injects them automatically (this
1693 is enabled in buildd mode per default). C<--arch> is necessary if the build
1694 log contains no architecture information as written by dpkg-buildpackage.
1695
1696     blhc --debian --all --arch=amd64 path/to/log/file
1697
1698 =head1 BUILDD TAGS
1699
1700 The following tags are used in I<--buildd> mode. In braces the additional data
1701 which is displayed.
1702
1703 =over 2
1704
1705 =item B<I-hardening-wrapper-used>
1706
1707 The package uses hardening-wrapper which intercepts calls to gcc and adds
1708 hardening flags. The build log doesn't contain any hardening flags and thus
1709 can't be checked by blhc.
1710
1711 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1712
1713 Build log contains lines which hide the real compiler flags. For example:
1714
1715     CC test-a.c
1716     CC test-b.c
1717     CC test-c.c
1718     LD test
1719
1720 Most of the time either C<export V=1> or C<export verbose=1> in
1721 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1722 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1723 patched to remove the C<@>s hiding the real compiler commands.
1724
1725 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1726
1727 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1728
1729 =item B<I-invalid-cmake-used> (version)
1730
1731 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1732 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1733 patch was rejected by upstream and later reverted in Debian. Thus those two
1734 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1735 handle them (for example by passing them to CFLAGS). To prevent false
1736 negatives just blacklist those two versions.
1737
1738 =item B<I-no-compiler-commands>
1739
1740 No compiler commands were detected. Either the log contains none or they were
1741 not correctly detected by blhc (please report the bug in this case).
1742
1743 =back
1744
1745 =head1 EXIT STATUS
1746
1747 The exit status is a "bit mask", each listed status is ORed when the error
1748 condition occurs to get the result.
1749
1750 =over 4
1751
1752 =item B<0>
1753
1754 Success.
1755
1756 =item B<1>
1757
1758 No compiler commands were found.
1759
1760 =item B<2>
1761
1762 Invalid arguments/options given to blhc.
1763
1764 =item B<4>
1765
1766 Non verbose build.
1767
1768 =item B<8>
1769
1770 Missing hardening flags.
1771
1772 =item B<16>
1773
1774 Hardening wrapper detected, no tests performed.
1775
1776 =item B<32>
1777
1778 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1779 TAGS"> for a detailed explanation.
1780
1781 =back
1782
1783 =head1 AUTHOR
1784
1785 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1786
1787 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1788 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1789
1790 =head1 LICENSE AND COPYRIGHT
1791
1792 Copyright (C) 2012-2020 by Simon Ruderich
1793
1794 This program is free software: you can redistribute it and/or modify
1795 it under the terms of the GNU General Public License as published by
1796 the Free Software Foundation, either version 3 of the License, or
1797 (at your option) any later version.
1798
1799 This program is distributed in the hope that it will be useful,
1800 but WITHOUT ANY WARRANTY; without even the implied warranty of
1801 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1802 GNU General Public License for more details.
1803
1804 You should have received a copy of the GNU General Public License
1805 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1806
1807 =head1 SEE ALSO
1808
1809 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1810
1811 =cut