bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2023  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.13';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool["']?\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=[23]', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-D_FORTIFY_SOURCE=[23]'       => '-D_FORTIFY_SOURCE=2',
 303     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 304     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 305 );
 306
 307 my %exit_code = (
 308     no_compiler_commands => 1 << 0,
 309     # used by POD::Usage => 1 << 1,
 310     non_verbose_build    => 1 << 2,
 311     flags_missing        => 1 << 3,
 312     hardening_wrapper    => 1 << 4,
 313     invalid_cmake        => 1 << 5,
 314 );
 315
 316 my %buildd_tag = (
 317     no_compiler_commands => 'I-no-compiler-commands',
 318     non_verbose_build    => 'W-compiler-flags-hidden',
 319     flags_missing        => 'W-dpkg-buildflags-missing',
 320     hardening_wrapper    => 'I-hardening-wrapper-used',
 321     invalid_cmake        => 'I-invalid-cmake-used',
 322 );
 323
 324 # Statistics of missing flags and non-verbose build commands. Used for
 325 # $option_buildd.
 326 my %statistics = (
 327     preprocess          => 0,
 328     preprocess_missing  => 0,
 329     compile             => 0,
 330     compile_missing     => 0,
 331     compile_cpp         => 0,
 332     compile_cpp_missing => 0,
 333     link                => 0,
 334     link_missing        => 0,
 335     commands            => 0,
 336     commands_nonverbose => 0,
 337 );
 338
 339 # Use colored (ANSI) output?
 340 my $option_color;
 341
 342
 343 # FUNCTIONS
 344
 345 sub split_line {
 346     my ($line) = @_;
 347
 348     my @work = ($line);
 349     foreach my $delim (';', '&&', '||') {
 350         my @x;
 351         foreach (@work) {
 352             push @x, Text::ParseWords::parse_line(qr/\Q$delim\E/, 1, $_);
 353         }
 354         @work = @x;
 355     }
 356
 357     return map {
 358         # Ensure newline at the line end - necessary for
 359         # correct parsing later.
 360         $_ =~ s/\s+$//;
 361         $_ .= "\n";
 362     } @work;
 363 }
 364
 365 sub error_flags {
 366     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 367
 368     # Get string value of qr//-escaped regexps and if requested rename them.
 369     my @missing_flags = map {
 370             $flag_renames_ref->{$_}
 371         } @{$missing_flags_ref};
 372
 373     my $flags = join ' ', @missing_flags;
 374     printf '%d:', $number if defined $number;
 375     printf '%s (%s)%s %s',
 376            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 377            $line;
 378
 379     return;
 380 }
 381 sub error_non_verbose_build {
 382     my ($line, $number) = @_;
 383
 384     printf '%d:', $number if defined $number;
 385     printf '%s%s %s',
 386            error_color('NONVERBOSE BUILD', 'red'),
 387            error_color(':', 'yellow'),
 388            $line;
 389
 390     return;
 391 }
 392 sub error_invalid_cmake {
 393     my ($version) = @_;
 394
 395     printf "%s%s %s\n",
 396             error_color('INVALID CMAKE', 'red'),
 397             error_color(':', 'yellow'),
 398             $version;
 399
 400     return;
 401 }
 402 sub error_hardening_wrapper {
 403     printf "%s%s %s\n",
 404             error_color('HARDENING WRAPPER', 'red'),
 405             error_color(':', 'yellow'),
 406             'no checks possible, aborting';
 407
 408     return;
 409 }
 410 sub error_color {
 411     my ($message, $color) = @_;
 412
 413     if ($option_color) {
 414         return Term::ANSIColor::colored($message, $color);
 415     } else {
 416         return $message;
 417     }
 418 }
 419
 420 sub any_flags_used {
 421     my ($line, @flags) = @_;
 422
 423     foreach my $flag (@flags) {
 424         return 1 if $line =~ /$flag/;
 425     }
 426
 427     return 0;
 428 }
 429 sub all_flags_used {
 430     my ($line, $missing_flags_ref, @flags) = @_;
 431
 432     my @missing_flags = ();
 433     foreach my $flag (@flags) {
 434         if (not $line =~ /$flag/) {
 435             push @missing_flags, $flag;
 436         }
 437     }
 438
 439     return 1 if scalar @missing_flags == 0;
 440
 441     @{$missing_flags_ref} = @missing_flags;
 442     return 0;
 443 }
 444 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 445 # $good_flag is present.
 446 sub flag_overwritten {
 447     my ($line, $good_flag, $bad_flags) = @_;
 448
 449     if (not any_flags_used($line, @{$bad_flags})) {
 450         return 0;
 451     }
 452
 453     my $bad_pos = 0;
 454     foreach my $flag (@{$bad_flags}) {
 455         while ($line =~ /$flag/g) {
 456             if ($bad_pos < $+[0]) {
 457                 $bad_pos = $+[0];
 458             }
 459         }
 460     }
 461     my $good_pos = 0;
 462     while ($line =~ /$good_flag/g) {
 463         $good_pos = $+[0];
 464     }
 465     if ($good_pos > $bad_pos) {
 466         return 0;
 467     }
 468     return 1;
 469 }
 470
 471 sub cppflags_fortify_broken {
 472     my ($line, $missing_flags) = @_;
 473
 474     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 475     my $fortify_source = $def_cppflags_fortify[0];
 476
 477     # Some build systems enable/disable fortify source multiple times, check
 478     # the final result.
 479     if (not flag_overwritten($line,
 480                              $fortify_source,
 481                              \@def_cppflags_fortify_bad)) {
 482         return 0;
 483     }
 484     push @{$missing_flags}, $fortify_source;
 485     return 1;
 486 }
 487
 488 sub cflags_stack_broken {
 489     my ($line, $missing_flags, $strong) = @_;
 490
 491     my $flag = $strong ? $def_cflags_stack_strong[0]
 492                        : $def_cflags_stack[0];
 493
 494     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 495         return 0;
 496     }
 497     push @{$missing_flags}, $flag;
 498     return 1;
 499 }
 500
 501 # Modifies $missing_flags_ref array.
 502 sub pic_pie_conflict {
 503     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 504
 505     return 0 if not $pie;
 506     return 0 if not any_flags_used($line, @def_ldflags_pic);
 507
 508     my %flags = map { $_ => 1 } @flags_pie;
 509
 510     # Remove all PIE flags from @missing_flags as they are not required with
 511     # -fPIC.
 512     my @result = grep {
 513         not exists $flags{$_}
 514     } @{$missing_flags_ref};
 515     @{$missing_flags_ref} = @result;
 516
 517     # We got a conflict when no flags are left, thus only PIE flags were
 518     # missing. If other flags were missing abort because the conflict is not
 519     # the problem.
 520     return scalar @result == 0;
 521 }
 522
 523 sub is_non_verbose_build {
 524     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 525
 526     if ($line =~ /$libtool_regex/o) {
 527         # libtool's --silent hides the real compiler flags.
 528         if ($line =~ /\s--silent/) {
 529             return 1;
 530         # If --silent is not present, skip this line as some compiler flags
 531         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 532         # internally. libtool displays the real compiler command on the next
 533         # line, so the flags are checked as usual.
 534         } else {
 535             ${$skip_ref} = 1;
 536             return 0;
 537         }
 538     }
 539
 540     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 541                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 542                 or $line =~ /^\s*[][\/0-9 ]*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 543                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 544                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 545         return 0;
 546     }
 547
 548     # False positives.
 549     #
 550     # C++ compiler setting.
 551     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 552     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 553     # "Compiling" non binary files.
 554     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|pyx|el)['"]?\s*(?:\.\.\.|because it changed\.)?$/;
 555     return 0 if $line =~ /^\s*[Cc]ompiling catalog \S+\.po\b/;
 556     # "Compiling" with no file name.
 557     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 558         # $file_extension_regex may need spaces around the filename.
 559         return 0 if not " $1 " =~ /$file_extension_regex/o;
 560     }
 561
 562     my $file = $1;
 563
 564     # On the first pass we only check if this line is verbose or not.
 565     return 1 if not defined $input_ref;
 566
 567     # Second pass, we have access to the next lines.
 568     ${$skip_ref} = 0;
 569
 570     # CMake and other build systems print the non-verbose messages also when
 571     # building verbose. If a compiler and the file name occurs in the next
 572     # lines, treat it as verbose build.
 573     if (defined $file) {
 574         # Get filename, we can't use the complete path as only parts of it are
 575         # used in the real compiler command.
 576         $file =~ m{/([^/\s]+)$};
 577         $file = $1;
 578
 579         for (my $i = 1; $i <= $line_count; $i++) {
 580             my $next_line = $input_ref->[$line_offset + $i];
 581             last unless defined $next_line;
 582
 583             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 584                 # Not a non-verbose line, but we still have to skip the
 585                 # current line as it doesn't contain any compiler commands.
 586                 ${$skip_ref} = 1;
 587                 return 0;
 588             }
 589         }
 590     }
 591
 592     return 1;
 593 }
 594
 595 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 596 sub remove_flags {
 597     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 598
 599     my %removes = map { $_ => 1 } @flags;
 600     foreach my $flags (@{$flag_refs_ref}) {
 601         @{$flags} = grep {
 602             # Flag found as string.
 603             not exists $removes{$_}
 604             # Flag found as string representation of regexp.
 605                 and (not defined $flag_renames_ref->{$_}
 606                         or not exists $removes{$flag_renames_ref->{$_}})
 607         } @{$flags};
 608     }
 609
 610     return;
 611 }
 612
 613 # Modifies $flag_renames_ref hash.
 614 sub compile_flag_regexp {
 615     my ($flag_renames_ref, @flags) = @_;
 616
 617     my @result = ();
 618     foreach my $flag (@flags) {
 619         # Compile flag regexp for faster execution.
 620         my $regex = qr/\s(['"]?)$flag\1(?:\s|\\)/;
 621
 622         # Store flag name in replacement string for correct flags in messages
 623         # with qr//ed flag regexps.
 624         $flag_renames_ref->{$regex}
 625             = (exists $flag_renames_ref->{$flag})
 626                 ? $flag_renames_ref->{$flag}
 627                 : $flag;
 628
 629         push @result, $regex;
 630     }
 631     return @result;
 632 }
 633
 634 # Does any extension in @extensions exist in %{$extensions_ref}?
 635 sub extension_found {
 636     my ($extensions_ref, @extensions) = @_;
 637
 638     foreach my $extension (@extensions) {
 639         if (exists $extensions_ref->{$extension}) {
 640             return 1;
 641         }
 642     }
 643     return 0;
 644 }
 645
 646
 647 # MAIN
 648
 649 # Parse command line arguments.
 650 my $option_help             = 0;
 651 my $option_version          = 0;
 652 my $option_pie              = 0;
 653 my $option_bindnow          = 0;
 654 my @option_ignore_arch      = ();
 655 my @option_ignore_flag      = ();
 656 my @option_ignore_arch_flag = ();
 657 my @option_ignore_line      = ();
 658 my @option_ignore_arch_line = ();
 659 my $option_all              = 0;
 660 my $option_arch             = undef;
 661 my $option_buildd           = 0;
 662 my $option_debian           = 0;
 663    $option_color            = 0;
 664 my $option_line_numbers     = 0;
 665 if (not Getopt::Long::GetOptions(
 666             'help|h|?'           => \$option_help,
 667             'version'            => \$option_version,
 668             # Hardening options.
 669             'pie'                => \$option_pie,
 670             'bindnow'            => \$option_bindnow,
 671             'all'                => \$option_all,
 672             # Ignore.
 673             'ignore-arch=s'      => \@option_ignore_arch,
 674             'ignore-flag=s'      => \@option_ignore_flag,
 675             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 676             'ignore-line=s'      => \@option_ignore_line,
 677             'ignore-arch-line=s' => \@option_ignore_arch_line,
 678             # Misc.
 679             'color'              => \$option_color,
 680             'arch=s'             => \$option_arch,
 681             'buildd'             => \$option_buildd,
 682             'debian'             => \$option_debian,
 683             'line-numbers'       => \$option_line_numbers,
 684         )) {
 685     require Pod::Usage;
 686     Pod::Usage::pod2usage(2);
 687 }
 688 if ($option_help) {
 689     require Pod::Usage;
 690     Pod::Usage::pod2usage(1);
 691 }
 692 if ($option_version) {
 693     print <<"EOF";
 694 blhc $VERSION  Copyright (C) 2012-2023  Simon Ruderich
 695
 696 This program is free software: you can redistribute it and/or modify
 697 it under the terms of the GNU General Public License as published by
 698 the Free Software Foundation, either version 3 of the License, or
 699 (at your option) any later version.
 700
 701 This program is distributed in the hope that it will be useful,
 702 but WITHOUT ANY WARRANTY; without even the implied warranty of
 703 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 704 GNU General Public License for more details.
 705
 706 You should have received a copy of the GNU General Public License
 707 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 708 EOF
 709     exit 0;
 710 }
 711
 712 # Arguments missing.
 713 if (scalar @ARGV == 0) {
 714     require Pod::Usage;
 715     Pod::Usage::pod2usage(2);
 716 }
 717
 718 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 719 # installed on Debian's buildds.
 720 if (not $option_buildd) {
 721     require Term::ANSIColor;
 722 }
 723
 724 if ($option_all) {
 725     $option_pie     = 1;
 726     $option_bindnow = 1;
 727 }
 728
 729 # Precompiled ignores for faster lookup.
 730 my %option_ignore_arch_flag = ();
 731 my %option_ignore_arch_line = ();
 732
 733 # Strip flags which should be ignored.
 734 if (scalar @option_ignore_flag > 0) {
 735     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 736 }
 737 # Same for arch specific ignore flags, but only prepare here.
 738 if (scalar @option_ignore_arch_flag > 0) {
 739     foreach my $ignore (@option_ignore_arch_flag) {
 740         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 741
 742         if (not $ignore_arch or not $ignore_flag) {
 743             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 744                         . '("arch:flag" expected)' . "\n", $ignore;
 745             require Pod::Usage;
 746             Pod::Usage::pod2usage(2);
 747         }
 748
 749         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 750     }
 751 }
 752
 753 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 754 # faster with this.
 755 foreach my $flags (@flag_refs_all) {
 756     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 757 }
 758
 759 # Precompile ignore line regexps, also anchor at beginning and end of line.
 760 # Additional entries are also extracted from the build log, see below.
 761 foreach my $ignore (@option_ignore_line) {
 762     $ignore = qr/^$ignore$/;
 763 }
 764 # Same for arch specific ignore lines.
 765 if (scalar @option_ignore_arch_line > 0) {
 766     foreach my $ignore (@option_ignore_arch_line) {
 767         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 768
 769         if (not $ignore_arch or not $ignore_line) {
 770             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 771                         . '("arch:line" expected)' . "\n", $ignore;
 772             require Pod::Usage;
 773             Pod::Usage::pod2usage(2);
 774         }
 775
 776         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 777     }
 778 }
 779
 780 # Final exit code.
 781 my $exit = 0;
 782
 783 FILE:
 784 foreach my $file (@ARGV) {
 785     print "checking '$file'...\n" if scalar @ARGV > 1;
 786
 787     -f $file or die "No such file: $file";
 788
 789     open my $fh, '<', $file or die $!;
 790
 791     # Architecture of this file.
 792     my $arch = $option_arch;
 793
 794     # Hardening options. Not all architectures support all hardening options.
 795     my $harden_format  = 1;
 796     my $harden_fortify = 1;
 797     my $harden_stack   = 1;
 798     my $harden_stack_strong = 1;
 799     my $harden_relro   = 1;
 800     my $harden_bindnow = $option_bindnow; # defaults to 0
 801     my $harden_pie     = $option_pie;     # defaults to 0
 802
 803     # Number of parallel jobs to prevent false positives when detecting
 804     # non-verbose builds. As not all jobs declare the number of parallel jobs
 805     # use a large enough default.
 806     my $parallel = 10;
 807
 808     # Don't check for PIE flags if automatically applied by the compiler. Only
 809     # used in buildd and Debian mode.
 810     my $disable_harden_pie = 0;
 811     if ($option_debian) {
 812         $disable_harden_pie = 1;
 813     }
 814
 815     my $number = 0;
 816     while (my $line = <$fh>) {
 817         $number++;
 818
 819         # Detect architecture automatically unless overridden. For buildd logs
 820         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 821         # build logs which aren't built (wrong architecture, build error,
 822         # etc.).
 823         if (not $arch) {
 824             if (index($line, 'Build Architecture: ') == 0) {
 825                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 826             # For old logs (sbuild << 0.63.0-1).
 827             } elsif (index($line, 'Architecture: ') == 0) {
 828                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 829             }
 830         }
 831
 832         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 833         # check for hardening flags in buildd mode if an older dpkg-dev is
 834         # used. Default flags (-g -O2) are still checked.
 835         #
 836         # Packages which were built before 1.16.1 but used their own hardening
 837         # flags are not checked.
 838         #
 839         # Strong stack protector is used since dpkg 1.17.11.
 840         #
 841         # Recent GCC versions automatically use PIE (only on supported
 842         # architectures) and dpkg respects this properly since 1.18.15 and
 843         # doesn't pass PIE flags manually.
 844         if ($option_buildd
 845                 and index($line, 'Toolchain package versions: ') == 0) {
 846             require Dpkg::Version;
 847
 848             my $disable = 1;
 849             my $disable_strong = 1;
 850
 851             if ($line =~ /\bdpkg-dev_(\S+)/) {
 852                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 853                     $disable = 0;
 854                 }
 855                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 856                     $disable_strong = 0;
 857                 }
 858                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 859                     $disable_harden_pie = 1;
 860                 }
 861             }
 862
 863             if ($disable) {
 864                 $harden_format  = 0;
 865                 $harden_fortify = 0;
 866                 $harden_stack   = 0;
 867                 $harden_relro   = 0;
 868                 $harden_bindnow = 0;
 869                 $harden_pie     = 0;
 870             }
 871             if ($disable_strong) {
 872                 $harden_stack_strong = 0;
 873             }
 874         }
 875
 876         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 877         # this was later dropped because upstream rejected the patch. Thus
 878         # build logs with these versions will have fortify hardening flags
 879         # enabled, even though they may be not correctly set and are missing
 880         # when build with later CMake versions. Thanks to Aron Xu for letting
 881         # me know.
 882         if (index($line, 'Package versions: ') == 0
 883                 and $line =~ /\bcmake_(\S+)/
 884                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 885             if (not $option_buildd) {
 886                 error_invalid_cmake($1);
 887                 $exit |= $exit_code{invalid_cmake};
 888             } else {
 889                 print "$buildd_tag{invalid_cmake}|$1|\n";
 890             }
 891         }
 892
 893         # Debian's build daemons use "Filtered Build-Depends:" (or just
 894         # "Build-Depends:" in older versions) for the build dependencies, but
 895         # pbuilder uses "Depends:"; support both.
 896         if (index($line, 'Filtered Build-Depends: ') == 0
 897                 or index($line, 'Build-Depends: ') == 0
 898                 or index($line, 'Depends: ') == 0) {
 899             # If hardening wrapper is used (wraps calls to gcc and adds
 900             # hardening flags automatically) we can't perform any checks,
 901             # abort.
 902             if ($line =~ /\bhardening-wrapper\b/) {
 903                 if (not $option_buildd) {
 904                     error_hardening_wrapper();
 905                     $exit |= $exit_code{hardening_wrapper};
 906                 } else {
 907                     print "$buildd_tag{hardening_wrapper}||\n";
 908                 }
 909                 next FILE;
 910             }
 911         }
 912
 913         # This flags is not always available, but if it is use it.
 914         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 915             $parallel = $1 * 2;
 916         }
 917
 918         # We skip over unimportant lines at the beginning of the log to
 919         # prevent false positives.
 920         last if index($line, 'dpkg-buildpackage: ') == 0;
 921     }
 922
 923     # Input lines, contain only the lines with compiler commands.
 924     my @input = ();
 925     # Non-verbose lines in the input. Used to reduce calls to
 926     # is_non_verbose_build() (which is quite slow) in the second loop when
 927     # it's already clear if a line is non-verbose or not.
 928     my @input_nonverbose = ();
 929     # Input line number.
 930     my @input_number = ();
 931
 932     my $continuation = 0;
 933     my $complete_line = undef;
 934     my $non_verbose;
 935     while (my $line = <$fh>) {
 936         $number++;
 937
 938         # And stop at the end of the build log. Package details (reported by
 939         # the buildd logs) are not important for us. This also prevents false
 940         # positives.
 941         last if index($line, 'Build finished at ') == 0
 942                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 943
 944         if (not $continuation) {
 945             $non_verbose = 0;
 946         }
 947
 948         # Detect architecture automatically unless overridden.
 949         if (not $arch
 950                 and index($line, 'dpkg-buildpackage: info: host architecture ') == 0) {
 951             $arch = substr $line, 43, -1; # -1 to ignore '\n' at the end
 952         # Older versions of dpkg-buildpackage
 953         } elsif (not $arch
 954                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 955             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 956
 957             # Old buildd logs use e.g. "host architecture is alpha", remove
 958             # the "is", otherwise debarch_to_debtriplet() will not detect the
 959             # architecture.
 960             if (index($arch, 'is ') == 0) {
 961                 $arch = substr $arch, 3;
 962             }
 963         }
 964
 965         # Permit dynamic excludes from within the build log to ignore false
 966         # positives. Cannot use a separate config file as we often only have
 967         # the build log itself.
 968         if (index($line, 'blhc: ignore-line-regexp: ') == 0) {
 969             my $ignore = substr $line, 26, -1; # -1 to ignore '\n' at the end
 970             push @option_ignore_line, qr/^$ignore$/;
 971             next;
 972         }
 973
 974         next if $line =~ /^\s*#/;
 975         # Ignore compiler warnings for now.
 976         next if $line =~ /$warning_regex/o;
 977
 978         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 979             # Remove all ANSI color sequences which are sometimes used in
 980             # non-verbose builds.
 981             $line = Term::ANSIColor::colorstrip($line);
 982             # Also strip '\0xf' (delete previous character), used by Elinks'
 983             # build system.
 984             $line =~ s/\x0f//g;
 985             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 986             # what it does).
 987             $line =~ s/\033\(B//g;
 988         }
 989
 990         # Check if this line indicates a non verbose build.
 991         my $skip = 0;
 992         $non_verbose |= is_non_verbose_build($line, \$skip);
 993         next if $skip;
 994
 995         # Treat each command as a single line so we don't ignore valid
 996         # commands when handling false positives. split_line() is slow, only
 997         # use it when necessary.
 998         my @line = ($line !~ /(?:;|&&|\|\|)/)
 999                  ? ($line)
1000                  : split_line($line);
1001         foreach my $line (@line) {
1002             if ($continuation) {
1003                 $continuation = 0;
1004
1005                 # Join lines, but leave the "\" in place so it's clear where
1006                 # the original line break was.
1007                 chomp $complete_line;
1008                 $complete_line .= ' ' . $line;
1009             }
1010             # Line continuation, line ends with "\".
1011             if ($line =~ /\\$/) {
1012                 $continuation = 1;
1013                 # Start line continuation.
1014                 if (not defined $complete_line) {
1015                     $complete_line = $line;
1016                 }
1017                 next;
1018             }
1019
1020             # Use the complete line if a line continuation occurred.
1021             if (defined $complete_line) {
1022                 $line = $complete_line;
1023                 $complete_line = undef;
1024             }
1025
1026             my $noenv = $line;
1027             # Strip (basic) environment variables for compiler detection. This
1028             # prevents false positives when environment variables contain
1029             # compiler binaries. Nested quotes, command substitution, etc. is
1030             # not supported.
1031             $noenv =~ s/^
1032                 \s*
1033                 (?:
1034                     [a-zA-Z_]+          # environment variable name
1035                     =
1036                     (?:
1037                         [^\s"'\$`\\]+   # non-quoted string
1038                         |
1039                         '[^"'\$`\\]*'   # single-quoted string
1040                         |
1041                         "[^"'\$`\\]*"   # double-quoted string
1042                     )
1043                     \s+
1044                 )*
1045             //x;
1046             # Ignore lines with no compiler commands.
1047             next if not $non_verbose
1048                     and not $noenv =~ /$cc_regex_normal/o;
1049             # Ignore lines with no filenames with extensions. May miss some
1050             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1051             # a problem as the log will most likely contain other non-verbose
1052             # commands which are detected.
1053             next if not $non_verbose
1054                     and not $line =~ /$file_extension_regex/o;
1055
1056             # Ignore false positives.
1057             #
1058             # `./configure` output.
1059             next if not $non_verbose
1060                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1061             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1062                                 [Cc]ompiler[\s.]*:?\s+
1063                                 /x;
1064             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1065                                 \s*=\s*$cc_regex_full
1066                                 # optional compiler options, don't allow
1067                                 # "everything" here to prevent false negatives
1068                                 \s*(?:\s-\S+)*\s*$}xo;
1069             # `echo` is never a compiler command
1070             next if $line =~ /^\s*echo\s/;
1071             # Ignore calls to `make` because they can contain environment
1072             # variables which look like compiler commands, e.g. CC=).
1073             next if $line =~ /^\s*make\s/;
1074             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1075             # line (or similar for other architectures) which gets recognized
1076             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1077             # C++ files. No hardening flags are relevant during this step,
1078             # thus ignore `moc-qt*` lines. The resulting files will be
1079             # compiled in a separate step (and therefore checked).
1080             next if $line =~ m{^\S+(?:/bin/moc(?:-qt[45])?|/lib/qt6/libexec/moc)
1081                                \s.+\s
1082                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1083                                \s}x;
1084             # nvcc is not a regular C compiler
1085             next if $line =~ m{^\S+/bin/nvcc\s};
1086             # Ignore false positives when the line contains only CC=gcc but no
1087             # other gcc command.
1088             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1089                 my $before = $1;
1090                 my $after  = $2;
1091                 next if     not $before =~ /$cc_regex_normal/o
1092                         and not $after  =~ /$cc_regex_normal/o;
1093             }
1094             # Ignore false positives caused by gcc -v. It outputs a line
1095             # looking like a normal compiler line but which is sometimes
1096             # missing hardening flags, although the normal compiler line
1097             # contains them.
1098             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1099                                    [0-9.]+/cc1(?:plus)?}xo;
1100             # Ignore false positive with `rm` which may remove files which
1101             # look like a compiler executable thus causing the line to be
1102             # treated as a normal compiler line.
1103             next if $line =~ m{^\s*rm\s+};
1104             next if $line =~ m{^\s*dwz\s+};
1105             # Some build systems emit "gcc > file".
1106             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1107             # Hex output may contain "cc".
1108             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1109             # Meson build output
1110             next if $line =~ /^C\+\+ linker for the host machine: /;
1111             # Embedded `gcc -print-*` commands
1112             next if $line =~ /`$cc_regex_normal\s*[^`]*-print-\S+`/;
1113             # cmake checking for compiler flags without setting CPPFLAGS
1114             next if $line =~ m{^\s*/usr/(bin|lib)/(ccache/)?c\+\+ -dM -E -c /usr/share/cmake-\S+/Modules/CMakeCXXCompilerABI\.cpp};
1115
1116             # Check if additional hardening options were used. Used to ensure
1117             # they are used for the complete build.
1118             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1119                                                          @def_ldflags_pie);
1120             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1121
1122             push @input, $line;
1123             push @input_nonverbose, $non_verbose;
1124             push @input_number, $number if $option_line_numbers;
1125         }
1126     }
1127
1128     close $fh or die $!;
1129
1130     # Ignore arch if requested.
1131     if (scalar @option_ignore_arch > 0 and $arch) {
1132         foreach my $ignore (@option_ignore_arch) {
1133             if ($arch eq $ignore) {
1134                 print "ignoring architecture '$arch'\n";
1135                 next FILE;
1136             }
1137         }
1138     }
1139
1140     if (scalar @input == 0) {
1141         if (not $option_buildd) {
1142             print "No compiler commands!\n";
1143             $exit |= $exit_code{no_compiler_commands};
1144         } else {
1145             print "$buildd_tag{no_compiler_commands}||\n";
1146         }
1147         next FILE;
1148     }
1149
1150     if ($option_buildd) {
1151         $statistics{commands} += scalar @input;
1152     }
1153
1154     # Option or auto detected.
1155     if ($arch) {
1156         # The following was partially copied from dpkg-dev 1.22.0
1157         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, set_build_features and
1158         # _add_build_flags()), copyright Raphaël Hertzog <hertzog@debian.org>,
1159         # Guillem Jover <guillem@debian.org>, Kees Cook <kees@debian.org>,
1160         # Canonical, Ltd. licensed under GPL version 2 or later. Keep it in
1161         # sync.
1162
1163         require Dpkg::Arch;
1164         my ($os, $cpu);
1165         # Recent dpkg versions use a quadruplet for arch. Support both.
1166         eval {
1167             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1168         };
1169         if ($@) {
1170             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1171         }
1172
1173         my %builtin_pie_arch = map { $_ => 1 } qw(
1174             amd64
1175             arm64
1176             armel
1177             armhf
1178             hurd-amd64
1179             hurd-i386
1180             i386
1181             kfreebsd-amd64
1182             kfreebsd-i386
1183             mips
1184             mips64
1185             mips64el
1186             mips64r6
1187             mips64r6el
1188             mipsel
1189             mipsn32
1190             mipsn32el
1191             mipsn32r6
1192             mipsn32r6el
1193             mipsr6
1194             mipsr6el
1195             powerpc
1196             ppc64
1197             ppc64el
1198             riscv64
1199             s390x
1200             sparc
1201             sparc64
1202         );
1203
1204         # Disable unsupported hardening options.
1205         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/ or $cpu eq 'hppa') {
1206             $harden_pie = 0;
1207         }
1208         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1209             $harden_stack = 0;
1210             $harden_stack_strong = 0;
1211         }
1212         if ($cpu =~ /^(?:ia64|hppa)$/) {
1213             $harden_relro   = 0;
1214             $harden_bindnow = 0;
1215         }
1216
1217         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1218             $harden_pie = 0;
1219         }
1220     }
1221
1222     # Default values.
1223     my @cflags   = @def_cflags;
1224     my @cxxflags = @def_cxxflags;
1225     my @cppflags = @def_cppflags;
1226     my @ldflags  = @def_ldflags;
1227     # Check the specified hardening options, same order as dpkg-buildflags.
1228     if ($harden_pie) {
1229         @cflags   = (@cflags,   @def_cflags_pie);
1230         @cxxflags = (@cxxflags, @def_cflags_pie);
1231         @ldflags  = (@ldflags,  @def_ldflags_pie);
1232     }
1233     if ($harden_stack_strong) {
1234         @cflags   = (@cflags,   @def_cflags_stack_strong);
1235         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1236     } elsif ($harden_stack) {
1237         @cflags   = (@cflags,   @def_cflags_stack);
1238         @cxxflags = (@cxxflags, @def_cflags_stack);
1239     }
1240     if ($harden_fortify) {
1241         @cflags   = (@cflags,   @def_cflags_fortify);
1242         @cxxflags = (@cxxflags, @def_cflags_fortify);
1243         @cppflags = (@cppflags, @def_cppflags_fortify);
1244     }
1245     if ($harden_format) {
1246         @cflags   = (@cflags,   @def_cflags_format);
1247         @cxxflags = (@cxxflags, @def_cflags_format);
1248     }
1249     if ($harden_relro) {
1250         @ldflags = (@ldflags, @def_ldflags_relro);
1251     }
1252     if ($harden_bindnow) {
1253         @ldflags = (@ldflags, @def_ldflags_bindnow);
1254     }
1255
1256     # Ada doesn't support format hardening flags, see #680117 for more
1257     # information. Same for fortran.
1258     my @cflags_backup;
1259     my @cflags_noformat = grep {
1260         my $ok = 1;
1261         foreach my $flag (@def_cflags_format) {
1262             $ok = 0 if $_ eq $flag;
1263         }
1264         $ok;
1265     } @cflags;
1266
1267     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1268     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1269     # as long as @def_cppflags_fortify contains only one variable.
1270     if (scalar @def_cppflags_fortify == 0) {
1271         $harden_fortify = 0;
1272     }
1273
1274     # Ignore flags for this arch if requested.
1275     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1276         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1277
1278         remove_flags(\@local_flag_refs,
1279                      \%flag_renames,
1280                      @{$option_ignore_arch_flag{$arch}});
1281     }
1282
1283     my @ignore_line = @option_ignore_line;
1284     # Ignore lines for this arch if requested.
1285     if ($arch and exists $option_ignore_arch_line{$arch}) {
1286         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1287     }
1288
1289 LINE:
1290     for (my $i = 0; $i < scalar @input; $i++) {
1291         my $line = $input[$i];
1292
1293         # Ignore line if requested.
1294         foreach my $ignore (@ignore_line) {
1295             next LINE if $line =~ /$ignore/;
1296         }
1297
1298         my $skip = 0;
1299         if ($input_nonverbose[$i]
1300                 and is_non_verbose_build($line, \$skip,
1301                                          \@input, $i, $parallel)) {
1302             if (not $option_buildd) {
1303                 error_non_verbose_build($line, $input_number[$i]);
1304                 $exit |= $exit_code{non_verbose_build};
1305             } else {
1306                 $statistics{commands_nonverbose}++;
1307             }
1308             next;
1309         }
1310         # Even if it's a verbose build, we might have to skip this line (see
1311         # is_non_verbose_build()).
1312         next if $skip;
1313
1314         my $orig_line = $line;
1315
1316         # Remove everything until and including the compiler command. Makes
1317         # checks easier and faster.
1318         $line =~ s/^.*?$cc_regex//o;
1319         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1320         # the brace and similar characters at the line end.
1321         $line =~ s/['")]+$//;
1322
1323         # Skip unnecessary tests when only preprocessing.
1324         my $flag_preprocess = 0;
1325
1326         my $dependency = 0;
1327         my $preprocess = 0;
1328         my $compile    = 0;
1329         my $link       = 0;
1330
1331         # Preprocess, compile, assemble.
1332         if ($line =~ /\s(-E|-S|-c)\b/) {
1333             $preprocess      = 1;
1334             $flag_preprocess = 1 if $1 eq '-E';
1335             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1336         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1337         # -MT -MQ) are always used with -M/-MM.
1338         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1339             $dependency = 1;
1340         # Otherwise assume we are linking.
1341         } else {
1342             $link = 1;
1343         }
1344
1345         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1346         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1347             $dependency      = 0;
1348             $flag_preprocess = 0;
1349         }
1350
1351         # Dependency generation for Makefiles, no preprocessing or other flags
1352         # needed.
1353         next if $dependency;
1354
1355         # Get all file extensions on this line.
1356         my @extensions = $line =~ /$file_extension_regex/go;
1357         # Ignore all unknown extensions to speedup the search below.
1358         @extensions = grep { exists $extension{$_} } @extensions;
1359
1360         # These file types don't require preprocessing.
1361         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1362             $preprocess = 0;
1363         }
1364         # These file types require preprocessing.
1365         if (extension_found(\%extensions_preprocess, @extensions)) {
1366             # Prevent false positives with "libtool: link: g++ -include test.h
1367             # .." compiler lines.
1368             if ($orig_line !~ /$libtool_link_regex/o) {
1369                 $preprocess = 1;
1370             }
1371         }
1372
1373         if (not $flag_preprocess) {
1374             # If there are source files then it's compiling/linking in one
1375             # step and we must check both. We only check for source files
1376             # here, because header files cause too many false positives.
1377             if (extension_found(\%extensions_compile_link, @extensions)) {
1378                 # Assembly files don't need CFLAGS.
1379                 if (not extension_found(\%extensions_compile, @extensions)
1380                         and extension_found(\%extensions_no_compile, @extensions)) {
1381                     $compile = 0;
1382                 # But the rest does.
1383                 } else {
1384                     $compile = 1;
1385                 }
1386             # No compilable extensions found, either linking or compiling
1387             # header flags.
1388             #
1389             # If there are also no object files we are just compiling headers
1390             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1391             # to our liberal checks for compiler lines, this also reduces the
1392             # number of false positives considerably.
1393             } elsif ($link
1394                     and not extension_found(\%extensions_object, @extensions)) {
1395                 $link = 0;
1396             }
1397         }
1398
1399         my $compile_cpp = 0;
1400         my $restore_cflags = 0;
1401         # Assume CXXFLAGS are required when a C++ file is specified in the
1402         # compiler line.
1403         if ($compile
1404                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1405             $compile     = 0;
1406             $compile_cpp = 1;
1407         # Ada needs special CFLAGS
1408         } elsif (extension_found(\%extensions_ada, @extensions)) {
1409             $restore_cflags = 1;
1410             $preprocess = 0; # Ada uses no CPPFLAGS
1411             @cflags_backup = @cflags;
1412             @cflags        = @cflags_noformat;
1413         # Same for fortran
1414         } elsif (extension_found(\%extensions_fortran, @extensions)) {
1415             $restore_cflags = 1;
1416             @cflags_backup = @cflags;
1417             @cflags        = @cflags_noformat;
1418         }
1419
1420         if ($option_buildd) {
1421             $statistics{preprocess}++  if $preprocess;
1422             $statistics{compile}++     if $compile;
1423             $statistics{compile_cpp}++ if $compile_cpp;
1424             $statistics{link}++        if $link;
1425         }
1426
1427         # Check if there are flags indicating a debug build. If that's true,
1428         # skip the check for -O2. This prevents fortification, but that's fine
1429         # for a debug build.
1430         if (any_flags_used($line, @def_cflags_debug)) {
1431             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1432             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1433         }
1434
1435         # Check hardening flags.
1436         my @missing;
1437         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1438                     or (($harden_stack or $harden_stack_strong)
1439                         and cflags_stack_broken($line, \@missing,
1440                                                 $harden_stack_strong)))
1441                 # Libraries linked with -fPIC don't have to (and can't) be
1442                 # linked with -fPIE as well. It's no error if only PIE flags
1443                 # are missing.
1444                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1445                 # Assume dpkg-buildflags returns the correct flags.
1446                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1447             if (not $option_buildd) {
1448                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1449                             $input[$i], $input_number[$i]);
1450                 $exit |= $exit_code{flags_missing};
1451             } else {
1452                 $statistics{compile_missing}++;
1453             }
1454         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1455                 # Libraries linked with -fPIC don't have to (and can't) be
1456                 # linked with -fPIE as well. It's no error if only PIE flags
1457                 # are missing.
1458                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1459                 # Assume dpkg-buildflags returns the correct flags.
1460                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1461             if (not $option_buildd) {
1462                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1463                             $input[$i], $input_number[$i]);
1464                 $exit |= $exit_code{flags_missing};
1465             } else {
1466                 $statistics{compile_cpp_missing}++;
1467             }
1468         }
1469         if ($preprocess
1470                 and (not all_flags_used($line, \@missing, @cppflags)
1471                     # The fortify flag might be overwritten, detect that.
1472                      or ($harden_fortify
1473                          and cppflags_fortify_broken($line, \@missing)))
1474                 # Assume dpkg-buildflags returns the correct flags.
1475                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1476             if (not $option_buildd) {
1477                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1478                             $input[$i], $input_number[$i]);
1479                 $exit |= $exit_code{flags_missing};
1480             } else {
1481                 $statistics{preprocess_missing}++;
1482             }
1483         }
1484         if ($link and not all_flags_used($line, \@missing, @ldflags)
1485                 # Same here, -fPIC conflicts with -fPIE.
1486                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1487                 # Assume dpkg-buildflags returns the correct flags.
1488                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1489             if (not $option_buildd) {
1490                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1491                             $input[$i], $input_number[$i]);
1492                 $exit |= $exit_code{flags_missing};
1493             } else {
1494                 $statistics{link_missing}++;
1495             }
1496         }
1497
1498         # Restore normal CFLAGS.
1499         if ($restore_cflags) {
1500             @cflags = @cflags_backup;
1501         }
1502     }
1503 }
1504
1505 # Print statistics for buildd mode, only output in this mode.
1506 if ($option_buildd) {
1507     my @warning;
1508
1509     if ($statistics{preprocess_missing}) {
1510         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1511                                $statistics{preprocess_missing},
1512                                $statistics{preprocess};
1513     }
1514     if ($statistics{compile_missing}) {
1515         push @warning, sprintf 'CFLAGS %d (of %d)',
1516                                $statistics{compile_missing},
1517                                $statistics{compile};
1518     }
1519     if ($statistics{compile_cpp_missing}) {
1520         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1521                                $statistics{compile_cpp_missing},
1522                                $statistics{compile_cpp};
1523     }
1524     if ($statistics{link_missing}) {
1525         push @warning, sprintf 'LDFLAGS %d (of %d)',
1526                                $statistics{link_missing},
1527                                $statistics{link};
1528     }
1529     if (scalar @warning) {
1530         local $" = ', '; # array join string
1531         print "$buildd_tag{flags_missing}|@warning missing|\n";
1532     }
1533
1534     if ($statistics{commands_nonverbose}) {
1535         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1536                $statistics{commands_nonverbose},
1537                $statistics{commands},
1538     }
1539 }
1540
1541
1542 exit $exit;
1543
1544
1545 __END__
1546
1547 =head1 NAME
1548
1549 blhc - build log hardening check, checks build logs for missing hardening flags
1550
1551 =head1 SYNOPSIS
1552
1553 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1554
1555 =head1 DESCRIPTION
1556
1557 blhc is a small tool which checks build logs for missing hardening flags. It's
1558 licensed under the GPL 3 or later.
1559
1560 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1561 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1562 official buildd build logs)) to help maintainers detect missing hardening
1563 flags in their packages.
1564
1565 Only gcc is detected as compiler at the moment. If other compilers support
1566 hardening flags as well, please report them.
1567
1568 If there's no output, no flags are missing and the build log is fine.
1569
1570 See F<README> for details about performed checks, auto-detection and
1571 limitations.
1572
1573 =head1 FALSE POSITIVES
1574
1575 To suppress false positives you can embed the following string in the build
1576 log:
1577
1578     blhc: ignore-line-regexp: REGEXP
1579
1580 All lines fully matching REGEXP (see B<--ignore-line> for details) will be
1581 ignored. The string can be embedded multiple times to ignore different
1582 regexps.
1583
1584 Please use this feature sparingly so that missing flags are not overlooked. If
1585 you find false positives which affect more packages please report a bug.
1586
1587 To generate this string simply use echo in C<debian/rules>; make sure to use @
1588 to suppress the echo command itself as it could also trigger a false positive.
1589 If the build process takes a long time edit the C<.build> file in place and
1590 tweak the ignore string until B<blhc --all --debian package.build> no longer
1591 reports any false positives.
1592
1593 =head1 OPTIONS
1594
1595 =over 8
1596
1597 =item B<--all>
1598
1599 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1600 auto detected.
1601
1602 =item B<--arch> I<architecture>
1603
1604 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1605 disables hardening flags not available on this architecture. Is detected
1606 automatically if dpkg-buildpackage is used.
1607
1608 =item B<--bindnow>
1609
1610 Force check for all +bindnow hardening flags. By default it's auto detected.
1611
1612 =item B<--buildd>
1613
1614 Special mode for buildds when automatically parsing log files. The following
1615 changes are in effect:
1616
1617 =over 2
1618
1619 =item *
1620
1621 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1622 possible tags.
1623
1624 =item *
1625
1626 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1627 detected).
1628
1629 =item *
1630
1631 Don't require Term::ANSIColor.
1632
1633 =item *
1634
1635 Return exit code 0, unless there was a error (-I, -W messages don't count as
1636 error).
1637
1638 =back
1639
1640 =item B<--debian>
1641
1642 Apply Debian-specific settings. At the moment this only disables checking for
1643 PIE which is automatically applied by Debian's GCC and no longer requires a
1644 compiler command line argument.
1645
1646 =item B<--color>
1647
1648 Use colored (ANSI) output for warning messages.
1649
1650 =item B<--line-numbers>
1651
1652 Display line numbers.
1653
1654 =item B<--ignore-arch> I<arch>
1655
1656 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1657
1658 Used to prevent false positives. This option can be specified multiple times.
1659
1660 =item B<--ignore-arch-flag> I<arch>:I<flag>
1661
1662 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1663
1664 =item B<--ignore-arch-line> I<arch>:I<line>
1665
1666 Like B<--ignore-line>, but only ignore line on I<arch>.
1667
1668 =item B<--ignore-flag> I<flag>
1669
1670 Don't print an error when the specific flag is missing in a compiler line.
1671 I<flag> is a string.
1672
1673 Used to prevent false positives. This option can be specified multiple times.
1674
1675 =item B<--ignore-line> I<regex>
1676
1677 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1678 at the beginning and end of the line to prevent false negatives.
1679
1680 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1681 warnings (which have line continuation resolved).
1682
1683 Used to prevent false positives. This option can be specified multiple times.
1684
1685 =item B<--pie>
1686
1687 Force check for all +pie hardening flags. By default it's auto detected.
1688
1689 =item B<-h -? --help>
1690
1691 Print available options.
1692
1693 =item B<--version>
1694
1695 Print version number and license.
1696
1697 =back
1698
1699 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1700 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1701 all other commands as well.
1702
1703 =head1 EXAMPLES
1704
1705 Normal usage, parse a single log file.
1706
1707     blhc path/to/log/file
1708
1709 If there's no output, no flags are missing and the build log is fine.
1710
1711 Parse multiple log files. The exit code is ORed over all files.
1712
1713     blhc path/to/directory/with/log/files/*
1714
1715 Don't treat missing C<-g> as error:
1716
1717     blhc --ignore-flag -g path/to/log/file
1718
1719 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1720
1721     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1722
1723 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1724 false positive.
1725
1726     blhc --ignore-line '\./script gcc file' path/to/log/file
1727
1728 Ignore lines matching C<./script gcc file> somewhere in the line.
1729
1730     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1731
1732 Use blhc with pbuilder.
1733
1734     pbuilder path/to/package.dsc | tee path/log/file
1735     blhc path/to/file || echo flags missing
1736
1737 Assume this build log was created on a Debian system and thus don't warn about
1738 missing PIE flags if the current architecture injects them automatically (this
1739 is enabled in buildd mode per default). C<--arch> is necessary if the build
1740 log contains no architecture information as written by dpkg-buildpackage.
1741
1742     blhc --debian --all --arch=amd64 path/to/log/file
1743
1744 =head1 BUILDD TAGS
1745
1746 The following tags are used in I<--buildd> mode. In braces the additional data
1747 which is displayed.
1748
1749 =over 2
1750
1751 =item B<I-hardening-wrapper-used>
1752
1753 The package uses hardening-wrapper which intercepts calls to gcc and adds
1754 hardening flags. The build log doesn't contain any hardening flags and thus
1755 can't be checked by blhc.
1756
1757 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1758
1759 Build log contains lines which hide the real compiler flags. For example:
1760
1761     CC test-a.c
1762     CC test-b.c
1763     CC test-c.c
1764     LD test
1765
1766 Most of the time either C<export V=1> or C<export verbose=1> in
1767 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1768 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1769 patched to remove the C<@>s hiding the real compiler commands.
1770
1771 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1772
1773 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1774
1775 =item B<I-invalid-cmake-used> (version)
1776
1777 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1778 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1779 patch was rejected by upstream and later reverted in Debian. Thus those two
1780 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1781 handle them (for example by passing them to CFLAGS). To prevent false
1782 negatives just blacklist those two versions.
1783
1784 =item B<I-no-compiler-commands>
1785
1786 No compiler commands were detected. Either the log contains none or they were
1787 not correctly detected by blhc (please report the bug in this case).
1788
1789 =back
1790
1791 =head1 EXIT STATUS
1792
1793 The exit status is a "bit mask", each listed status is ORed when the error
1794 condition occurs to get the result.
1795
1796 =over 4
1797
1798 =item B<0>
1799
1800 Success.
1801
1802 =item B<1>
1803
1804 No compiler commands were found.
1805
1806 =item B<2>
1807
1808 Invalid arguments/options given to blhc.
1809
1810 =item B<4>
1811
1812 Non verbose build.
1813
1814 =item B<8>
1815
1816 Missing hardening flags.
1817
1818 =item B<16>
1819
1820 Hardening wrapper detected, no tests performed.
1821
1822 =item B<32>
1823
1824 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1825 TAGS"> for a detailed explanation.
1826
1827 =back
1828
1829 =head1 AUTHOR
1830
1831 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1832
1833 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1834 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1835
1836 =head1 LICENSE AND COPYRIGHT
1837
1838 Copyright (C) 2012-2023 by Simon Ruderich
1839
1840 This program is free software: you can redistribute it and/or modify
1841 it under the terms of the GNU General Public License as published by
1842 the Free Software Foundation, either version 3 of the License, or
1843 (at your option) any later version.
1844
1845 This program is distributed in the hope that it will be useful,
1846 but WITHOUT ANY WARRANTY; without even the implied warranty of
1847 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1848 GNU General Public License for more details.
1849
1850 You should have received a copy of the GNU General Public License
1851 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1852
1853 =head1 SEE ALSO
1854
1855 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1856
1857 =cut