b45439ca9e533a7e01fbb2bc8759d5be8571d29e
[blhc/blhc.git] / bin / blhc
1 #!/usr/bin/perl
2
3 # Build log hardening check, checks build logs for missing hardening flags.
4
5 # Copyright (C) 2012-2013  Simon Ruderich
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20
21 use strict;
22 use warnings;
23
24 use Getopt::Long ();
25 use Text::ParseWords ();
26
27 our $VERSION = '0.04';
28
29
30 # CONSTANTS/VARIABLES
31
32 # Regex to catch compiler commands.
33 my $cc_regex = qr/
34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
35     (?<!\.)                # ignore file names, e.g. "test.gcc"
36     (?:cc|gcc|g\+\+|c\+\+)
37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
38     /x;
39 # Full regex which matches the complete compiler name. Used in a few places to
40 # prevent false negatives.
41 my $cc_regex_full = qr/
42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
43     $cc_regex
44     /x;
45 # Regex to check if a line contains a compiler command.
46 my $cc_regex_normal = qr/
47     \b$cc_regex(?:\s|\\)
48     /x;
49 # Regex to catch (GCC) compiler warnings.
50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
51
52 # List of source file extensions which require preprocessing.
53 my @source_preprocess_compile_cpp = (
54     # C++
55     qw( cc cp cxx cpp CPP c++ C ),
56     # Objective-C++
57     qw( mm M ),
58 );
59 my @source_preprocess_compile = (
60     # C
61     qw( c ),
62     # Objective-C
63     qw( m ),
64     # (Objective-)C++
65     @source_preprocess_compile_cpp,
66     # Fortran
67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
68 );
69 my @source_preprocess_no_compile = (
70     # Assembly
71     qw( S sx ),
72 );
73 my @source_preprocess = (
74     @source_preprocess_compile,
75     @source_preprocess_no_compile,
76 );
77 # List of source file extensions which don't require preprocessing.
78 my @source_no_preprocess_compile_cpp = (
79     # C++
80     qw( ii ),
81     # Objective-C++
82     qw( mii ),
83 );
84 my @source_no_preprocess_compile_ada = (
85     # Ada body
86     qw( adb ),
87     # If you add another file, fix use of @source_no_preprocess_compile_ada
88     # below (search for $compile_ada).
89 );
90 my @source_no_preprocess_compile = (
91     # C
92     qw( i ),
93     # (Objective-)C++
94     @source_no_preprocess_compile_cpp,
95     # Objective-C
96     qw( mi ),
97     # Fortran
98     qw( f for ftn f90 f95 f03 f08 ),
99     # Ada
100     @source_no_preprocess_compile_ada,
101 );
102 my @source_no_preprocess_no_compile = (
103     # Assembly
104     qw( s ),
105     # Ada specification
106     qw( ads ),
107 );
108 my @source_no_preprocess = (
109     @source_no_preprocess_compile,
110     @source_no_preprocess_no_compile,
111 );
112 # List of header file extensions which require preprocessing.
113 my @header_preprocess = (
114     # C, C++, Objective-C, Objective-C++
115     qw( h ),
116     # C++
117     qw( hh H hp hxx hpp HPP h++ tcc ),
118 );
119 # Object files.
120 my @object = (
121     # Normal object files.
122     qw ( o ),
123     # Libtool object files.
124     qw ( lo la ),
125     # Dynamic libraries. bzip2 uses .sho.
126     qw ( so sho ),
127     # Static libraries.
128     qw ( a ),
129 );
130
131 # Hashes for fast extensions lookup to check if a file falls in one of these
132 # categories.
133 my %extensions_no_preprocess = map { $_ => 1 } (
134     # There's no @header_no_preprocess.
135     @source_no_preprocess,
136 );
137 my %extensions_preprocess = map { $_ => 1 } (
138     @header_preprocess,
139     @source_preprocess,
140 );
141 my %extensions_compile_link = map { $_ => 1 } (
142     @source_preprocess,
143     @source_no_preprocess,
144 );
145 my %extensions_compile = map { $_ => 1 } (
146     @source_preprocess_compile,
147     @source_no_preprocess_compile,
148 );
149 my %extensions_no_compile = map { $_ => 1 } (
150     @source_preprocess_no_compile,
151     @source_no_preprocess_no_compile,
152 );
153 my %extensions_compile_cpp = map { $_ => 1 } (
154     @source_preprocess_compile_cpp,
155     @source_no_preprocess_compile_cpp,
156 );
157 my %extensions_object = map { $_ => 1 } (
158     @object,
159 );
160 my %extension = map { $_ => 1 } (
161     @source_no_preprocess,
162     @header_preprocess,
163     @source_preprocess,
164     @object,
165 );
166
167 # Regexp to match file extensions.
168 my $file_extension_regex = qr/
169     \s
170     \S+             # Filename without extension.
171     \.
172     ([^\/\\.,;:\s]+)# File extension.
173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
174                     # word characters at the end and because \b matches double
175                     # extensions (like .cpp.o). Works always as all lines are
176                     # terminated with "\n".
177     /x;
178
179 # Expected (hardening) flags. All flags are used as regexps (and compiled to
180 # real regexps below for better execution speed).
181 my @def_cflags = (
182     '-g',
183     '-O(?:2|3)',
184 );
185 my @def_cflags_format = (
186     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
187     '-Werror=format-security', # implies -Wformat-security
188 );
189 my @def_cflags_fortify = (
190     # fortify needs at least -O1, but -O2 is recommended anyway
191 );
192 my @def_cflags_stack = (
193     '-fstack-protector',
194     '--param[= ]ssp-buffer-size=4',
195 );
196 my @def_cflags_pie = (
197     '-fPIE',
198 );
199 my @def_cxxflags = (
200     @def_cflags,
201 );
202 # @def_cxxflags_* is the same as @def_cflags_*.
203 my @def_cppflags = ();
204 my @def_cppflags_fortify = (
205     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
206     # If you add another flag fix hack below (search for "Hack to fix").
207 );
208 my @def_cppflags_fortify_bad = (
209     # These flags may overwrite -D_FORTIFY_SOURCE=2.
210     '-U_FORTIFY_SOURCE',
211     '-D_FORTIFY_SOURCE=0',
212     '-D_FORTIFY_SOURCE=1',
213 );
214 my @def_ldflags = ();
215 my @def_ldflags_relro = (
216     '-Wl,(?:-z,)?relro',
217 );
218 my @def_ldflags_bindnow = (
219     '-Wl,(?:-z,)?now',
220 );
221 my @def_ldflags_pie = (
222     '-fPIE',
223     '-pie',
224 );
225 my @def_ldflags_pic = (
226     '-fPIC',
227     '-fpic',
228     '-shared',
229 );
230 # References to all flags checked by the flag checker.
231 my @flag_refs = (
232     \@def_cflags,
233     \@def_cflags_format,
234     \@def_cflags_fortify,
235     \@def_cflags_stack,
236     \@def_cflags_pie,
237     \@def_cxxflags,
238     \@def_cppflags,
239     \@def_cppflags_fortify,
240     \@def_ldflags,
241     \@def_ldflags_relro,
242     \@def_ldflags_bindnow,
243     \@def_ldflags_pie,
244 );
245 # References to all used flags.
246 my @flag_refs_all = (
247     @flag_refs,
248     \@def_cppflags_fortify_bad,
249     \@def_ldflags_pic,
250 );
251 # Renaming rules for the output so the regex parts are not visible. Also
252 # stores string values of flag regexps above, see compile_flag_regexp().
253 my %flag_renames = (
254     '-O(?:2|3)'                    => '-O2',
255     '-Wformat(?:=2)?'              => '-Wformat',
256     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
257     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
258     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
259 );
260
261 my %exit_code = (
262     no_compiler_commands => 1 << 0,
263     # used by POD::Usage => 1 << 1,
264     non_verbose_build    => 1 << 2,
265     flags_missing        => 1 << 3,
266     hardening_wrapper    => 1 << 4,
267     invalid_cmake        => 1 << 5,
268 );
269
270 my %buildd_tag = (
271     no_compiler_commands => 'I-no-compiler-commands',
272     non_verbose_build    => 'W-compiler-flags-hidden',
273     flags_missing        => 'W-dpkg-buildflags-missing',
274     hardening_wrapper    => 'I-hardening-wrapper-used',
275     invalid_cmake        => 'I-invalid-cmake-used',
276 );
277
278 # Statistics of missing flags and non-verbose build commands. Used for
279 # $option_buildd.
280 my %statistics = (
281     preprocess          => 0,
282     preprocess_missing  => 0,
283     compile             => 0,
284     compile_missing     => 0,
285     compile_cpp         => 0,
286     compile_cpp_missing => 0,
287     link                => 0,
288     link_missing        => 0,
289     commands            => 0,
290     commands_nonverbose => 0,
291 );
292
293 # Use colored (ANSI) output?
294 my $option_color;
295
296
297 # FUNCTIONS
298
299 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
300 sub array_equal {
301     my ($first_ref, $second_ref) = @_;
302
303     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
304
305     my $length = scalar @{$first_ref};
306     for (my $i = 0; $i < $length; $i++) {
307         return 0 if $first_ref->[$i] ne $second_ref->[$i];
308     }
309
310     return 1;
311 }
312
313 sub error_flags {
314     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
315
316     # Get string value of qr//-escaped regexps and if requested rename them.
317     my @missing_flags = map {
318             $flag_renames_ref->{$_}
319         } @{$missing_flags_ref};
320
321     my $flags = join ' ', @missing_flags;
322     printf '%s (%s)%s %s',
323            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
324            $line;
325
326     return;
327 }
328 sub error_non_verbose_build {
329     my ($line) = @_;
330
331     printf '%s%s %s',
332            error_color('NONVERBOSE BUILD', 'red'),
333            error_color(':', 'yellow'),
334            $line;
335
336     return;
337 }
338 sub error_invalid_cmake {
339     my ($version) = @_;
340
341     printf "%s%s %s\n",
342             error_color('INVALID CMAKE', 'red'),
343             error_color(':', 'yellow'),
344             $version;
345
346     return;
347 }
348 sub error_hardening_wrapper {
349     printf "%s%s %s\n",
350             error_color('HARDENING WRAPPER', 'red'),
351             error_color(':', 'yellow'),
352             'no checks possible, aborting';
353
354     return;
355 }
356 sub error_color {
357     my ($message, $color) = @_;
358
359     if ($option_color) {
360         return Term::ANSIColor::colored($message, $color);
361     } else {
362         return $message;
363     }
364 }
365
366 sub any_flags_used {
367     my ($line, @flags) = @_;
368
369     foreach my $flag (@flags) {
370         return 1 if $line =~ /$flag/;
371     }
372
373     return 0;
374 }
375 sub all_flags_used {
376     my ($line, $missing_flags_ref, @flags) = @_;
377
378     my @missing_flags = ();
379     foreach my $flag (@flags) {
380         if (not $line =~ /$flag/) {
381             push @missing_flags, $flag;
382         }
383     }
384
385     return 1 if scalar @missing_flags == 0;
386
387     @{$missing_flags_ref} = @missing_flags;
388     return 0;
389 }
390
391 sub cppflags_fortify_broken {
392     my ($line, $missing_flags) = @_;
393
394     # This doesn't take the position into account, but is a simple solution.
395     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
396     # is wrong anyway.
397
398     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
399         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
400         push @{$missing_flags}, $def_cppflags_fortify[0];
401         return 1;
402     }
403
404     return 0;
405 }
406
407 # Modifies $missing_flags_ref array.
408 sub pic_pie_conflict {
409     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
410
411     return 0 if not $pie;
412     return 0 if not any_flags_used($line, @def_ldflags_pic);
413
414     my %flags = map { $_ => 1 } @flags_pie;
415
416     # Remove all PIE flags from @missing_flags as they are not required with
417     # -fPIC.
418     my @result = grep {
419         not exists $flags{$_}
420     } @{$missing_flags_ref};
421     @{$missing_flags_ref} = @result;
422
423     # We got a conflict when no flags are left, thus only PIE flags were
424     # missing. If other flags were missing abort because the conflict is not
425     # the problem.
426     return scalar @result == 0;
427 }
428
429 sub is_non_verbose_build {
430     my ($line, $next_line, $skip_ref) = @_;
431
432     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
433                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
434                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
435                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
436                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
437         return 0;
438     }
439
440     # False positives.
441     #
442     # C++ compiler setting.
443     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
444     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
445     # "Compiling" non binary files.
446     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?(?:\.\.\.)?$/;
447     # "Compiling" with no file name.
448     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
449         # $file_extension_regex may need spaces around the filename.
450         return 0 if not " $1 " =~ /$file_extension_regex/o;
451     }
452
453     my $file = $1;
454
455     # On the first pass we only check if this line is verbose or not.
456     return 1 if not defined $next_line;
457
458     # Second pass, we have access to the next line.
459     ${$skip_ref} = 0;
460
461     # CMake and other build systems print the non-verbose messages also when
462     # building verbose. If a compiler and the file name occurs in the next
463     # line, treat it as verbose build.
464     if (defined $file) {
465         # Get filename, we can't use the complete path as only parts of it are
466         # used in the real compiler command.
467         $file =~ m{/([^/\s]+)$};
468         $file = $1;
469
470         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
471             # Not a non-verbose line, but we still have to skip the current line
472             # as it doesn't contain any compiler commands.
473             ${$skip_ref} = 1;
474             return 0;
475         }
476     }
477
478     return 1;
479 }
480
481 # Remove @flags from $flag_refs_ref, and $flag_renames_ref.
482 sub remove_flags {
483     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
484
485     my %removes = map { $_ => 1 } @flags;
486     foreach my $flags (@{$flag_refs_ref}) {
487         @{$flags} = grep {
488             # Flag found as string.
489             not exists $removes{$_}
490             # Flag found as string representation of regexp.
491                 and (not defined $flag_renames_ref->{$_}
492                         or not exists $removes{$flag_renames_ref->{$_}})
493         } @{$flags};
494     }
495
496     return;
497 }
498
499 # Modifies $flag_renames_ref hash.
500 sub compile_flag_regexp {
501     my ($flag_renames_ref, @flags) = @_;
502
503     my @result = ();
504     foreach my $flag (@flags) {
505         # Compile flag regexp for faster execution.
506         my $regex = qr/\s$flag(?:\s|\\)/;
507
508         # Store flag name in replacement string for correct flags in messages
509         # with qr//ed flag regexps.
510         $flag_renames_ref->{$regex}
511             = (exists $flag_renames_ref->{$flag})
512                 ? $flag_renames_ref->{$flag}
513                 : $flag;
514
515         push @result, $regex;
516     }
517     return @result;
518 }
519
520 # Does any extension in @extensions exist in %{$extensions_ref}?
521 sub extension_found {
522     my ($extensions_ref, @extensions) = @_;
523
524     foreach my $extension (@extensions) {
525         if (exists $extensions_ref->{$extension}) {
526             return 1;
527         }
528     }
529     return 0;
530 }
531
532
533 # MAIN
534
535 # Parse command line arguments.
536 my $option_help             = 0;
537 my $option_version          = 0;
538 my $option_pie              = 0;
539 my $option_bindnow          = 0;
540 my @option_ignore_arch      = ();
541 my @option_ignore_flag      = ();
542 my @option_ignore_arch_flag = ();
543 my @option_ignore_line      = ();
544 my @option_ignore_arch_line = ();
545 my $option_all              = 0;
546 my $option_arch             = undef;
547 my $option_buildd           = 0;
548    $option_color            = 0;
549 if (not Getopt::Long::GetOptions(
550             'help|h|?'           => \$option_help,
551             'version'            => \$option_version,
552             # Hardening options.
553             'pie'                => \$option_pie,
554             'bindnow'            => \$option_bindnow,
555             'all'                => \$option_all,
556             # Ignore.
557             'ignore-arch=s'      => \@option_ignore_arch,
558             'ignore-flag=s'      => \@option_ignore_flag,
559             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
560             'ignore-line=s'      => \@option_ignore_line,
561             'ignore-arch-line=s' => \@option_ignore_arch_line,
562             # Misc.
563             'color'              => \$option_color,
564             'arch=s'             => \$option_arch,
565             'buildd'             => \$option_buildd,
566         )) {
567     require Pod::Usage;
568     Pod::Usage::pod2usage(2);
569 }
570 if ($option_help) {
571     require Pod::Usage;
572     Pod::Usage::pod2usage(1);
573 }
574 if ($option_version) {
575     print <<"EOF";
576 blhc $VERSION  Copyright (C) 2012-2013  Simon Ruderich
577
578 This program is free software: you can redistribute it and/or modify
579 it under the terms of the GNU General Public License as published by
580 the Free Software Foundation, either version 3 of the License, or
581 (at your option) any later version.
582
583 This program is distributed in the hope that it will be useful,
584 but WITHOUT ANY WARRANTY; without even the implied warranty of
585 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
586 GNU General Public License for more details.
587
588 You should have received a copy of the GNU General Public License
589 along with this program.  If not, see <http://www.gnu.org/licenses/>.
590 EOF
591     exit 0;
592 }
593
594 # Arguments missing.
595 if (scalar @ARGV == 0) {
596     require Pod::Usage;
597     Pod::Usage::pod2usage(2);
598 }
599
600 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
601 # installed on Debian's buildds.
602 if (not $option_buildd) {
603     require Term::ANSIColor;
604 }
605
606 if ($option_all) {
607     $option_pie     = 1;
608     $option_bindnow = 1;
609 }
610
611 # Precompiled ignores for faster lookup.
612 my %option_ignore_arch_flag = ();
613 my %option_ignore_arch_line = ();
614
615 # Strip flags which should be ignored.
616 if (scalar @option_ignore_flag > 0) {
617     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
618 }
619 # Same for arch specific ignore flags, but only prepare here.
620 if (scalar @option_ignore_arch_flag > 0) {
621     foreach my $ignore (@option_ignore_arch_flag) {
622         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
623
624         if (not $ignore_arch or not $ignore_flag) {
625             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
626                         . '("arch:flag" expected)' . "\n", $ignore;
627             require Pod::Usage;
628             Pod::Usage::pod2usage(2);
629         }
630
631         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
632     }
633 }
634
635 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
636 # faster with this.
637 foreach my $flags (@flag_refs_all) {
638     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
639 }
640
641 # Precompile ignore line regexps, also anchor at beginning and end of line.
642 foreach my $ignore (@option_ignore_line) {
643     $ignore = qr/^$ignore$/;
644 }
645 # Same for arch specific ignore lines.
646 if (scalar @option_ignore_arch_line > 0) {
647     foreach my $ignore (@option_ignore_arch_line) {
648         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
649
650         if (not $ignore_arch or not $ignore_line) {
651             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
652                         . '("arch:line" expected)' . "\n", $ignore;
653             require Pod::Usage;
654             Pod::Usage::pod2usage(2);
655         }
656
657         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
658     }
659 }
660
661 # Final exit code.
662 my $exit = 0;
663
664 FILE:
665 foreach my $file (@ARGV) {
666     print "checking '$file'...\n" if scalar @ARGV > 1;
667
668     -f $file or die "No such file: $file";
669
670     open my $fh, '<', $file or die $!;
671
672     # Architecture of this file.
673     my $arch = $option_arch;
674
675     # Hardening options. Not all architectures support all hardening options.
676     my $harden_format  = 1;
677     my $harden_fortify = 1;
678     my $harden_stack   = 1;
679     my $harden_relro   = 1;
680     my $harden_bindnow = $option_bindnow; # defaults to 0
681     my $harden_pie     = $option_pie;     # defaults to 0
682
683     # Does this build log use ada? Ada also uses gcc as compiler but uses
684     # different CFLAGS. But only perform ada checks if an ada compiler used
685     # for performance reasons.
686     my $ada = 0;
687
688     while (my $line = <$fh>) {
689         # Detect architecture automatically unless overridden. For buildd logs
690         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
691         # build logs which aren't built (wrong architecture, build error,
692         # etc.).
693         if (not $arch) {
694             if (index($line, 'Build Architecture: ') == 0) {
695                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
696             # For old logs (sbuild << 0.63.0-1).
697             } elsif (index($line, 'Architecture: ') == 0) {
698                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
699             }
700         }
701
702         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
703         # check for hardening flags in buildd mode if an older dpkg-dev is
704         # used. Default flags (-g -O2) are still checked.
705         #
706         # Packages which were built before 1.16.1 but used their own hardening
707         # flags are not checked.
708         if ($option_buildd
709                 and index($line, 'Toolchain package versions: ') == 0) {
710             require Dpkg::Version;
711             if (not $line =~ /\bdpkg-dev_(\S+)/
712                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
713                 $harden_format  = 0;
714                 $harden_fortify = 0;
715                 $harden_stack   = 0;
716                 $harden_relro   = 0;
717                 $harden_bindnow = 0;
718                 $harden_pie     = 0;
719             }
720         }
721
722         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
723         # this was later dropped because upstream rejected the patch. Thus
724         # build logs with these versions will have fortify hardening flags
725         # enabled, even though they may be not correctly set and are missing
726         # when build with later CMake versions. Thanks to Aron Xu for letting
727         # me know.
728         if (index($line, 'Package versions: ') == 0
729                 and $line =~ /\bcmake_(\S+)/
730                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
731             if (not $option_buildd) {
732                 error_invalid_cmake($1);
733                 $exit |= $exit_code{invalid_cmake};
734             } else {
735                 print "$buildd_tag{invalid_cmake}|$1|\n";
736             }
737         }
738
739         # Debian's build daemons use "Filtered Build-Depends:" (or just
740         # "Build-Depends:" in older versions) for the build dependencies, but
741         # pbuilder uses "Depends:"; support both.
742         if (index($line, 'Filtered Build-Depends: ') == 0
743                 or index($line, 'Build-Depends: ') == 0
744                 or index($line, 'Depends: ') == 0) {
745             # If hardening wrapper is used (wraps calls to gcc and adds
746             # hardening flags automatically) we can't perform any checks,
747             # abort.
748             if ($line =~ /\bhardening-wrapper\b/) {
749                 if (not $option_buildd) {
750                     error_hardening_wrapper();
751                     $exit |= $exit_code{hardening_wrapper};
752                 } else {
753                     print "$buildd_tag{hardening_wrapper}||\n";
754                 }
755                 next FILE;
756             }
757
758             # Ada compiler.
759             if ($line =~ /\bgnat\b/) {
760                 $ada = 1;
761             }
762         }
763
764         # We skip over unimportant lines at the beginning of the log to
765         # prevent false positives.
766         last if index($line, 'dpkg-buildpackage: ') == 0;
767     }
768
769     # Input lines, contain only the lines with compiler commands.
770     my @input = ();
771     # Non-verbose lines in the input. Used to reduce calls to
772     # is_non_verbose_build() (which is quite slow) in the second loop when
773     # it's already clear if a line is non-verbose or not.
774     my @input_nonverbose = ();
775
776     my $continuation = 0;
777     my $complete_line = undef;
778     my $non_verbose;
779     while (my $line = <$fh>) {
780         # And stop at the end of the build log. Package details (reported by
781         # the buildd logs) are not important for us. This also prevents false
782         # positives.
783         last if index($line, 'Build finished at ') == 0
784                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
785
786         if (not $continuation) {
787             $non_verbose = 0;
788         }
789
790         # Detect architecture automatically unless overridden.
791         if (not $arch
792                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
793             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
794
795             # Old buildd logs use e.g. "host architecture is alpha", remove
796             # the "is", otherwise debarch_to_debtriplet() will not detect the
797             # architecture.
798             if (index($arch, 'is ') == 0) {
799                 $arch = substr $arch, 3;
800             }
801         }
802
803         # Ignore compiler warnings for now.
804         next if $line =~ /$warning_regex/o;
805
806         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
807             # Remove all ANSI color sequences which are sometimes used in
808             # non-verbose builds.
809             $line = Term::ANSIColor::colorstrip($line);
810             # Also strip '\0xf' (delete previous character), used by Elinks'
811             # build system.
812             $line =~ s/\x0f//g;
813             # And "ESC(B" which seems to be used on armhf and hurd (not sure
814             # what it does).
815             $line =~ s/\033\(B//g;
816         }
817
818         # Check if this line indicates a non verbose build.
819         $non_verbose |= is_non_verbose_build($line);
820
821         # One line may contain multiple commands (";"). Treat each one as
822         # single line. parse_line() is slow, only use it when necessary.
823         my @line = (index($line, ';') == -1)
824                  ? ($line)
825                  : map {
826                        # Ensure newline at the line end - necessary for
827                        # correct parsing later.
828                        $_ =~ s/\s+$//;
829                        $_ .= "\n";
830                    } Text::ParseWords::parse_line(';', 1, $line);
831         foreach my $line (@line) {
832             if ($continuation) {
833                 $continuation = 0;
834
835                 # Join lines, but leave the "\" in place so it's clear where
836                 # the original line break was.
837                 chomp $complete_line;
838                 $complete_line .= ' ' . $line;
839             }
840             # Line continuation, line ends with "\".
841             if ($line =~ /\\$/) {
842                 $continuation = 1;
843                 # Start line continuation.
844                 if (not defined $complete_line) {
845                     $complete_line = $line;
846                 }
847                 next;
848             }
849
850             # Use the complete line if a line continuation occurred.
851             if (defined $complete_line) {
852                 $line = $complete_line;
853                 $complete_line = undef;
854             }
855
856             # Ignore lines with no compiler commands.
857             next if not $non_verbose
858                     and not $line =~ /$cc_regex_normal/o;
859             # Ignore lines with no filenames with extensions. May miss some
860             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
861             # a problem as the log will most likely contain other non-verbose
862             # commands which are detected.
863             next if not $non_verbose
864                     and not $line =~ /$file_extension_regex/o;
865
866             # Ignore false positives.
867             #
868             # `./configure` output.
869             next if not $non_verbose
870                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
871             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
872                                 [Cc]ompiler[\s.]*:?\s+
873                                 /x;
874             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
875                                 \s*=\s*$cc_regex_full
876                                 # optional compiler options, don't allow
877                                 # "everything" here to prevent false negatives
878                                 \s*(?:\s-\S+)*\s*$}xo;
879             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
880             # line (or similar for other architectures) which gets recognized
881             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
882             # C++ files. No hardening flags are relevant during this step,
883             # thus ignore `moc-qt*` lines. The resulting files will be
884             # compiled in a separate step (and therefore checked).
885             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
886                                \s.+\s
887                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
888                                \s}x;
889             # Ignore false positives when the line contains only CC=gcc but no
890             # other gcc command.
891             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
892                 my $before = $1;
893                 my $after  = $2;
894                 next if     not $before =~ /$cc_regex_normal/o
895                         and not $after  =~ /$cc_regex_normal/o;
896             }
897
898             # Check if additional hardening options were used. Used to ensure
899             # they are used for the complete build.
900             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
901                                                          @def_ldflags_pie);
902             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
903
904             push @input, $line;
905             push @input_nonverbose, $non_verbose;
906         }
907     }
908
909     close $fh or die $!;
910
911     # Ignore arch if requested.
912     if (scalar @option_ignore_arch > 0 and $arch) {
913         foreach my $ignore (@option_ignore_arch) {
914             if ($arch eq $ignore) {
915                 print "ignoring architecture '$arch'\n";
916                 next FILE;
917             }
918         }
919     }
920
921     if (scalar @input == 0) {
922         if (not $option_buildd) {
923             print "No compiler commands!\n";
924             $exit |= $exit_code{no_compiler_commands};
925         } else {
926             print "$buildd_tag{no_compiler_commands}||\n";
927         }
928         next FILE;
929     }
930
931     if ($option_buildd) {
932         $statistics{commands} += scalar @input;
933     }
934
935     # Option or auto detected.
936     if ($arch) {
937         # The following was partially copied from dpkg-dev 1.17.1
938         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
939         # copyright RaphaĆ«l Hertzog <hertzog@debian.org>, Kees Cook
940         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
941         # later. Keep it in sync.
942
943         require Dpkg::Arch;
944         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
945
946         # Disable unsupported hardening options.
947         if ($os !~ /^(?:linux|knetbsd|hurd)$/ or
948                 $cpu =~ /^(?:hppa|mips|mipsel|avr32)$/) {
949             $harden_pie = 0;
950         }
951         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa|arm64)$/
952                 or $arch eq 'arm') {
953             $harden_stack = 0;
954         }
955         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
956             $harden_relro   = 0;
957             $harden_bindnow = 0;
958         }
959     }
960
961     # Default values.
962     my @cflags   = @def_cflags;
963     my @cxxflags = @def_cxxflags;
964     my @cppflags = @def_cppflags;
965     my @ldflags  = @def_ldflags;
966     # Check the specified hardening options, same order as dpkg-buildflags.
967     if ($harden_pie) {
968         @cflags   = (@cflags,   @def_cflags_pie);
969         @cxxflags = (@cxxflags, @def_cflags_pie);
970         @ldflags  = (@ldflags,  @def_ldflags_pie);
971     }
972     if ($harden_stack) {
973         @cflags   = (@cflags,   @def_cflags_stack);
974         @cxxflags = (@cxxflags, @def_cflags_stack);
975     }
976     if ($harden_fortify) {
977         @cflags   = (@cflags,   @def_cflags_fortify);
978         @cxxflags = (@cxxflags, @def_cflags_fortify);
979         @cppflags = (@cppflags, @def_cppflags_fortify);
980     }
981     if ($harden_format) {
982         @cflags   = (@cflags,   @def_cflags_format);
983         @cxxflags = (@cxxflags, @def_cflags_format);
984     }
985     if ($harden_relro) {
986         @ldflags = (@ldflags, @def_ldflags_relro);
987     }
988     if ($harden_bindnow) {
989         @ldflags = (@ldflags, @def_ldflags_bindnow);
990     }
991
992     # Stores normal CFLAGS when @cflags_ada are temporarily used.
993     my @cflags_backup;
994     # Ada CFLAGS, only set if ada is used.
995     my @cflags_ada;
996     # Ada doesn't support format hardening flags, see #680117 for more
997     # information. Filter them out if ada is used.
998     if ($ada and $harden_format) {
999         @cflags_ada = grep {
1000             my $ok = 1;
1001             foreach my $flag (@def_cflags_format) {
1002                 $ok = 0 if $_ eq $flag;
1003             }
1004             $ok;
1005         } @cflags;
1006     }
1007
1008     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1009     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1010     # as long as @def_cppflags_fortify contains only one variable.
1011     if (scalar @def_cppflags_fortify == 0) {
1012         $harden_fortify = 0;
1013     }
1014
1015     # Ignore flags for this arch if requested.
1016     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1017         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1018
1019         remove_flags(\@local_flag_refs,
1020                      \%flag_renames,
1021                      @{$option_ignore_arch_flag{$arch}});
1022     }
1023
1024     my @ignore_line = @option_ignore_line;
1025     # Ignore lines for this arch if requested.
1026     if ($arch and exists $option_ignore_arch_line{$arch}) {
1027         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1028     }
1029
1030 LINE:
1031     for (my $i = 0; $i < scalar @input; $i++) {
1032         my $line = $input[$i];
1033
1034         # Ignore line if requested.
1035         foreach my $ignore (@ignore_line) {
1036             next LINE if $line =~ /$ignore/;
1037         }
1038
1039         my $skip = 0;
1040         if ($input_nonverbose[$i]
1041                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1042             if (not $option_buildd) {
1043                 error_non_verbose_build($line);
1044                 $exit |= $exit_code{non_verbose_build};
1045             } else {
1046                 $statistics{commands_nonverbose}++;
1047             }
1048             next;
1049         }
1050         # Even if it's a verbose build, we might have to skip this line (see
1051         # is_non_verbose_build()).
1052         next if $skip;
1053
1054         # Remove everything until and including the compiler command. Makes
1055         # checks easier and faster.
1056         $line =~ s/^.*?$cc_regex//o;
1057         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1058         # the brace and similar characters at the line end.
1059         $line =~ s/['")]+$//;
1060
1061         # Skip unnecessary tests when only preprocessing.
1062         my $flag_preprocess = 0;
1063
1064         my $dependency = 0;
1065         my $preprocess = 0;
1066         my $compile    = 0;
1067         my $link       = 0;
1068
1069         # Preprocess, compile, assemble.
1070         if ($line =~ /\s(-E|-S|-c)\b/) {
1071             $preprocess      = 1;
1072             $flag_preprocess = 1 if $1 eq '-E';
1073             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1074         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1075         # -MT -MQ) are always used with -M/-MM.
1076         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1077             $dependency = 1;
1078         # Otherwise assume we are linking.
1079         } else {
1080             $link = 1;
1081         }
1082
1083         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1084         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1085             $dependency      = 0;
1086             $flag_preprocess = 0;
1087         }
1088
1089         # Dependency generation for Makefiles, no preprocessing or other flags
1090         # needed.
1091         next if $dependency;
1092
1093         # Get all file extensions on this line.
1094         my @extensions = $line =~ /$file_extension_regex/go;
1095         # Ignore all unknown extensions to speedup the search below.
1096         @extensions = grep { exists $extension{$_} } @extensions;
1097
1098         # These file types don't require preprocessing.
1099         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1100             $preprocess = 0;
1101         }
1102         # These file types require preprocessing.
1103         if (extension_found(\%extensions_preprocess, @extensions)) {
1104             $preprocess = 1;
1105         }
1106
1107         if (not $flag_preprocess) {
1108             # If there are source files then it's compiling/linking in one
1109             # step and we must check both. We only check for source files
1110             # here, because header files cause too many false positives.
1111             if (extension_found(\%extensions_compile_link, @extensions)) {
1112                 # Assembly files don't need CFLAGS.
1113                 if (not extension_found(\%extensions_compile, @extensions)
1114                         and extension_found(\%extensions_no_compile, @extensions)) {
1115                     $compile = 0;
1116                 # But the rest does.
1117                 } else {
1118                     $compile = 1;
1119                 }
1120             # No compilable extensions found, either linking or compiling
1121             # header flags.
1122             #
1123             # If there are also no object files we are just compiling headers
1124             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1125             # to our liberal checks for compiler lines, this also reduces the
1126             # number of false positives considerably.
1127             } elsif ($link
1128                     and not extension_found(\%extensions_object, @extensions)) {
1129                 $link = 0;
1130             }
1131         }
1132
1133         my $compile_cpp = 0;
1134         my $compile_ada = 0;
1135         # Assume CXXFLAGS are required when a C++ file is specified in the
1136         # compiler line.
1137         if ($compile
1138                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1139             $compile     = 0;
1140             $compile_cpp = 1;
1141         # Ada needs special CFLAGS, use them if only ada files are compiled.
1142         } elsif ($ada
1143                     and $compile
1144                     and array_equal(\@extensions,
1145                                     \@source_no_preprocess_compile_ada)) {
1146             $compile_ada = 1;
1147             @cflags_backup = @cflags;
1148             @cflags        = @cflags_ada;
1149         }
1150
1151         if ($option_buildd) {
1152             $statistics{preprocess}++  if $preprocess;
1153             $statistics{compile}++     if $compile;
1154             $statistics{compile_cpp}++ if $compile_cpp;
1155             $statistics{link}++        if $link;
1156         }
1157
1158         # Check hardening flags.
1159         my @missing;
1160         if ($compile and not all_flags_used($line, \@missing, @cflags)
1161                 # Libraries linked with -fPIC don't have to (and can't) be
1162                 # linked with -fPIE as well. It's no error if only PIE flags
1163                 # are missing.
1164                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1165                 # Assume dpkg-buildflags returns the correct flags.
1166                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1167             if (not $option_buildd) {
1168                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1169                 $exit |= $exit_code{flags_missing};
1170             } else {
1171                 $statistics{compile_missing}++;
1172             }
1173         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1174                 # Libraries linked with -fPIC don't have to (and can't) be
1175                 # linked with -fPIE as well. It's no error if only PIE flags
1176                 # are missing.
1177                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1178                 # Assume dpkg-buildflags returns the correct flags.
1179                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1180             if (not $option_buildd) {
1181                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1182                 $exit |= $exit_code{flags_missing};
1183             } else {
1184                 $statistics{compile_cpp_missing}++;
1185             }
1186         }
1187         if ($preprocess
1188                 and (not all_flags_used($line, \@missing, @cppflags)
1189                     # The fortify flag might be overwritten, detect that.
1190                      or ($harden_fortify
1191                          and cppflags_fortify_broken($line, \@missing)))
1192                 # Assume dpkg-buildflags returns the correct flags.
1193                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1194             if (not $option_buildd) {
1195                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1196                 $exit |= $exit_code{flags_missing};
1197             } else {
1198                 $statistics{preprocess_missing}++;
1199             }
1200         }
1201         if ($link and not all_flags_used($line, \@missing, @ldflags)
1202                 # Same here, -fPIC conflicts with -fPIE.
1203                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1204                 # Assume dpkg-buildflags returns the correct flags.
1205                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1206             if (not $option_buildd) {
1207                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1208                 $exit |= $exit_code{flags_missing};
1209             } else {
1210                 $statistics{link_missing}++;
1211             }
1212         }
1213
1214         # Restore normal CFLAGS.
1215         if ($compile_ada) {
1216             @cflags = @cflags_backup;
1217         }
1218     }
1219 }
1220
1221 # Print statistics for buildd mode, only output in this mode.
1222 if ($option_buildd) {
1223     my @warning;
1224
1225     if ($statistics{preprocess_missing}) {
1226         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1227                                $statistics{preprocess_missing},
1228                                $statistics{preprocess};
1229     }
1230     if ($statistics{compile_missing}) {
1231         push @warning, sprintf 'CFLAGS %d (of %d)',
1232                                $statistics{compile_missing},
1233                                $statistics{compile};
1234     }
1235     if ($statistics{compile_cpp_missing}) {
1236         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1237                                $statistics{compile_cpp_missing},
1238                                $statistics{compile_cpp};
1239     }
1240     if ($statistics{link_missing}) {
1241         push @warning, sprintf 'LDFLAGS %d (of %d)',
1242                                $statistics{link_missing},
1243                                $statistics{link};
1244     }
1245     if (scalar @warning) {
1246         local $" = ', '; # array join string
1247         print "$buildd_tag{flags_missing}|@warning missing|\n";
1248     }
1249
1250     if ($statistics{commands_nonverbose}) {
1251         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1252                $statistics{commands_nonverbose},
1253                $statistics{commands},
1254     }
1255 }
1256
1257
1258 exit $exit;
1259
1260
1261 __END__
1262
1263 =head1 NAME
1264
1265 blhc - build log hardening check, checks build logs for missing hardening flags
1266
1267 =head1 SYNOPSIS
1268
1269 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1270
1271 =head1 DESCRIPTION
1272
1273 blhc is a small tool which checks build logs for missing hardening flags. It's
1274 licensed under the GPL 3 or later.
1275
1276 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1277 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1278 official buildd build logs)) to help maintainers detect missing hardening
1279 flags in their packages.
1280
1281 Only gcc is detected as compiler at the moment. If other compilers support
1282 hardening flags as well, please report them.
1283
1284 If there's no output, no flags are missing and the build log is fine.
1285
1286 See F<README> for details about performed checks, auto-detection and
1287 limitations.
1288
1289 =head1 OPTIONS
1290
1291 =over 8
1292
1293 =item B<--all>
1294
1295 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1296 auto detected.
1297
1298 =item B<--arch> I<architecture>
1299
1300 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1301 disables hardening flags not available on this architecture. Is detected
1302 automatically if dpkg-buildpackage is used.
1303
1304 =item B<--bindnow>
1305
1306 Force check for all +bindnow hardening flags. By default it's auto detected.
1307
1308 =item B<--buildd>
1309
1310 Special mode for buildds when automatically parsing log files. The following
1311 changes are in effect:
1312
1313 =over 2
1314
1315 =item *
1316
1317 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1318 possible tags.
1319
1320 =item *
1321
1322 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1323 detected).
1324
1325 =item *
1326
1327 Don't require Term::ANSIColor.
1328
1329 =item *
1330
1331 Return exit code 0, unless there was a error (-I, -W messages don't count as
1332 error).
1333
1334 =back
1335
1336 =item B<--color>
1337
1338 Use colored (ANSI) output for warning messages.
1339
1340 =item B<--ignore-arch> I<arch>
1341
1342 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1343
1344 Used to prevent false positives. This option can be specified multiple times.
1345
1346 =item B<--ignore-arch-flag> I<arch>:I<flag>
1347
1348 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1349
1350 =item B<--ignore-arch-line> I<arch>:I<line>
1351
1352 Like B<--ignore-line>, but only ignore line on I<arch>.
1353
1354 =item B<--ignore-flag> I<flag>
1355
1356 Don't print an error when the specific flag is missing in a compiler line.
1357 I<flag> is a string.
1358
1359 Used to prevent false positives. This option can be specified multiple times.
1360
1361 =item B<--ignore-line> I<regex>
1362
1363 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1364 at the beginning and end of the line to prevent false negatives.
1365
1366 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1367 warnings (which have line continuation resolved).
1368
1369 Used to prevent false positives. This option can be specified multiple times.
1370
1371 =item B<--pie>
1372
1373 Force check for all +pie hardening flags. By default it's auto detected.
1374
1375 =item B<-h -? --help>
1376
1377 Print available options.
1378
1379 =item B<--version>
1380
1381 Print version number and license.
1382
1383 =back
1384
1385 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1386 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1387 all other commands as well.
1388
1389 =head1 EXAMPLES
1390
1391 Normal usage, parse a single log file.
1392
1393     blhc path/to/log/file
1394
1395 If there's no output, no flags are missing and the build log is fine.
1396
1397 Parse multiple log files. The exit code is ORed over all files.
1398
1399     blhc path/to/directory/with/log/files/*
1400
1401 Don't treat missing C<-g> as error:
1402
1403     blhc --ignore-flag -g path/to/log/file
1404
1405 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1406
1407     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1408
1409 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1410 false positive.
1411
1412     blhc --ignore-line '\./script gcc file' path/to/log/file
1413
1414 Ignore lines matching C<./script gcc file> somewhere in the line.
1415
1416     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1417
1418 Use blhc with pbuilder.
1419
1420     pbuilder path/to/package.dsc | tee path/log/file
1421     blhc path/to/file || echo flags missing
1422
1423 =head1 BUILDD TAGS
1424
1425 The following tags are used in I<--buildd> mode. In braces the additional data
1426 which is displayed.
1427
1428 =over 2
1429
1430 =item B<I-hardening-wrapper-used>
1431
1432 The package uses hardening-wrapper which intercepts calls to gcc and adds
1433 hardening flags. The build log doesn't contain any hardening flags and thus
1434 can't be checked by blhc.
1435
1436 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1437
1438 Build log contains lines which hide the real compiler flags. For example:
1439
1440     CC test-a.c
1441     CC test-b.c
1442     CC test-c.c
1443     LD test
1444
1445 Most of the time either C<export V=1> or C<export verbose=1> in
1446 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1447 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1448 patched to remove the C<@>s hiding the real compiler commands.
1449
1450 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1451
1452 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1453
1454 =item B<I-invalid-cmake-used> (version)
1455
1456 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1457 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1458 patch was rejected by upstream and later reverted in Debian. Thus those two
1459 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1460 handle them (for example by passing them to CFLAGS). To prevent false
1461 negatives just blacklist those two versions.
1462
1463 =item B<I-no-compiler-commands>
1464
1465 No compiler commands were detected. Either the log contains none or they were
1466 not correctly detected by blhc (please report the bug in this case).
1467
1468 =back
1469
1470 =head1 EXIT STATUS
1471
1472 The exit status is a "bit mask", each listed status is ORed when the error
1473 condition occurs to get the result.
1474
1475 =over 4
1476
1477 =item B<0>
1478
1479 Success.
1480
1481 =item B<1>
1482
1483 No compiler commands were found.
1484
1485 =item B<2>
1486
1487 Invalid arguments/options given to blhc.
1488
1489 =item B<4>
1490
1491 Non verbose build.
1492
1493 =item B<8>
1494
1495 Missing hardening flags.
1496
1497 =item B<16>
1498
1499 Hardening wrapper detected, no tests performed.
1500
1501 =item B<32>
1502
1503 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1504 TAGS"> for a detailed explanation.
1505
1506 =back
1507
1508 =head1 AUTHOR
1509
1510 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1511
1512 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1513 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1514
1515 =head1 LICENSE AND COPYRIGHT
1516
1517 Copyright (C) 2012-2013 by Simon Ruderich
1518
1519 This program is free software: you can redistribute it and/or modify
1520 it under the terms of the GNU General Public License as published by
1521 the Free Software Foundation, either version 3 of the License, or
1522 (at your option) any later version.
1523
1524 This program is distributed in the hope that it will be useful,
1525 but WITHOUT ANY WARRANTY; without even the implied warranty of
1526 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1527 GNU General Public License for more details.
1528
1529 You should have received a copy of the GNU General Public License
1530 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1531
1532 =head1 SEE ALSO
1533
1534 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1535
1536 =cut