bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.03';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps.
 180 my @def_cflags = (
 181     '-g',
 182     '-O(?:2|3)',
 183 );
 184 my @def_cflags_format = (
 185     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 186     '-Werror=format-security', # implies -Wformat-security
 187 );
 188 my @def_cflags_fortify = (
 189     # fortify needs at least -O1, but -O2 is recommended anyway
 190 );
 191 my @def_cflags_stack = (
 192     '-fstack-protector',
 193     '--param=ssp-buffer-size=4',
 194 );
 195 my @def_cflags_pie = (
 196     '-fPIE',
 197 );
 198 my @def_cxxflags = (
 199     @def_cflags,
 200 );
 201 # @def_cxxflags_* is the same as @def_cflags_*.
 202 my @def_cppflags = ();
 203 my @def_cppflags_fortify = (
 204     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 205     # If you add another flag fix hack below (search for "Hack to fix").
 206 );
 207 my @def_cppflags_fortify_bad = (
 208     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 209     '-U_FORTIFY_SOURCE',
 210     '-D_FORTIFY_SOURCE=0',
 211     '-D_FORTIFY_SOURCE=1',
 212 );
 213 my @def_ldflags = ();
 214 my @def_ldflags_relro = (
 215     '-Wl,(?:-z,)?relro',
 216 );
 217 my @def_ldflags_bindnow = (
 218     '-Wl,(?:-z,)?now',
 219 );
 220 my @def_ldflags_pie = (
 221     '-fPIE',
 222     '-pie',
 223 );
 224 my @def_ldflags_pic = (
 225     '-fPIC',
 226     '-fpic',
 227     '-shared',
 228 );
 229 # References to all flags checked by the flag checker.
 230 my @flag_refs = (
 231     \@def_cflags,
 232     \@def_cflags_format,
 233     \@def_cflags_fortify,
 234     \@def_cflags_stack,
 235     \@def_cflags_pie,
 236     \@def_cxxflags,
 237     \@def_cppflags,
 238     \@def_cppflags_fortify,
 239     \@def_ldflags,
 240     \@def_ldflags_relro,
 241     \@def_ldflags_bindnow,
 242     \@def_ldflags_pie,
 243 );
 244 # References to all used flags.
 245 my @flag_refs_all = (
 246     @flag_refs,
 247     \@def_cppflags_fortify_bad,
 248     \@def_ldflags_pic,
 249 );
 250 # Renaming rules for the output so the regex parts are not visible. Also
 251 # stores string values of flag regexps above, see compile_flag_regexp().
 252 my %flag_renames = (
 253     '-O(?:2|3)'         => '-O2',
 254     '-Wformat(?:=2)?'   => '-Wformat',
 255     '-Wl,(?:-z,)?relro' => '-Wl,-z,relro',
 256     '-Wl,(?:-z,)?now'   => '-Wl,-z,now',
 257 );
 258
 259 my %exit_code = (
 260     no_compiler_commands => 1 << 0,
 261     # used by POD::Usage => 1 << 1,
 262     non_verbose_build    => 1 << 2,
 263     flags_missing        => 1 << 3,
 264     hardening_wrapper    => 1 << 4,
 265     invalid_cmake        => 1 << 5,
 266 );
 267
 268 my %buildd_tag = (
 269     no_compiler_commands => 'I-no-compiler-commands',
 270     non_verbose_build    => 'W-compiler-flags-hidden',
 271     flags_missing        => 'W-dpkg-buildflags-missing',
 272     hardening_wrapper    => 'I-hardening-wrapper-used',
 273     invalid_cmake        => 'I-invalid-cmake-used',
 274 );
 275
 276 # Statistics of missing flags and non-verbose build commands. Used for
 277 # $option_buildd.
 278 my %statistics = (
 279     preprocess          => 0,
 280     preprocess_missing  => 0,
 281     compile             => 0,
 282     compile_missing     => 0,
 283     compile_cpp         => 0,
 284     compile_cpp_missing => 0,
 285     link                => 0,
 286     link_missing        => 0,
 287     commands            => 0,
 288     commands_nonverbose => 0,
 289 );
 290
 291 # Use colored (ANSI) output?
 292 my $option_color;
 293
 294
 295 # FUNCTIONS
 296
 297 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 298 sub array_equal {
 299     my ($first_ref, $second_ref) = @_;
 300
 301     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 302
 303     my $length = scalar @{$first_ref};
 304     for (my $i = 0; $i < $length; $i++) {
 305         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 306     }
 307
 308     return 1;
 309 }
 310
 311 sub error_flags {
 312     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 313
 314     # Get string value of qr//-escaped regexps and if requested rename them.
 315     my @missing_flags = map {
 316             $flag_renames_ref->{$_}
 317         } @{$missing_flags_ref};
 318
 319     my $flags = join ' ', @missing_flags;
 320     printf '%s (%s)%s %s',
 321            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 322            $line;
 323
 324     return;
 325 }
 326 sub error_non_verbose_build {
 327     my ($line) = @_;
 328
 329     printf '%s%s %s',
 330            error_color('NONVERBOSE BUILD', 'red'),
 331            error_color(':', 'yellow'),
 332            $line;
 333
 334     return;
 335 }
 336 sub error_invalid_cmake {
 337     my ($version) = @_;
 338
 339     printf "%s%s %s\n",
 340             error_color('INVALID CMAKE', 'red'),
 341             error_color(':', 'yellow'),
 342             $version;
 343
 344     return;
 345 }
 346 sub error_hardening_wrapper {
 347     printf "%s%s %s\n",
 348             error_color('HARDENING WRAPPER', 'red'),
 349             error_color(':', 'yellow'),
 350             'no checks possible, aborting';
 351
 352     return;
 353 }
 354 sub error_color {
 355     my ($message, $color) = @_;
 356
 357     if ($option_color) {
 358         return Term::ANSIColor::colored($message, $color);
 359     } else {
 360         return $message;
 361     }
 362 }
 363
 364 sub any_flags_used {
 365     my ($line, @flags) = @_;
 366
 367     foreach my $flag (@flags) {
 368         return 1 if $line =~ /$flag/;
 369     }
 370
 371     return 0;
 372 }
 373 sub all_flags_used {
 374     my ($line, $missing_flags_ref, @flags) = @_;
 375
 376     my @missing_flags = ();
 377     foreach my $flag (@flags) {
 378         if (not $line =~ /$flag/) {
 379             push @missing_flags, $flag;
 380         }
 381     }
 382
 383     return 1 if scalar @missing_flags == 0;
 384
 385     @{$missing_flags_ref} = @missing_flags;
 386     return 0;
 387 }
 388
 389 sub cppflags_fortify_broken {
 390     my ($line, $missing_flags) = @_;
 391
 392     # This doesn't take the position into account, but is a simple solution.
 393     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 394     # is wrong anyway.
 395
 396     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 397         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 398         push @{$missing_flags}, $def_cppflags_fortify[0];
 399         return 1;
 400     }
 401
 402     return 0;
 403 }
 404
 405 # Modifies $missing_flags_ref array.
 406 sub pic_pie_conflict {
 407     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 408
 409     return 0 if not $pie;
 410     return 0 if not any_flags_used($line, @def_ldflags_pic);
 411
 412     my %flags = map { $_ => 1 } @flags_pie;
 413
 414     # Remove all PIE flags from @missing_flags as they are not required with
 415     # -fPIC.
 416     my @result = grep {
 417         not exists $flags{$_}
 418     } @{$missing_flags_ref};
 419     @{$missing_flags_ref} = @result;
 420
 421     # We got a conflict when no flags are left, thus only PIE flags were
 422     # missing. If other flags were missing abort because the conflict is not
 423     # the problem.
 424     return scalar @result == 0;
 425 }
 426
 427 sub is_non_verbose_build {
 428     my ($line, $next_line, $skip_ref) = @_;
 429
 430     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 431                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 432                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 433                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 434                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 435         return 0;
 436     }
 437
 438     # False positives.
 439     #
 440     # C++ compiler setting.
 441     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 442     # "Compiling" with no file name.
 443     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 444         # $file_extension_regex may need spaces around the filename.
 445         return 0 if not " $1 " =~ /$file_extension_regex/o;
 446     }
 447
 448     my $file = $1;
 449
 450     # On the first pass we only check if this line is verbose or not.
 451     return 1 if not defined $next_line;
 452
 453     # Second pass, we have access to the next line.
 454     ${$skip_ref} = 0;
 455
 456     # CMake and other build systems print the non-verbose messages also when
 457     # building verbose. If a compiler and the file name occurs in the next
 458     # line, treat it as verbose build.
 459     if (defined $file) {
 460         # Get filename, we can't use the complete path as only parts of it are
 461         # used in the real compiler command.
 462         $file =~ m{/([^/\s]+)$};
 463         $file = $1;
 464
 465         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 466             # Not a non-verbose line, but we still have to skip the current line
 467             # as it doesn't contain any compiler commands.
 468             ${$skip_ref} = 1;
 469             return 0;
 470         }
 471     }
 472
 473     return 1;
 474 }
 475
 476 sub remove_flags {
 477     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 478
 479     my %removes = map { $_ => 1 } @flags;
 480     foreach my $flags (@{$flag_refs_ref}) {
 481         @{$flags} = grep {
 482             # Flag found as string.
 483             not exists $removes{$_}
 484             # Flag found as string representation of regexp.
 485                 and (not defined $flag_renames_ref->{$_}
 486                         or not exists $removes{$flag_renames_ref->{$_}})
 487         } @{$flags};
 488     }
 489
 490     return;
 491 }
 492
 493 sub compile_flag_regexp {
 494     my ($flag_renames_ref, @flags) = @_;
 495
 496     my @result = ();
 497     foreach my $flag (@flags) {
 498         # Store flag name in replacement string for correct flags in messages
 499         # with qr//ed flag regexps.
 500         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 501             = (exists $flag_renames_ref->{$flag})
 502                 ? $flag_renames_ref->{$flag}
 503                 : $flag;
 504
 505         # Compile flag regexp for faster execution.
 506         push @result, qr/\s$flag(?:\s|\\)/;
 507     }
 508     return @result;
 509 }
 510
 511 sub extension_found {
 512     my ($extensions_ref, @extensions) = @_;
 513
 514     my $found = 0;
 515     foreach my $extension (@extensions) {
 516         if (exists $extensions_ref->{$extension}) {
 517             $found = 1;
 518             last;
 519         }
 520     }
 521     return $found;
 522 }
 523
 524
 525 # MAIN
 526
 527 # Parse command line arguments.
 528 my $option_help             = 0;
 529 my $option_version          = 0;
 530 my $option_pie              = 0;
 531 my $option_bindnow          = 0;
 532 my @option_ignore_arch      = ();
 533 my @option_ignore_flag      = ();
 534 my @option_ignore_arch_flag = ();
 535 my @option_ignore_line      = ();
 536 my @option_ignore_arch_line = ();
 537 my $option_all              = 0;
 538 my $option_arch             = undef;
 539 my $option_buildd           = 0;
 540    $option_color            = 0;
 541 if (not Getopt::Long::GetOptions(
 542             'help|h|?'           => \$option_help,
 543             'version'            => \$option_version,
 544             # Hardening options.
 545             'pie'                => \$option_pie,
 546             'bindnow'            => \$option_bindnow,
 547             'all'                => \$option_all,
 548             # Ignore.
 549             'ignore-arch=s'      => \@option_ignore_arch,
 550             'ignore-flag=s'      => \@option_ignore_flag,
 551             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 552             'ignore-line=s'      => \@option_ignore_line,
 553             'ignore-arch-line=s' => \@option_ignore_arch_line,
 554             # Misc.
 555             'color'              => \$option_color,
 556             'arch=s'             => \$option_arch,
 557             'buildd'             => \$option_buildd,
 558         )) {
 559     require Pod::Usage;
 560     Pod::Usage::pod2usage(2);
 561 }
 562 if ($option_help) {
 563     require Pod::Usage;
 564     Pod::Usage::pod2usage(1);
 565 }
 566 if ($option_version) {
 567     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 568
 569 This program is free software: you can redistribute it and/or modify
 570 it under the terms of the GNU General Public License as published by
 571 the Free Software Foundation, either version 3 of the License, or
 572 (at your option) any later version.
 573
 574 This program is distributed in the hope that it will be useful,
 575 but WITHOUT ANY WARRANTY; without even the implied warranty of
 576 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 577 GNU General Public License for more details.
 578
 579 You should have received a copy of the GNU General Public License
 580 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 581 ";
 582     exit 0;
 583 }
 584
 585 # Arguments missing.
 586 if (scalar @ARGV == 0) {
 587     require Pod::Usage;
 588     Pod::Usage::pod2usage(2);
 589 }
 590
 591 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 592 # installed on Debian's buildds.
 593 if (not $option_buildd) {
 594     require Term::ANSIColor;
 595 }
 596
 597 if ($option_all) {
 598     $option_pie     = 1;
 599     $option_bindnow = 1;
 600 }
 601
 602 # Precompiled ignores for faster lookup.
 603 my %option_ignore_arch_flag = ();
 604 my %option_ignore_arch_line = ();
 605
 606 # Strip flags which should be ignored.
 607 if (scalar @option_ignore_flag > 0) {
 608     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 609 }
 610 # Same for arch specific ignore flags, but only prepare here.
 611 if (scalar @option_ignore_arch_flag > 0) {
 612     foreach my $ignore (@option_ignore_arch_flag) {
 613         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 614
 615         if (not $ignore_arch or not $ignore_flag) {
 616             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 617                         . '("arch:flag" expected)' . "\n", $ignore;
 618             require Pod::Usage;
 619             Pod::Usage::pod2usage(2);
 620         }
 621
 622         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 623     }
 624 }
 625
 626 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 627 # faster with this.
 628 foreach my $flags (@flag_refs_all) {
 629     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 630 }
 631
 632 # Precompile ignore line regexps, also anchor at beginning and end of line.
 633 foreach my $ignore (@option_ignore_line) {
 634     $ignore = qr/^$ignore$/;
 635 }
 636 # Same for arch specific ignore lines.
 637 if (scalar @option_ignore_arch_line > 0) {
 638     foreach my $ignore (@option_ignore_arch_line) {
 639         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 640
 641         if (not $ignore_arch or not $ignore_line) {
 642             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 643                         . '("arch:line" expected)' . "\n", $ignore;
 644             require Pod::Usage;
 645             Pod::Usage::pod2usage(2);
 646         }
 647
 648         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 649     }
 650 }
 651
 652 # Final exit code.
 653 my $exit = 0;
 654
 655 FILE:
 656 foreach my $file (@ARGV) {
 657     print "checking '$file'...\n" if scalar @ARGV > 1;
 658
 659     -f $file or die "No such file: $file";
 660
 661     open my $fh, '<', $file or die $!;
 662
 663     # Architecture of this file.
 664     my $arch = $option_arch;
 665
 666     # Hardening options. Not all architectures support all hardening options.
 667     my $harden_format  = 1;
 668     my $harden_fortify = 1;
 669     my $harden_stack   = 1;
 670     my $harden_relro   = 1;
 671     my $harden_bindnow = $option_bindnow; # defaults to 0
 672     my $harden_pie     = $option_pie;     # defaults to 0
 673
 674     # Does this build log use ada? Ada also uses gcc as compiler but uses
 675     # different CFLAGS. But only perform ada checks if an ada compiler used
 676     # for performance reasons.
 677     my $ada = 0;
 678
 679     while (my $line = <$fh>) {
 680         # Detect architecture automatically unless overridden. For buildd logs
 681         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 682         # build logs which aren't built (wrong architecture, build error,
 683         # etc.).
 684         if (not $arch and index($line, 'Architecture: ') == 0) {
 685             $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 686         }
 687
 688         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 689         # check for hardening flags in buildd mode if an older dpkg-dev is
 690         # used. Default flags (-g -O2) are still checked.
 691         #
 692         # Packages which were built before 1.16.1 but used their own hardening
 693         # flags are not checked.
 694         if ($option_buildd
 695                 and index($line, 'Toolchain package versions: ') == 0) {
 696             require Dpkg::Version;
 697             if (not $line =~ /\bdpkg-dev_(\S+)/
 698                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 699                 $harden_format  = 0;
 700                 $harden_fortify = 0;
 701                 $harden_stack   = 0;
 702                 $harden_relro   = 0;
 703                 $harden_bindnow = 0;
 704                 $harden_pie     = 0;
 705             }
 706         }
 707
 708         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 709         # this was later dropped because upstream rejected the patch. Thus
 710         # build logs with these versions will have fortify hardening flags
 711         # enabled, even though they may be not correctly set and are missing
 712         # when build with later CMake versions. Thanks to Aron Xu for letting
 713         # me know.
 714         if (index($line, 'Package versions: ') == 0
 715                 and $line =~ /\bcmake_(\S+)/
 716                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 717             if (not $option_buildd) {
 718                 error_invalid_cmake($1);
 719                 $exit |= $exit_code{invalid_cmake};
 720             } else {
 721                 print "$buildd_tag{invalid_cmake}|$1|\n";
 722             }
 723         }
 724
 725         if (index($line, 'Build-Depends: ') == 0) {
 726             # If hardening wrapper is used (wraps calls to gcc and adds
 727             # hardening flags automatically) we can't perform any checks,
 728             # abort.
 729             if ($line =~ /\bhardening-wrapper\b/) {
 730                 if (not $option_buildd) {
 731                     error_hardening_wrapper();
 732                     $exit |= $exit_code{hardening_wrapper};
 733                 } else {
 734                     print "$buildd_tag{hardening_wrapper}||\n";
 735                 }
 736                 next FILE;
 737             }
 738
 739             # Ada compiler.
 740             if ($line =~ /\bgnat\b/) {
 741                 $ada = 1;
 742             }
 743         }
 744
 745         # We skip over unimportant lines at the beginning of the log to
 746         # prevent false positives.
 747         last if index($line, 'dpkg-buildpackage: ') == 0;
 748     }
 749
 750     # Input lines, contain only the lines with compiler commands.
 751     my @input = ();
 752     # Non-verbose lines in the input. Used to reduce calls to
 753     # is_non_verbose_build() (which is quite slow) in the second loop when
 754     # it's already clear if a line is non-verbose or not.
 755     my @input_nonverbose = ();
 756
 757     my $continuation = 0;
 758     my $complete_line = undef;
 759     while (my $line = <$fh>) {
 760         # And stop at the end of the build log. Package details (reported by
 761         # the buildd logs) are not important for us. This also prevents false
 762         # positives.
 763         last if index($line, 'Build finished at ') == 0
 764                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 765
 766         # Detect architecture automatically unless overridden.
 767         if (not $arch
 768                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 769             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 770         }
 771
 772         # Ignore compiler warnings for now.
 773         next if $line =~ /$warning_regex/o;
 774
 775         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 776             # Remove all ANSI color sequences which are sometimes used in
 777             # non-verbose builds.
 778             $line = Term::ANSIColor::colorstrip($line);
 779             # Also strip '\0xf' (delete previous character), used by Elinks'
 780             # build system.
 781             $line =~ s/\x0f//g;
 782             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 783             # what it does).
 784             $line =~ s/\033\(B//g;
 785         }
 786
 787         # Check if this line indicates a non verbose build.
 788         my $non_verbose = is_non_verbose_build($line);
 789
 790         # One line may contain multiple commands (";"). Treat each one as
 791         # single line. parse_line() is slow, only use it when necessary.
 792         my @line = (index($line, ';') == -1)
 793                  ? ($line)
 794                  : map {
 795                        # Ensure newline at the line end - necessary for
 796                        # correct parsing later.
 797                        $_ =~ s/\s+$//;
 798                        $_ .= "\n";
 799                    } Text::ParseWords::parse_line(';', 1, $line);
 800         foreach my $line (@line) {
 801             if ($continuation) {
 802                 $continuation = 0;
 803
 804                 # Join lines, but leave the "\" in place so it's clear where
 805                 # the original line break was.
 806                 chomp $complete_line;
 807                 $complete_line .= ' ' . $line;
 808             }
 809             # Line continuation, line ends with "\".
 810             if ($line =~ /\\$/) {
 811                 $continuation = 1;
 812                 # Start line continuation.
 813                 if (not defined $complete_line) {
 814                     $complete_line = $line;
 815                 }
 816                 next;
 817             }
 818
 819             # Use the complete line if a line continuation occurred.
 820             if (defined $complete_line) {
 821                 $line = $complete_line;
 822                 $complete_line = undef;
 823             }
 824
 825             # Ignore lines with no compiler commands.
 826             next if not $non_verbose
 827                     and not $line =~ /$cc_regex_normal/o;
 828             # Ignore lines with no filenames with extensions. May miss some
 829             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 830             # a problem as the log will most likely contain other non-verbose
 831             # commands which are detected.
 832             next if not $non_verbose
 833                     and not $line =~ /$file_extension_regex/o;
 834
 835             # Ignore false positives.
 836             #
 837             # `./configure` output.
 838             next if not $non_verbose
 839                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 840             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 841                                 [Cc]ompiler[\s.]*:?\s+
 842                                 /x;
 843             next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 844             # `moc-qt4`, contains '-I/usr/share/qt4/mkspecs/linux-g++' (or
 845             # similar for other architectures) which gets recognized as a
 846             # compiler line. Ignore it.
 847             next if $line =~ m{^/usr/bin/moc-qt4
 848                                \s.+\s
 849                                -I/usr/share/qt4/mkspecs/[a-z]+-g\++(?:-64)?
 850                                \s}x;
 851             # Ignore false positives when the line contains only CC=gcc but no
 852             # other gcc command.
 853             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 854                 my $before = $1;
 855                 my $after  = $2;
 856                 next if     not $before =~ /$cc_regex_normal/o
 857                         and not $after  =~ /$cc_regex_normal/o;
 858             }
 859
 860             # Check if additional hardening options were used. Used to ensure
 861             # they are used for the complete build.
 862             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 863                                                          @def_ldflags_pie);
 864             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 865
 866             push @input, $line;
 867             push @input_nonverbose, $non_verbose;
 868         }
 869     }
 870
 871     close $fh or die $!;
 872
 873     # Ignore arch if requested.
 874     if (scalar @option_ignore_arch > 0 and $arch) {
 875         foreach my $ignore (@option_ignore_arch) {
 876             if ($arch eq $ignore) {
 877                 print "ignoring architecture '$arch'\n";
 878                 next FILE;
 879             }
 880         }
 881     }
 882
 883     if (scalar @input == 0) {
 884         if (not $option_buildd) {
 885             print "No compiler commands!\n";
 886             $exit |= $exit_code{no_compiler_commands};
 887         } else {
 888             print "$buildd_tag{no_compiler_commands}||\n";
 889         }
 890         next FILE;
 891     }
 892
 893     if ($option_buildd) {
 894         $statistics{commands} += scalar @input;
 895     }
 896
 897     # Option or auto detected.
 898     if ($arch) {
 899         # The following was partially copied from dpkg-dev 1.16.4.3
 900         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 901         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 902         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 903         # later. Keep it in sync.
 904
 905         require Dpkg::Arch;
 906         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 907
 908         # Disable unsupported hardening options.
 909         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 910             $harden_stack = 0;
 911         }
 912         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 913             $harden_relro   = 0;
 914             $harden_bindnow = 0;
 915         }
 916     }
 917
 918     # Default values.
 919     my @cflags   = @def_cflags;
 920     my @cxxflags = @def_cxxflags;
 921     my @cppflags = @def_cppflags;
 922     my @ldflags  = @def_ldflags;
 923     # Check the specified hardening options, same order as dpkg-buildflags.
 924     if ($harden_pie) {
 925         @cflags   = (@cflags,   @def_cflags_pie);
 926         @cxxflags = (@cxxflags, @def_cflags_pie);
 927         @ldflags  = (@ldflags,  @def_ldflags_pie);
 928     }
 929     if ($harden_stack) {
 930         @cflags   = (@cflags,   @def_cflags_stack);
 931         @cxxflags = (@cxxflags, @def_cflags_stack);
 932     }
 933     if ($harden_fortify) {
 934         @cflags   = (@cflags,   @def_cflags_fortify);
 935         @cxxflags = (@cxxflags, @def_cflags_fortify);
 936         @cppflags = (@cppflags, @def_cppflags_fortify);
 937     }
 938     if ($harden_format) {
 939         @cflags   = (@cflags,   @def_cflags_format);
 940         @cxxflags = (@cxxflags, @def_cflags_format);
 941     }
 942     if ($harden_relro) {
 943         @ldflags = (@ldflags, @def_ldflags_relro);
 944     }
 945     if ($harden_bindnow) {
 946         @ldflags = (@ldflags, @def_ldflags_bindnow);
 947     }
 948
 949     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 950     my @cflags_backup;
 951     # Ada CFLAGS.
 952     my @cflags_ada = @cflags;
 953     # Ada doesn't support format hardening flags, see #680117 for more
 954     # information. Filter them out if ada is used.
 955     if ($ada and $harden_format) {
 956         @cflags_ada = grep {
 957             my $ok = 1;
 958             foreach my $flag (@def_cflags_format) {
 959                 $ok = 0 if $_ eq $flag;
 960             }
 961             $ok;
 962         } @cflags;
 963     }
 964
 965     # Hack to fix cppflags_fortify_broken() if --ignore-flag
 966     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
 967     # as long as @def_cppflags_fortify contains only one variable.
 968     if (scalar @def_cppflags_fortify == 0) {
 969         $harden_fortify = 0;
 970     }
 971
 972     # Ignore flags for this arch if requested.
 973     if ($arch and exists $option_ignore_arch_flag{$arch}) {
 974         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
 975
 976         remove_flags(\@local_flag_refs,
 977                      \%flag_renames,
 978                      @{$option_ignore_arch_flag{$arch}});
 979     }
 980
 981     my @ignore_line = @option_ignore_line;
 982     # Ignore lines for this arch if requested.
 983     if ($arch and exists $option_ignore_arch_line{$arch}) {
 984         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
 985     }
 986
 987 LINE:
 988     for (my $i = 0; $i < scalar @input; $i++) {
 989         my $line = $input[$i];
 990
 991         # Ignore line if requested.
 992         foreach my $ignore (@ignore_line) {
 993             next LINE if $line =~ /$ignore/;
 994         }
 995
 996         my $skip = 0;
 997         if ($input_nonverbose[$i]
 998                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 999             if (not $option_buildd) {
1000                 error_non_verbose_build($line);
1001                 $exit |= $exit_code{non_verbose_build};
1002             } else {
1003                 $statistics{commands_nonverbose}++;
1004             }
1005             next;
1006         }
1007         # Even if it's a verbose build, we might have to skip this line.
1008         next if $skip;
1009
1010         # Remove everything until and including the compiler command. Makes
1011         # checks easier and faster.
1012         $line =~ s/^.*?$cc_regex//o;
1013         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1014         # the brace and similar characters at the line end.
1015         $line =~ s/['")]+$//;
1016
1017         # Skip unnecessary tests when only preprocessing.
1018         my $flag_preprocess = 0;
1019
1020         my $dependency = 0;
1021         my $preprocess = 0;
1022         my $compile    = 0;
1023         my $link       = 0;
1024
1025         # Preprocess, compile, assemble.
1026         if ($line =~ /\s(-E|-S|-c)\b/) {
1027             $preprocess      = 1;
1028             $flag_preprocess = 1 if $1 eq '-E';
1029             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1030         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1031         # -MT -MQ) are always used with -M/-MM.
1032         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1033             $dependency = 1;
1034         # Otherwise assume we are linking.
1035         } else {
1036             $link = 1;
1037         }
1038
1039         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1040         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1041             $dependency      = 0;
1042             $flag_preprocess = 0;
1043         }
1044
1045         # Dependency generation for Makefiles, no preprocessing or other flags
1046         # needed.
1047         next if $dependency;
1048
1049         # Get all file extensions on this line.
1050         my @extensions = $line =~ /$file_extension_regex/go;
1051         # Ignore all unknown extensions to speedup the search below.
1052         @extensions = grep { exists $extension{$_} } @extensions;
1053
1054         # These file types don't require preprocessing.
1055         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1056             $preprocess = 0;
1057         }
1058         # These file types require preprocessing.
1059         if (extension_found(\%extensions_preprocess, @extensions)) {
1060             $preprocess = 1;
1061         }
1062
1063         if (not $flag_preprocess) {
1064             # If there are source files then it's compiling/linking in one
1065             # step and we must check both. We only check for source files
1066             # here, because header files cause too many false positives.
1067             if (extension_found(\%extensions_compile_link, @extensions)) {
1068                 # Assembly files don't need CFLAGS.
1069                 if (not extension_found(\%extensions_compile, @extensions)
1070                         and extension_found(\%extensions_no_compile, @extensions)) {
1071                     $compile = 0;
1072                 # But the rest does.
1073                 } else {
1074                     $compile = 1;
1075                 }
1076             # No compilable extensions found, either linking or compiling
1077             # header flags.
1078             #
1079             # If there are also no object files we are just compiling headers
1080             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1081             # to our liberal checks for compiler lines, this also reduces the
1082             # number of false positives considerably.
1083             } elsif ($link
1084                     and not extension_found(\%extensions_object, @extensions)) {
1085                 $link = 0;
1086             }
1087         }
1088
1089         my $compile_cpp = 0;
1090         my $compile_ada = 0;
1091         # Assume CXXFLAGS are required when a C++ file is specified in the
1092         # compiler line.
1093         if ($compile
1094                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1095             $compile     = 0;
1096             $compile_cpp = 1;
1097         # Ada needs special CFLAGS, use them if only ada files are compiled.
1098         } elsif ($ada
1099                     and $compile
1100                     and array_equal(\@extensions,
1101                                     \@source_no_preprocess_compile_ada)) {
1102             $compile_ada = 1;
1103             @cflags_backup = @cflags;
1104             @cflags        = @cflags_ada;
1105         }
1106
1107         if ($option_buildd) {
1108             $statistics{preprocess}++  if $preprocess;
1109             $statistics{compile}++     if $compile;
1110             $statistics{compile_cpp}++ if $compile_cpp;
1111             $statistics{link}++        if $link;
1112         }
1113
1114         # Check hardening flags.
1115         my @missing;
1116         if ($compile and not all_flags_used($line, \@missing, @cflags)
1117                 # Libraries linked with -fPIC don't have to (and can't) be
1118                 # linked with -fPIE as well. It's no error if only PIE flags
1119                 # are missing.
1120                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1121                 # Assume dpkg-buildflags returns the correct flags.
1122                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1123             if (not $option_buildd) {
1124                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1125                 $exit |= $exit_code{flags_missing};
1126             } else {
1127                 $statistics{compile_missing}++;
1128             }
1129         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1130                 # Libraries linked with -fPIC don't have to (and can't) be
1131                 # linked with -fPIE as well. It's no error if only PIE flags
1132                 # are missing.
1133                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1134                 # Assume dpkg-buildflags returns the correct flags.
1135                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1136             if (not $option_buildd) {
1137                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1138                 $exit |= $exit_code{flags_missing};
1139             } else {
1140                 $statistics{compile_cpp_missing}++;
1141             }
1142         }
1143         if ($preprocess
1144                 and (not all_flags_used($line, \@missing, @cppflags)
1145                     # The fortify flag might be overwritten, detect that.
1146                      or ($harden_fortify
1147                          and cppflags_fortify_broken($line, \@missing)))
1148                 # Assume dpkg-buildflags returns the correct flags.
1149                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1150             if (not $option_buildd) {
1151                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1152                 $exit |= $exit_code{flags_missing};
1153             } else {
1154                 $statistics{preprocess_missing}++;
1155             }
1156         }
1157         if ($link and not all_flags_used($line, \@missing, @ldflags)
1158                 # Same here, -fPIC conflicts with -fPIE.
1159                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1160                 # Assume dpkg-buildflags returns the correct flags.
1161                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1162             if (not $option_buildd) {
1163                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1164                 $exit |= $exit_code{flags_missing};
1165             } else {
1166                 $statistics{link_missing}++;
1167             }
1168         }
1169
1170         # Restore normal CFLAGS.
1171         if ($compile_ada) {
1172             @cflags = @cflags_backup;
1173         }
1174     }
1175 }
1176
1177 # Print statistics for buildd mode, only output in this mode.
1178 if ($option_buildd) {
1179     my @warning;
1180
1181     if ($statistics{preprocess_missing}) {
1182         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1183                                $statistics{preprocess_missing},
1184                                $statistics{preprocess};
1185     }
1186     if ($statistics{compile_missing}) {
1187         push @warning, sprintf 'CFLAGS %d (of %d)',
1188                                $statistics{compile_missing},
1189                                $statistics{compile};
1190     }
1191     if ($statistics{compile_cpp_missing}) {
1192         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1193                                $statistics{compile_cpp_missing},
1194                                $statistics{compile_cpp};
1195     }
1196     if ($statistics{link_missing}) {
1197         push @warning, sprintf 'LDFLAGS %d (of %d)',
1198                                $statistics{link_missing},
1199                                $statistics{link};
1200     }
1201     if (scalar @warning) {
1202         local $" = ', '; # array join string
1203         print "$buildd_tag{flags_missing}|@warning missing|\n";
1204     }
1205
1206     if ($statistics{commands_nonverbose}) {
1207         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1208                $statistics{commands_nonverbose},
1209                $statistics{commands},
1210     }
1211 }
1212
1213
1214 exit $exit;
1215
1216
1217 __END__
1218
1219 =head1 NAME
1220
1221 blhc - build log hardening check, checks build logs for missing hardening flags
1222
1223 =head1 SYNOPSIS
1224
1225 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1226
1227 =head1 DESCRIPTION
1228
1229 blhc is a small tool which checks build logs for missing hardening flags. It's
1230 licensed under the GPL 3 or later.
1231
1232 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1233 tools using dpkg-buildpackage like pbuilder or the official buildd build logs)
1234 to help maintainers detect missing hardening flags in their packages.
1235
1236 Only gcc is detected as compiler at the moment. If other compilers support
1237 hardening flags as well, please report them.
1238
1239 If there's no output, no flags are missing and the build log is fine.
1240
1241 =head1 OPTIONS
1242
1243 =over 8
1244
1245 =item B<--all>
1246
1247 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1248 auto detected.
1249
1250 =item B<--arch> I<architecture>
1251
1252 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1253 disables hardening flags not available on this architecture. Is detected
1254 automatically if dpkg-buildpackage is used.
1255
1256 =item B<--bindnow>
1257
1258 Force check for all +bindnow hardening flags. By default it's auto detected.
1259
1260 =item B<--buildd>
1261
1262 Special mode for buildds when automatically parsing log files. The following
1263 changes are in effect:
1264
1265 =over 2
1266
1267 =item *
1268
1269 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1270 possible tags.
1271
1272 =item *
1273
1274 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1275 detected).
1276
1277 =item *
1278
1279 Don't require Term::ANSIColor.
1280
1281 =item *
1282
1283 Return exit code 0, unless there was a error (-I, -W messages don't count as
1284 error).
1285
1286 =back
1287
1288 =item B<--color>
1289
1290 Use colored (ANSI) output for warning messages.
1291
1292 =item B<--ignore-arch> I<arch>
1293
1294 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1295
1296 Used to prevent false positives. This option can be specified multiple times.
1297
1298 =item B<--ignore-arch-flag> I<arch>:I<flag>
1299
1300 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1301
1302 =item B<--ignore-arch-line> I<arch>:I<line>
1303
1304 Like B<--ignore-line>, but only ignore line on I<arch>.
1305
1306 =item B<--ignore-flag> I<flag>
1307
1308 Don't print an error when the specific flag is missing in a compiler line.
1309 I<flag> is a string.
1310
1311 Used to prevent false positives. This option can be specified multiple times.
1312
1313 =item B<--ignore-line> I<regex>
1314
1315 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1316 at the beginning and end of the line to prevent false negatives.
1317
1318 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1319 warnings (which have line continuation resolved).
1320
1321 Used to prevent false positives. This option can be specified multiple times.
1322
1323 =item B<--pie>
1324
1325 Force check for all +pie hardening flags. By default it's auto detected.
1326
1327 =item B<-h -? --help>
1328
1329 Print available options.
1330
1331 =item B<--version>
1332
1333 Print version number and license.
1334
1335 =back
1336
1337 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1338 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1339 all other commands as well.
1340
1341 =head1 EXAMPLES
1342
1343 Normal usage, parse a single log file.
1344
1345     blhc path/to/log/file
1346
1347 If there's no output, no flags are missing and the build log is fine.
1348
1349 Parse multiple log files. The exit code is ORed over all files.
1350
1351     blhc path/to/directory/with/log/files/*
1352
1353 Don't treat missing C<-g> as error:
1354
1355     blhc --ignore-flag -g path/to/log/file
1356
1357 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1358
1359     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1360
1361 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1362 false positive.
1363
1364     blhc --ignore-line '\./script gcc file' path/to/log/file
1365
1366 Ignore lines matching C<./script gcc file> somewhere in the line.
1367
1368     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1369
1370 Use blhc with pbuilder.
1371
1372     pbuilder path/to/package.dsc | tee path/log/file
1373     blhc path/to/file || echo flags missing
1374
1375 =head1 BUILDD TAGS
1376
1377 The following tags are used in I<--buildd> mode. In braces the additional data
1378 which is displayed.
1379
1380 =over 2
1381
1382 =item B<I-hardening-wrapper-used>
1383
1384 The package uses hardening-wrapper which intercepts calls to gcc and adds
1385 hardening flags. The build log doesn't contain any hardening flags and thus
1386 can't be checked by blhc.
1387
1388 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1389
1390 Build log contains lines which hide the real compiler flags. For example:
1391
1392     CC test-a.c
1393     CC test-b.c
1394     CC test-c.c
1395     LD test
1396
1397 Most of the time either C<export V=1> or C<export verbose=1> in
1398 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1399 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1400 patched to remove the C<@>s hiding the real compiler commands.
1401
1402 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1403
1404 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1405
1406 =item B<I-invalid-cmake-used> (version)
1407
1408 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1409 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1410 patch was rejected by upstream and later reverted in Debian. Thus those two
1411 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1412 handle them (for example by passing them to CFLAGS). To prevent false
1413 negatives just blacklist those two versions.
1414
1415 =item B<I-no-compiler-commands>
1416
1417 No compiler commands were detected. Either the log contains none or they were
1418 not correctly detected by blhc (please report the bug in this case).
1419
1420 =back
1421
1422 =head1 EXIT STATUS
1423
1424 The exit status is a "bit mask", each listed status is ORed when the error
1425 condition occurs to get the result.
1426
1427 =over 4
1428
1429 =item B<0>
1430
1431 Success.
1432
1433 =item B<1>
1434
1435 No compiler commands were found.
1436
1437 =item B<2>
1438
1439 Invalid arguments/options given to blhc.
1440
1441 =item B<4>
1442
1443 Non verbose build.
1444
1445 =item B<8>
1446
1447 Missing hardening flags.
1448
1449 =item B<16>
1450
1451 Hardening wrapper detected, no tests performed.
1452
1453 =item B<32>
1454
1455 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1456 TAGS"> for a detailed explanation.
1457
1458 =back
1459
1460 =head1 AUTHOR
1461
1462 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1463
1464 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1465 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1466
1467 =head1 LICENSE AND COPYRIGHT
1468
1469 Copyright (C) 2012 by Simon Ruderich
1470
1471 This program is free software: you can redistribute it and/or modify
1472 it under the terms of the GNU General Public License as published by
1473 the Free Software Foundation, either version 3 of the License, or
1474 (at your option) any later version.
1475
1476 This program is distributed in the hope that it will be useful,
1477 but WITHOUT ANY WARRANTY; without even the implied warranty of
1478 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1479 GNU General Public License for more details.
1480
1481 You should have received a copy of the GNU General Public License
1482 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1483
1484 =head1 SEE ALSO
1485
1486 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1487
1488 =cut