bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.01';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
  35     (?:-[\d.]+)?
  36     /x;
  37 # Full regex which matches the complete compiler name. Used in a few places to
  38 # prevent false negatives.
  39 my $cc_regex_full = qr/
  40     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  41     $cc_regex
  42     /x;
  43 # Regex to catch (GCC) compiler warnings.
  44 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  45
  46 # List of source file extensions which require preprocessing.
  47 my @source_preprocess_compile_cpp = (
  48     # C++
  49     qw( cc cp cxx cpp CPP c++ C ),
  50     # Objective-C++
  51     qw( mm Mr),
  52 );
  53 my @source_preprocess_compile = (
  54     # C
  55     qw( c ),
  56     # Objective-C
  57     qw( m ),
  58     # (Objective-)C++
  59     @source_preprocess_compile_cpp,
  60     # Fortran
  61     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  62 );
  63 my @source_preprocess_no_compile = (
  64     # Assembly
  65     qw( s ),
  66 );
  67 my @source_preprocess = (
  68     @source_preprocess_compile,
  69     @source_preprocess_no_compile,
  70 );
  71 # List of source file extensions which don't require preprocessing.
  72 my @source_no_preprocess_compile_cpp = (
  73     # C++
  74     qw( ii ),
  75     # Objective-C++
  76     qw( mii ),
  77 );
  78 my @source_no_preprocess_compile = (
  79     # C
  80     qw( i ),
  81     # (Objective-)C++
  82     @source_no_preprocess_compile_cpp,
  83     # Objective-C
  84     qw( mi ),
  85     # Fortran
  86     qw( f for ftn f90 f95 f03 f08 ),
  87 );
  88 my @source_no_preprocess_no_compile = (
  89     # Assembly
  90     qw( S sx ),
  91 );
  92 my @source_no_preprocess = (
  93     @source_no_preprocess_compile,
  94     @source_no_preprocess_no_compile,
  95 );
  96 # List of header file extensions which require preprocessing.
  97 my @header_preprocess = (
  98     # C, C++, Objective-C, Objective-C++
  99     qw( h ),
 100     # C++
 101     qw( hh H hp hxx hpp HPP h++ tcc ),
 102 );
 103
 104 # Hashes for fast extensions lookup to check if a file falls in one of these
 105 # categories.
 106 my %extensions_no_preprocess = map { $_ => 1 } (
 107     @source_no_preprocess,
 108 );
 109 my %extensions_preprocess = map { $_ => 1 } (
 110     @header_preprocess,
 111     @source_preprocess,
 112 );
 113 my %extensions_compile_link = map { $_ => 1 } (
 114     @source_preprocess,
 115     @source_no_preprocess,
 116 );
 117 my %extensions_compile = map { $_ => 1 } (
 118     @source_preprocess_compile,
 119     @source_no_preprocess_compile,
 120 );
 121 my %extensions_no_compile = map { $_ => 1 } (
 122     @source_preprocess_no_compile,
 123     @source_no_preprocess_no_compile,
 124 );
 125 my %extensions_compile_cpp = map { $_ => 1 } (
 126     @source_preprocess_compile_cpp,
 127     @source_no_preprocess_compile_cpp,
 128 );
 129 my %extension = map { $_ => 1 } (
 130     @source_no_preprocess,
 131     @header_preprocess,
 132     @source_preprocess,
 133 );
 134
 135 # Regexp to match file extensions.
 136 my $file_extension_regex = qr/
 137     \s
 138     \S+             # Filename without extension.
 139     \.
 140     ([^\/\\.,;:\s]+)# File extension.
 141     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 142                     # word characters at the end and because \b matches double
 143                     # extensions (like .cpp.o). Works always as all lines are
 144                     # terminated with "\n".
 145     /x;
 146
 147 # Expected (hardening) flags. All flags are used as regexps.
 148 my @def_cflags = (
 149     '-g',
 150     '-O(?:2|3)',
 151 );
 152 my @def_cflags_format = (
 153     '-Wformat',
 154     '-Wformat-security',
 155     '-Werror=format-security',
 156 );
 157 my @def_cflags_fortify = (
 158     # fortify needs at least -O1, but -O2 is recommended anyway
 159 );
 160 my @def_cflags_stack = (
 161     '-fstack-protector',
 162     '--param=ssp-buffer-size=4',
 163 );
 164 my @def_cflags_pie = (
 165     '-fPIE',
 166 );
 167 my @def_cxxflags = (
 168     @def_cflags,
 169 );
 170 # @def_cxxflags_* is the same as @def_cflags_*.
 171 my @def_cppflags = ();
 172 my @def_cppflags_fortify = (
 173     '-D_FORTIFY_SOURCE=2',
 174 );
 175 my @def_ldflags = ();
 176 my @def_ldflags_relro = (
 177     '-Wl,(?:-z,)?relro',
 178 );
 179 my @def_ldflags_bindnow = (
 180     '-Wl,(?:-z,)?now',
 181 );
 182 my @def_ldflags_pie = (
 183     '-fPIE',
 184     '-pie',
 185 );
 186 my @def_ldflags_pic = (
 187     '-fPIC',
 188     '-fpic',
 189     '-shared',
 190 );
 191 # References to all flags checked by the parser.
 192 my @flag_refs = (
 193     \@def_cflags,
 194     \@def_cflags_format,
 195     \@def_cflags_fortify,
 196     \@def_cflags_stack,
 197     \@def_cflags_pie,
 198     \@def_cxxflags,
 199     \@def_cppflags,
 200     \@def_cppflags_fortify,
 201     \@def_ldflags,
 202     \@def_ldflags_relro,
 203     \@def_ldflags_bindnow,
 204 );
 205 # References to all used flags.
 206 my @flag_refs_all = (
 207     @flag_refs,
 208     \@def_ldflags_pie,
 209     \@def_ldflags_pic,
 210 );
 211 # Renaming rules for the output so the regex parts are not visible. Also
 212 # stores string values of flag regexps above, see compile_flag_regexp().
 213 my %flag_renames = (
 214     '-O(?:2|3)'         => '-O2',
 215     '-Wl,(?:-z,)?relro' => '-Wl,-z,relro',
 216     '-Wl,(?:-z,)?now'   => '-Wl,-z,now',
 217 );
 218
 219 my %exit_code = (
 220     no_compiler_commands => 1 << 0,
 221     # used by POD::Usage => 1 << 1,
 222     non_verbose_build    => 1 << 2,
 223     flags_missing        => 1 << 3,
 224     hardening_wrapper    => 1 << 4,
 225     invalid_cmake        => 1 << 5,
 226 );
 227
 228 # Statistics of missing flags and non-verbose build commands. Used for
 229 # $option_buildd.
 230 my %statistics = (
 231     preprocess          => 0,
 232     preprocess_missing  => 0,
 233     compile             => 0,
 234     compile_missing     => 0,
 235     compile_cpp         => 0,
 236     compile_cpp_missing => 0,
 237     link                => 0,
 238     link_missing        => 0,
 239     commands            => 0,
 240     commands_nonverbose => 0,
 241 );
 242
 243 # Use colored (ANSI) output?
 244 my $option_color;
 245
 246
 247 # FUNCTIONS
 248
 249 sub error_flags {
 250     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 251
 252     # Get string value of qr//-escaped regexps and if requested rename them.
 253     my @missing_flags = map {
 254             $flag_renames_ref->{$_}
 255         } @{$missing_flags_ref};
 256
 257     my $flags = join ' ', @missing_flags;
 258     printf "%s (%s)%s %s",
 259            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 260            $line;
 261 }
 262 sub error_non_verbose_build {
 263     my ($line) = @_;
 264
 265     printf "%s%s %s",
 266            error_color('NONVERBOSE BUILD', 'red'),
 267            error_color(':', 'yellow'),
 268            $line;
 269 }
 270 sub error_invalid_cmake {
 271     my ($version) = @_;
 272
 273     printf "%s%s %s\n",
 274             error_color('INVALID CMAKE', 'red'),
 275             error_color(':', 'yellow'),
 276             $version;
 277 }
 278 sub error_hardening_wrapper {
 279     printf "%s%s %s\n",
 280             error_color('HARDENING WRAPPER', 'red'),
 281             error_color(':', 'yellow'),
 282             'no checks possible, aborting';
 283 }
 284 sub error_color {
 285     my ($message, $color) = @_;
 286
 287     if ($option_color) {
 288         return Term::ANSIColor::colored($message, $color);
 289     } else {
 290         return $message;
 291     }
 292 }
 293
 294 sub any_flags_used {
 295     my ($line, @flags) = @_;
 296
 297     foreach my $flag (@flags) {
 298         return 1 if $line =~ /$flag/;
 299     }
 300
 301     return 0;
 302 }
 303 sub all_flags_used {
 304     my ($line, $missing_flags_ref, @flags) = @_;
 305
 306     my @missing_flags = ();
 307     foreach my $flag (@flags) {
 308         if (not $line =~ /$flag/) {
 309             push @missing_flags, $flag;
 310         }
 311     }
 312
 313     return 1 if scalar @missing_flags == 0;
 314
 315     @{$missing_flags_ref} = @missing_flags;
 316     return 0;
 317 }
 318
 319 # Modifies $missing_flags_ref array.
 320 sub pic_pie_conflict {
 321     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 322
 323     return 0 if not $pie;
 324     return 0 if not any_flags_used($line, @def_ldflags_pic);
 325
 326     my %flags = map { $_ => 1 } @flags_pie;
 327
 328     # Remove all PIE flags from @missing_flags as they are not required with
 329     # -fPIC.
 330     my @result = grep {
 331         not exists $flags{$_}
 332     } @{$missing_flags_ref};
 333     @{$missing_flags_ref} = @result;
 334
 335     # We got a conflict when no flags are left, thus only PIE flags were
 336     # missing. If other flags were missing abort because the conflict is not
 337     # the problem.
 338     return scalar @result == 0;
 339 }
 340
 341 sub is_non_verbose_build {
 342     my ($line, $next_line, $skip_ref) = @_;
 343
 344     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 345                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 346                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 347                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 348                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 349         return 0;
 350     }
 351
 352     # False positives.
 353     #
 354     # C++ compiler setting.
 355     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 356     # "Compiling" with no file name.
 357     if ($line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/) {
 358         # $file_extension_regex may need spaces around the filename.
 359         return 0 if not " $1 " =~ /$file_extension_regex/o;
 360     }
 361
 362     my $file = $1;
 363
 364     # On the first pass we only check if this line is verbose or not.
 365     return 1 if not defined $next_line;
 366
 367     # Second pass, we have access to the next line.
 368     ${$skip_ref} = 0;
 369
 370     # CMake and other build systems print the non-verbose messages also when
 371     # building verbose. If a compiler and the file name occurs in the next
 372     # line, treat it as verbose build.
 373     if (defined $file) {
 374         # Get filename, we can't use the complete path as only parts of it are
 375         # used in the real compiler command.
 376         $file =~ m{/([^/\s]+)$};
 377         $file = $1;
 378
 379         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/o) {
 380             # We still have to skip the current line as it doesn't contain any
 381             # compiler commands.
 382             ${$skip_ref} = 1;
 383             return 0;
 384         }
 385     }
 386
 387     return 1;
 388 }
 389
 390 sub compile_flag_regexp {
 391     my ($flag_renames_ref, @flags) = @_;
 392
 393     my @result = ();
 394     foreach my $flag (@flags) {
 395         # Store flag name in replacement string for correct flags in messages
 396         # with qr//ed flag regexps.
 397         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 398             = (exists $flag_renames_ref->{$flag})
 399                 ? $flag_renames_ref->{$flag}
 400                 : $flag;
 401
 402         # Compile flag regexp for faster execution.
 403         push @result, qr/\s$flag(?:\s|\\)/;
 404     }
 405     return @result;
 406 }
 407
 408 sub extension_found {
 409     my ($extensions_ref, @extensions) = @_;
 410
 411     my $found = 0;
 412     foreach my $extension (@extensions) {
 413         if (exists $extensions_ref->{$extension}) {
 414             $found = 1;
 415             last;
 416         }
 417     }
 418     return $found;
 419 }
 420
 421
 422 # MAIN
 423
 424 # Parse command line arguments.
 425 my $option_help    = 0;
 426 my $option_version = 0;
 427 my $option_pie     = 0;
 428 my $option_bindnow = 0;
 429 my $option_all     = 0;
 430 my $option_arch    = undef;
 431 my $option_buildd  = 0;
 432    $option_color   = 0;
 433 if (not Getopt::Long::GetOptions(
 434             'help|h|?' => \$option_help,
 435             'version'  => \$option_version,
 436             # Hardening options.
 437             'pie'      => \$option_pie,
 438             'bindnow'  => \$option_bindnow,
 439             'all'      => \$option_all,
 440             # Misc.
 441             'color'    => \$option_color,
 442             'arch=s'   => \$option_arch,
 443             'buildd'   => \$option_buildd,
 444         )) {
 445     require Pod::Usage;
 446     Pod::Usage::pod2usage(2);
 447 }
 448 if ($option_help) {
 449     require Pod::Usage;
 450     Pod::Usage::pod2usage(1);
 451 }
 452 if ($option_version) {
 453     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 454
 455 This program is free software: you can redistribute it and/or modify
 456 it under the terms of the GNU General Public License as published by
 457 the Free Software Foundation, either version 3 of the License, or
 458 (at your option) any later version.
 459
 460 This program is distributed in the hope that it will be useful,
 461 but WITHOUT ANY WARRANTY; without even the implied warranty of
 462 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 463 GNU General Public License for more details.
 464
 465 You should have received a copy of the GNU General Public License
 466 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 467 ";
 468     exit 0;
 469 }
 470
 471 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 472 # installed on Debian's buildds.
 473 if (not $option_buildd) {
 474     require Term::ANSIColor;
 475 }
 476
 477 if ($option_all) {
 478     $option_pie     = 1;
 479     $option_bindnow = 1;
 480 }
 481
 482 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 483 # faster with this.
 484 foreach my $flags (@flag_refs_all) {
 485     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 486 }
 487
 488 # Final exit code.
 489 my $exit = 0;
 490
 491 FILE: foreach my $file (@ARGV) {
 492     print "checking '$file'...\n" if scalar @ARGV > 1;
 493
 494     open my $fh, '<', $file or die "$!: $file";
 495
 496     # Architecture of this file.
 497     my $arch = $option_arch;
 498
 499     # Hardening options. Not all architectures support all hardening options.
 500     my $harden_format  = 1;
 501     my $harden_fortify = 1;
 502     my $harden_stack   = 1;
 503     my $harden_relro   = 1;
 504     my $harden_bindnow = $option_bindnow; # defaults to 0
 505     my $harden_pie     = $option_pie;     # defaults to 0
 506
 507     while (my $line = <$fh>) {
 508         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 509         # check for hardening flags in buildd mode if an older dpkg-dev is
 510         # used. Default flags (-g -O2) are still checked.
 511         #
 512         # Packages which were built before 1.16.1 but used their own hardening
 513         # flags are not checked.
 514         if ($option_buildd and $line =~ /^Toolchain package versions: /) {
 515             require Dpkg::Version;
 516             if ($line !~ /\bdpkg-dev_(\S+)/
 517                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 518                 $harden_format  = 0;
 519                 $harden_fortify = 0;
 520                 $harden_stack   = 0;
 521                 $harden_relro   = 0;
 522                 $harden_bindnow = 0;
 523                 $harden_pie     = 0;
 524             }
 525         }
 526
 527         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 528         # this was later dropped because upstream rejected the patch. Thus
 529         # build logs with these versions will have fortify hardening flags
 530         # enabled, even though they may be not correctly set and are missing
 531         # when build with later CMake versions. Thanks to Aron Xu for letting
 532         # me know.
 533         if ($line =~ /^Package versions: /
 534                 and $line =~ /\bcmake_(\S+)/
 535                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 536             if (not $option_buildd) {
 537                 error_invalid_cmake($1);
 538             } else {
 539                 print "W-invalid-cmake-used $1\n";
 540             }
 541             $exit |= $exit_code{invalid_cmake};
 542         }
 543
 544         # If hardening wrapper is used (wraps calls to gcc and adds hardening
 545         # flags automatically) we can't perform any checks, abort.
 546         if ($line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
 547             if (not $option_buildd) {
 548                 error_hardening_wrapper();
 549             } else {
 550                 print "I-hardening-wrapper-used\n";
 551             }
 552             $exit |= $exit_code{hardening_wrapper};
 553             next FILE;
 554         }
 555
 556         # We skip over unimportant lines at the beginning of the log to
 557         # prevent false positives.
 558         last if $line =~ /^dpkg-buildpackage:/;
 559     }
 560
 561     # Input lines, contain only the lines with compiler commands.
 562     my @input = ();
 563
 564     my $continuation = 0;
 565     my $complete_line = undef;
 566     while (my $line = <$fh>) {
 567         # And stop at the end of the build log. Package details (reported by
 568         # the buildd logs) are not important for us. This also prevents false
 569         # positives.
 570         last if $line =~ /^Build finished at \d{8}-\d{4}$/;
 571
 572         # Detect architecture automatically unless overridden.
 573         if (not $arch
 574                 and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 575             $arch = $1;
 576         }
 577
 578         # Ignore compiler warnings for now.
 579         next if $line =~ /$warning_regex/o;
 580
 581         if (not $option_buildd and $line =~ /\033/) { # esc
 582             # Remove all ANSI color sequences which are sometimes used in
 583             # non-verbose builds.
 584             $line = Term::ANSIColor::colorstrip($line);
 585             # Also strip '\0xf' (delete previous character), used by Elinks'
 586             # build system.
 587             $line =~ s/\x0f//g;
 588             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 589             # what it does).
 590             $line =~ s/\033\(B//g;
 591         }
 592
 593         # Check if this line indicates a non verbose build.
 594         my $non_verbose = is_non_verbose_build($line);
 595
 596         # One line may contain multiple commands (";"). Treat each one as
 597         # single line. parse_line() is slow, only use it when necessary.
 598         my @line = (not $line =~ /;/)
 599                  ? ($line)
 600                  : map {
 601                        # Ensure newline at the line end - necessary for
 602                        # correct parsing later.
 603                        $_ =~ s/\s+$//;
 604                        $_ .= "\n";
 605                    } Text::ParseWords::parse_line(';', 1, $line);
 606         foreach $line (@line) {
 607             if ($continuation) {
 608                 $continuation = 0;
 609
 610                 # Join lines, but leave the "\" in place so it's clear where
 611                 # the original line break was.
 612                 chomp $complete_line;
 613                 $complete_line .= ' ' . $line;
 614             }
 615             # Line continuation, line ends with "\".
 616             if ($line =~ /\\\s*$/) {
 617                 $continuation = 1;
 618                 # Start line continuation.
 619                 if (not defined $complete_line) {
 620                     $complete_line = $line;
 621                 }
 622                 next;
 623             }
 624
 625             if (not $continuation) {
 626                 # Use the complete line if a line continuation occurred.
 627                 if (defined $complete_line) {
 628                     $line = $complete_line;
 629                     $complete_line = undef;
 630                 }
 631
 632                 # Ignore lines with no compiler commands.
 633                 next if not $non_verbose
 634                         and not $line =~ /\b$cc_regex(?:\s|\\)/o;
 635                 # Ignore lines with no filenames with extensions. May miss
 636                 # some non-verbose builds (e.g. "gcc -o test" [sic!]), but
 637                 # shouldn't be a problem as the log will most likely contain
 638                 # other non-verbose commands which are detected.
 639                 next if not $non_verbose
 640                         and not $line =~ /$file_extension_regex/o;
 641
 642                 # Ignore false positives.
 643                 #
 644                 # `./configure` output.
 645                 next if not $non_verbose
 646                         and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
 647                 next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 648                                    (?:C|c)ompiler[\s.]*:?\s+
 649                                  /xo;
 650                 next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 651
 652                 # Check if additional hardening options were used. Used to
 653                 # ensure they are used for the complete build.
 654                 $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie, @def_ldflags_pie);
 655                 $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 656
 657                 push @input, $line;
 658             }
 659         }
 660     }
 661
 662     close $fh;
 663
 664     if (scalar @input == 0) {
 665         if (not $option_buildd) {
 666             print "No compiler commands!\n";
 667         } else {
 668             print "W-no-compiler-commands\n";
 669         }
 670         $exit |= $exit_code{no_compiler_commands};
 671         next FILE;
 672     }
 673
 674     if ($option_buildd) {
 675         $statistics{commands} += scalar @input;
 676     }
 677
 678     # Option or auto detected.
 679     if ($arch) {
 680         # The following was partially copied from dpkg-dev 1.16.1.2
 681         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 682         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 683         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 684         # later. Keep it in sync.
 685
 686         require Dpkg::Arch;
 687         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 688
 689         # Disable unsupported hardening options.
 690         if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $arch eq 'arm') {
 691             $harden_stack = 0;
 692         }
 693         if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 694             $harden_relro   = 0;
 695             $harden_bindnow = 0;
 696         }
 697     }
 698
 699     # Default values.
 700     my @cflags   = @def_cflags;
 701     my @cxxflags = @def_cxxflags;
 702     my @cppflags = @def_cppflags;
 703     my @ldflags  = @def_ldflags;
 704     # Check the specified hardening options, same order as dpkg-buildflags.
 705     if ($harden_pie) {
 706         @cflags   = (@cflags,   @def_cflags_pie);
 707         @cxxflags = (@cxxflags, @def_cflags_pie);
 708         @ldflags  = (@ldflags,  @def_ldflags_pie);
 709     }
 710     if ($harden_stack) {
 711         @cflags   = (@cflags,   @def_cflags_stack);
 712         @cxxflags = (@cxxflags, @def_cflags_stack);
 713     }
 714     if ($harden_fortify) {
 715         @cflags   = (@cflags,   @def_cflags_fortify);
 716         @cxxflags = (@cxxflags, @def_cflags_fortify);
 717         @cppflags = (@cppflags, @def_cppflags_fortify);
 718     }
 719     if ($harden_format) {
 720         @cflags   = (@cflags,   @def_cflags_format);
 721         @cxxflags = (@cxxflags, @def_cflags_format);
 722     }
 723     if ($harden_relro) {
 724         @ldflags = (@ldflags, @def_ldflags_relro);
 725     }
 726     if ($harden_bindnow) {
 727         @ldflags = (@ldflags, @def_ldflags_bindnow);
 728     }
 729
 730     for (my $i = 0; $i < scalar @input; $i++) {
 731         my $line = $input[$i];
 732
 733         my $skip = 0;
 734         if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 735             if (not $option_buildd) {
 736                 error_non_verbose_build($line);
 737             } else {
 738                 $statistics{commands_nonverbose}++;
 739             }
 740             $exit |= $exit_code{non_verbose_build};
 741             next;
 742         }
 743         # Even if it's a verbose build, we might have to skip this line.
 744         next if $skip;
 745
 746         # Remove everything until and including the compiler command. Makes
 747         # checks easier and faster.
 748         $line =~ s/^.*?$cc_regex//o;
 749         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
 750         # the brace and similar characters.
 751         $line =~ s/['")]+$//;
 752
 753         # Skip unnecessary tests when only preprocessing.
 754         my $flag_preprocess = 0;
 755
 756         my $dependency = 0;
 757         my $preprocess = 0;
 758         my $compile    = 0;
 759         my $link       = 0;
 760
 761         # Preprocess, compile, assemble.
 762         if ($line =~ /\s(-E|-S|-c)\b/) {
 763             $preprocess      = 1;
 764             $flag_preprocess = 1 if $1 eq '-E';
 765             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
 766         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
 767         # -MT -MQ) are always used with -M/-MM.
 768         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
 769             $dependency = 1;
 770         # Otherwise assume we are linking.
 771         } else {
 772             $link = 1;
 773         }
 774
 775         # -MD/-MMD also cause dependency generation, but they don't imply -E!
 776         if ($line =~ /\s(?:-MD|-MMD)\b/) {
 777             $dependency      = 0;
 778             $flag_preprocess = 0;
 779         }
 780
 781         # Dependency generation for Makefiles, no preprocessing or other flags
 782         # needed.
 783         next if $dependency;
 784
 785         # Get all file extensions on this line.
 786         my @extensions = $line =~ /$file_extension_regex/go;
 787         # Ignore all unknown extensions to speedup the search below.
 788         @extensions = grep { exists $extension{$_} } @extensions;
 789
 790         # These file types don't require preprocessing.
 791         if (extension_found(\%extensions_no_preprocess, @extensions)) {
 792             $preprocess = 0;
 793         }
 794         # These file types require preprocessing.
 795         if (extension_found(\%extensions_preprocess, @extensions)) {
 796             $preprocess = 1;
 797         }
 798
 799         # If there are source files then it's compiling/linking in one step
 800         # and we must check both. We only check for source files here, because
 801         # header files cause too many false positives.
 802         if (not $flag_preprocess
 803                 and extension_found(\%extensions_compile_link, @extensions)) {
 804             # Assembly files don't need CFLAGS.
 805             if (not extension_found(\%extensions_compile, @extensions)
 806                     and extension_found(\%extensions_no_compile, @extensions)) {
 807                 $compile = 0;
 808             # But the rest does.
 809             } else {
 810                 $compile = 1;
 811             }
 812         }
 813
 814         # Assume CXXFLAGS are required when a C++ file is specified in the
 815         # compiler line.
 816         my $compile_cpp = 0;
 817         if ($compile
 818                 and extension_found(\%extensions_compile_cpp, @extensions)) {
 819             $compile     = 0;
 820             $compile_cpp = 1;
 821         }
 822
 823         if ($option_buildd) {
 824             $statistics{preprocess}++  if $preprocess;
 825             $statistics{compile}++     if $compile;
 826             $statistics{compile_cpp}++ if $compile_cpp;
 827             $statistics{link}++        if $link;
 828         }
 829
 830         # Check hardening flags.
 831         my @missing;
 832         if ($compile and not all_flags_used($line, \@missing, @cflags)
 833                 # Libraries linked with -fPIC don't have to (and can't) be
 834                 # linked with -fPIE as well. It's no error if only PIE flags
 835                 # are missing.
 836                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 837                 # Assume dpkg-buildflags returns the correct flags.
 838                 and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
 839             if (not $option_buildd) {
 840                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 841             } else {
 842                 $statistics{compile_missing}++;
 843             }
 844             $exit |= $exit_code{flags_missing};
 845         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
 846                 # Libraries linked with -fPIC don't have to (and can't) be
 847                 # linked with -fPIE as well. It's no error if only PIE flags
 848                 # are missing.
 849                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 850                 # Assume dpkg-buildflags returns the correct flags.
 851                 and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
 852             if (not $option_buildd) {
 853                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 854             } else {
 855                 $statistics{compile_cpp_missing}++;
 856             }
 857             $exit |= $exit_code{flags_missing};
 858         }
 859         if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
 860                 # Assume dpkg-buildflags returns the correct flags.
 861                 and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
 862             if (not $option_buildd) {
 863                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 864             } else {
 865                 $statistics{preprocess_missing}++;
 866             }
 867             $exit |= $exit_code{flags_missing};
 868         }
 869         if ($link and not all_flags_used($line, \@missing, @ldflags)
 870                 # Same here, -fPIC conflicts with -fPIE.
 871                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
 872                 # Assume dpkg-buildflags returns the correct flags.
 873                 and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
 874             if (not $option_buildd) {
 875                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 876             } else {
 877                 $statistics{link_missing}++;
 878             }
 879             $exit |= $exit_code{flags_missing};
 880         }
 881     }
 882 }
 883
 884 # Print statistics for buildd mode, only output in this mode.
 885 if ($option_buildd) {
 886     my @warning;
 887
 888     if ($statistics{preprocess_missing}) {
 889         push @warning, sprintf "CPPFLAGS %d (of %d)",
 890                                $statistics{preprocess_missing},
 891                                $statistics{preprocess};
 892     }
 893     if ($statistics{compile_missing}) {
 894         push @warning, sprintf "CFLAGS %d (of %d)",
 895                                $statistics{compile_missing},
 896                                $statistics{compile};
 897     }
 898     if ($statistics{compile_cpp_missing}) {
 899         push @warning, sprintf "CXXFLAGS %d (of %d)",
 900                                $statistics{compile_cpp_missing},
 901                                $statistics{compile_cpp};
 902     }
 903     if ($statistics{link_missing}) {
 904         push @warning, sprintf "LDFLAGS %d (of %d)",
 905                                $statistics{link_missing},
 906                                $statistics{link};
 907     }
 908     if (scalar @warning) {
 909         local $" = ', '; # array join string
 910         print "W-dpkg-buildflags-missing @warning missing\n";
 911     }
 912
 913     if ($statistics{commands_nonverbose}) {
 914         printf "W-compiler-flags-hidden %d (of %d) hidden\n",
 915                $statistics{commands_nonverbose},
 916                $statistics{commands},
 917     }
 918 }
 919
 920
 921 exit $exit;
 922
 923
 924 __END__
 925
 926 =head1 NAME
 927
 928 blhc - build log hardening check, checks build logs for missing hardening flags
 929
 930 =head1 SYNOPSIS
 931
 932 B<blhc> [I<options>] I<E<lt>dpkg-buildpackage build log fileE<gt>..>
 933
 934 =head1 DESCRIPTION
 935
 936 blhc is a small tool which checks build logs for missing hardening flags and
 937 other important warnings. It's licensed under the GPL 3 or later.
 938
 939 =head1 OPTIONS
 940
 941 =over 8
 942
 943 =item B<--all>
 944
 945 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 946 auto detected.
 947
 948 =item B<--arch> I<architecture>
 949
 950 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 951 disables hardening flags not available on this architecture. Is detected
 952 automatically if dpkg-buildpackage is used.
 953
 954 =item B<--bindnow>
 955
 956 Force check for all +bindnow hardening flags. By default it's auto detected.
 957
 958 =item B<--buildd>
 959
 960 Special mode for buildds when automatically parsing log files. The following
 961 changes are in effect:
 962
 963 =over 2
 964
 965 =item
 966
 967 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
 968 detected).
 969
 970 =back
 971
 972 =item B<--color>
 973
 974 Use colored (ANSI) output for warning messages.
 975
 976 =item B<--pie>
 977
 978 Force check for all +pie hardening flags. By default it's auto detected.
 979
 980 =item B<-h -? --help>
 981
 982 Print available options.
 983
 984 =item B<--version>
 985
 986 Print version number and license.
 987
 988 =back
 989
 990 Auto detection for B<--pie> and B<--bindnow> only works if at least one
 991 command uses the required hardening flag (e.g. -fPIE). Then it's required for
 992 all other commands as well.
 993
 994 =head1 EXIT STATUS
 995
 996 The exit status is a "bit mask", each listed status is ORed when the error
 997 condition occurs to get the result.
 998
 999 =over 4
1000
1001 =item B<0>
1002
1003 Success.
1004
1005 =item B<1>
1006
1007 No compiler commands were found.
1008
1009 =item B<2>
1010
1011 Invalid arguments/options given to blhc.
1012
1013 =item B<4>
1014
1015 Non verbose build.
1016
1017 =item B<8>
1018
1019 Missing hardening flags.
1020
1021 =item B<16>
1022
1023 Hardening wrapper detected, no tests performed.
1024
1025 =back
1026
1027 =head1 AUTHOR
1028
1029 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1030
1031 =head1 COPYRIGHT AND LICENSE
1032
1033 Copyright (C) 2012 by Simon Ruderich
1034
1035 This program is free software: you can redistribute it and/or modify
1036 it under the terms of the GNU General Public License as published by
1037 the Free Software Foundation, either version 3 of the License, or
1038 (at your option) any later version.
1039
1040 This program is distributed in the hope that it will be useful,
1041 but WITHOUT ANY WARRANTY; without even the implied warranty of
1042 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1043 GNU General Public License for more details.
1044
1045 You should have received a copy of the GNU General Public License
1046 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1047
1048 =cut