bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Term::ANSIColor ();
  26
  27 our $VERSION = '0.01';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/(?:[a-z0-9_]+-(?:linux|kfreebsd)-gnu(?:eabi|eabihf)?-)?
  34                   (?:(?<!\.)cc|gcc|g\+\+|c\+\+)
  35                   (?:-[\d.]+)?/x;
  36 # Regex to catch (GCC) compiler warnings.
  37 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  38
  39 # Expected (hardening) flags. All flags are used as regexps.
  40 my @cflags = (
  41     '-g',
  42     '-O(?:2|3)',
  43 );
  44 my @cflags_format = (
  45     '-Wformat',
  46     '-Wformat-security',
  47     '-Werror=format-security',
  48 );
  49 my @cflags_fortify = (
  50     # fortify needs at least -O1, but -O2 is recommended anyway
  51 );
  52 my @cflags_stack = (
  53     '-fstack-protector',
  54     '--param=ssp-buffer-size=4',
  55 );
  56 my @cflags_pie = (
  57     '-fPIE',
  58 );
  59 my @cppflags = ();
  60 my @cppflags_fortify = (
  61     '-D_FORTIFY_SOURCE=2',
  62 );
  63 my @ldflags = ();
  64 my @ldflags_relro = (
  65     '-Wl,(-z,)?relro',
  66 );
  67 my @ldflags_bindnow = (
  68     '-Wl,(-z,)?now',
  69 );
  70 my @ldflags_pie = (
  71     '-fPIE',
  72     '-pie',
  73 );
  74 # Renaming rules for the output so the regex parts are not visible.
  75 my %flag_renames = (
  76     '-O(?:2|3)'       => '-O2',
  77     '-Wl,(-z,)?relro' => '-Wl,-z,relro',
  78     '-Wl,(-z,)?now'   => '-Wl,-z,now',
  79 );
  80
  81
  82 # FUNCTIONS
  83
  84 sub error_flags {
  85     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
  86
  87     # Rename flags if requested.
  88     my @missing_flags = map {
  89         (exists $flag_renames_ref->{$_})
  90             ? $flag_renames_ref->{$_}
  91             : $_
  92     } @{$missing_flags_ref};
  93
  94     my $flags = join ' ', @missing_flags;
  95     printf "%s (%s)%s %s",
  96            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
  97            $line;
  98 }
  99 sub error_non_verbose_build {
 100     my ($line) = @_;
 101
 102     printf "%s%s %s",
 103            error_color('NONVERBOSE BUILD', 'red'),
 104            error_color(':', 'yellow'),
 105            $line;
 106 }
 107 sub error_color {
 108     my ($message, $color) = @_;
 109
 110     # Use colors when writing to a terminal.
 111     if (-t STDOUT) {
 112         return Term::ANSIColor::colored($message, $color);
 113     } else {
 114         return $message;
 115     }
 116 }
 117
 118 sub any_flags_used {
 119     my ($line, @flags) = @_;
 120
 121     foreach my $flag (@flags) {
 122         return 1 if $line =~ /\s$flag(?:\s|\\|$)/;
 123     }
 124
 125     return 0;
 126 }
 127 sub all_flags_used {
 128     my ($line, $missing_flags_ref, @flags) = @_;
 129
 130     my @missing_flags = ();
 131     foreach my $flag (@flags) {
 132         if ($line !~ /\s$flag(?:\s|\\|$)/) {
 133             push @missing_flags, $flag;
 134         }
 135     }
 136
 137     if (scalar @missing_flags == 0) {
 138         return 1;
 139     }
 140
 141     @{$missing_flags_ref} = @missing_flags;
 142     return 0;
 143 }
 144
 145 # Modifies $missing_flags_ref array.
 146 sub pic_pie_conflict {
 147     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 148
 149     return 0 if not $pie;
 150     return 0 if not any_flags_used($line, ('-fPIC', '-fpic'));
 151
 152     my %flags = map { $_ => 1 } @flags_pie;
 153
 154     # Remove all PIE flags from @missing_flags as they are not required with
 155     # -fPIC.
 156     my @result = grep {
 157         not exists $flags{$_}
 158     } @{$missing_flags_ref};
 159     @{$missing_flags_ref} = @result;
 160
 161     # We got a conflict when no flags are left, thus only PIE flags were
 162     # missing. If other flags were missing abort because the conflict is not
 163     # the problem.
 164     return scalar @result == 0;
 165 }
 166
 167 sub is_non_verbose_build {
 168     my ($line, $next_line, $skip_ref) = @_;
 169
 170     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 171                 or $line =~ /^\s*\[?(?:CC|CCLD|LD)\]?\s+(.+?)$/
 172                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 173                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 174                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 175         return 0;
 176     }
 177
 178     my $file = $1;
 179
 180     # On the first pass we only check if this line is verbose or not.
 181     return 1 if not defined $next_line;
 182
 183     # Second pass, we have access to the next line.
 184     ${$skip_ref} = 0;
 185
 186     # CMake and other build systems print the non-verbose messages also when
 187     # building verbose. If a compiler and the file name occurs in the next
 188     # line, treat it as verbose build.
 189     if (defined $file) {
 190         # Get filename, we can't use the complete path as only parts of it are
 191         # used in the real compiler command.
 192         $file =~ m{/([a-zA-Z0-9._-]+)$};
 193         $file = $1;
 194
 195         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/) {
 196             # We still have to skip the current line as it doesn't contain any
 197             # compiler commands.
 198             ${$skip_ref} = 1;
 199             return 0;
 200         }
 201     }
 202
 203     return 1;
 204 }
 205
 206
 207 # MAIN
 208
 209 # Hardening options. Not all architectures support all hardening options.
 210 my $harden_format  = 1;
 211 my $harden_fortify = 1;
 212 my $harden_stack   = 1;
 213 my $harden_relro   = 1;
 214 my $harden_bindnow = 0;
 215 my $harden_pie     = 0;
 216
 217 # Parse command line arguments.
 218 my $option_help    = 0;
 219 my $option_version = 0;
 220 my $option_all     = 0;
 221 my $option_arch    = undef;
 222 if (not Getopt::Long::GetOptions(
 223             'help|h|?' => \$option_help,
 224             'version'  => \$option_version,
 225             # Hardening options.
 226             'pie'      => \$harden_pie,
 227             'bindnow'  => \$harden_bindnow,
 228             'all'      => \$option_all,
 229             # Misc.
 230             'arch'     => \$option_arch,
 231         )) {
 232     require Pod::Usage;
 233     Pod::Usage::pod2usage(2);
 234 }
 235 if ($option_help) {
 236     require Pod::Usage;
 237     Pod::Usage::pod2usage(1);
 238 }
 239 if ($option_version) {
 240     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 241
 242 This program is free software: you can redistribute it and/or modify
 243 it under the terms of the GNU General Public License as published by
 244 the Free Software Foundation, either version 3 of the License, or
 245 (at your option) any later version.
 246
 247 This program is distributed in the hope that it will be useful,
 248 but WITHOUT ANY WARRANTY; without even the implied warranty of
 249 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 250 GNU General Public License for more details.
 251
 252 You should have received a copy of the GNU General Public License
 253 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 254 ";
 255     exit 0;
 256 }
 257
 258 if ($option_all) {
 259     $harden_pie     = 1;
 260     $harden_bindnow = 1;
 261 }
 262
 263 # Final exit code.
 264 my $exit = 0;
 265
 266 # Input lines, contain only the lines with compiler commands.
 267 my @input = ();
 268
 269 my $start = 0;
 270 my $continuation = 0;
 271 my $complete_line = undef;
 272 while (my $line = <>) {
 273     # We skip over unimportant lines at the beginning to prevent false
 274     # positives.
 275     $start = 1 if $line =~ /^dpkg-buildpackage:/;
 276     next if not $start;
 277
 278     # Detect architecture automatically unless overridden.
 279     if (not $option_arch
 280             and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 281         $option_arch = $1;
 282     }
 283
 284     # Ignore compiler warnings for now.
 285     next if $line =~ /$warning_regex/;
 286
 287     # Remove all ANSI color sequences which are sometimes used in non-verbose
 288     # builds.
 289     $line = Term::ANSIColor::colorstrip($line);
 290     # Also strip '\0xf' (delete previous character), used by Elink's build
 291     # system.
 292     $line =~ s/\x0f//g;
 293     # And "ESC(B" which seems to be used on armhf and hurd (not sure what it
 294     # does).
 295     $line =~ s/\033\(B//g;
 296
 297     # Check if this line indicates a non verbose build.
 298     my $non_verbose = is_non_verbose_build($line);
 299
 300     # One line may contain multiple commands (";"). Treat each one as single
 301     # line.
 302     my @line = split /(?<!\\);/, $line;
 303     foreach $line (@line) {
 304         # Add newline, drop all other whitespace at the end of a line.
 305         $line =~ s/\s+$//;
 306         $line .= "\n";
 307
 308         if ($continuation) {
 309             $continuation = 0;
 310
 311             # Join lines, but leave the "\" in place so it's clear where the
 312             # original line break was.
 313             chomp $complete_line;
 314             $complete_line .= ' ' . $line;
 315         }
 316         # Line continuation, line ends with "\".
 317         if ($line =~ /\\\s*$/) {
 318             $continuation = 1;
 319             # Start line continuation.
 320             if (not defined $complete_line) {
 321                 $complete_line = $line;
 322             }
 323             next;
 324         }
 325
 326         if (not $continuation) {
 327             # Use the complete line if a line continuation occurred.
 328             if (defined $complete_line) {
 329                 $line = $complete_line;
 330                 $complete_line = undef;
 331             }
 332
 333             # Ignore lines with no compiler commands.
 334             next if $line !~ /\b$cc_regex(?:\s|\\)/ and not $non_verbose;
 335
 336             # Ignore false positives.
 337             #
 338             # `./configure` output.
 339             next if not $non_verbose and $line =~ /^checking /;
 340             next if $line =~ /^\s*(?:C\s+)?
 341                                (?:C|c)ompiler[\s.]*:\s+
 342                                $cc_regex
 343                                (?:\s-std=[a-z0-9:+]+)?\s*$
 344                              /x
 345                     or $line =~ /^\s*(?:- )?(?:CC|CXX)\s*=\s*$cc_regex\s*$/
 346                     or $line =~ /^\s*-- Check for working (?:C|CXX) compiler: /
 347                     or $line =~ /^\s*(?:echo )?Using [A-Z_]+\s*=\s*/;
 348             # Debian buildd output.
 349             next if $line =~ /^\s*Depends: .*?$cc_regex.*?$/
 350                     and $line !~ /\s-./; # option, prevent false negatives
 351
 352
 353             push @input, $line;
 354         }
 355     }
 356 }
 357
 358 if (scalar @input == 0) {
 359     print "No compiler commands!\n";
 360     $exit |= 1;
 361     exit $exit;
 362 }
 363
 364 # Option or auto detected.
 365 if ($option_arch) {
 366     # The following was partially copied from dpkg-dev 1.16.1.2
 367     # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 368     # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 369     # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 370     # later. Keep it in sync.
 371
 372     require Dpkg::Arch;
 373     my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($option_arch);
 374
 375     # Disable unsupported hardening options.
 376     if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $option_arch eq 'arm') {
 377         $harden_stack = 0;
 378     }
 379     if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 380         $harden_relro   = 0;
 381         $harden_bindnow = 0;
 382     }
 383 }
 384
 385 # Check if additional hardening options were used. Used to ensure they are
 386 # used for the complete build.
 387 foreach my $line (@input) {
 388     $harden_pie     = 1 if any_flags_used($line, @cflags_pie, @ldflags_pie);
 389     $harden_bindnow = 1 if any_flags_used($line, @ldflags_bindnow);
 390 }
 391
 392 # Check the specified hardening options, same order as dpkg-buildflags.
 393 if ($harden_pie) {
 394     @cflags  = (@cflags,  @cflags_pie);
 395     @ldflags = (@ldflags, @ldflags_pie);
 396 }
 397 if ($harden_stack) {
 398     @cflags = (@cflags, @cflags_stack);
 399 }
 400 if ($harden_fortify) {
 401     @cflags   = (@cflags,   @cflags_fortify);
 402     @cppflags = (@cppflags, @cppflags_fortify);
 403 }
 404 if ($harden_format) {
 405     @cflags = (@cflags, @cflags_format);
 406 }
 407 if ($harden_relro) {
 408     @ldflags = (@ldflags, @ldflags_relro);
 409 }
 410 if ($harden_bindnow) {
 411     @ldflags = (@ldflags, @ldflags_bindnow);
 412 }
 413
 414 for (my $i = 0; $i < scalar @input; $i++) {
 415     my $line = $input[$i];
 416
 417     my $skip = 0;
 418     if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 419         error_non_verbose_build($line);
 420         $exit |= 1 << 2;
 421         next;
 422     }
 423     # Even if it's a verbose build, we might have to skip this line.
 424     next if $skip;
 425
 426
 427     # Is this a compiler or linker command?
 428     my $compiler = 1;
 429     my $linker   = 0;
 430
 431     # Linker commands.
 432     if ($line =~ m{\s-o                        # -o
 433                    [\s\\]*\s+                  # possible line continuation
 434                    (?:[/.A-Za-z0-9~_-]+/)?     # path to file
 435                         [A-Za-z0-9~_-]+        # binary name (no dots!)
 436                    (?:[0-9.]*\.so[0-9.]*[a-z]? # library (including version)
 437                     |\.la
 438                     |\.cgi)?                   # CGI binary
 439                    (?:\s|\\|$)                 # end of file name
 440                   }x
 441             or $line =~ /^libtool: link: /
 442             or $line =~ m{\s*/bin/bash .+?libtool\s+(.+?\s+)?--mode=(re)?link}) {
 443         $compiler = 0;
 444         $linker   = 1;
 445     }
 446
 447     # If there are source files then it's compiling/linking in one step and we
 448     # must check both.
 449     if ($line =~ /\.(?:c|cc|cpp)\b/) {
 450         $compiler = 1;
 451     }
 452
 453     # Check hardening flags.
 454     my @missing;
 455     if ($compiler and not all_flags_used($line, \@missing, @cflags)
 456             # Libraries linked with -fPIC don't have to (and can't) be linked
 457             # with -fPIE as well. It's no error if only PIE flags are missing.
 458             and not pic_pie_conflict($line, $harden_pie, \@missing, @cflags_pie)) {
 459         error_flags('CFLAGS missing', \@missing, \%flag_renames, $line);
 460         $exit |= 1 << 3;
 461     }
 462     if ($compiler and not all_flags_used($line, \@missing, @cppflags)) {
 463         error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $line);
 464         $exit |= 1 << 3;
 465     }
 466     if ($linker and not all_flags_used($line, \@missing, @ldflags)
 467             # Same here, -fPIC conflicts with -fPIE.
 468             and not pic_pie_conflict($line, $harden_pie, \@missing, @ldflags_pie)) {
 469         error_flags('LDFLAGS missing', \@missing, \%flag_renames, $line);
 470         $exit |= 1 << 3;
 471     }
 472 }
 473
 474 exit $exit;
 475
 476
 477 __END__
 478
 479 =head1 NAME
 480
 481 blhc - build log hardening check, checks build logs for missing hardening flags
 482
 483 =head1 SYNOPSIS
 484
 485 B<blhc> [-h -? --help]
 486
 487 B<blhc> [--pie] [--bindnow] [--all]
 488
 489     --help                  available options
 490     --version               version number and license
 491     --pie                   force +pie check
 492     --bindnow               force +bindbow check
 493     --all                   force +all (+pie, +bindnow) check
 494     --arch                  set architecture (autodetected)
 495
 496 =head1 DESCRIPTION
 497
 498 blhc is a small tool which checks build logs for missing hardening flags and
 499 other important warnings. It's licensed under the GPL 3 or later.
 500
 501 =head1 OPTIONS
 502
 503 =over 8
 504
 505 =item B<-h -? --help>
 506
 507 Print available options.
 508
 509 =item B<--version>
 510
 511 Print version number and license.
 512
 513 =item B<--pie>
 514
 515 Force check for all +pie hardening flags. By default it's auto detected.
 516
 517 =item B<--bindnow>
 518
 519 Force check for all +bindnow hardening flags. By default it's auto detected.
 520
 521 =item B<--all>
 522
 523 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 524 auto detected.
 525
 526 =item B<--arch>
 527
 528 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 529 disables hardening flags not available on this architecture. Is detected
 530 automatically if dpkg-buildpackage is used.
 531
 532 =back
 533
 534 Auto detection only works if at least one command uses the required hardening
 535 flag (e.g. -fPIE). Then it's required for all other commands as well.
 536
 537 =head1 EXIT STATUS
 538
 539 The exit status is a "bit mask", each listed status is ORed when the error
 540 condition occurs to get the result.
 541
 542 =over 8
 543
 544 =item B<0>
 545
 546 Success.
 547
 548 =item B<1>
 549
 550 No compiler commands were found.
 551
 552 =item B<2>
 553
 554 Invalid arguments/options given to blhc.
 555
 556 =item B<4>
 557
 558 Non verbose build.
 559
 560 =item B<8>
 561
 562 Missing hardening flags.
 563
 564 =back
 565
 566 =head1 AUTHOR
 567
 568 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
 569
 570 =head1 COPYRIGHT AND LICENSE
 571
 572 Copyright (C) 2012 by Simon Ruderich
 573
 574 This program is free software: you can redistribute it and/or modify
 575 it under the terms of the GNU General Public License as published by
 576 the Free Software Foundation, either version 3 of the License, or
 577 (at your option) any later version.
 578
 579 This program is distributed in the hope that it will be useful,
 580 but WITHOUT ANY WARRANTY; without even the implied warranty of
 581 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 582 GNU General Public License for more details.
 583
 584 You should have received a copy of the GNU General Public License
 585 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 586
 587 =cut