bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2013  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.04';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 180 # real regexps below for better execution speed).
 181 my @def_cflags = (
 182     '-g',
 183     '-O(?:2|3)',
 184 );
 185 my @def_cflags_format = (
 186     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 187     '-Werror=format-security', # implies -Wformat-security
 188 );
 189 my @def_cflags_fortify = (
 190     # fortify needs at least -O1, but -O2 is recommended anyway
 191 );
 192 my @def_cflags_stack = (
 193     '-fstack-protector',
 194     '--param[= ]ssp-buffer-size=4',
 195 );
 196 my @def_cflags_pie = (
 197     '-fPIE',
 198 );
 199 my @def_cxxflags = (
 200     @def_cflags,
 201 );
 202 # @def_cxxflags_* is the same as @def_cflags_*.
 203 my @def_cppflags = ();
 204 my @def_cppflags_fortify = (
 205     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 206     # If you add another flag fix hack below (search for "Hack to fix").
 207 );
 208 my @def_cppflags_fortify_bad = (
 209     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 210     '-U_FORTIFY_SOURCE',
 211     '-D_FORTIFY_SOURCE=0',
 212     '-D_FORTIFY_SOURCE=1',
 213 );
 214 my @def_ldflags = ();
 215 my @def_ldflags_relro = (
 216     '-Wl,(?:-z,)?relro',
 217 );
 218 my @def_ldflags_bindnow = (
 219     '-Wl,(?:-z,)?now',
 220 );
 221 my @def_ldflags_pie = (
 222     '-fPIE',
 223     '-pie',
 224 );
 225 my @def_ldflags_pic = (
 226     '-fPIC',
 227     '-fpic',
 228     '-shared',
 229 );
 230 # References to all flags checked by the flag checker.
 231 my @flag_refs = (
 232     \@def_cflags,
 233     \@def_cflags_format,
 234     \@def_cflags_fortify,
 235     \@def_cflags_stack,
 236     \@def_cflags_pie,
 237     \@def_cxxflags,
 238     \@def_cppflags,
 239     \@def_cppflags_fortify,
 240     \@def_ldflags,
 241     \@def_ldflags_relro,
 242     \@def_ldflags_bindnow,
 243     \@def_ldflags_pie,
 244 );
 245 # References to all used flags.
 246 my @flag_refs_all = (
 247     @flag_refs,
 248     \@def_cppflags_fortify_bad,
 249     \@def_ldflags_pic,
 250 );
 251 # Renaming rules for the output so the regex parts are not visible. Also
 252 # stores string values of flag regexps above, see compile_flag_regexp().
 253 my %flag_renames = (
 254     '-O(?:2|3)'                    => '-O2',
 255     '-Wformat(?:=2)?'              => '-Wformat',
 256     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 257     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 258     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 259 );
 260
 261 my %exit_code = (
 262     no_compiler_commands => 1 << 0,
 263     # used by POD::Usage => 1 << 1,
 264     non_verbose_build    => 1 << 2,
 265     flags_missing        => 1 << 3,
 266     hardening_wrapper    => 1 << 4,
 267     invalid_cmake        => 1 << 5,
 268 );
 269
 270 my %buildd_tag = (
 271     no_compiler_commands => 'I-no-compiler-commands',
 272     non_verbose_build    => 'W-compiler-flags-hidden',
 273     flags_missing        => 'W-dpkg-buildflags-missing',
 274     hardening_wrapper    => 'I-hardening-wrapper-used',
 275     invalid_cmake        => 'I-invalid-cmake-used',
 276 );
 277
 278 # Statistics of missing flags and non-verbose build commands. Used for
 279 # $option_buildd.
 280 my %statistics = (
 281     preprocess          => 0,
 282     preprocess_missing  => 0,
 283     compile             => 0,
 284     compile_missing     => 0,
 285     compile_cpp         => 0,
 286     compile_cpp_missing => 0,
 287     link                => 0,
 288     link_missing        => 0,
 289     commands            => 0,
 290     commands_nonverbose => 0,
 291 );
 292
 293 # Use colored (ANSI) output?
 294 my $option_color;
 295
 296
 297 # FUNCTIONS
 298
 299 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 300 sub array_equal {
 301     my ($first_ref, $second_ref) = @_;
 302
 303     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 304
 305     my $length = scalar @{$first_ref};
 306     for (my $i = 0; $i < $length; $i++) {
 307         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 308     }
 309
 310     return 1;
 311 }
 312
 313 sub error_flags {
 314     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 315
 316     # Get string value of qr//-escaped regexps and if requested rename them.
 317     my @missing_flags = map {
 318             $flag_renames_ref->{$_}
 319         } @{$missing_flags_ref};
 320
 321     my $flags = join ' ', @missing_flags;
 322     printf '%s (%s)%s %s',
 323            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 324            $line;
 325
 326     return;
 327 }
 328 sub error_non_verbose_build {
 329     my ($line) = @_;
 330
 331     printf '%s%s %s',
 332            error_color('NONVERBOSE BUILD', 'red'),
 333            error_color(':', 'yellow'),
 334            $line;
 335
 336     return;
 337 }
 338 sub error_invalid_cmake {
 339     my ($version) = @_;
 340
 341     printf "%s%s %s\n",
 342             error_color('INVALID CMAKE', 'red'),
 343             error_color(':', 'yellow'),
 344             $version;
 345
 346     return;
 347 }
 348 sub error_hardening_wrapper {
 349     printf "%s%s %s\n",
 350             error_color('HARDENING WRAPPER', 'red'),
 351             error_color(':', 'yellow'),
 352             'no checks possible, aborting';
 353
 354     return;
 355 }
 356 sub error_color {
 357     my ($message, $color) = @_;
 358
 359     if ($option_color) {
 360         return Term::ANSIColor::colored($message, $color);
 361     } else {
 362         return $message;
 363     }
 364 }
 365
 366 sub any_flags_used {
 367     my ($line, @flags) = @_;
 368
 369     foreach my $flag (@flags) {
 370         return 1 if $line =~ /$flag/;
 371     }
 372
 373     return 0;
 374 }
 375 sub all_flags_used {
 376     my ($line, $missing_flags_ref, @flags) = @_;
 377
 378     my @missing_flags = ();
 379     foreach my $flag (@flags) {
 380         if (not $line =~ /$flag/) {
 381             push @missing_flags, $flag;
 382         }
 383     }
 384
 385     return 1 if scalar @missing_flags == 0;
 386
 387     @{$missing_flags_ref} = @missing_flags;
 388     return 0;
 389 }
 390
 391 sub cppflags_fortify_broken {
 392     my ($line, $missing_flags) = @_;
 393
 394     # This doesn't take the position into account, but is a simple solution.
 395     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 396     # is wrong anyway.
 397
 398     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 399         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 400         push @{$missing_flags}, $def_cppflags_fortify[0];
 401         return 1;
 402     }
 403
 404     return 0;
 405 }
 406
 407 # Modifies $missing_flags_ref array.
 408 sub pic_pie_conflict {
 409     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 410
 411     return 0 if not $pie;
 412     return 0 if not any_flags_used($line, @def_ldflags_pic);
 413
 414     my %flags = map { $_ => 1 } @flags_pie;
 415
 416     # Remove all PIE flags from @missing_flags as they are not required with
 417     # -fPIC.
 418     my @result = grep {
 419         not exists $flags{$_}
 420     } @{$missing_flags_ref};
 421     @{$missing_flags_ref} = @result;
 422
 423     # We got a conflict when no flags are left, thus only PIE flags were
 424     # missing. If other flags were missing abort because the conflict is not
 425     # the problem.
 426     return scalar @result == 0;
 427 }
 428
 429 sub is_non_verbose_build {
 430     my ($line, $next_line, $skip_ref) = @_;
 431
 432     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 433                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 434                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 435                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 436                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 437         return 0;
 438     }
 439
 440     # False positives.
 441     #
 442     # C++ compiler setting.
 443     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 444     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 445     # "Compiling" non binary files.
 446     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?(?:\.\.\.)?$/;
 447     # "Compiling" with no file name.
 448     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 449         # $file_extension_regex may need spaces around the filename.
 450         return 0 if not " $1 " =~ /$file_extension_regex/o;
 451     }
 452
 453     my $file = $1;
 454
 455     # On the first pass we only check if this line is verbose or not.
 456     return 1 if not defined $next_line;
 457
 458     # Second pass, we have access to the next line.
 459     ${$skip_ref} = 0;
 460
 461     # CMake and other build systems print the non-verbose messages also when
 462     # building verbose. If a compiler and the file name occurs in the next
 463     # line, treat it as verbose build.
 464     if (defined $file) {
 465         # Get filename, we can't use the complete path as only parts of it are
 466         # used in the real compiler command.
 467         $file =~ m{/([^/\s]+)$};
 468         $file = $1;
 469
 470         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 471             # Not a non-verbose line, but we still have to skip the current line
 472             # as it doesn't contain any compiler commands.
 473             ${$skip_ref} = 1;
 474             return 0;
 475         }
 476     }
 477
 478     return 1;
 479 }
 480
 481 # Remove @flags from $flag_refs_ref, and $flag_renames_ref.
 482 sub remove_flags {
 483     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 484
 485     my %removes = map { $_ => 1 } @flags;
 486     foreach my $flags (@{$flag_refs_ref}) {
 487         @{$flags} = grep {
 488             # Flag found as string.
 489             not exists $removes{$_}
 490             # Flag found as string representation of regexp.
 491                 and (not defined $flag_renames_ref->{$_}
 492                         or not exists $removes{$flag_renames_ref->{$_}})
 493         } @{$flags};
 494     }
 495
 496     return;
 497 }
 498
 499 # Modifies $flag_renames_ref hash.
 500 sub compile_flag_regexp {
 501     my ($flag_renames_ref, @flags) = @_;
 502
 503     my @result = ();
 504     foreach my $flag (@flags) {
 505         # Compile flag regexp for faster execution.
 506         my $regex = qr/\s$flag(?:\s|\\)/;
 507
 508         # Store flag name in replacement string for correct flags in messages
 509         # with qr//ed flag regexps.
 510         $flag_renames_ref->{$regex}
 511             = (exists $flag_renames_ref->{$flag})
 512                 ? $flag_renames_ref->{$flag}
 513                 : $flag;
 514
 515         push @result, $regex;
 516     }
 517     return @result;
 518 }
 519
 520 # Does any extension in @extensions exist in %{$extensions_ref}?
 521 sub extension_found {
 522     my ($extensions_ref, @extensions) = @_;
 523
 524     foreach my $extension (@extensions) {
 525         if (exists $extensions_ref->{$extension}) {
 526             return 1;
 527         }
 528     }
 529     return 0;
 530 }
 531
 532
 533 # MAIN
 534
 535 # Parse command line arguments.
 536 my $option_help             = 0;
 537 my $option_version          = 0;
 538 my $option_pie              = 0;
 539 my $option_bindnow          = 0;
 540 my @option_ignore_arch      = ();
 541 my @option_ignore_flag      = ();
 542 my @option_ignore_arch_flag = ();
 543 my @option_ignore_line      = ();
 544 my @option_ignore_arch_line = ();
 545 my $option_all              = 0;
 546 my $option_arch             = undef;
 547 my $option_buildd           = 0;
 548    $option_color            = 0;
 549 if (not Getopt::Long::GetOptions(
 550             'help|h|?'           => \$option_help,
 551             'version'            => \$option_version,
 552             # Hardening options.
 553             'pie'                => \$option_pie,
 554             'bindnow'            => \$option_bindnow,
 555             'all'                => \$option_all,
 556             # Ignore.
 557             'ignore-arch=s'      => \@option_ignore_arch,
 558             'ignore-flag=s'      => \@option_ignore_flag,
 559             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 560             'ignore-line=s'      => \@option_ignore_line,
 561             'ignore-arch-line=s' => \@option_ignore_arch_line,
 562             # Misc.
 563             'color'              => \$option_color,
 564             'arch=s'             => \$option_arch,
 565             'buildd'             => \$option_buildd,
 566         )) {
 567     require Pod::Usage;
 568     Pod::Usage::pod2usage(2);
 569 }
 570 if ($option_help) {
 571     require Pod::Usage;
 572     Pod::Usage::pod2usage(1);
 573 }
 574 if ($option_version) {
 575     print <<"EOF";
 576 blhc $VERSION  Copyright (C) 2012-2013  Simon Ruderich
 577
 578 This program is free software: you can redistribute it and/or modify
 579 it under the terms of the GNU General Public License as published by
 580 the Free Software Foundation, either version 3 of the License, or
 581 (at your option) any later version.
 582
 583 This program is distributed in the hope that it will be useful,
 584 but WITHOUT ANY WARRANTY; without even the implied warranty of
 585 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 586 GNU General Public License for more details.
 587
 588 You should have received a copy of the GNU General Public License
 589 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 590 EOF
 591     exit 0;
 592 }
 593
 594 # Arguments missing.
 595 if (scalar @ARGV == 0) {
 596     require Pod::Usage;
 597     Pod::Usage::pod2usage(2);
 598 }
 599
 600 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 601 # installed on Debian's buildds.
 602 if (not $option_buildd) {
 603     require Term::ANSIColor;
 604 }
 605
 606 if ($option_all) {
 607     $option_pie     = 1;
 608     $option_bindnow = 1;
 609 }
 610
 611 # Precompiled ignores for faster lookup.
 612 my %option_ignore_arch_flag = ();
 613 my %option_ignore_arch_line = ();
 614
 615 # Strip flags which should be ignored.
 616 if (scalar @option_ignore_flag > 0) {
 617     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 618 }
 619 # Same for arch specific ignore flags, but only prepare here.
 620 if (scalar @option_ignore_arch_flag > 0) {
 621     foreach my $ignore (@option_ignore_arch_flag) {
 622         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 623
 624         if (not $ignore_arch or not $ignore_flag) {
 625             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 626                         . '("arch:flag" expected)' . "\n", $ignore;
 627             require Pod::Usage;
 628             Pod::Usage::pod2usage(2);
 629         }
 630
 631         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 632     }
 633 }
 634
 635 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 636 # faster with this.
 637 foreach my $flags (@flag_refs_all) {
 638     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 639 }
 640
 641 # Precompile ignore line regexps, also anchor at beginning and end of line.
 642 foreach my $ignore (@option_ignore_line) {
 643     $ignore = qr/^$ignore$/;
 644 }
 645 # Same for arch specific ignore lines.
 646 if (scalar @option_ignore_arch_line > 0) {
 647     foreach my $ignore (@option_ignore_arch_line) {
 648         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 649
 650         if (not $ignore_arch or not $ignore_line) {
 651             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 652                         . '("arch:line" expected)' . "\n", $ignore;
 653             require Pod::Usage;
 654             Pod::Usage::pod2usage(2);
 655         }
 656
 657         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 658     }
 659 }
 660
 661 # Final exit code.
 662 my $exit = 0;
 663
 664 FILE:
 665 foreach my $file (@ARGV) {
 666     print "checking '$file'...\n" if scalar @ARGV > 1;
 667
 668     -f $file or die "No such file: $file";
 669
 670     open my $fh, '<', $file or die $!;
 671
 672     # Architecture of this file.
 673     my $arch = $option_arch;
 674
 675     # Hardening options. Not all architectures support all hardening options.
 676     my $harden_format  = 1;
 677     my $harden_fortify = 1;
 678     my $harden_stack   = 1;
 679     my $harden_relro   = 1;
 680     my $harden_bindnow = $option_bindnow; # defaults to 0
 681     my $harden_pie     = $option_pie;     # defaults to 0
 682
 683     # Does this build log use ada? Ada also uses gcc as compiler but uses
 684     # different CFLAGS. But only perform ada checks if an ada compiler used
 685     # for performance reasons.
 686     my $ada = 0;
 687
 688     while (my $line = <$fh>) {
 689         # Detect architecture automatically unless overridden. For buildd logs
 690         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 691         # build logs which aren't built (wrong architecture, build error,
 692         # etc.).
 693         if (not $arch) {
 694             if (index($line, 'Build Architecture: ') == 0) {
 695                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 696             # For old logs (sbuild << 0.63.0-1).
 697             } elsif (index($line, 'Architecture: ') == 0) {
 698                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 699             }
 700         }
 701
 702         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 703         # check for hardening flags in buildd mode if an older dpkg-dev is
 704         # used. Default flags (-g -O2) are still checked.
 705         #
 706         # Packages which were built before 1.16.1 but used their own hardening
 707         # flags are not checked.
 708         if ($option_buildd
 709                 and index($line, 'Toolchain package versions: ') == 0) {
 710             require Dpkg::Version;
 711             if (not $line =~ /\bdpkg-dev_(\S+)/
 712                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 713                 $harden_format  = 0;
 714                 $harden_fortify = 0;
 715                 $harden_stack   = 0;
 716                 $harden_relro   = 0;
 717                 $harden_bindnow = 0;
 718                 $harden_pie     = 0;
 719             }
 720         }
 721
 722         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 723         # this was later dropped because upstream rejected the patch. Thus
 724         # build logs with these versions will have fortify hardening flags
 725         # enabled, even though they may be not correctly set and are missing
 726         # when build with later CMake versions. Thanks to Aron Xu for letting
 727         # me know.
 728         if (index($line, 'Package versions: ') == 0
 729                 and $line =~ /\bcmake_(\S+)/
 730                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 731             if (not $option_buildd) {
 732                 error_invalid_cmake($1);
 733                 $exit |= $exit_code{invalid_cmake};
 734             } else {
 735                 print "$buildd_tag{invalid_cmake}|$1|\n";
 736             }
 737         }
 738
 739         # Debian's build daemons use "Filtered Build-Depends:" (or just
 740         # "Build-Depends:" in older versions) for the build dependencies, but
 741         # pbuilder uses "Depends:"; support both.
 742         if (index($line, 'Filtered Build-Depends: ') == 0
 743                 or index($line, 'Build-Depends: ') == 0
 744                 or index($line, 'Depends: ') == 0) {
 745             # If hardening wrapper is used (wraps calls to gcc and adds
 746             # hardening flags automatically) we can't perform any checks,
 747             # abort.
 748             if ($line =~ /\bhardening-wrapper\b/) {
 749                 if (not $option_buildd) {
 750                     error_hardening_wrapper();
 751                     $exit |= $exit_code{hardening_wrapper};
 752                 } else {
 753                     print "$buildd_tag{hardening_wrapper}||\n";
 754                 }
 755                 next FILE;
 756             }
 757
 758             # Ada compiler.
 759             if ($line =~ /\bgnat\b/) {
 760                 $ada = 1;
 761             }
 762         }
 763
 764         # We skip over unimportant lines at the beginning of the log to
 765         # prevent false positives.
 766         last if index($line, 'dpkg-buildpackage: ') == 0;
 767     }
 768
 769     # Input lines, contain only the lines with compiler commands.
 770     my @input = ();
 771     # Non-verbose lines in the input. Used to reduce calls to
 772     # is_non_verbose_build() (which is quite slow) in the second loop when
 773     # it's already clear if a line is non-verbose or not.
 774     my @input_nonverbose = ();
 775
 776     my $continuation = 0;
 777     my $complete_line = undef;
 778     while (my $line = <$fh>) {
 779         # And stop at the end of the build log. Package details (reported by
 780         # the buildd logs) are not important for us. This also prevents false
 781         # positives.
 782         last if index($line, 'Build finished at ') == 0
 783                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 784
 785         # Detect architecture automatically unless overridden.
 786         if (not $arch
 787                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 788             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 789
 790             # Old buildd logs use e.g. "host architecture is alpha", remove
 791             # the "is", otherwise debarch_to_debtriplet() will not detect the
 792             # architecture.
 793             if (index($arch, 'is ') == 0) {
 794                 $arch = substr $arch, 3;
 795             }
 796         }
 797
 798         # Ignore compiler warnings for now.
 799         next if $line =~ /$warning_regex/o;
 800
 801         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 802             # Remove all ANSI color sequences which are sometimes used in
 803             # non-verbose builds.
 804             $line = Term::ANSIColor::colorstrip($line);
 805             # Also strip '\0xf' (delete previous character), used by Elinks'
 806             # build system.
 807             $line =~ s/\x0f//g;
 808             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 809             # what it does).
 810             $line =~ s/\033\(B//g;
 811         }
 812
 813         # Check if this line indicates a non verbose build.
 814         my $non_verbose = is_non_verbose_build($line);
 815
 816         # One line may contain multiple commands (";"). Treat each one as
 817         # single line. parse_line() is slow, only use it when necessary.
 818         my @line = (index($line, ';') == -1)
 819                  ? ($line)
 820                  : map {
 821                        # Ensure newline at the line end - necessary for
 822                        # correct parsing later.
 823                        $_ =~ s/\s+$//;
 824                        $_ .= "\n";
 825                    } Text::ParseWords::parse_line(';', 1, $line);
 826         foreach my $line (@line) {
 827             if ($continuation) {
 828                 $continuation = 0;
 829
 830                 # Join lines, but leave the "\" in place so it's clear where
 831                 # the original line break was.
 832                 chomp $complete_line;
 833                 $complete_line .= ' ' . $line;
 834             }
 835             # Line continuation, line ends with "\".
 836             if ($line =~ /\\$/) {
 837                 $continuation = 1;
 838                 # Start line continuation.
 839                 if (not defined $complete_line) {
 840                     $complete_line = $line;
 841                 }
 842                 next;
 843             }
 844
 845             # Use the complete line if a line continuation occurred.
 846             if (defined $complete_line) {
 847                 $line = $complete_line;
 848                 $complete_line = undef;
 849             }
 850
 851             # Ignore lines with no compiler commands.
 852             next if not $non_verbose
 853                     and not $line =~ /$cc_regex_normal/o;
 854             # Ignore lines with no filenames with extensions. May miss some
 855             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 856             # a problem as the log will most likely contain other non-verbose
 857             # commands which are detected.
 858             next if not $non_verbose
 859                     and not $line =~ /$file_extension_regex/o;
 860
 861             # Ignore false positives.
 862             #
 863             # `./configure` output.
 864             next if not $non_verbose
 865                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 866             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 867                                 [Cc]ompiler[\s.]*:?\s+
 868                                 /x;
 869             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 870                                 \s*=\s*$cc_regex_full
 871                                 # optional compiler options, don't allow
 872                                 # "everything" here to prevent false negatives
 873                                 \s*(?:\s-\S+)*\s*$}xo;
 874             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 875             # line (or similar for other architectures) which gets recognized
 876             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 877             # C++ files. No hardening flags are relevant during this step,
 878             # thus ignore `moc-qt*` lines. The resulting files will be
 879             # compiled in a separate step (and therefore checked).
 880             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 881                                \s.+\s
 882                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 883                                \s}x;
 884             # Ignore false positives when the line contains only CC=gcc but no
 885             # other gcc command.
 886             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 887                 my $before = $1;
 888                 my $after  = $2;
 889                 next if     not $before =~ /$cc_regex_normal/o
 890                         and not $after  =~ /$cc_regex_normal/o;
 891             }
 892
 893             # Check if additional hardening options were used. Used to ensure
 894             # they are used for the complete build.
 895             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 896                                                          @def_ldflags_pie);
 897             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 898
 899             push @input, $line;
 900             push @input_nonverbose, $non_verbose;
 901         }
 902     }
 903
 904     close $fh or die $!;
 905
 906     # Ignore arch if requested.
 907     if (scalar @option_ignore_arch > 0 and $arch) {
 908         foreach my $ignore (@option_ignore_arch) {
 909             if ($arch eq $ignore) {
 910                 print "ignoring architecture '$arch'\n";
 911                 next FILE;
 912             }
 913         }
 914     }
 915
 916     if (scalar @input == 0) {
 917         if (not $option_buildd) {
 918             print "No compiler commands!\n";
 919             $exit |= $exit_code{no_compiler_commands};
 920         } else {
 921             print "$buildd_tag{no_compiler_commands}||\n";
 922         }
 923         next FILE;
 924     }
 925
 926     if ($option_buildd) {
 927         $statistics{commands} += scalar @input;
 928     }
 929
 930     # Option or auto detected.
 931     if ($arch) {
 932         # The following was partially copied from dpkg-dev 1.17.1
 933         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 934         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 935         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 936         # later. Keep it in sync.
 937
 938         require Dpkg::Arch;
 939         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 940
 941         # Disable unsupported hardening options.
 942         if ($os !~ /^(?:linux|knetbsd|hurd)$/ or
 943                 $cpu =~ /^(?:hppa|mips|mipsel|avr32)$/) {
 944             $harden_pie = 0;
 945         }
 946         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa|arm64)$/
 947                 or $arch eq 'arm') {
 948             $harden_stack = 0;
 949         }
 950         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 951             $harden_relro   = 0;
 952             $harden_bindnow = 0;
 953         }
 954     }
 955
 956     # Default values.
 957     my @cflags   = @def_cflags;
 958     my @cxxflags = @def_cxxflags;
 959     my @cppflags = @def_cppflags;
 960     my @ldflags  = @def_ldflags;
 961     # Check the specified hardening options, same order as dpkg-buildflags.
 962     if ($harden_pie) {
 963         @cflags   = (@cflags,   @def_cflags_pie);
 964         @cxxflags = (@cxxflags, @def_cflags_pie);
 965         @ldflags  = (@ldflags,  @def_ldflags_pie);
 966     }
 967     if ($harden_stack) {
 968         @cflags   = (@cflags,   @def_cflags_stack);
 969         @cxxflags = (@cxxflags, @def_cflags_stack);
 970     }
 971     if ($harden_fortify) {
 972         @cflags   = (@cflags,   @def_cflags_fortify);
 973         @cxxflags = (@cxxflags, @def_cflags_fortify);
 974         @cppflags = (@cppflags, @def_cppflags_fortify);
 975     }
 976     if ($harden_format) {
 977         @cflags   = (@cflags,   @def_cflags_format);
 978         @cxxflags = (@cxxflags, @def_cflags_format);
 979     }
 980     if ($harden_relro) {
 981         @ldflags = (@ldflags, @def_ldflags_relro);
 982     }
 983     if ($harden_bindnow) {
 984         @ldflags = (@ldflags, @def_ldflags_bindnow);
 985     }
 986
 987     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 988     my @cflags_backup;
 989     # Ada CFLAGS, only set if ada is used.
 990     my @cflags_ada;
 991     # Ada doesn't support format hardening flags, see #680117 for more
 992     # information. Filter them out if ada is used.
 993     if ($ada and $harden_format) {
 994         @cflags_ada = grep {
 995             my $ok = 1;
 996             foreach my $flag (@def_cflags_format) {
 997                 $ok = 0 if $_ eq $flag;
 998             }
 999             $ok;
1000         } @cflags;
1001     }
1002
1003     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1004     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1005     # as long as @def_cppflags_fortify contains only one variable.
1006     if (scalar @def_cppflags_fortify == 0) {
1007         $harden_fortify = 0;
1008     }
1009
1010     # Ignore flags for this arch if requested.
1011     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1012         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1013
1014         remove_flags(\@local_flag_refs,
1015                      \%flag_renames,
1016                      @{$option_ignore_arch_flag{$arch}});
1017     }
1018
1019     my @ignore_line = @option_ignore_line;
1020     # Ignore lines for this arch if requested.
1021     if ($arch and exists $option_ignore_arch_line{$arch}) {
1022         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1023     }
1024
1025 LINE:
1026     for (my $i = 0; $i < scalar @input; $i++) {
1027         my $line = $input[$i];
1028
1029         # Ignore line if requested.
1030         foreach my $ignore (@ignore_line) {
1031             next LINE if $line =~ /$ignore/;
1032         }
1033
1034         my $skip = 0;
1035         if ($input_nonverbose[$i]
1036                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1037             if (not $option_buildd) {
1038                 error_non_verbose_build($line);
1039                 $exit |= $exit_code{non_verbose_build};
1040             } else {
1041                 $statistics{commands_nonverbose}++;
1042             }
1043             next;
1044         }
1045         # Even if it's a verbose build, we might have to skip this line (see
1046         # is_non_verbose_build()).
1047         next if $skip;
1048
1049         # Remove everything until and including the compiler command. Makes
1050         # checks easier and faster.
1051         $line =~ s/^.*?$cc_regex//o;
1052         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1053         # the brace and similar characters at the line end.
1054         $line =~ s/['")]+$//;
1055
1056         # Skip unnecessary tests when only preprocessing.
1057         my $flag_preprocess = 0;
1058
1059         my $dependency = 0;
1060         my $preprocess = 0;
1061         my $compile    = 0;
1062         my $link       = 0;
1063
1064         # Preprocess, compile, assemble.
1065         if ($line =~ /\s(-E|-S|-c)\b/) {
1066             $preprocess      = 1;
1067             $flag_preprocess = 1 if $1 eq '-E';
1068             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1069         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1070         # -MT -MQ) are always used with -M/-MM.
1071         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1072             $dependency = 1;
1073         # Otherwise assume we are linking.
1074         } else {
1075             $link = 1;
1076         }
1077
1078         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1079         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1080             $dependency      = 0;
1081             $flag_preprocess = 0;
1082         }
1083
1084         # Dependency generation for Makefiles, no preprocessing or other flags
1085         # needed.
1086         next if $dependency;
1087
1088         # Get all file extensions on this line.
1089         my @extensions = $line =~ /$file_extension_regex/go;
1090         # Ignore all unknown extensions to speedup the search below.
1091         @extensions = grep { exists $extension{$_} } @extensions;
1092
1093         # These file types don't require preprocessing.
1094         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1095             $preprocess = 0;
1096         }
1097         # These file types require preprocessing.
1098         if (extension_found(\%extensions_preprocess, @extensions)) {
1099             $preprocess = 1;
1100         }
1101
1102         if (not $flag_preprocess) {
1103             # If there are source files then it's compiling/linking in one
1104             # step and we must check both. We only check for source files
1105             # here, because header files cause too many false positives.
1106             if (extension_found(\%extensions_compile_link, @extensions)) {
1107                 # Assembly files don't need CFLAGS.
1108                 if (not extension_found(\%extensions_compile, @extensions)
1109                         and extension_found(\%extensions_no_compile, @extensions)) {
1110                     $compile = 0;
1111                 # But the rest does.
1112                 } else {
1113                     $compile = 1;
1114                 }
1115             # No compilable extensions found, either linking or compiling
1116             # header flags.
1117             #
1118             # If there are also no object files we are just compiling headers
1119             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1120             # to our liberal checks for compiler lines, this also reduces the
1121             # number of false positives considerably.
1122             } elsif ($link
1123                     and not extension_found(\%extensions_object, @extensions)) {
1124                 $link = 0;
1125             }
1126         }
1127
1128         my $compile_cpp = 0;
1129         my $compile_ada = 0;
1130         # Assume CXXFLAGS are required when a C++ file is specified in the
1131         # compiler line.
1132         if ($compile
1133                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1134             $compile     = 0;
1135             $compile_cpp = 1;
1136         # Ada needs special CFLAGS, use them if only ada files are compiled.
1137         } elsif ($ada
1138                     and $compile
1139                     and array_equal(\@extensions,
1140                                     \@source_no_preprocess_compile_ada)) {
1141             $compile_ada = 1;
1142             @cflags_backup = @cflags;
1143             @cflags        = @cflags_ada;
1144         }
1145
1146         if ($option_buildd) {
1147             $statistics{preprocess}++  if $preprocess;
1148             $statistics{compile}++     if $compile;
1149             $statistics{compile_cpp}++ if $compile_cpp;
1150             $statistics{link}++        if $link;
1151         }
1152
1153         # Check hardening flags.
1154         my @missing;
1155         if ($compile and not all_flags_used($line, \@missing, @cflags)
1156                 # Libraries linked with -fPIC don't have to (and can't) be
1157                 # linked with -fPIE as well. It's no error if only PIE flags
1158                 # are missing.
1159                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1160                 # Assume dpkg-buildflags returns the correct flags.
1161                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1162             if (not $option_buildd) {
1163                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1164                 $exit |= $exit_code{flags_missing};
1165             } else {
1166                 $statistics{compile_missing}++;
1167             }
1168         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1169                 # Libraries linked with -fPIC don't have to (and can't) be
1170                 # linked with -fPIE as well. It's no error if only PIE flags
1171                 # are missing.
1172                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1173                 # Assume dpkg-buildflags returns the correct flags.
1174                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1175             if (not $option_buildd) {
1176                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1177                 $exit |= $exit_code{flags_missing};
1178             } else {
1179                 $statistics{compile_cpp_missing}++;
1180             }
1181         }
1182         if ($preprocess
1183                 and (not all_flags_used($line, \@missing, @cppflags)
1184                     # The fortify flag might be overwritten, detect that.
1185                      or ($harden_fortify
1186                          and cppflags_fortify_broken($line, \@missing)))
1187                 # Assume dpkg-buildflags returns the correct flags.
1188                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1189             if (not $option_buildd) {
1190                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1191                 $exit |= $exit_code{flags_missing};
1192             } else {
1193                 $statistics{preprocess_missing}++;
1194             }
1195         }
1196         if ($link and not all_flags_used($line, \@missing, @ldflags)
1197                 # Same here, -fPIC conflicts with -fPIE.
1198                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1199                 # Assume dpkg-buildflags returns the correct flags.
1200                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1201             if (not $option_buildd) {
1202                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1203                 $exit |= $exit_code{flags_missing};
1204             } else {
1205                 $statistics{link_missing}++;
1206             }
1207         }
1208
1209         # Restore normal CFLAGS.
1210         if ($compile_ada) {
1211             @cflags = @cflags_backup;
1212         }
1213     }
1214 }
1215
1216 # Print statistics for buildd mode, only output in this mode.
1217 if ($option_buildd) {
1218     my @warning;
1219
1220     if ($statistics{preprocess_missing}) {
1221         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1222                                $statistics{preprocess_missing},
1223                                $statistics{preprocess};
1224     }
1225     if ($statistics{compile_missing}) {
1226         push @warning, sprintf 'CFLAGS %d (of %d)',
1227                                $statistics{compile_missing},
1228                                $statistics{compile};
1229     }
1230     if ($statistics{compile_cpp_missing}) {
1231         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1232                                $statistics{compile_cpp_missing},
1233                                $statistics{compile_cpp};
1234     }
1235     if ($statistics{link_missing}) {
1236         push @warning, sprintf 'LDFLAGS %d (of %d)',
1237                                $statistics{link_missing},
1238                                $statistics{link};
1239     }
1240     if (scalar @warning) {
1241         local $" = ', '; # array join string
1242         print "$buildd_tag{flags_missing}|@warning missing|\n";
1243     }
1244
1245     if ($statistics{commands_nonverbose}) {
1246         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1247                $statistics{commands_nonverbose},
1248                $statistics{commands},
1249     }
1250 }
1251
1252
1253 exit $exit;
1254
1255
1256 __END__
1257
1258 =head1 NAME
1259
1260 blhc - build log hardening check, checks build logs for missing hardening flags
1261
1262 =head1 SYNOPSIS
1263
1264 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1265
1266 =head1 DESCRIPTION
1267
1268 blhc is a small tool which checks build logs for missing hardening flags. It's
1269 licensed under the GPL 3 or later.
1270
1271 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1272 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1273 official buildd build logs)) to help maintainers detect missing hardening
1274 flags in their packages.
1275
1276 Only gcc is detected as compiler at the moment. If other compilers support
1277 hardening flags as well, please report them.
1278
1279 If there's no output, no flags are missing and the build log is fine.
1280
1281 See F<README> for details about performed checks, auto-detection and
1282 limitations.
1283
1284 =head1 OPTIONS
1285
1286 =over 8
1287
1288 =item B<--all>
1289
1290 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1291 auto detected.
1292
1293 =item B<--arch> I<architecture>
1294
1295 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1296 disables hardening flags not available on this architecture. Is detected
1297 automatically if dpkg-buildpackage is used.
1298
1299 =item B<--bindnow>
1300
1301 Force check for all +bindnow hardening flags. By default it's auto detected.
1302
1303 =item B<--buildd>
1304
1305 Special mode for buildds when automatically parsing log files. The following
1306 changes are in effect:
1307
1308 =over 2
1309
1310 =item *
1311
1312 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1313 possible tags.
1314
1315 =item *
1316
1317 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1318 detected).
1319
1320 =item *
1321
1322 Don't require Term::ANSIColor.
1323
1324 =item *
1325
1326 Return exit code 0, unless there was a error (-I, -W messages don't count as
1327 error).
1328
1329 =back
1330
1331 =item B<--color>
1332
1333 Use colored (ANSI) output for warning messages.
1334
1335 =item B<--ignore-arch> I<arch>
1336
1337 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1338
1339 Used to prevent false positives. This option can be specified multiple times.
1340
1341 =item B<--ignore-arch-flag> I<arch>:I<flag>
1342
1343 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1344
1345 =item B<--ignore-arch-line> I<arch>:I<line>
1346
1347 Like B<--ignore-line>, but only ignore line on I<arch>.
1348
1349 =item B<--ignore-flag> I<flag>
1350
1351 Don't print an error when the specific flag is missing in a compiler line.
1352 I<flag> is a string.
1353
1354 Used to prevent false positives. This option can be specified multiple times.
1355
1356 =item B<--ignore-line> I<regex>
1357
1358 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1359 at the beginning and end of the line to prevent false negatives.
1360
1361 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1362 warnings (which have line continuation resolved).
1363
1364 Used to prevent false positives. This option can be specified multiple times.
1365
1366 =item B<--pie>
1367
1368 Force check for all +pie hardening flags. By default it's auto detected.
1369
1370 =item B<-h -? --help>
1371
1372 Print available options.
1373
1374 =item B<--version>
1375
1376 Print version number and license.
1377
1378 =back
1379
1380 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1381 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1382 all other commands as well.
1383
1384 =head1 EXAMPLES
1385
1386 Normal usage, parse a single log file.
1387
1388     blhc path/to/log/file
1389
1390 If there's no output, no flags are missing and the build log is fine.
1391
1392 Parse multiple log files. The exit code is ORed over all files.
1393
1394     blhc path/to/directory/with/log/files/*
1395
1396 Don't treat missing C<-g> as error:
1397
1398     blhc --ignore-flag -g path/to/log/file
1399
1400 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1401
1402     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1403
1404 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1405 false positive.
1406
1407     blhc --ignore-line '\./script gcc file' path/to/log/file
1408
1409 Ignore lines matching C<./script gcc file> somewhere in the line.
1410
1411     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1412
1413 Use blhc with pbuilder.
1414
1415     pbuilder path/to/package.dsc | tee path/log/file
1416     blhc path/to/file || echo flags missing
1417
1418 =head1 BUILDD TAGS
1419
1420 The following tags are used in I<--buildd> mode. In braces the additional data
1421 which is displayed.
1422
1423 =over 2
1424
1425 =item B<I-hardening-wrapper-used>
1426
1427 The package uses hardening-wrapper which intercepts calls to gcc and adds
1428 hardening flags. The build log doesn't contain any hardening flags and thus
1429 can't be checked by blhc.
1430
1431 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1432
1433 Build log contains lines which hide the real compiler flags. For example:
1434
1435     CC test-a.c
1436     CC test-b.c
1437     CC test-c.c
1438     LD test
1439
1440 Most of the time either C<export V=1> or C<export verbose=1> in
1441 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1442 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1443 patched to remove the C<@>s hiding the real compiler commands.
1444
1445 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1446
1447 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1448
1449 =item B<I-invalid-cmake-used> (version)
1450
1451 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1452 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1453 patch was rejected by upstream and later reverted in Debian. Thus those two
1454 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1455 handle them (for example by passing them to CFLAGS). To prevent false
1456 negatives just blacklist those two versions.
1457
1458 =item B<I-no-compiler-commands>
1459
1460 No compiler commands were detected. Either the log contains none or they were
1461 not correctly detected by blhc (please report the bug in this case).
1462
1463 =back
1464
1465 =head1 EXIT STATUS
1466
1467 The exit status is a "bit mask", each listed status is ORed when the error
1468 condition occurs to get the result.
1469
1470 =over 4
1471
1472 =item B<0>
1473
1474 Success.
1475
1476 =item B<1>
1477
1478 No compiler commands were found.
1479
1480 =item B<2>
1481
1482 Invalid arguments/options given to blhc.
1483
1484 =item B<4>
1485
1486 Non verbose build.
1487
1488 =item B<8>
1489
1490 Missing hardening flags.
1491
1492 =item B<16>
1493
1494 Hardening wrapper detected, no tests performed.
1495
1496 =item B<32>
1497
1498 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1499 TAGS"> for a detailed explanation.
1500
1501 =back
1502
1503 =head1 AUTHOR
1504
1505 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1506
1507 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1508 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1509
1510 =head1 LICENSE AND COPYRIGHT
1511
1512 Copyright (C) 2012-2013 by Simon Ruderich
1513
1514 This program is free software: you can redistribute it and/or modify
1515 it under the terms of the GNU General Public License as published by
1516 the Free Software Foundation, either version 3 of the License, or
1517 (at your option) any later version.
1518
1519 This program is distributed in the hope that it will be useful,
1520 but WITHOUT ANY WARRANTY; without even the implied warranty of
1521 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1522 GNU General Public License for more details.
1523
1524 You should have received a copy of the GNU General Public License
1525 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1526
1527 =head1 SEE ALSO
1528
1529 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1530
1531 =cut