bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2018  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.08';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector',
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong',
 230 );
 231 my @def_cflags_pie = (
 232     '-fPIE',
 233 );
 234 my @def_cxxflags = (
 235     @def_cflags,
 236 );
 237 # @def_cxxflags_* is the same as @def_cflags_*.
 238 my @def_cppflags = ();
 239 my @def_cppflags_fortify = (
 240     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 241     # If you add another flag fix hack below (search for "Hack to fix") and
 242     # $def_cppflags_fortify[0].
 243 );
 244 my @def_cppflags_fortify_bad = (
 245     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 246     '-U_FORTIFY_SOURCE',
 247     '-D_FORTIFY_SOURCE=0',
 248     '-D_FORTIFY_SOURCE=1',
 249 );
 250 my @def_ldflags = ();
 251 my @def_ldflags_relro = (
 252     '-Wl,(?:-z,)?relro',
 253 );
 254 my @def_ldflags_bindnow = (
 255     '-Wl,(?:-z,)?now',
 256 );
 257 my @def_ldflags_pie = (
 258     '-fPIE',
 259     '-pie',
 260 );
 261 my @def_ldflags_pic = (
 262     '-fPIC',
 263     '-fpic',
 264     '-shared',
 265 );
 266 # References to all flags checked by the flag checker.
 267 my @flag_refs = (
 268     \@def_cflags,
 269     \@def_cflags_format,
 270     \@def_cflags_fortify,
 271     \@def_cflags_stack,
 272     \@def_cflags_stack_strong,
 273     \@def_cflags_pie,
 274     \@def_cxxflags,
 275     \@def_cppflags,
 276     \@def_cppflags_fortify,
 277     \@def_ldflags,
 278     \@def_ldflags_relro,
 279     \@def_ldflags_bindnow,
 280     \@def_ldflags_pie,
 281 );
 282 # References to all used flags.
 283 my @flag_refs_all = (
 284     @flag_refs,
 285     \@def_cflags_debug,
 286     \@def_cppflags_fortify_bad,
 287     \@def_ldflags_pic,
 288 );
 289 # Renaming rules for the output so the regex parts are not visible. Also
 290 # stores string values of flag regexps above, see compile_flag_regexp().
 291 my %flag_renames = (
 292     '-O(?:2|3)'                    => '-O2',
 293     '-Wformat(?:=2)?'              => '-Wformat',
 294     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 295     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 296     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 297 );
 298
 299 my %exit_code = (
 300     no_compiler_commands => 1 << 0,
 301     # used by POD::Usage => 1 << 1,
 302     non_verbose_build    => 1 << 2,
 303     flags_missing        => 1 << 3,
 304     hardening_wrapper    => 1 << 4,
 305     invalid_cmake        => 1 << 5,
 306 );
 307
 308 my %buildd_tag = (
 309     no_compiler_commands => 'I-no-compiler-commands',
 310     non_verbose_build    => 'W-compiler-flags-hidden',
 311     flags_missing        => 'W-dpkg-buildflags-missing',
 312     hardening_wrapper    => 'I-hardening-wrapper-used',
 313     invalid_cmake        => 'I-invalid-cmake-used',
 314 );
 315
 316 # Statistics of missing flags and non-verbose build commands. Used for
 317 # $option_buildd.
 318 my %statistics = (
 319     preprocess          => 0,
 320     preprocess_missing  => 0,
 321     compile             => 0,
 322     compile_missing     => 0,
 323     compile_cpp         => 0,
 324     compile_cpp_missing => 0,
 325     link                => 0,
 326     link_missing        => 0,
 327     commands            => 0,
 328     commands_nonverbose => 0,
 329 );
 330
 331 # Use colored (ANSI) output?
 332 my $option_color;
 333
 334
 335 # FUNCTIONS
 336
 337 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 338 sub array_equal {
 339     my ($first_ref, $second_ref) = @_;
 340
 341     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 342
 343     my $length = scalar @{$first_ref};
 344     for (my $i = 0; $i < $length; $i++) {
 345         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 346     }
 347
 348     return 1;
 349 }
 350
 351 sub error_flags {
 352     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 353
 354     # Get string value of qr//-escaped regexps and if requested rename them.
 355     my @missing_flags = map {
 356             $flag_renames_ref->{$_}
 357         } @{$missing_flags_ref};
 358
 359     my $flags = join ' ', @missing_flags;
 360     printf '%d:', $number if defined $number;
 361     printf '%s (%s)%s %s',
 362            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 363            $line;
 364
 365     return;
 366 }
 367 sub error_non_verbose_build {
 368     my ($line, $number) = @_;
 369
 370     printf '%d:', $number if defined $number;
 371     printf '%s%s %s',
 372            error_color('NONVERBOSE BUILD', 'red'),
 373            error_color(':', 'yellow'),
 374            $line;
 375
 376     return;
 377 }
 378 sub error_invalid_cmake {
 379     my ($version) = @_;
 380
 381     printf "%s%s %s\n",
 382             error_color('INVALID CMAKE', 'red'),
 383             error_color(':', 'yellow'),
 384             $version;
 385
 386     return;
 387 }
 388 sub error_hardening_wrapper {
 389     printf "%s%s %s\n",
 390             error_color('HARDENING WRAPPER', 'red'),
 391             error_color(':', 'yellow'),
 392             'no checks possible, aborting';
 393
 394     return;
 395 }
 396 sub error_color {
 397     my ($message, $color) = @_;
 398
 399     if ($option_color) {
 400         return Term::ANSIColor::colored($message, $color);
 401     } else {
 402         return $message;
 403     }
 404 }
 405
 406 sub any_flags_used {
 407     my ($line, @flags) = @_;
 408
 409     foreach my $flag (@flags) {
 410         return 1 if $line =~ /$flag/;
 411     }
 412
 413     return 0;
 414 }
 415 sub all_flags_used {
 416     my ($line, $missing_flags_ref, @flags) = @_;
 417
 418     my @missing_flags = ();
 419     foreach my $flag (@flags) {
 420         if (not $line =~ /$flag/) {
 421             push @missing_flags, $flag;
 422         }
 423     }
 424
 425     return 1 if scalar @missing_flags == 0;
 426
 427     @{$missing_flags_ref} = @missing_flags;
 428     return 0;
 429 }
 430 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 431 # $good_flag is present.
 432 sub flag_overwritten {
 433     my ($line, $good_flag, $bad_flags) = @_;
 434
 435     if (not any_flags_used($line, @{$bad_flags})) {
 436         return 0;
 437     }
 438
 439     my $bad_pos = 0;
 440     foreach my $flag (@{$bad_flags}) {
 441         while ($line =~ /$flag/g) {
 442             if ($bad_pos < $+[0]) {
 443                 $bad_pos = $+[0];
 444             }
 445         }
 446     }
 447     my $good_pos = 0;
 448     while ($line =~ /$good_flag/g) {
 449         $good_pos = $+[0];
 450     }
 451     if ($good_pos > $bad_pos) {
 452         return 0;
 453     }
 454     return 1;
 455 }
 456
 457 sub cppflags_fortify_broken {
 458     my ($line, $missing_flags) = @_;
 459
 460     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 461     my $fortify_source = $def_cppflags_fortify[0];
 462
 463     # Some build systems enable/disable fortify source multiple times, check
 464     # the final result.
 465     if (not flag_overwritten($line,
 466                              $fortify_source,
 467                              \@def_cppflags_fortify_bad)) {
 468         return 0;
 469     }
 470     push @{$missing_flags}, $fortify_source;
 471     return 1;
 472 }
 473
 474 # Modifies $missing_flags_ref array.
 475 sub pic_pie_conflict {
 476     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 477
 478     return 0 if not $pie;
 479     return 0 if not any_flags_used($line, @def_ldflags_pic);
 480
 481     my %flags = map { $_ => 1 } @flags_pie;
 482
 483     # Remove all PIE flags from @missing_flags as they are not required with
 484     # -fPIC.
 485     my @result = grep {
 486         not exists $flags{$_}
 487     } @{$missing_flags_ref};
 488     @{$missing_flags_ref} = @result;
 489
 490     # We got a conflict when no flags are left, thus only PIE flags were
 491     # missing. If other flags were missing abort because the conflict is not
 492     # the problem.
 493     return scalar @result == 0;
 494 }
 495
 496 sub is_non_verbose_build {
 497     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 498
 499     if ($line =~ /$libtool_regex/o) {
 500         # libtool's --silent hides the real compiler flags.
 501         if ($line =~ /\s--silent/) {
 502             return 1;
 503         # If --silent is not present, skip this line as some compiler flags
 504         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 505         # internally. libtool displays the real compiler command on the next
 506         # line, so the flags are checked as usual.
 507         } else {
 508             ${$skip_ref} = 1;
 509             return 0;
 510         }
 511     }
 512
 513     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 514                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 515                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 516                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 517                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 518         return 0;
 519     }
 520
 521     # False positives.
 522     #
 523     # C++ compiler setting.
 524     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 525     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 526     # "Compiling" non binary files.
 527     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 528     # "Compiling" with no file name.
 529     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 530         # $file_extension_regex may need spaces around the filename.
 531         return 0 if not " $1 " =~ /$file_extension_regex/o;
 532     }
 533
 534     my $file = $1;
 535
 536     # On the first pass we only check if this line is verbose or not.
 537     return 1 if not defined $input_ref;
 538
 539     # Second pass, we have access to the next lines.
 540     ${$skip_ref} = 0;
 541
 542     # CMake and other build systems print the non-verbose messages also when
 543     # building verbose. If a compiler and the file name occurs in the next
 544     # lines, treat it as verbose build.
 545     if (defined $file) {
 546         # Get filename, we can't use the complete path as only parts of it are
 547         # used in the real compiler command.
 548         $file =~ m{/([^/\s]+)$};
 549         $file = $1;
 550
 551         for (my $i = 1; $i <= $line_count; $i++) {
 552             my $next_line = $input_ref->[$line_offset + $i];
 553             last unless defined $next_line;
 554
 555             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 556                 # Not a non-verbose line, but we still have to skip the
 557                 # current line as it doesn't contain any compiler commands.
 558                 ${$skip_ref} = 1;
 559                 return 0;
 560             }
 561         }
 562     }
 563
 564     return 1;
 565 }
 566
 567 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 568 sub remove_flags {
 569     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 570
 571     my %removes = map { $_ => 1 } @flags;
 572     foreach my $flags (@{$flag_refs_ref}) {
 573         @{$flags} = grep {
 574             # Flag found as string.
 575             not exists $removes{$_}
 576             # Flag found as string representation of regexp.
 577                 and (not defined $flag_renames_ref->{$_}
 578                         or not exists $removes{$flag_renames_ref->{$_}})
 579         } @{$flags};
 580     }
 581
 582     return;
 583 }
 584
 585 # Modifies $flag_renames_ref hash.
 586 sub compile_flag_regexp {
 587     my ($flag_renames_ref, @flags) = @_;
 588
 589     my @result = ();
 590     foreach my $flag (@flags) {
 591         # Compile flag regexp for faster execution.
 592         my $regex = qr/\s$flag(?:\s|\\)/;
 593
 594         # Store flag name in replacement string for correct flags in messages
 595         # with qr//ed flag regexps.
 596         $flag_renames_ref->{$regex}
 597             = (exists $flag_renames_ref->{$flag})
 598                 ? $flag_renames_ref->{$flag}
 599                 : $flag;
 600
 601         push @result, $regex;
 602     }
 603     return @result;
 604 }
 605
 606 # Does any extension in @extensions exist in %{$extensions_ref}?
 607 sub extension_found {
 608     my ($extensions_ref, @extensions) = @_;
 609
 610     foreach my $extension (@extensions) {
 611         if (exists $extensions_ref->{$extension}) {
 612             return 1;
 613         }
 614     }
 615     return 0;
 616 }
 617
 618
 619 # MAIN
 620
 621 # Parse command line arguments.
 622 my $option_help             = 0;
 623 my $option_version          = 0;
 624 my $option_pie              = 0;
 625 my $option_bindnow          = 0;
 626 my @option_ignore_arch      = ();
 627 my @option_ignore_flag      = ();
 628 my @option_ignore_arch_flag = ();
 629 my @option_ignore_line      = ();
 630 my @option_ignore_arch_line = ();
 631 my $option_all              = 0;
 632 my $option_arch             = undef;
 633 my $option_buildd           = 0;
 634 my $option_debian           = 0;
 635    $option_color            = 0;
 636 my $option_line_numbers     = 0;
 637 if (not Getopt::Long::GetOptions(
 638             'help|h|?'           => \$option_help,
 639             'version'            => \$option_version,
 640             # Hardening options.
 641             'pie'                => \$option_pie,
 642             'bindnow'            => \$option_bindnow,
 643             'all'                => \$option_all,
 644             # Ignore.
 645             'ignore-arch=s'      => \@option_ignore_arch,
 646             'ignore-flag=s'      => \@option_ignore_flag,
 647             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 648             'ignore-line=s'      => \@option_ignore_line,
 649             'ignore-arch-line=s' => \@option_ignore_arch_line,
 650             # Misc.
 651             'color'              => \$option_color,
 652             'arch=s'             => \$option_arch,
 653             'buildd'             => \$option_buildd,
 654             'debian'             => \$option_debian,
 655             'line-numbers'       => \$option_line_numbers,
 656         )) {
 657     require Pod::Usage;
 658     Pod::Usage::pod2usage(2);
 659 }
 660 if ($option_help) {
 661     require Pod::Usage;
 662     Pod::Usage::pod2usage(1);
 663 }
 664 if ($option_version) {
 665     print <<"EOF";
 666 blhc $VERSION  Copyright (C) 2012-2018  Simon Ruderich
 667
 668 This program is free software: you can redistribute it and/or modify
 669 it under the terms of the GNU General Public License as published by
 670 the Free Software Foundation, either version 3 of the License, or
 671 (at your option) any later version.
 672
 673 This program is distributed in the hope that it will be useful,
 674 but WITHOUT ANY WARRANTY; without even the implied warranty of
 675 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 676 GNU General Public License for more details.
 677
 678 You should have received a copy of the GNU General Public License
 679 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 680 EOF
 681     exit 0;
 682 }
 683
 684 # Arguments missing.
 685 if (scalar @ARGV == 0) {
 686     require Pod::Usage;
 687     Pod::Usage::pod2usage(2);
 688 }
 689
 690 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 691 # installed on Debian's buildds.
 692 if (not $option_buildd) {
 693     require Term::ANSIColor;
 694 }
 695
 696 if ($option_all) {
 697     $option_pie     = 1;
 698     $option_bindnow = 1;
 699 }
 700
 701 # Precompiled ignores for faster lookup.
 702 my %option_ignore_arch_flag = ();
 703 my %option_ignore_arch_line = ();
 704
 705 # Strip flags which should be ignored.
 706 if (scalar @option_ignore_flag > 0) {
 707     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 708 }
 709 # Same for arch specific ignore flags, but only prepare here.
 710 if (scalar @option_ignore_arch_flag > 0) {
 711     foreach my $ignore (@option_ignore_arch_flag) {
 712         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 713
 714         if (not $ignore_arch or not $ignore_flag) {
 715             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 716                         . '("arch:flag" expected)' . "\n", $ignore;
 717             require Pod::Usage;
 718             Pod::Usage::pod2usage(2);
 719         }
 720
 721         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 722     }
 723 }
 724
 725 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 726 # faster with this.
 727 foreach my $flags (@flag_refs_all) {
 728     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 729 }
 730
 731 # Precompile ignore line regexps, also anchor at beginning and end of line.
 732 foreach my $ignore (@option_ignore_line) {
 733     $ignore = qr/^$ignore$/;
 734 }
 735 # Same for arch specific ignore lines.
 736 if (scalar @option_ignore_arch_line > 0) {
 737     foreach my $ignore (@option_ignore_arch_line) {
 738         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 739
 740         if (not $ignore_arch or not $ignore_line) {
 741             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 742                         . '("arch:line" expected)' . "\n", $ignore;
 743             require Pod::Usage;
 744             Pod::Usage::pod2usage(2);
 745         }
 746
 747         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 748     }
 749 }
 750
 751 # Final exit code.
 752 my $exit = 0;
 753
 754 FILE:
 755 foreach my $file (@ARGV) {
 756     print "checking '$file'...\n" if scalar @ARGV > 1;
 757
 758     -f $file or die "No such file: $file";
 759
 760     open my $fh, '<', $file or die $!;
 761
 762     # Architecture of this file.
 763     my $arch = $option_arch;
 764
 765     # Hardening options. Not all architectures support all hardening options.
 766     my $harden_format  = 1;
 767     my $harden_fortify = 1;
 768     my $harden_stack   = 1;
 769     my $harden_stack_strong = 1;
 770     my $harden_relro   = 1;
 771     my $harden_bindnow = $option_bindnow; # defaults to 0
 772     my $harden_pie     = $option_pie;     # defaults to 0
 773
 774     # Does this build log use ada? Ada also uses gcc as compiler but uses
 775     # different CFLAGS. But only perform ada checks if an ada compiler is used
 776     # for performance reasons.
 777     my $ada = 0;
 778     # Fortran also requires different CFLAGS.
 779     my $fortran = 0;
 780
 781     # Number of parallel jobs to prevent false positives when detecting
 782     # non-verbose builds. As not all jobs declare the number of parallel jobs
 783     # use a large enough default.
 784     my $parallel = 10;
 785
 786     # Don't check for PIE flags if automatically applied by the compiler. Only
 787     # used in buildd and Debian mode.
 788     my $disable_harden_pie = 0;
 789     if ($option_debian) {
 790         $disable_harden_pie = 1;
 791     }
 792
 793     my $number = 0;
 794     while (my $line = <$fh>) {
 795         $number++;
 796
 797         # Detect architecture automatically unless overridden. For buildd logs
 798         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 799         # build logs which aren't built (wrong architecture, build error,
 800         # etc.).
 801         if (not $arch) {
 802             if (index($line, 'Build Architecture: ') == 0) {
 803                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 804             # For old logs (sbuild << 0.63.0-1).
 805             } elsif (index($line, 'Architecture: ') == 0) {
 806                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 807             }
 808         }
 809
 810         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 811         # check for hardening flags in buildd mode if an older dpkg-dev is
 812         # used. Default flags (-g -O2) are still checked.
 813         #
 814         # Packages which were built before 1.16.1 but used their own hardening
 815         # flags are not checked.
 816         #
 817         # Strong stack protector is used since dpkg 1.17.11.
 818         #
 819         # Recent GCC versions automatically use PIE (only on supported
 820         # architectures) and dpkg respects this properly since 1.18.15 and
 821         # doesn't pass PIE flags manually.
 822         if ($option_buildd
 823                 and index($line, 'Toolchain package versions: ') == 0) {
 824             require Dpkg::Version;
 825
 826             my $disable = 1;
 827             my $disable_strong = 1;
 828
 829             if ($line =~ /\bdpkg-dev_(\S+)/) {
 830                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 831                     $disable = 0;
 832                 }
 833                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 834                     $disable_strong = 0;
 835                 }
 836                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 837                     $disable_harden_pie = 1;
 838                 }
 839             }
 840
 841             if ($disable) {
 842                 $harden_format  = 0;
 843                 $harden_fortify = 0;
 844                 $harden_stack   = 0;
 845                 $harden_relro   = 0;
 846                 $harden_bindnow = 0;
 847                 $harden_pie     = 0;
 848             }
 849             if ($disable_strong) {
 850                 $harden_stack_strong = 0;
 851             }
 852         }
 853
 854         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 855         # this was later dropped because upstream rejected the patch. Thus
 856         # build logs with these versions will have fortify hardening flags
 857         # enabled, even though they may be not correctly set and are missing
 858         # when build with later CMake versions. Thanks to Aron Xu for letting
 859         # me know.
 860         if (index($line, 'Package versions: ') == 0
 861                 and $line =~ /\bcmake_(\S+)/
 862                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 863             if (not $option_buildd) {
 864                 error_invalid_cmake($1);
 865                 $exit |= $exit_code{invalid_cmake};
 866             } else {
 867                 print "$buildd_tag{invalid_cmake}|$1|\n";
 868             }
 869         }
 870
 871         # Debian's build daemons use "Filtered Build-Depends:" (or just
 872         # "Build-Depends:" in older versions) for the build dependencies, but
 873         # pbuilder uses "Depends:"; support both.
 874         if (index($line, 'Filtered Build-Depends: ') == 0
 875                 or index($line, 'Build-Depends: ') == 0
 876                 or index($line, 'Depends: ') == 0) {
 877             # If hardening wrapper is used (wraps calls to gcc and adds
 878             # hardening flags automatically) we can't perform any checks,
 879             # abort.
 880             if ($line =~ /\bhardening-wrapper\b/) {
 881                 if (not $option_buildd) {
 882                     error_hardening_wrapper();
 883                     $exit |= $exit_code{hardening_wrapper};
 884                 } else {
 885                     print "$buildd_tag{hardening_wrapper}||\n";
 886                 }
 887                 next FILE;
 888             }
 889
 890             # Ada compiler.
 891             if ($line =~ /\bgnat\b/) {
 892                 $ada = 1;
 893             }
 894             # Fortran compiler.
 895             if ($line =~ /\bgfortran\b/) {
 896                 $fortran = 1;
 897             }
 898         }
 899
 900         # This flags is not always available, but if it is use it.
 901         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 902             $parallel = $1 * 2;
 903         }
 904
 905         # We skip over unimportant lines at the beginning of the log to
 906         # prevent false positives.
 907         last if index($line, 'dpkg-buildpackage: ') == 0;
 908     }
 909
 910     # Input lines, contain only the lines with compiler commands.
 911     my @input = ();
 912     # Non-verbose lines in the input. Used to reduce calls to
 913     # is_non_verbose_build() (which is quite slow) in the second loop when
 914     # it's already clear if a line is non-verbose or not.
 915     my @input_nonverbose = ();
 916     # Input line number.
 917     my @input_number = ();
 918
 919     my $continuation = 0;
 920     my $complete_line = undef;
 921     my $non_verbose;
 922     while (my $line = <$fh>) {
 923         $number++;
 924
 925         # And stop at the end of the build log. Package details (reported by
 926         # the buildd logs) are not important for us. This also prevents false
 927         # positives.
 928         last if index($line, 'Build finished at ') == 0
 929                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 930
 931         if (not $continuation) {
 932             $non_verbose = 0;
 933         }
 934
 935         # Detect architecture automatically unless overridden.
 936         if (not $arch
 937                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 938             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 939
 940             # Old buildd logs use e.g. "host architecture is alpha", remove
 941             # the "is", otherwise debarch_to_debtriplet() will not detect the
 942             # architecture.
 943             if (index($arch, 'is ') == 0) {
 944                 $arch = substr $arch, 3;
 945             }
 946         }
 947
 948         next if $line =~ /^\s*#/;
 949         # Ignore compiler warnings for now.
 950         next if $line =~ /$warning_regex/o;
 951
 952         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 953             # Remove all ANSI color sequences which are sometimes used in
 954             # non-verbose builds.
 955             $line = Term::ANSIColor::colorstrip($line);
 956             # Also strip '\0xf' (delete previous character), used by Elinks'
 957             # build system.
 958             $line =~ s/\x0f//g;
 959             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 960             # what it does).
 961             $line =~ s/\033\(B//g;
 962         }
 963
 964         # Check if this line indicates a non verbose build.
 965         my $skip = 0;
 966         $non_verbose |= is_non_verbose_build($line, \$skip);
 967         next if $skip;
 968
 969         # One line may contain multiple commands (";"). Treat each one as
 970         # single line. parse_line() is slow, only use it when necessary.
 971         my @line = (index($line, ';') == -1)
 972                  ? ($line)
 973                  : map {
 974                        # Ensure newline at the line end - necessary for
 975                        # correct parsing later.
 976                        $_ =~ s/\s+$//;
 977                        $_ .= "\n";
 978                    } Text::ParseWords::parse_line(';', 1, $line);
 979         foreach my $line (@line) {
 980             if ($continuation) {
 981                 $continuation = 0;
 982
 983                 # Join lines, but leave the "\" in place so it's clear where
 984                 # the original line break was.
 985                 chomp $complete_line;
 986                 $complete_line .= ' ' . $line;
 987             }
 988             # Line continuation, line ends with "\".
 989             if ($line =~ /\\$/) {
 990                 $continuation = 1;
 991                 # Start line continuation.
 992                 if (not defined $complete_line) {
 993                     $complete_line = $line;
 994                 }
 995                 next;
 996             }
 997
 998             # Use the complete line if a line continuation occurred.
 999             if (defined $complete_line) {
1000                 $line = $complete_line;
1001                 $complete_line = undef;
1002             }
1003
1004             # Ignore lines with no compiler commands.
1005             next if not $non_verbose
1006                     and not $line =~ /$cc_regex_normal/o;
1007             # Ignore lines with no filenames with extensions. May miss some
1008             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1009             # a problem as the log will most likely contain other non-verbose
1010             # commands which are detected.
1011             next if not $non_verbose
1012                     and not $line =~ /$file_extension_regex/o;
1013
1014             # Ignore false positives.
1015             #
1016             # `./configure` output.
1017             next if not $non_verbose
1018                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1019             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1020                                 [Cc]ompiler[\s.]*:?\s+
1021                                 /x;
1022             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1023                                 \s*=\s*$cc_regex_full
1024                                 # optional compiler options, don't allow
1025                                 # "everything" here to prevent false negatives
1026                                 \s*(?:\s-\S+)*\s*$}xo;
1027             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1028             # line (or similar for other architectures) which gets recognized
1029             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1030             # C++ files. No hardening flags are relevant during this step,
1031             # thus ignore `moc-qt*` lines. The resulting files will be
1032             # compiled in a separate step (and therefore checked).
1033             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1034                                \s.+\s
1035                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1036                                \s}x;
1037             # Ignore false positives when the line contains only CC=gcc but no
1038             # other gcc command.
1039             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1040                 my $before = $1;
1041                 my $after  = $2;
1042                 next if     not $before =~ /$cc_regex_normal/o
1043                         and not $after  =~ /$cc_regex_normal/o;
1044             }
1045             # Ignore false positives caused by gcc -v. It outputs a line
1046             # looking like a normal compiler line but which is sometimes
1047             # missing hardening flags, although the normal compiler line
1048             # contains them.
1049             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1050                                    [0-9.]+/cc1(?:plus)?}xo;
1051             # Ignore false positive with `rm` which may remove files which
1052             # look like a compiler executable thus causing the line to be
1053             # treated as a normal compiler line.
1054             next if $line =~ m{^\s*rm\s+};
1055             # Some build systems emit "gcc > file".
1056             next if $line =~ m{$cc_regex_normal\s*>\s*\S+};
1057
1058             # Check if additional hardening options were used. Used to ensure
1059             # they are used for the complete build.
1060             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1061                                                          @def_ldflags_pie);
1062             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1063
1064             push @input, $line;
1065             push @input_nonverbose, $non_verbose;
1066             push @input_number, $number if $option_line_numbers;
1067         }
1068     }
1069
1070     close $fh or die $!;
1071
1072     # Ignore arch if requested.
1073     if (scalar @option_ignore_arch > 0 and $arch) {
1074         foreach my $ignore (@option_ignore_arch) {
1075             if ($arch eq $ignore) {
1076                 print "ignoring architecture '$arch'\n";
1077                 next FILE;
1078             }
1079         }
1080     }
1081
1082     if (scalar @input == 0) {
1083         if (not $option_buildd) {
1084             print "No compiler commands!\n";
1085             $exit |= $exit_code{no_compiler_commands};
1086         } else {
1087             print "$buildd_tag{no_compiler_commands}||\n";
1088         }
1089         next FILE;
1090     }
1091
1092     if ($option_buildd) {
1093         $statistics{commands} += scalar @input;
1094     }
1095
1096     # Option or auto detected.
1097     if ($arch) {
1098         # The following was partially copied from dpkg-dev 1.19.0.5
1099         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1100         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1101         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1102         # licensed under GPL version 2 or later. Keep it in sync.
1103
1104         require Dpkg::Arch;
1105         my ($os, $cpu);
1106         # Recent dpkg versions use a quadruplet for arch. Support both.
1107         eval {
1108             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1109         };
1110         if ($@) {
1111             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1112         }
1113
1114         my %builtin_pie_arch = map { $_ => 1 } qw(
1115             amd64 arm64 armel armhf hurd-i386 i386 kfreebsd-amd64 kfreebsd-i386
1116             mips mipsel mips64el powerpc ppc64 ppc64el s390x sparc sparc64
1117         );
1118
1119         # Disable unsupported hardening options.
1120         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1121                 or $cpu =~ /^(?:hppa|avr32)$/) {
1122             $harden_pie = 0;
1123         }
1124         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1125             $harden_stack = 0;
1126             $harden_stack_strong = 0;
1127         }
1128         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1129             $harden_relro   = 0;
1130             $harden_bindnow = 0;
1131         }
1132
1133         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1134             $harden_pie = 0;
1135         }
1136     }
1137
1138     # Default values.
1139     my @cflags   = @def_cflags;
1140     my @cxxflags = @def_cxxflags;
1141     my @cppflags = @def_cppflags;
1142     my @ldflags  = @def_ldflags;
1143     # Check the specified hardening options, same order as dpkg-buildflags.
1144     if ($harden_pie) {
1145         @cflags   = (@cflags,   @def_cflags_pie);
1146         @cxxflags = (@cxxflags, @def_cflags_pie);
1147         @ldflags  = (@ldflags,  @def_ldflags_pie);
1148     }
1149     if ($harden_stack_strong) {
1150         @cflags   = (@cflags,   @def_cflags_stack_strong);
1151         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1152     } elsif ($harden_stack) {
1153         @cflags   = (@cflags,   @def_cflags_stack);
1154         @cxxflags = (@cxxflags, @def_cflags_stack);
1155     }
1156     if ($harden_fortify) {
1157         @cflags   = (@cflags,   @def_cflags_fortify);
1158         @cxxflags = (@cxxflags, @def_cflags_fortify);
1159         @cppflags = (@cppflags, @def_cppflags_fortify);
1160     }
1161     if ($harden_format) {
1162         @cflags   = (@cflags,   @def_cflags_format);
1163         @cxxflags = (@cxxflags, @def_cflags_format);
1164     }
1165     if ($harden_relro) {
1166         @ldflags = (@ldflags, @def_ldflags_relro);
1167     }
1168     if ($harden_bindnow) {
1169         @ldflags = (@ldflags, @def_ldflags_bindnow);
1170     }
1171
1172     # Ada doesn't support format hardening flags, see #680117 for more
1173     # information. Same for fortran. Filter them out if either language is
1174     # used.
1175     my @cflags_backup;
1176     my @cflags_noformat;
1177     if (($ada or $fortran) and $harden_format) {
1178         @cflags_noformat = grep {
1179             my $ok = 1;
1180             foreach my $flag (@def_cflags_format) {
1181                 $ok = 0 if $_ eq $flag;
1182             }
1183             $ok;
1184         } @cflags;
1185     }
1186
1187     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1188     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1189     # as long as @def_cppflags_fortify contains only one variable.
1190     if (scalar @def_cppflags_fortify == 0) {
1191         $harden_fortify = 0;
1192     }
1193
1194     # Ignore flags for this arch if requested.
1195     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1196         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1197
1198         remove_flags(\@local_flag_refs,
1199                      \%flag_renames,
1200                      @{$option_ignore_arch_flag{$arch}});
1201     }
1202
1203     my @ignore_line = @option_ignore_line;
1204     # Ignore lines for this arch if requested.
1205     if ($arch and exists $option_ignore_arch_line{$arch}) {
1206         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1207     }
1208
1209 LINE:
1210     for (my $i = 0; $i < scalar @input; $i++) {
1211         my $line = $input[$i];
1212
1213         # Ignore line if requested.
1214         foreach my $ignore (@ignore_line) {
1215             next LINE if $line =~ /$ignore/;
1216         }
1217
1218         my $skip = 0;
1219         if ($input_nonverbose[$i]
1220                 and is_non_verbose_build($line, \$skip,
1221                                          \@input, $i, $parallel)) {
1222             if (not $option_buildd) {
1223                 error_non_verbose_build($line, $input_number[$i]);
1224                 $exit |= $exit_code{non_verbose_build};
1225             } else {
1226                 $statistics{commands_nonverbose}++;
1227             }
1228             next;
1229         }
1230         # Even if it's a verbose build, we might have to skip this line (see
1231         # is_non_verbose_build()).
1232         next if $skip;
1233
1234         my $orig_line = $line;
1235
1236         # Remove everything until and including the compiler command. Makes
1237         # checks easier and faster.
1238         $line =~ s/^.*?$cc_regex//o;
1239         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1240         # the brace and similar characters at the line end.
1241         $line =~ s/['")]+$//;
1242
1243         # Skip unnecessary tests when only preprocessing.
1244         my $flag_preprocess = 0;
1245
1246         my $dependency = 0;
1247         my $preprocess = 0;
1248         my $compile    = 0;
1249         my $link       = 0;
1250
1251         # Preprocess, compile, assemble.
1252         if ($line =~ /\s(-E|-S|-c)\b/) {
1253             $preprocess      = 1;
1254             $flag_preprocess = 1 if $1 eq '-E';
1255             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1256         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1257         # -MT -MQ) are always used with -M/-MM.
1258         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1259             $dependency = 1;
1260         # Otherwise assume we are linking.
1261         } else {
1262             $link = 1;
1263         }
1264
1265         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1266         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1267             $dependency      = 0;
1268             $flag_preprocess = 0;
1269         }
1270
1271         # Dependency generation for Makefiles, no preprocessing or other flags
1272         # needed.
1273         next if $dependency;
1274
1275         # Get all file extensions on this line.
1276         my @extensions = $line =~ /$file_extension_regex/go;
1277         # Ignore all unknown extensions to speedup the search below.
1278         @extensions = grep { exists $extension{$_} } @extensions;
1279
1280         # These file types don't require preprocessing.
1281         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1282             $preprocess = 0;
1283         }
1284         # These file types require preprocessing.
1285         if (extension_found(\%extensions_preprocess, @extensions)) {
1286             # Prevent false positives with "libtool: link: g++ -include test.h
1287             # .." compiler lines.
1288             if ($orig_line !~ /$libtool_link_regex/o) {
1289                 $preprocess = 1;
1290             }
1291         }
1292
1293         if (not $flag_preprocess) {
1294             # If there are source files then it's compiling/linking in one
1295             # step and we must check both. We only check for source files
1296             # here, because header files cause too many false positives.
1297             if (extension_found(\%extensions_compile_link, @extensions)) {
1298                 # Assembly files don't need CFLAGS.
1299                 if (not extension_found(\%extensions_compile, @extensions)
1300                         and extension_found(\%extensions_no_compile, @extensions)) {
1301                     $compile = 0;
1302                 # But the rest does.
1303                 } else {
1304                     $compile = 1;
1305                 }
1306             # No compilable extensions found, either linking or compiling
1307             # header flags.
1308             #
1309             # If there are also no object files we are just compiling headers
1310             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1311             # to our liberal checks for compiler lines, this also reduces the
1312             # number of false positives considerably.
1313             } elsif ($link
1314                     and not extension_found(\%extensions_object, @extensions)) {
1315                 $link = 0;
1316             }
1317         }
1318
1319         my $compile_cpp = 0;
1320         my $restore_cflags = 0;
1321         # Assume CXXFLAGS are required when a C++ file is specified in the
1322         # compiler line.
1323         if ($compile
1324                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1325             $compile     = 0;
1326             $compile_cpp = 1;
1327         # Ada needs special CFLAGS, use them if only ada files are compiled.
1328         } elsif ($ada
1329                 and extension_found(\%extensions_ada, @extensions)) {
1330             $restore_cflags = 1;
1331             $preprocess = 0; # Ada uses no CPPFLAGS
1332             @cflags_backup = @cflags;
1333             @cflags        = @cflags_noformat;
1334         # Same for fortran.
1335         } elsif ($fortran
1336                 and extension_found(\%extensions_fortran, @extensions)) {
1337             $restore_cflags = 1;
1338             @cflags_backup = @cflags;
1339             @cflags        = @cflags_noformat;
1340         }
1341
1342         if ($option_buildd) {
1343             $statistics{preprocess}++  if $preprocess;
1344             $statistics{compile}++     if $compile;
1345             $statistics{compile_cpp}++ if $compile_cpp;
1346             $statistics{link}++        if $link;
1347         }
1348
1349         # Check if there are flags indicating a debug build. If that's true,
1350         # skip the check for -O2. This prevents fortification, but that's fine
1351         # for a debug build.
1352         if (any_flags_used($line, @def_cflags_debug)) {
1353             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1354             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1355         }
1356
1357         # Check hardening flags.
1358         my @missing;
1359         if ($compile and not all_flags_used($line, \@missing, @cflags)
1360                 # Libraries linked with -fPIC don't have to (and can't) be
1361                 # linked with -fPIE as well. It's no error if only PIE flags
1362                 # are missing.
1363                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1364                 # Assume dpkg-buildflags returns the correct flags.
1365                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1366             if (not $option_buildd) {
1367                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1368                             $input[$i], $input_number[$i]);
1369                 $exit |= $exit_code{flags_missing};
1370             } else {
1371                 $statistics{compile_missing}++;
1372             }
1373         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1374                 # Libraries linked with -fPIC don't have to (and can't) be
1375                 # linked with -fPIE as well. It's no error if only PIE flags
1376                 # are missing.
1377                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1378                 # Assume dpkg-buildflags returns the correct flags.
1379                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1380             if (not $option_buildd) {
1381                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1382                             $input[$i], $input_number[$i]);
1383                 $exit |= $exit_code{flags_missing};
1384             } else {
1385                 $statistics{compile_cpp_missing}++;
1386             }
1387         }
1388         if ($preprocess
1389                 and (not all_flags_used($line, \@missing, @cppflags)
1390                     # The fortify flag might be overwritten, detect that.
1391                      or ($harden_fortify
1392                          and cppflags_fortify_broken($line, \@missing)))
1393                 # Assume dpkg-buildflags returns the correct flags.
1394                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1395             if (not $option_buildd) {
1396                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1397                             $input[$i], $input_number[$i]);
1398                 $exit |= $exit_code{flags_missing};
1399             } else {
1400                 $statistics{preprocess_missing}++;
1401             }
1402         }
1403         if ($link and not all_flags_used($line, \@missing, @ldflags)
1404                 # Same here, -fPIC conflicts with -fPIE.
1405                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1406                 # Assume dpkg-buildflags returns the correct flags.
1407                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1408             if (not $option_buildd) {
1409                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1410                             $input[$i], $input_number[$i]);
1411                 $exit |= $exit_code{flags_missing};
1412             } else {
1413                 $statistics{link_missing}++;
1414             }
1415         }
1416
1417         # Restore normal CFLAGS.
1418         if ($restore_cflags) {
1419             @cflags = @cflags_backup;
1420         }
1421     }
1422 }
1423
1424 # Print statistics for buildd mode, only output in this mode.
1425 if ($option_buildd) {
1426     my @warning;
1427
1428     if ($statistics{preprocess_missing}) {
1429         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1430                                $statistics{preprocess_missing},
1431                                $statistics{preprocess};
1432     }
1433     if ($statistics{compile_missing}) {
1434         push @warning, sprintf 'CFLAGS %d (of %d)',
1435                                $statistics{compile_missing},
1436                                $statistics{compile};
1437     }
1438     if ($statistics{compile_cpp_missing}) {
1439         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1440                                $statistics{compile_cpp_missing},
1441                                $statistics{compile_cpp};
1442     }
1443     if ($statistics{link_missing}) {
1444         push @warning, sprintf 'LDFLAGS %d (of %d)',
1445                                $statistics{link_missing},
1446                                $statistics{link};
1447     }
1448     if (scalar @warning) {
1449         local $" = ', '; # array join string
1450         print "$buildd_tag{flags_missing}|@warning missing|\n";
1451     }
1452
1453     if ($statistics{commands_nonverbose}) {
1454         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1455                $statistics{commands_nonverbose},
1456                $statistics{commands},
1457     }
1458 }
1459
1460
1461 exit $exit;
1462
1463
1464 __END__
1465
1466 =head1 NAME
1467
1468 blhc - build log hardening check, checks build logs for missing hardening flags
1469
1470 =head1 SYNOPSIS
1471
1472 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1473
1474 =head1 DESCRIPTION
1475
1476 blhc is a small tool which checks build logs for missing hardening flags. It's
1477 licensed under the GPL 3 or later.
1478
1479 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1480 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1481 official buildd build logs)) to help maintainers detect missing hardening
1482 flags in their packages.
1483
1484 Only gcc is detected as compiler at the moment. If other compilers support
1485 hardening flags as well, please report them.
1486
1487 If there's no output, no flags are missing and the build log is fine.
1488
1489 See F<README> for details about performed checks, auto-detection and
1490 limitations.
1491
1492 =head1 OPTIONS
1493
1494 =over 8
1495
1496 =item B<--all>
1497
1498 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1499 auto detected.
1500
1501 =item B<--arch> I<architecture>
1502
1503 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1504 disables hardening flags not available on this architecture. Is detected
1505 automatically if dpkg-buildpackage is used.
1506
1507 =item B<--bindnow>
1508
1509 Force check for all +bindnow hardening flags. By default it's auto detected.
1510
1511 =item B<--buildd>
1512
1513 Special mode for buildds when automatically parsing log files. The following
1514 changes are in effect:
1515
1516 =over 2
1517
1518 =item *
1519
1520 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1521 possible tags.
1522
1523 =item *
1524
1525 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1526 detected).
1527
1528 =item *
1529
1530 Don't require Term::ANSIColor.
1531
1532 =item *
1533
1534 Return exit code 0, unless there was a error (-I, -W messages don't count as
1535 error).
1536
1537 =back
1538
1539 =item B<--debian>
1540
1541 Apply Debian-specific settings. At the moment this only disables checking for
1542 PIE which is automatically applied by Debian's GCC and no longer requires a
1543 compiler command line argument.
1544
1545 =item B<--color>
1546
1547 Use colored (ANSI) output for warning messages.
1548
1549 =item B<--line-numbers>
1550
1551 Display line numbers.
1552
1553 =item B<--ignore-arch> I<arch>
1554
1555 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1556
1557 Used to prevent false positives. This option can be specified multiple times.
1558
1559 =item B<--ignore-arch-flag> I<arch>:I<flag>
1560
1561 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1562
1563 =item B<--ignore-arch-line> I<arch>:I<line>
1564
1565 Like B<--ignore-line>, but only ignore line on I<arch>.
1566
1567 =item B<--ignore-flag> I<flag>
1568
1569 Don't print an error when the specific flag is missing in a compiler line.
1570 I<flag> is a string.
1571
1572 Used to prevent false positives. This option can be specified multiple times.
1573
1574 =item B<--ignore-line> I<regex>
1575
1576 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1577 at the beginning and end of the line to prevent false negatives.
1578
1579 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1580 warnings (which have line continuation resolved).
1581
1582 Used to prevent false positives. This option can be specified multiple times.
1583
1584 =item B<--pie>
1585
1586 Force check for all +pie hardening flags. By default it's auto detected.
1587
1588 =item B<-h -? --help>
1589
1590 Print available options.
1591
1592 =item B<--version>
1593
1594 Print version number and license.
1595
1596 =back
1597
1598 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1599 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1600 all other commands as well.
1601
1602 =head1 EXAMPLES
1603
1604 Normal usage, parse a single log file.
1605
1606     blhc path/to/log/file
1607
1608 If there's no output, no flags are missing and the build log is fine.
1609
1610 Parse multiple log files. The exit code is ORed over all files.
1611
1612     blhc path/to/directory/with/log/files/*
1613
1614 Don't treat missing C<-g> as error:
1615
1616     blhc --ignore-flag -g path/to/log/file
1617
1618 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1619
1620     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1621
1622 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1623 false positive.
1624
1625     blhc --ignore-line '\./script gcc file' path/to/log/file
1626
1627 Ignore lines matching C<./script gcc file> somewhere in the line.
1628
1629     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1630
1631 Use blhc with pbuilder.
1632
1633     pbuilder path/to/package.dsc | tee path/log/file
1634     blhc path/to/file || echo flags missing
1635
1636 Assume this build log was created on a Debian system and thus don't warn about
1637 missing PIE flags if the current architecture injects them automatically (this
1638 is enabled in buildd mode per default). C<--arch> is necessary if the build
1639 log contains no architecture information as written by dpkg-buildpackage.
1640
1641     blhc --debian --all --arch=amd64 path/to/log/file
1642
1643 =head1 BUILDD TAGS
1644
1645 The following tags are used in I<--buildd> mode. In braces the additional data
1646 which is displayed.
1647
1648 =over 2
1649
1650 =item B<I-hardening-wrapper-used>
1651
1652 The package uses hardening-wrapper which intercepts calls to gcc and adds
1653 hardening flags. The build log doesn't contain any hardening flags and thus
1654 can't be checked by blhc.
1655
1656 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1657
1658 Build log contains lines which hide the real compiler flags. For example:
1659
1660     CC test-a.c
1661     CC test-b.c
1662     CC test-c.c
1663     LD test
1664
1665 Most of the time either C<export V=1> or C<export verbose=1> in
1666 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1667 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1668 patched to remove the C<@>s hiding the real compiler commands.
1669
1670 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1671
1672 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1673
1674 =item B<I-invalid-cmake-used> (version)
1675
1676 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1677 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1678 patch was rejected by upstream and later reverted in Debian. Thus those two
1679 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1680 handle them (for example by passing them to CFLAGS). To prevent false
1681 negatives just blacklist those two versions.
1682
1683 =item B<I-no-compiler-commands>
1684
1685 No compiler commands were detected. Either the log contains none or they were
1686 not correctly detected by blhc (please report the bug in this case).
1687
1688 =back
1689
1690 =head1 EXIT STATUS
1691
1692 The exit status is a "bit mask", each listed status is ORed when the error
1693 condition occurs to get the result.
1694
1695 =over 4
1696
1697 =item B<0>
1698
1699 Success.
1700
1701 =item B<1>
1702
1703 No compiler commands were found.
1704
1705 =item B<2>
1706
1707 Invalid arguments/options given to blhc.
1708
1709 =item B<4>
1710
1711 Non verbose build.
1712
1713 =item B<8>
1714
1715 Missing hardening flags.
1716
1717 =item B<16>
1718
1719 Hardening wrapper detected, no tests performed.
1720
1721 =item B<32>
1722
1723 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1724 TAGS"> for a detailed explanation.
1725
1726 =back
1727
1728 =head1 AUTHOR
1729
1730 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1731
1732 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1733 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1734
1735 =head1 LICENSE AND COPYRIGHT
1736
1737 Copyright (C) 2012-2018 by Simon Ruderich
1738
1739 This program is free software: you can redistribute it and/or modify
1740 it under the terms of the GNU General Public License as published by
1741 the Free Software Foundation, either version 3 of the License, or
1742 (at your option) any later version.
1743
1744 This program is distributed in the hope that it will be useful,
1745 but WITHOUT ANY WARRANTY; without even the implied warranty of
1746 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1747 GNU General Public License for more details.
1748
1749 You should have received a copy of the GNU General Public License
1750 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1751
1752 =head1 SEE ALSO
1753
1754 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1755
1756 =cut