bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2018  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.09';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+|gfortran|mpicc|mpicxx|mpifort)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full_prefix = qr/
  42     [a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?
  43     /x;
  44 my $cc_regex_full = qr/
  45     (?:$cc_regex_full_prefix-)?
  46     $cc_regex
  47     /x;
  48 # Regex to check if a line contains a compiler command.
  49 my $cc_regex_normal = qr/
  50     \b$cc_regex(?:\s|\\)
  51     /x;
  52 # Regex to catch (GCC) compiler warnings.
  53 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  54 # Regex to catch libtool commands and not lines which show commands executed
  55 # by libtool (e.g. libtool: link: ...).
  56 my $libtool_regex = qr/\blibtool\s.*--mode=/;
  57 my $libtool_link_regex = qr/\blibtool: link: /;
  58
  59 # List of source file extensions which require preprocessing.
  60 my @source_preprocess_compile_cpp = (
  61     # C++
  62     qw( cc cp cxx cpp CPP c++ C ),
  63     # Objective-C++
  64     qw( mm M ),
  65 );
  66 my @source_preprocess_compile_fortran = (
  67     # Fortran
  68     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  69 );
  70 my @source_preprocess_compile = (
  71     # C
  72     qw( c ),
  73     # Objective-C
  74     qw( m ),
  75     # (Objective-)C++
  76     @source_preprocess_compile_cpp,
  77     # Fortran
  78     @source_preprocess_compile_fortran,
  79 );
  80 my @source_preprocess_no_compile = (
  81     # Assembly
  82     qw( S sx ),
  83 );
  84 my @source_preprocess = (
  85     @source_preprocess_compile,
  86     @source_preprocess_no_compile,
  87 );
  88 # List of source file extensions which don't require preprocessing.
  89 my @source_no_preprocess_compile_cpp = (
  90     # C++
  91     qw( ii ),
  92     # Objective-C++
  93     qw( mii ),
  94 );
  95 my @source_no_preprocess_compile_ada = (
  96     # Ada source
  97     qw( ada ),
  98     # Ada body
  99     qw( adb ),
 100 );
 101 my @source_no_preprocess_compile_fortran = (
 102     # Fortran
 103     qw( f for ftn f90 f95 f03 f08 ),
 104 );
 105 my @source_no_preprocess_compile = (
 106     # C
 107     qw( i ),
 108     # (Objective-)C++
 109     @source_no_preprocess_compile_cpp,
 110     # Objective-C
 111     qw( mi ),
 112     # Fortran
 113     @source_no_preprocess_compile_fortran,
 114     # Ada
 115     @source_no_preprocess_compile_ada,
 116 );
 117 my @source_no_preprocess_no_compile_ada = (
 118     # Ada specification
 119     qw( ads ),
 120 );
 121 my @source_no_preprocess_no_compile = (
 122     # Assembly
 123     qw( s ),
 124     # Ada
 125     @source_no_preprocess_no_compile_ada,
 126 );
 127 my @source_no_preprocess = (
 128     @source_no_preprocess_compile,
 129     @source_no_preprocess_no_compile,
 130 );
 131 # List of header file extensions which require preprocessing.
 132 my @header_preprocess = (
 133     # C, C++, Objective-C, Objective-C++
 134     qw( h ),
 135     # C++
 136     qw( hh H hp hxx hpp HPP h++ tcc ),
 137 );
 138 # Object files.
 139 my @object = (
 140     # Normal object files.
 141     qw ( o ),
 142     # Libtool object files.
 143     qw ( lo la ),
 144     # Dynamic libraries. bzip2 uses .sho.
 145     qw ( so sho ),
 146     # Static libraries.
 147     qw ( a ),
 148 );
 149
 150 # Hashes for fast extensions lookup to check if a file falls in one of these
 151 # categories.
 152 my %extensions_no_preprocess = map { $_ => 1 } (
 153     # There's no @header_no_preprocess.
 154     @source_no_preprocess,
 155 );
 156 my %extensions_preprocess = map { $_ => 1 } (
 157     @header_preprocess,
 158     @source_preprocess,
 159 );
 160 my %extensions_compile_link = map { $_ => 1 } (
 161     @source_preprocess,
 162     @source_no_preprocess,
 163 );
 164 my %extensions_compile = map { $_ => 1 } (
 165     @source_preprocess_compile,
 166     @source_no_preprocess_compile,
 167 );
 168 my %extensions_no_compile = map { $_ => 1 } (
 169     @source_preprocess_no_compile,
 170     @source_no_preprocess_no_compile,
 171 );
 172 my %extensions_compile_cpp = map { $_ => 1 } (
 173     @source_preprocess_compile_cpp,
 174     @source_no_preprocess_compile_cpp,
 175 );
 176 my %extensions_ada = map { $_ => 1 } (
 177     @source_no_preprocess_compile_ada,
 178     @source_no_preprocess_no_compile_ada,
 179 );
 180 my %extensions_fortran = map { $_ => 1 } (
 181     @source_no_preprocess_compile_fortran,
 182     @source_preprocess_compile_fortran,
 183 );
 184 my %extensions_object = map { $_ => 1 } (
 185     @object,
 186 );
 187 my %extension = map { $_ => 1 } (
 188     @source_no_preprocess,
 189     @header_preprocess,
 190     @source_preprocess,
 191     @object,
 192 );
 193
 194 # Regexp to match file extensions.
 195 my $file_extension_regex = qr/
 196     \s
 197     \S+             # Filename without extension.
 198     \.
 199     ([^\/\\.,;:\s]+)# File extension.
 200     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 201                     # word characters at the end and because \b matches double
 202                     # extensions (like .cpp.o). Works always as all lines are
 203                     # terminated with "\n".
 204     /x;
 205
 206 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 207 # real regexps below for better execution speed).
 208 my @def_cflags = (
 209     '-g',
 210     '-O(?:2|3)', # keep at index 1, search for @def_cflags_debug to change it
 211 );
 212 my @def_cflags_debug = (
 213     # These flags indicate a debug build which disables checks for -O2.
 214     '-O0',
 215     '-Og',
 216 );
 217 my @def_cflags_format = (
 218     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 219     '-Werror=format-security', # implies -Wformat-security
 220 );
 221 my @def_cflags_fortify = (
 222     # fortify needs at least -O1, but -O2 is recommended anyway
 223 );
 224 my @def_cflags_stack = (
 225     '-fstack-protector', # keep first, used by cflags_stack_broken()
 226     '--param[= ]ssp-buffer-size=4',
 227 );
 228 my @def_cflags_stack_strong = (
 229     '-fstack-protector-strong', # keep first, used by cflags_stack_broken()
 230 );
 231 my @def_cflags_stack_bad = (
 232     # Blacklist all stack protector options for simplicity.
 233     '-fno-stack-protector',
 234     '-fno-stack-protector-all',
 235     '-fno-stack-protector-strong',
 236 );
 237 my @def_cflags_pie = (
 238     '-fPIE',
 239 );
 240 my @def_cxxflags = (
 241     @def_cflags,
 242 );
 243 # @def_cxxflags_* is the same as @def_cflags_*.
 244 my @def_cppflags = ();
 245 my @def_cppflags_fortify = (
 246     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 247     # If you add another flag fix hack below (search for "Hack to fix") and
 248     # $def_cppflags_fortify[0].
 249 );
 250 my @def_cppflags_fortify_bad = (
 251     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 252     '-U_FORTIFY_SOURCE',
 253     '-D_FORTIFY_SOURCE=0',
 254     '-D_FORTIFY_SOURCE=1',
 255 );
 256 my @def_ldflags = ();
 257 my @def_ldflags_relro = (
 258     '-Wl,(?:-z,)?relro',
 259 );
 260 my @def_ldflags_bindnow = (
 261     '-Wl,(?:-z,)?now',
 262 );
 263 my @def_ldflags_pie = (
 264     '-fPIE',
 265     '-pie',
 266 );
 267 my @def_ldflags_pic = (
 268     '-fPIC',
 269     '-fpic',
 270     '-shared',
 271 );
 272 # References to all flags checked by the flag checker.
 273 my @flag_refs = (
 274     \@def_cflags,
 275     \@def_cflags_format,
 276     \@def_cflags_fortify,
 277     \@def_cflags_stack,
 278     \@def_cflags_stack_strong,
 279     \@def_cflags_stack_bad,
 280     \@def_cflags_pie,
 281     \@def_cxxflags,
 282     \@def_cppflags,
 283     \@def_cppflags_fortify,
 284     \@def_ldflags,
 285     \@def_ldflags_relro,
 286     \@def_ldflags_bindnow,
 287     \@def_ldflags_pie,
 288 );
 289 # References to all used flags.
 290 my @flag_refs_all = (
 291     @flag_refs,
 292     \@def_cflags_debug,
 293     \@def_cppflags_fortify_bad,
 294     \@def_ldflags_pic,
 295 );
 296 # Renaming rules for the output so the regex parts are not visible. Also
 297 # stores string values of flag regexps above, see compile_flag_regexp().
 298 my %flag_renames = (
 299     '-O(?:2|3)'                    => '-O2',
 300     '-Wformat(?:=2)?'              => '-Wformat',
 301     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 302     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 303     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 304 );
 305
 306 my %exit_code = (
 307     no_compiler_commands => 1 << 0,
 308     # used by POD::Usage => 1 << 1,
 309     non_verbose_build    => 1 << 2,
 310     flags_missing        => 1 << 3,
 311     hardening_wrapper    => 1 << 4,
 312     invalid_cmake        => 1 << 5,
 313 );
 314
 315 my %buildd_tag = (
 316     no_compiler_commands => 'I-no-compiler-commands',
 317     non_verbose_build    => 'W-compiler-flags-hidden',
 318     flags_missing        => 'W-dpkg-buildflags-missing',
 319     hardening_wrapper    => 'I-hardening-wrapper-used',
 320     invalid_cmake        => 'I-invalid-cmake-used',
 321 );
 322
 323 # Statistics of missing flags and non-verbose build commands. Used for
 324 # $option_buildd.
 325 my %statistics = (
 326     preprocess          => 0,
 327     preprocess_missing  => 0,
 328     compile             => 0,
 329     compile_missing     => 0,
 330     compile_cpp         => 0,
 331     compile_cpp_missing => 0,
 332     link                => 0,
 333     link_missing        => 0,
 334     commands            => 0,
 335     commands_nonverbose => 0,
 336 );
 337
 338 # Use colored (ANSI) output?
 339 my $option_color;
 340
 341
 342 # FUNCTIONS
 343
 344 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 345 sub array_equal {
 346     my ($first_ref, $second_ref) = @_;
 347
 348     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 349
 350     my $length = scalar @{$first_ref};
 351     for (my $i = 0; $i < $length; $i++) {
 352         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 353     }
 354
 355     return 1;
 356 }
 357
 358 sub error_flags {
 359     my ($message, $missing_flags_ref, $flag_renames_ref, $line, $number) = @_;
 360
 361     # Get string value of qr//-escaped regexps and if requested rename them.
 362     my @missing_flags = map {
 363             $flag_renames_ref->{$_}
 364         } @{$missing_flags_ref};
 365
 366     my $flags = join ' ', @missing_flags;
 367     printf '%d:', $number if defined $number;
 368     printf '%s (%s)%s %s',
 369            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 370            $line;
 371
 372     return;
 373 }
 374 sub error_non_verbose_build {
 375     my ($line, $number) = @_;
 376
 377     printf '%d:', $number if defined $number;
 378     printf '%s%s %s',
 379            error_color('NONVERBOSE BUILD', 'red'),
 380            error_color(':', 'yellow'),
 381            $line;
 382
 383     return;
 384 }
 385 sub error_invalid_cmake {
 386     my ($version) = @_;
 387
 388     printf "%s%s %s\n",
 389             error_color('INVALID CMAKE', 'red'),
 390             error_color(':', 'yellow'),
 391             $version;
 392
 393     return;
 394 }
 395 sub error_hardening_wrapper {
 396     printf "%s%s %s\n",
 397             error_color('HARDENING WRAPPER', 'red'),
 398             error_color(':', 'yellow'),
 399             'no checks possible, aborting';
 400
 401     return;
 402 }
 403 sub error_color {
 404     my ($message, $color) = @_;
 405
 406     if ($option_color) {
 407         return Term::ANSIColor::colored($message, $color);
 408     } else {
 409         return $message;
 410     }
 411 }
 412
 413 sub any_flags_used {
 414     my ($line, @flags) = @_;
 415
 416     foreach my $flag (@flags) {
 417         return 1 if $line =~ /$flag/;
 418     }
 419
 420     return 0;
 421 }
 422 sub all_flags_used {
 423     my ($line, $missing_flags_ref, @flags) = @_;
 424
 425     my @missing_flags = ();
 426     foreach my $flag (@flags) {
 427         if (not $line =~ /$flag/) {
 428             push @missing_flags, $flag;
 429         }
 430     }
 431
 432     return 1 if scalar @missing_flags == 0;
 433
 434     @{$missing_flags_ref} = @missing_flags;
 435     return 0;
 436 }
 437 # Check if any of \@bad_flags occurs after $good_flag. Doesn't check if
 438 # $good_flag is present.
 439 sub flag_overwritten {
 440     my ($line, $good_flag, $bad_flags) = @_;
 441
 442     if (not any_flags_used($line, @{$bad_flags})) {
 443         return 0;
 444     }
 445
 446     my $bad_pos = 0;
 447     foreach my $flag (@{$bad_flags}) {
 448         while ($line =~ /$flag/g) {
 449             if ($bad_pos < $+[0]) {
 450                 $bad_pos = $+[0];
 451             }
 452         }
 453     }
 454     my $good_pos = 0;
 455     while ($line =~ /$good_flag/g) {
 456         $good_pos = $+[0];
 457     }
 458     if ($good_pos > $bad_pos) {
 459         return 0;
 460     }
 461     return 1;
 462 }
 463
 464 sub cppflags_fortify_broken {
 465     my ($line, $missing_flags) = @_;
 466
 467     # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 468     my $fortify_source = $def_cppflags_fortify[0];
 469
 470     # Some build systems enable/disable fortify source multiple times, check
 471     # the final result.
 472     if (not flag_overwritten($line,
 473                              $fortify_source,
 474                              \@def_cppflags_fortify_bad)) {
 475         return 0;
 476     }
 477     push @{$missing_flags}, $fortify_source;
 478     return 1;
 479 }
 480
 481 sub cflags_stack_broken {
 482     my ($line, $missing_flags, $strong) = @_;
 483
 484     my $flag = $strong ? $def_cflags_stack_strong[0]
 485                        : $def_cflags_stack[0];
 486
 487     if (not flag_overwritten($line, $flag, \@def_cflags_stack_bad)) {
 488         return 0;
 489     }
 490     push @{$missing_flags}, $flag;
 491     return 1;
 492 }
 493
 494 # Modifies $missing_flags_ref array.
 495 sub pic_pie_conflict {
 496     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 497
 498     return 0 if not $pie;
 499     return 0 if not any_flags_used($line, @def_ldflags_pic);
 500
 501     my %flags = map { $_ => 1 } @flags_pie;
 502
 503     # Remove all PIE flags from @missing_flags as they are not required with
 504     # -fPIC.
 505     my @result = grep {
 506         not exists $flags{$_}
 507     } @{$missing_flags_ref};
 508     @{$missing_flags_ref} = @result;
 509
 510     # We got a conflict when no flags are left, thus only PIE flags were
 511     # missing. If other flags were missing abort because the conflict is not
 512     # the problem.
 513     return scalar @result == 0;
 514 }
 515
 516 sub is_non_verbose_build {
 517     my ($line, $skip_ref, $input_ref, $line_offset, $line_count) = @_;
 518
 519     if ($line =~ /$libtool_regex/o) {
 520         # libtool's --silent hides the real compiler flags.
 521         if ($line =~ /\s--silent/) {
 522             return 1;
 523         # If --silent is not present, skip this line as some compiler flags
 524         # might be missing (e.g. -fPIE) which are handled correctly by libtool
 525         # internally. libtool displays the real compiler command on the next
 526         # line, so the flags are checked as usual.
 527         } else {
 528             ${$skip_ref} = 1;
 529             return 0;
 530         }
 531     }
 532
 533     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 534                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 535                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 536                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 537                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 538         return 0;
 539     }
 540
 541     # False positives.
 542     #
 543     # C++ compiler setting.
 544     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 545     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 546     # "Compiling" non binary files.
 547     return 0 if $line =~ /^\s*Compiling \S+\.(?:py|el)['"]?\s*(?:\.\.\.)?$/;
 548     # "Compiling" with no file name.
 549     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 550         # $file_extension_regex may need spaces around the filename.
 551         return 0 if not " $1 " =~ /$file_extension_regex/o;
 552     }
 553
 554     my $file = $1;
 555
 556     # On the first pass we only check if this line is verbose or not.
 557     return 1 if not defined $input_ref;
 558
 559     # Second pass, we have access to the next lines.
 560     ${$skip_ref} = 0;
 561
 562     # CMake and other build systems print the non-verbose messages also when
 563     # building verbose. If a compiler and the file name occurs in the next
 564     # lines, treat it as verbose build.
 565     if (defined $file) {
 566         # Get filename, we can't use the complete path as only parts of it are
 567         # used in the real compiler command.
 568         $file =~ m{/([^/\s]+)$};
 569         $file = $1;
 570
 571         for (my $i = 1; $i <= $line_count; $i++) {
 572             my $next_line = $input_ref->[$line_offset + $i];
 573             last unless defined $next_line;
 574
 575             if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 576                 # Not a non-verbose line, but we still have to skip the
 577                 # current line as it doesn't contain any compiler commands.
 578                 ${$skip_ref} = 1;
 579                 return 0;
 580             }
 581         }
 582     }
 583
 584     return 1;
 585 }
 586
 587 # Remove @flags from $flag_refs_ref, uses $flag_renames_ref as reference.
 588 sub remove_flags {
 589     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 590
 591     my %removes = map { $_ => 1 } @flags;
 592     foreach my $flags (@{$flag_refs_ref}) {
 593         @{$flags} = grep {
 594             # Flag found as string.
 595             not exists $removes{$_}
 596             # Flag found as string representation of regexp.
 597                 and (not defined $flag_renames_ref->{$_}
 598                         or not exists $removes{$flag_renames_ref->{$_}})
 599         } @{$flags};
 600     }
 601
 602     return;
 603 }
 604
 605 # Modifies $flag_renames_ref hash.
 606 sub compile_flag_regexp {
 607     my ($flag_renames_ref, @flags) = @_;
 608
 609     my @result = ();
 610     foreach my $flag (@flags) {
 611         # Compile flag regexp for faster execution.
 612         my $regex = qr/\s$flag(?:\s|\\)/;
 613
 614         # Store flag name in replacement string for correct flags in messages
 615         # with qr//ed flag regexps.
 616         $flag_renames_ref->{$regex}
 617             = (exists $flag_renames_ref->{$flag})
 618                 ? $flag_renames_ref->{$flag}
 619                 : $flag;
 620
 621         push @result, $regex;
 622     }
 623     return @result;
 624 }
 625
 626 # Does any extension in @extensions exist in %{$extensions_ref}?
 627 sub extension_found {
 628     my ($extensions_ref, @extensions) = @_;
 629
 630     foreach my $extension (@extensions) {
 631         if (exists $extensions_ref->{$extension}) {
 632             return 1;
 633         }
 634     }
 635     return 0;
 636 }
 637
 638
 639 # MAIN
 640
 641 # Parse command line arguments.
 642 my $option_help             = 0;
 643 my $option_version          = 0;
 644 my $option_pie              = 0;
 645 my $option_bindnow          = 0;
 646 my @option_ignore_arch      = ();
 647 my @option_ignore_flag      = ();
 648 my @option_ignore_arch_flag = ();
 649 my @option_ignore_line      = ();
 650 my @option_ignore_arch_line = ();
 651 my $option_all              = 0;
 652 my $option_arch             = undef;
 653 my $option_buildd           = 0;
 654 my $option_debian           = 0;
 655    $option_color            = 0;
 656 my $option_line_numbers     = 0;
 657 if (not Getopt::Long::GetOptions(
 658             'help|h|?'           => \$option_help,
 659             'version'            => \$option_version,
 660             # Hardening options.
 661             'pie'                => \$option_pie,
 662             'bindnow'            => \$option_bindnow,
 663             'all'                => \$option_all,
 664             # Ignore.
 665             'ignore-arch=s'      => \@option_ignore_arch,
 666             'ignore-flag=s'      => \@option_ignore_flag,
 667             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 668             'ignore-line=s'      => \@option_ignore_line,
 669             'ignore-arch-line=s' => \@option_ignore_arch_line,
 670             # Misc.
 671             'color'              => \$option_color,
 672             'arch=s'             => \$option_arch,
 673             'buildd'             => \$option_buildd,
 674             'debian'             => \$option_debian,
 675             'line-numbers'       => \$option_line_numbers,
 676         )) {
 677     require Pod::Usage;
 678     Pod::Usage::pod2usage(2);
 679 }
 680 if ($option_help) {
 681     require Pod::Usage;
 682     Pod::Usage::pod2usage(1);
 683 }
 684 if ($option_version) {
 685     print <<"EOF";
 686 blhc $VERSION  Copyright (C) 2012-2018  Simon Ruderich
 687
 688 This program is free software: you can redistribute it and/or modify
 689 it under the terms of the GNU General Public License as published by
 690 the Free Software Foundation, either version 3 of the License, or
 691 (at your option) any later version.
 692
 693 This program is distributed in the hope that it will be useful,
 694 but WITHOUT ANY WARRANTY; without even the implied warranty of
 695 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 696 GNU General Public License for more details.
 697
 698 You should have received a copy of the GNU General Public License
 699 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 700 EOF
 701     exit 0;
 702 }
 703
 704 # Arguments missing.
 705 if (scalar @ARGV == 0) {
 706     require Pod::Usage;
 707     Pod::Usage::pod2usage(2);
 708 }
 709
 710 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 711 # installed on Debian's buildds.
 712 if (not $option_buildd) {
 713     require Term::ANSIColor;
 714 }
 715
 716 if ($option_all) {
 717     $option_pie     = 1;
 718     $option_bindnow = 1;
 719 }
 720
 721 # Precompiled ignores for faster lookup.
 722 my %option_ignore_arch_flag = ();
 723 my %option_ignore_arch_line = ();
 724
 725 # Strip flags which should be ignored.
 726 if (scalar @option_ignore_flag > 0) {
 727     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 728 }
 729 # Same for arch specific ignore flags, but only prepare here.
 730 if (scalar @option_ignore_arch_flag > 0) {
 731     foreach my $ignore (@option_ignore_arch_flag) {
 732         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 733
 734         if (not $ignore_arch or not $ignore_flag) {
 735             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 736                         . '("arch:flag" expected)' . "\n", $ignore;
 737             require Pod::Usage;
 738             Pod::Usage::pod2usage(2);
 739         }
 740
 741         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 742     }
 743 }
 744
 745 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 746 # faster with this.
 747 foreach my $flags (@flag_refs_all) {
 748     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 749 }
 750
 751 # Precompile ignore line regexps, also anchor at beginning and end of line.
 752 foreach my $ignore (@option_ignore_line) {
 753     $ignore = qr/^$ignore$/;
 754 }
 755 # Same for arch specific ignore lines.
 756 if (scalar @option_ignore_arch_line > 0) {
 757     foreach my $ignore (@option_ignore_arch_line) {
 758         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 759
 760         if (not $ignore_arch or not $ignore_line) {
 761             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 762                         . '("arch:line" expected)' . "\n", $ignore;
 763             require Pod::Usage;
 764             Pod::Usage::pod2usage(2);
 765         }
 766
 767         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 768     }
 769 }
 770
 771 # Final exit code.
 772 my $exit = 0;
 773
 774 FILE:
 775 foreach my $file (@ARGV) {
 776     print "checking '$file'...\n" if scalar @ARGV > 1;
 777
 778     -f $file or die "No such file: $file";
 779
 780     open my $fh, '<', $file or die $!;
 781
 782     # Architecture of this file.
 783     my $arch = $option_arch;
 784
 785     # Hardening options. Not all architectures support all hardening options.
 786     my $harden_format  = 1;
 787     my $harden_fortify = 1;
 788     my $harden_stack   = 1;
 789     my $harden_stack_strong = 1;
 790     my $harden_relro   = 1;
 791     my $harden_bindnow = $option_bindnow; # defaults to 0
 792     my $harden_pie     = $option_pie;     # defaults to 0
 793
 794     # Does this build log use ada? Ada also uses gcc as compiler but uses
 795     # different CFLAGS. But only perform ada checks if an ada compiler is used
 796     # for performance reasons.
 797     my $ada = 0;
 798     # Fortran also requires different CFLAGS.
 799     my $fortran = 0;
 800
 801     # Number of parallel jobs to prevent false positives when detecting
 802     # non-verbose builds. As not all jobs declare the number of parallel jobs
 803     # use a large enough default.
 804     my $parallel = 10;
 805
 806     # Don't check for PIE flags if automatically applied by the compiler. Only
 807     # used in buildd and Debian mode.
 808     my $disable_harden_pie = 0;
 809     if ($option_debian) {
 810         $disable_harden_pie = 1;
 811     }
 812
 813     my $number = 0;
 814     while (my $line = <$fh>) {
 815         $number++;
 816
 817         # Detect architecture automatically unless overridden. For buildd logs
 818         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 819         # build logs which aren't built (wrong architecture, build error,
 820         # etc.).
 821         if (not $arch) {
 822             if (index($line, 'Build Architecture: ') == 0) {
 823                 $arch = substr $line, 20, -1; # -1 to ignore '\n' at the end
 824             # For old logs (sbuild << 0.63.0-1).
 825             } elsif (index($line, 'Architecture: ') == 0) {
 826                 $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 827             }
 828         }
 829
 830         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 831         # check for hardening flags in buildd mode if an older dpkg-dev is
 832         # used. Default flags (-g -O2) are still checked.
 833         #
 834         # Packages which were built before 1.16.1 but used their own hardening
 835         # flags are not checked.
 836         #
 837         # Strong stack protector is used since dpkg 1.17.11.
 838         #
 839         # Recent GCC versions automatically use PIE (only on supported
 840         # architectures) and dpkg respects this properly since 1.18.15 and
 841         # doesn't pass PIE flags manually.
 842         if ($option_buildd
 843                 and index($line, 'Toolchain package versions: ') == 0) {
 844             require Dpkg::Version;
 845
 846             my $disable = 1;
 847             my $disable_strong = 1;
 848
 849             if ($line =~ /\bdpkg-dev_(\S+)/) {
 850                 if (Dpkg::Version::version_compare($1, '1.16.1') >= 0) {
 851                     $disable = 0;
 852                 }
 853                 if (Dpkg::Version::version_compare($1, '1.17.11') >= 0) {
 854                     $disable_strong = 0;
 855                 }
 856                 if (Dpkg::Version::version_compare($1, '1.18.15') >= 0) {
 857                     $disable_harden_pie = 1;
 858                 }
 859             }
 860
 861             if ($disable) {
 862                 $harden_format  = 0;
 863                 $harden_fortify = 0;
 864                 $harden_stack   = 0;
 865                 $harden_relro   = 0;
 866                 $harden_bindnow = 0;
 867                 $harden_pie     = 0;
 868             }
 869             if ($disable_strong) {
 870                 $harden_stack_strong = 0;
 871             }
 872         }
 873
 874         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 875         # this was later dropped because upstream rejected the patch. Thus
 876         # build logs with these versions will have fortify hardening flags
 877         # enabled, even though they may be not correctly set and are missing
 878         # when build with later CMake versions. Thanks to Aron Xu for letting
 879         # me know.
 880         if (index($line, 'Package versions: ') == 0
 881                 and $line =~ /\bcmake_(\S+)/
 882                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 883             if (not $option_buildd) {
 884                 error_invalid_cmake($1);
 885                 $exit |= $exit_code{invalid_cmake};
 886             } else {
 887                 print "$buildd_tag{invalid_cmake}|$1|\n";
 888             }
 889         }
 890
 891         # Debian's build daemons use "Filtered Build-Depends:" (or just
 892         # "Build-Depends:" in older versions) for the build dependencies, but
 893         # pbuilder uses "Depends:"; support both.
 894         if (index($line, 'Filtered Build-Depends: ') == 0
 895                 or index($line, 'Build-Depends: ') == 0
 896                 or index($line, 'Depends: ') == 0) {
 897             # If hardening wrapper is used (wraps calls to gcc and adds
 898             # hardening flags automatically) we can't perform any checks,
 899             # abort.
 900             if ($line =~ /\bhardening-wrapper\b/) {
 901                 if (not $option_buildd) {
 902                     error_hardening_wrapper();
 903                     $exit |= $exit_code{hardening_wrapper};
 904                 } else {
 905                     print "$buildd_tag{hardening_wrapper}||\n";
 906                 }
 907                 next FILE;
 908             }
 909
 910             # Ada compiler.
 911             if ($line =~ /\bgnat\b/) {
 912                 $ada = 1;
 913             }
 914             # Fortran compiler.
 915             if ($line =~ /\bgfortran\b/) {
 916                 $fortran = 1;
 917             }
 918         }
 919
 920         # This flags is not always available, but if it is use it.
 921         if ($line =~ /^DEB_BUILD_OPTIONS=.*\bparallel=(\d+)/) {
 922             $parallel = $1 * 2;
 923         }
 924
 925         # We skip over unimportant lines at the beginning of the log to
 926         # prevent false positives.
 927         last if index($line, 'dpkg-buildpackage: ') == 0;
 928     }
 929
 930     # Input lines, contain only the lines with compiler commands.
 931     my @input = ();
 932     # Non-verbose lines in the input. Used to reduce calls to
 933     # is_non_verbose_build() (which is quite slow) in the second loop when
 934     # it's already clear if a line is non-verbose or not.
 935     my @input_nonverbose = ();
 936     # Input line number.
 937     my @input_number = ();
 938
 939     my $continuation = 0;
 940     my $complete_line = undef;
 941     my $non_verbose;
 942     while (my $line = <$fh>) {
 943         $number++;
 944
 945         # And stop at the end of the build log. Package details (reported by
 946         # the buildd logs) are not important for us. This also prevents false
 947         # positives.
 948         last if index($line, 'Build finished at ') == 0
 949                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 950
 951         if (not $continuation) {
 952             $non_verbose = 0;
 953         }
 954
 955         # Detect architecture automatically unless overridden.
 956         if (not $arch
 957                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 958             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 959
 960             # Old buildd logs use e.g. "host architecture is alpha", remove
 961             # the "is", otherwise debarch_to_debtriplet() will not detect the
 962             # architecture.
 963             if (index($arch, 'is ') == 0) {
 964                 $arch = substr $arch, 3;
 965             }
 966         }
 967
 968         next if $line =~ /^\s*#/;
 969         # Ignore compiler warnings for now.
 970         next if $line =~ /$warning_regex/o;
 971
 972         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 973             # Remove all ANSI color sequences which are sometimes used in
 974             # non-verbose builds.
 975             $line = Term::ANSIColor::colorstrip($line);
 976             # Also strip '\0xf' (delete previous character), used by Elinks'
 977             # build system.
 978             $line =~ s/\x0f//g;
 979             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 980             # what it does).
 981             $line =~ s/\033\(B//g;
 982         }
 983
 984         # Check if this line indicates a non verbose build.
 985         my $skip = 0;
 986         $non_verbose |= is_non_verbose_build($line, \$skip);
 987         next if $skip;
 988
 989         # One line may contain multiple commands (";"). Treat each one as
 990         # single line. parse_line() is slow, only use it when necessary.
 991         my @line = (index($line, ';') == -1)
 992                  ? ($line)
 993                  : map {
 994                        # Ensure newline at the line end - necessary for
 995                        # correct parsing later.
 996                        $_ =~ s/\s+$//;
 997                        $_ .= "\n";
 998                    } Text::ParseWords::parse_line(';', 1, $line);
 999         foreach my $line (@line) {
1000             if ($continuation) {
1001                 $continuation = 0;
1002
1003                 # Join lines, but leave the "\" in place so it's clear where
1004                 # the original line break was.
1005                 chomp $complete_line;
1006                 $complete_line .= ' ' . $line;
1007             }
1008             # Line continuation, line ends with "\".
1009             if ($line =~ /\\$/) {
1010                 $continuation = 1;
1011                 # Start line continuation.
1012                 if (not defined $complete_line) {
1013                     $complete_line = $line;
1014                 }
1015                 next;
1016             }
1017
1018             # Use the complete line if a line continuation occurred.
1019             if (defined $complete_line) {
1020                 $line = $complete_line;
1021                 $complete_line = undef;
1022             }
1023
1024             # Ignore lines with no compiler commands.
1025             next if not $non_verbose
1026                     and not $line =~ /$cc_regex_normal/o;
1027             # Ignore lines with no filenames with extensions. May miss some
1028             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
1029             # a problem as the log will most likely contain other non-verbose
1030             # commands which are detected.
1031             next if not $non_verbose
1032                     and not $line =~ /$file_extension_regex/o;
1033
1034             # Ignore false positives.
1035             #
1036             # `./configure` output.
1037             next if not $non_verbose
1038                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
1039             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
1040                                 [Cc]ompiler[\s.]*:?\s+
1041                                 /x;
1042             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
1043                                 \s*=\s*$cc_regex_full
1044                                 # optional compiler options, don't allow
1045                                 # "everything" here to prevent false negatives
1046                                 \s*(?:\s-\S+)*\s*$}xo;
1047             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
1048             # line (or similar for other architectures) which gets recognized
1049             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
1050             # C++ files. No hardening flags are relevant during this step,
1051             # thus ignore `moc-qt*` lines. The resulting files will be
1052             # compiled in a separate step (and therefore checked).
1053             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
1054                                \s.+\s
1055                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
1056                                \s}x;
1057             # Ignore false positives when the line contains only CC=gcc but no
1058             # other gcc command.
1059             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
1060                 my $before = $1;
1061                 my $after  = $2;
1062                 next if     not $before =~ /$cc_regex_normal/o
1063                         and not $after  =~ /$cc_regex_normal/o;
1064             }
1065             # Ignore false positives caused by gcc -v. It outputs a line
1066             # looking like a normal compiler line but which is sometimes
1067             # missing hardening flags, although the normal compiler line
1068             # contains them.
1069             next if $line =~ m{^\s+/usr/lib/gcc/$cc_regex_full_prefix/
1070                                    [0-9.]+/cc1(?:plus)?}xo;
1071             # Ignore false positive with `rm` which may remove files which
1072             # look like a compiler executable thus causing the line to be
1073             # treated as a normal compiler line.
1074             next if $line =~ m{^\s*rm\s+};
1075             # Some build systems emit "gcc > file".
1076             next if $line =~ m{$cc_regex_normal\s*>\s*\S+}o;
1077             # Hex output may contain "cc".
1078             next if $line =~ m#(?:\b[0-9a-fA-F]{2,}\b\s*){5}#;
1079
1080             # Check if additional hardening options were used. Used to ensure
1081             # they are used for the complete build.
1082             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
1083                                                          @def_ldflags_pie);
1084             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
1085
1086             push @input, $line;
1087             push @input_nonverbose, $non_verbose;
1088             push @input_number, $number if $option_line_numbers;
1089         }
1090     }
1091
1092     close $fh or die $!;
1093
1094     # Ignore arch if requested.
1095     if (scalar @option_ignore_arch > 0 and $arch) {
1096         foreach my $ignore (@option_ignore_arch) {
1097             if ($arch eq $ignore) {
1098                 print "ignoring architecture '$arch'\n";
1099                 next FILE;
1100             }
1101         }
1102     }
1103
1104     if (scalar @input == 0) {
1105         if (not $option_buildd) {
1106             print "No compiler commands!\n";
1107             $exit |= $exit_code{no_compiler_commands};
1108         } else {
1109             print "$buildd_tag{no_compiler_commands}||\n";
1110         }
1111         next FILE;
1112     }
1113
1114     if ($option_buildd) {
1115         $statistics{commands} += scalar @input;
1116     }
1117
1118     # Option or auto detected.
1119     if ($arch) {
1120         # The following was partially copied from dpkg-dev 1.19.0.5
1121         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, _add_build_flags()),
1122         # copyright Raphaël Hertzog <hertzog@debian.org>, Guillem Jover
1123         # <guillem@debian.org>, Kees Cook <kees@debian.org>, Canonical, Ltd.
1124         # licensed under GPL version 2 or later. Keep it in sync.
1125
1126         require Dpkg::Arch;
1127         my ($os, $cpu);
1128         # Recent dpkg versions use a quadruplet for arch. Support both.
1129         eval {
1130             (undef, undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtuple($arch);
1131         };
1132         if ($@) {
1133             (undef, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
1134         }
1135
1136         my %builtin_pie_arch = map { $_ => 1 } qw(
1137             amd64 arm64 armel armhf hurd-i386 i386 kfreebsd-amd64 kfreebsd-i386
1138             mips mipsel mips64el powerpc ppc64 ppc64el s390x sparc sparc64
1139         );
1140
1141         # Disable unsupported hardening options.
1142         if ($os !~ /^(?:linux|kfreebsd|knetbsd|hurd)$/
1143                 or $cpu =~ /^(?:hppa|avr32)$/) {
1144             $harden_pie = 0;
1145         }
1146         if ($cpu =~ /^(?:ia64|alpha|hppa|nios2)$/ or $arch eq 'arm') {
1147             $harden_stack = 0;
1148             $harden_stack_strong = 0;
1149         }
1150         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
1151             $harden_relro   = 0;
1152             $harden_bindnow = 0;
1153         }
1154
1155         if ($disable_harden_pie and exists $builtin_pie_arch{$arch}) {
1156             $harden_pie = 0;
1157         }
1158     }
1159
1160     # Default values.
1161     my @cflags   = @def_cflags;
1162     my @cxxflags = @def_cxxflags;
1163     my @cppflags = @def_cppflags;
1164     my @ldflags  = @def_ldflags;
1165     # Check the specified hardening options, same order as dpkg-buildflags.
1166     if ($harden_pie) {
1167         @cflags   = (@cflags,   @def_cflags_pie);
1168         @cxxflags = (@cxxflags, @def_cflags_pie);
1169         @ldflags  = (@ldflags,  @def_ldflags_pie);
1170     }
1171     if ($harden_stack_strong) {
1172         @cflags   = (@cflags,   @def_cflags_stack_strong);
1173         @cxxflags = (@cxxflags, @def_cflags_stack_strong);
1174     } elsif ($harden_stack) {
1175         @cflags   = (@cflags,   @def_cflags_stack);
1176         @cxxflags = (@cxxflags, @def_cflags_stack);
1177     }
1178     if ($harden_fortify) {
1179         @cflags   = (@cflags,   @def_cflags_fortify);
1180         @cxxflags = (@cxxflags, @def_cflags_fortify);
1181         @cppflags = (@cppflags, @def_cppflags_fortify);
1182     }
1183     if ($harden_format) {
1184         @cflags   = (@cflags,   @def_cflags_format);
1185         @cxxflags = (@cxxflags, @def_cflags_format);
1186     }
1187     if ($harden_relro) {
1188         @ldflags = (@ldflags, @def_ldflags_relro);
1189     }
1190     if ($harden_bindnow) {
1191         @ldflags = (@ldflags, @def_ldflags_bindnow);
1192     }
1193
1194     # Ada doesn't support format hardening flags, see #680117 for more
1195     # information. Same for fortran. Filter them out if either language is
1196     # used.
1197     my @cflags_backup;
1198     my @cflags_noformat;
1199     if (($ada or $fortran) and $harden_format) {
1200         @cflags_noformat = grep {
1201             my $ok = 1;
1202             foreach my $flag (@def_cflags_format) {
1203                 $ok = 0 if $_ eq $flag;
1204             }
1205             $ok;
1206         } @cflags;
1207     }
1208
1209     # Hack to fix cppflags_fortify_broken() if --ignore-flag
1210     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
1211     # as long as @def_cppflags_fortify contains only one variable.
1212     if (scalar @def_cppflags_fortify == 0) {
1213         $harden_fortify = 0;
1214     }
1215
1216     # Ignore flags for this arch if requested.
1217     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1218         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1219
1220         remove_flags(\@local_flag_refs,
1221                      \%flag_renames,
1222                      @{$option_ignore_arch_flag{$arch}});
1223     }
1224
1225     my @ignore_line = @option_ignore_line;
1226     # Ignore lines for this arch if requested.
1227     if ($arch and exists $option_ignore_arch_line{$arch}) {
1228         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1229     }
1230
1231 LINE:
1232     for (my $i = 0; $i < scalar @input; $i++) {
1233         my $line = $input[$i];
1234
1235         # Ignore line if requested.
1236         foreach my $ignore (@ignore_line) {
1237             next LINE if $line =~ /$ignore/;
1238         }
1239
1240         my $skip = 0;
1241         if ($input_nonverbose[$i]
1242                 and is_non_verbose_build($line, \$skip,
1243                                          \@input, $i, $parallel)) {
1244             if (not $option_buildd) {
1245                 error_non_verbose_build($line, $input_number[$i]);
1246                 $exit |= $exit_code{non_verbose_build};
1247             } else {
1248                 $statistics{commands_nonverbose}++;
1249             }
1250             next;
1251         }
1252         # Even if it's a verbose build, we might have to skip this line (see
1253         # is_non_verbose_build()).
1254         next if $skip;
1255
1256         my $orig_line = $line;
1257
1258         # Remove everything until and including the compiler command. Makes
1259         # checks easier and faster.
1260         $line =~ s/^.*?$cc_regex//o;
1261         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1262         # the brace and similar characters at the line end.
1263         $line =~ s/['")]+$//;
1264
1265         # Skip unnecessary tests when only preprocessing.
1266         my $flag_preprocess = 0;
1267
1268         my $dependency = 0;
1269         my $preprocess = 0;
1270         my $compile    = 0;
1271         my $link       = 0;
1272
1273         # Preprocess, compile, assemble.
1274         if ($line =~ /\s(-E|-S|-c)\b/) {
1275             $preprocess      = 1;
1276             $flag_preprocess = 1 if $1 eq '-E';
1277             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1278         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1279         # -MT -MQ) are always used with -M/-MM.
1280         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1281             $dependency = 1;
1282         # Otherwise assume we are linking.
1283         } else {
1284             $link = 1;
1285         }
1286
1287         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1288         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1289             $dependency      = 0;
1290             $flag_preprocess = 0;
1291         }
1292
1293         # Dependency generation for Makefiles, no preprocessing or other flags
1294         # needed.
1295         next if $dependency;
1296
1297         # Get all file extensions on this line.
1298         my @extensions = $line =~ /$file_extension_regex/go;
1299         # Ignore all unknown extensions to speedup the search below.
1300         @extensions = grep { exists $extension{$_} } @extensions;
1301
1302         # These file types don't require preprocessing.
1303         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1304             $preprocess = 0;
1305         }
1306         # These file types require preprocessing.
1307         if (extension_found(\%extensions_preprocess, @extensions)) {
1308             # Prevent false positives with "libtool: link: g++ -include test.h
1309             # .." compiler lines.
1310             if ($orig_line !~ /$libtool_link_regex/o) {
1311                 $preprocess = 1;
1312             }
1313         }
1314
1315         if (not $flag_preprocess) {
1316             # If there are source files then it's compiling/linking in one
1317             # step and we must check both. We only check for source files
1318             # here, because header files cause too many false positives.
1319             if (extension_found(\%extensions_compile_link, @extensions)) {
1320                 # Assembly files don't need CFLAGS.
1321                 if (not extension_found(\%extensions_compile, @extensions)
1322                         and extension_found(\%extensions_no_compile, @extensions)) {
1323                     $compile = 0;
1324                 # But the rest does.
1325                 } else {
1326                     $compile = 1;
1327                 }
1328             # No compilable extensions found, either linking or compiling
1329             # header flags.
1330             #
1331             # If there are also no object files we are just compiling headers
1332             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1333             # to our liberal checks for compiler lines, this also reduces the
1334             # number of false positives considerably.
1335             } elsif ($link
1336                     and not extension_found(\%extensions_object, @extensions)) {
1337                 $link = 0;
1338             }
1339         }
1340
1341         my $compile_cpp = 0;
1342         my $restore_cflags = 0;
1343         # Assume CXXFLAGS are required when a C++ file is specified in the
1344         # compiler line.
1345         if ($compile
1346                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1347             $compile     = 0;
1348             $compile_cpp = 1;
1349         # Ada needs special CFLAGS, use them if only ada files are compiled.
1350         } elsif ($ada
1351                 and extension_found(\%extensions_ada, @extensions)) {
1352             $restore_cflags = 1;
1353             $preprocess = 0; # Ada uses no CPPFLAGS
1354             @cflags_backup = @cflags;
1355             @cflags        = @cflags_noformat;
1356         # Same for fortran.
1357         } elsif ($fortran
1358                 and extension_found(\%extensions_fortran, @extensions)) {
1359             $restore_cflags = 1;
1360             @cflags_backup = @cflags;
1361             @cflags        = @cflags_noformat;
1362         }
1363
1364         if ($option_buildd) {
1365             $statistics{preprocess}++  if $preprocess;
1366             $statistics{compile}++     if $compile;
1367             $statistics{compile_cpp}++ if $compile_cpp;
1368             $statistics{link}++        if $link;
1369         }
1370
1371         # Check if there are flags indicating a debug build. If that's true,
1372         # skip the check for -O2. This prevents fortification, but that's fine
1373         # for a debug build.
1374         if (any_flags_used($line, @def_cflags_debug)) {
1375             remove_flags([\@cflags], \%flag_renames, $def_cflags[1]);
1376             remove_flags([\@cppflags], \%flag_renames, $def_cppflags_fortify[0]);
1377         }
1378
1379         # Check hardening flags.
1380         my @missing;
1381         if ($compile and (not all_flags_used($line, \@missing, @cflags)
1382                     or (($harden_stack or $harden_stack_strong)
1383                         and cflags_stack_broken($line, \@missing,
1384                                                 $harden_stack_strong)))
1385                 # Libraries linked with -fPIC don't have to (and can't) be
1386                 # linked with -fPIE as well. It's no error if only PIE flags
1387                 # are missing.
1388                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1389                 # Assume dpkg-buildflags returns the correct flags.
1390                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1391             if (not $option_buildd) {
1392                 error_flags('CFLAGS missing', \@missing, \%flag_renames,
1393                             $input[$i], $input_number[$i]);
1394                 $exit |= $exit_code{flags_missing};
1395             } else {
1396                 $statistics{compile_missing}++;
1397             }
1398         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1399                 # Libraries linked with -fPIC don't have to (and can't) be
1400                 # linked with -fPIE as well. It's no error if only PIE flags
1401                 # are missing.
1402                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1403                 # Assume dpkg-buildflags returns the correct flags.
1404                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1405             if (not $option_buildd) {
1406                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames,
1407                             $input[$i], $input_number[$i]);
1408                 $exit |= $exit_code{flags_missing};
1409             } else {
1410                 $statistics{compile_cpp_missing}++;
1411             }
1412         }
1413         if ($preprocess
1414                 and (not all_flags_used($line, \@missing, @cppflags)
1415                     # The fortify flag might be overwritten, detect that.
1416                      or ($harden_fortify
1417                          and cppflags_fortify_broken($line, \@missing)))
1418                 # Assume dpkg-buildflags returns the correct flags.
1419                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1420             if (not $option_buildd) {
1421                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames,
1422                             $input[$i], $input_number[$i]);
1423                 $exit |= $exit_code{flags_missing};
1424             } else {
1425                 $statistics{preprocess_missing}++;
1426             }
1427         }
1428         if ($link and not all_flags_used($line, \@missing, @ldflags)
1429                 # Same here, -fPIC conflicts with -fPIE.
1430                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1431                 # Assume dpkg-buildflags returns the correct flags.
1432                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1433             if (not $option_buildd) {
1434                 error_flags('LDFLAGS missing', \@missing, \%flag_renames,
1435                             $input[$i], $input_number[$i]);
1436                 $exit |= $exit_code{flags_missing};
1437             } else {
1438                 $statistics{link_missing}++;
1439             }
1440         }
1441
1442         # Restore normal CFLAGS.
1443         if ($restore_cflags) {
1444             @cflags = @cflags_backup;
1445         }
1446     }
1447 }
1448
1449 # Print statistics for buildd mode, only output in this mode.
1450 if ($option_buildd) {
1451     my @warning;
1452
1453     if ($statistics{preprocess_missing}) {
1454         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1455                                $statistics{preprocess_missing},
1456                                $statistics{preprocess};
1457     }
1458     if ($statistics{compile_missing}) {
1459         push @warning, sprintf 'CFLAGS %d (of %d)',
1460                                $statistics{compile_missing},
1461                                $statistics{compile};
1462     }
1463     if ($statistics{compile_cpp_missing}) {
1464         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1465                                $statistics{compile_cpp_missing},
1466                                $statistics{compile_cpp};
1467     }
1468     if ($statistics{link_missing}) {
1469         push @warning, sprintf 'LDFLAGS %d (of %d)',
1470                                $statistics{link_missing},
1471                                $statistics{link};
1472     }
1473     if (scalar @warning) {
1474         local $" = ', '; # array join string
1475         print "$buildd_tag{flags_missing}|@warning missing|\n";
1476     }
1477
1478     if ($statistics{commands_nonverbose}) {
1479         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1480                $statistics{commands_nonverbose},
1481                $statistics{commands},
1482     }
1483 }
1484
1485
1486 exit $exit;
1487
1488
1489 __END__
1490
1491 =head1 NAME
1492
1493 blhc - build log hardening check, checks build logs for missing hardening flags
1494
1495 =head1 SYNOPSIS
1496
1497 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1498
1499 =head1 DESCRIPTION
1500
1501 blhc is a small tool which checks build logs for missing hardening flags. It's
1502 licensed under the GPL 3 or later.
1503
1504 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1505 tools using dpkg-buildpackage like pbuilder or sbuild (which is used for the
1506 official buildd build logs)) to help maintainers detect missing hardening
1507 flags in their packages.
1508
1509 Only gcc is detected as compiler at the moment. If other compilers support
1510 hardening flags as well, please report them.
1511
1512 If there's no output, no flags are missing and the build log is fine.
1513
1514 See F<README> for details about performed checks, auto-detection and
1515 limitations.
1516
1517 =head1 OPTIONS
1518
1519 =over 8
1520
1521 =item B<--all>
1522
1523 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1524 auto detected.
1525
1526 =item B<--arch> I<architecture>
1527
1528 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1529 disables hardening flags not available on this architecture. Is detected
1530 automatically if dpkg-buildpackage is used.
1531
1532 =item B<--bindnow>
1533
1534 Force check for all +bindnow hardening flags. By default it's auto detected.
1535
1536 =item B<--buildd>
1537
1538 Special mode for buildds when automatically parsing log files. The following
1539 changes are in effect:
1540
1541 =over 2
1542
1543 =item *
1544
1545 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1546 possible tags.
1547
1548 =item *
1549
1550 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1551 detected).
1552
1553 =item *
1554
1555 Don't require Term::ANSIColor.
1556
1557 =item *
1558
1559 Return exit code 0, unless there was a error (-I, -W messages don't count as
1560 error).
1561
1562 =back
1563
1564 =item B<--debian>
1565
1566 Apply Debian-specific settings. At the moment this only disables checking for
1567 PIE which is automatically applied by Debian's GCC and no longer requires a
1568 compiler command line argument.
1569
1570 =item B<--color>
1571
1572 Use colored (ANSI) output for warning messages.
1573
1574 =item B<--line-numbers>
1575
1576 Display line numbers.
1577
1578 =item B<--ignore-arch> I<arch>
1579
1580 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1581
1582 Used to prevent false positives. This option can be specified multiple times.
1583
1584 =item B<--ignore-arch-flag> I<arch>:I<flag>
1585
1586 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1587
1588 =item B<--ignore-arch-line> I<arch>:I<line>
1589
1590 Like B<--ignore-line>, but only ignore line on I<arch>.
1591
1592 =item B<--ignore-flag> I<flag>
1593
1594 Don't print an error when the specific flag is missing in a compiler line.
1595 I<flag> is a string.
1596
1597 Used to prevent false positives. This option can be specified multiple times.
1598
1599 =item B<--ignore-line> I<regex>
1600
1601 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1602 at the beginning and end of the line to prevent false negatives.
1603
1604 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1605 warnings (which have line continuation resolved).
1606
1607 Used to prevent false positives. This option can be specified multiple times.
1608
1609 =item B<--pie>
1610
1611 Force check for all +pie hardening flags. By default it's auto detected.
1612
1613 =item B<-h -? --help>
1614
1615 Print available options.
1616
1617 =item B<--version>
1618
1619 Print version number and license.
1620
1621 =back
1622
1623 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1624 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1625 all other commands as well.
1626
1627 =head1 EXAMPLES
1628
1629 Normal usage, parse a single log file.
1630
1631     blhc path/to/log/file
1632
1633 If there's no output, no flags are missing and the build log is fine.
1634
1635 Parse multiple log files. The exit code is ORed over all files.
1636
1637     blhc path/to/directory/with/log/files/*
1638
1639 Don't treat missing C<-g> as error:
1640
1641     blhc --ignore-flag -g path/to/log/file
1642
1643 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1644
1645     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1646
1647 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1648 false positive.
1649
1650     blhc --ignore-line '\./script gcc file' path/to/log/file
1651
1652 Ignore lines matching C<./script gcc file> somewhere in the line.
1653
1654     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1655
1656 Use blhc with pbuilder.
1657
1658     pbuilder path/to/package.dsc | tee path/log/file
1659     blhc path/to/file || echo flags missing
1660
1661 Assume this build log was created on a Debian system and thus don't warn about
1662 missing PIE flags if the current architecture injects them automatically (this
1663 is enabled in buildd mode per default). C<--arch> is necessary if the build
1664 log contains no architecture information as written by dpkg-buildpackage.
1665
1666     blhc --debian --all --arch=amd64 path/to/log/file
1667
1668 =head1 BUILDD TAGS
1669
1670 The following tags are used in I<--buildd> mode. In braces the additional data
1671 which is displayed.
1672
1673 =over 2
1674
1675 =item B<I-hardening-wrapper-used>
1676
1677 The package uses hardening-wrapper which intercepts calls to gcc and adds
1678 hardening flags. The build log doesn't contain any hardening flags and thus
1679 can't be checked by blhc.
1680
1681 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1682
1683 Build log contains lines which hide the real compiler flags. For example:
1684
1685     CC test-a.c
1686     CC test-b.c
1687     CC test-c.c
1688     LD test
1689
1690 Most of the time either C<export V=1> or C<export verbose=1> in
1691 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1692 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1693 patched to remove the C<@>s hiding the real compiler commands.
1694
1695 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1696
1697 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1698
1699 =item B<I-invalid-cmake-used> (version)
1700
1701 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1702 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1703 patch was rejected by upstream and later reverted in Debian. Thus those two
1704 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1705 handle them (for example by passing them to CFLAGS). To prevent false
1706 negatives just blacklist those two versions.
1707
1708 =item B<I-no-compiler-commands>
1709
1710 No compiler commands were detected. Either the log contains none or they were
1711 not correctly detected by blhc (please report the bug in this case).
1712
1713 =back
1714
1715 =head1 EXIT STATUS
1716
1717 The exit status is a "bit mask", each listed status is ORed when the error
1718 condition occurs to get the result.
1719
1720 =over 4
1721
1722 =item B<0>
1723
1724 Success.
1725
1726 =item B<1>
1727
1728 No compiler commands were found.
1729
1730 =item B<2>
1731
1732 Invalid arguments/options given to blhc.
1733
1734 =item B<4>
1735
1736 Non verbose build.
1737
1738 =item B<8>
1739
1740 Missing hardening flags.
1741
1742 =item B<16>
1743
1744 Hardening wrapper detected, no tests performed.
1745
1746 =item B<32>
1747
1748 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1749 TAGS"> for a detailed explanation.
1750
1751 =back
1752
1753 =head1 AUTHOR
1754
1755 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1756
1757 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1758 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1759
1760 =head1 LICENSE AND COPYRIGHT
1761
1762 Copyright (C) 2012-2018 by Simon Ruderich
1763
1764 This program is free software: you can redistribute it and/or modify
1765 it under the terms of the GNU General Public License as published by
1766 the Free Software Foundation, either version 3 of the License, or
1767 (at your option) any later version.
1768
1769 This program is distributed in the hope that it will be useful,
1770 but WITHOUT ANY WARRANTY; without even the implied warranty of
1771 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1772 GNU General Public License for more details.
1773
1774 You should have received a copy of the GNU General Public License
1775 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1776
1777 =head1 SEE ALSO
1778
1779 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1780
1781 =cut