bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012-2013  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Text::ParseWords ();
  26
  27 our $VERSION = '0.04';
  28
  29
  30 # CONSTANTS/VARIABLES
  31
  32 # Regex to catch compiler commands.
  33 my $cc_regex = qr/
  34     (?<!\s-)               # ignore options, e.g. "-c++" [sic!] (used by swig)
  35     (?<!\.)                # ignore file names, e.g. "test.gcc"
  36     (?:cc|gcc|g\+\+|c\+\+)
  37     (?:-[\d.]+)?           # version suffix, e.g. "gcc-4.6"
  38     /x;
  39 # Full regex which matches the complete compiler name. Used in a few places to
  40 # prevent false negatives.
  41 my $cc_regex_full = qr/
  42     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  43     $cc_regex
  44     /x;
  45 # Regex to check if a line contains a compiler command.
  46 my $cc_regex_normal = qr/
  47     \b$cc_regex(?:\s|\\)
  48     /x;
  49 # Regex to catch (GCC) compiler warnings.
  50 my $warning_regex = qr/^(.+?):(\d+):\d+: warning: (.+?) \[(.+?)\]$/;
  51
  52 # List of source file extensions which require preprocessing.
  53 my @source_preprocess_compile_cpp = (
  54     # C++
  55     qw( cc cp cxx cpp CPP c++ C ),
  56     # Objective-C++
  57     qw( mm M ),
  58 );
  59 my @source_preprocess_compile = (
  60     # C
  61     qw( c ),
  62     # Objective-C
  63     qw( m ),
  64     # (Objective-)C++
  65     @source_preprocess_compile_cpp,
  66     # Fortran
  67     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  68 );
  69 my @source_preprocess_no_compile = (
  70     # Assembly
  71     qw( S sx ),
  72 );
  73 my @source_preprocess = (
  74     @source_preprocess_compile,
  75     @source_preprocess_no_compile,
  76 );
  77 # List of source file extensions which don't require preprocessing.
  78 my @source_no_preprocess_compile_cpp = (
  79     # C++
  80     qw( ii ),
  81     # Objective-C++
  82     qw( mii ),
  83 );
  84 my @source_no_preprocess_compile_ada = (
  85     # Ada body
  86     qw( adb ),
  87     # If you add another file, fix use of @source_no_preprocess_compile_ada
  88     # below (search for $compile_ada).
  89 );
  90 my @source_no_preprocess_compile = (
  91     # C
  92     qw( i ),
  93     # (Objective-)C++
  94     @source_no_preprocess_compile_cpp,
  95     # Objective-C
  96     qw( mi ),
  97     # Fortran
  98     qw( f for ftn f90 f95 f03 f08 ),
  99     # Ada
 100     @source_no_preprocess_compile_ada,
 101 );
 102 my @source_no_preprocess_no_compile = (
 103     # Assembly
 104     qw( s ),
 105     # Ada specification
 106     qw( ads ),
 107 );
 108 my @source_no_preprocess = (
 109     @source_no_preprocess_compile,
 110     @source_no_preprocess_no_compile,
 111 );
 112 # List of header file extensions which require preprocessing.
 113 my @header_preprocess = (
 114     # C, C++, Objective-C, Objective-C++
 115     qw( h ),
 116     # C++
 117     qw( hh H hp hxx hpp HPP h++ tcc ),
 118 );
 119 # Object files.
 120 my @object = (
 121     # Normal object files.
 122     qw ( o ),
 123     # Libtool object files.
 124     qw ( lo la ),
 125     # Dynamic libraries. bzip2 uses .sho.
 126     qw ( so sho ),
 127     # Static libraries.
 128     qw ( a ),
 129 );
 130
 131 # Hashes for fast extensions lookup to check if a file falls in one of these
 132 # categories.
 133 my %extensions_no_preprocess = map { $_ => 1 } (
 134     # There's no @header_no_preprocess.
 135     @source_no_preprocess,
 136 );
 137 my %extensions_preprocess = map { $_ => 1 } (
 138     @header_preprocess,
 139     @source_preprocess,
 140 );
 141 my %extensions_compile_link = map { $_ => 1 } (
 142     @source_preprocess,
 143     @source_no_preprocess,
 144 );
 145 my %extensions_compile = map { $_ => 1 } (
 146     @source_preprocess_compile,
 147     @source_no_preprocess_compile,
 148 );
 149 my %extensions_no_compile = map { $_ => 1 } (
 150     @source_preprocess_no_compile,
 151     @source_no_preprocess_no_compile,
 152 );
 153 my %extensions_compile_cpp = map { $_ => 1 } (
 154     @source_preprocess_compile_cpp,
 155     @source_no_preprocess_compile_cpp,
 156 );
 157 my %extensions_object = map { $_ => 1 } (
 158     @object,
 159 );
 160 my %extension = map { $_ => 1 } (
 161     @source_no_preprocess,
 162     @header_preprocess,
 163     @source_preprocess,
 164     @object,
 165 );
 166
 167 # Regexp to match file extensions.
 168 my $file_extension_regex = qr/
 169     \s
 170     \S+             # Filename without extension.
 171     \.
 172     ([^\/\\.,;:\s]+)# File extension.
 173     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 174                     # word characters at the end and because \b matches double
 175                     # extensions (like .cpp.o). Works always as all lines are
 176                     # terminated with "\n".
 177     /x;
 178
 179 # Expected (hardening) flags. All flags are used as regexps (and compiled to
 180 # real regexps below for better execution speed).
 181 my @def_cflags = (
 182     '-g',
 183     '-O(?:2|3)',
 184 );
 185 my @def_cflags_format = (
 186     '-Wformat(?:=2)?', # -Wformat=2 implies -Wformat, accept it too
 187     '-Werror=format-security', # implies -Wformat-security
 188 );
 189 my @def_cflags_fortify = (
 190     # fortify needs at least -O1, but -O2 is recommended anyway
 191 );
 192 my @def_cflags_stack = (
 193     '-fstack-protector',
 194     '--param[= ]ssp-buffer-size=4',
 195 );
 196 my @def_cflags_pie = (
 197     '-fPIE',
 198 );
 199 my @def_cxxflags = (
 200     @def_cflags,
 201 );
 202 # @def_cxxflags_* is the same as @def_cflags_*.
 203 my @def_cppflags = ();
 204 my @def_cppflags_fortify = (
 205     '-D_FORTIFY_SOURCE=2', # must be first, see cppflags_fortify_broken()
 206     # If you add another flag fix hack below (search for "Hack to fix").
 207 );
 208 my @def_cppflags_fortify_bad = (
 209     # These flags may overwrite -D_FORTIFY_SOURCE=2.
 210     '-U_FORTIFY_SOURCE',
 211     '-D_FORTIFY_SOURCE=0',
 212     '-D_FORTIFY_SOURCE=1',
 213 );
 214 my @def_ldflags = ();
 215 my @def_ldflags_relro = (
 216     '-Wl,(?:-z,)?relro',
 217 );
 218 my @def_ldflags_bindnow = (
 219     '-Wl,(?:-z,)?now',
 220 );
 221 my @def_ldflags_pie = (
 222     '-fPIE',
 223     '-pie',
 224 );
 225 my @def_ldflags_pic = (
 226     '-fPIC',
 227     '-fpic',
 228     '-shared',
 229 );
 230 # References to all flags checked by the flag checker.
 231 my @flag_refs = (
 232     \@def_cflags,
 233     \@def_cflags_format,
 234     \@def_cflags_fortify,
 235     \@def_cflags_stack,
 236     \@def_cflags_pie,
 237     \@def_cxxflags,
 238     \@def_cppflags,
 239     \@def_cppflags_fortify,
 240     \@def_ldflags,
 241     \@def_ldflags_relro,
 242     \@def_ldflags_bindnow,
 243     \@def_ldflags_pie,
 244 );
 245 # References to all used flags.
 246 my @flag_refs_all = (
 247     @flag_refs,
 248     \@def_cppflags_fortify_bad,
 249     \@def_ldflags_pic,
 250 );
 251 # Renaming rules for the output so the regex parts are not visible. Also
 252 # stores string values of flag regexps above, see compile_flag_regexp().
 253 my %flag_renames = (
 254     '-O(?:2|3)'                    => '-O2',
 255     '-Wformat(?:=2)?'              => '-Wformat',
 256     '--param[= ]ssp-buffer-size=4' => '--param=ssp-buffer-size=4',
 257     '-Wl,(?:-z,)?relro'            => '-Wl,-z,relro',
 258     '-Wl,(?:-z,)?now'              => '-Wl,-z,now',
 259 );
 260
 261 my %exit_code = (
 262     no_compiler_commands => 1 << 0,
 263     # used by POD::Usage => 1 << 1,
 264     non_verbose_build    => 1 << 2,
 265     flags_missing        => 1 << 3,
 266     hardening_wrapper    => 1 << 4,
 267     invalid_cmake        => 1 << 5,
 268 );
 269
 270 my %buildd_tag = (
 271     no_compiler_commands => 'I-no-compiler-commands',
 272     non_verbose_build    => 'W-compiler-flags-hidden',
 273     flags_missing        => 'W-dpkg-buildflags-missing',
 274     hardening_wrapper    => 'I-hardening-wrapper-used',
 275     invalid_cmake        => 'I-invalid-cmake-used',
 276 );
 277
 278 # Statistics of missing flags and non-verbose build commands. Used for
 279 # $option_buildd.
 280 my %statistics = (
 281     preprocess          => 0,
 282     preprocess_missing  => 0,
 283     compile             => 0,
 284     compile_missing     => 0,
 285     compile_cpp         => 0,
 286     compile_cpp_missing => 0,
 287     link                => 0,
 288     link_missing        => 0,
 289     commands            => 0,
 290     commands_nonverbose => 0,
 291 );
 292
 293 # Use colored (ANSI) output?
 294 my $option_color;
 295
 296
 297 # FUNCTIONS
 298
 299 # Only works for single-level arrays with no undef values. Thanks to perlfaq4.
 300 sub array_equal {
 301     my ($first_ref, $second_ref) = @_;
 302
 303     return 0 if scalar @{$first_ref} != scalar @{$second_ref};
 304
 305     my $length = scalar @{$first_ref};
 306     for (my $i = 0; $i < $length; $i++) {
 307         return 0 if $first_ref->[$i] ne $second_ref->[$i];
 308     }
 309
 310     return 1;
 311 }
 312
 313 sub error_flags {
 314     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 315
 316     # Get string value of qr//-escaped regexps and if requested rename them.
 317     my @missing_flags = map {
 318             $flag_renames_ref->{$_}
 319         } @{$missing_flags_ref};
 320
 321     my $flags = join ' ', @missing_flags;
 322     printf '%s (%s)%s %s',
 323            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 324            $line;
 325
 326     return;
 327 }
 328 sub error_non_verbose_build {
 329     my ($line) = @_;
 330
 331     printf '%s%s %s',
 332            error_color('NONVERBOSE BUILD', 'red'),
 333            error_color(':', 'yellow'),
 334            $line;
 335
 336     return;
 337 }
 338 sub error_invalid_cmake {
 339     my ($version) = @_;
 340
 341     printf "%s%s %s\n",
 342             error_color('INVALID CMAKE', 'red'),
 343             error_color(':', 'yellow'),
 344             $version;
 345
 346     return;
 347 }
 348 sub error_hardening_wrapper {
 349     printf "%s%s %s\n",
 350             error_color('HARDENING WRAPPER', 'red'),
 351             error_color(':', 'yellow'),
 352             'no checks possible, aborting';
 353
 354     return;
 355 }
 356 sub error_color {
 357     my ($message, $color) = @_;
 358
 359     if ($option_color) {
 360         return Term::ANSIColor::colored($message, $color);
 361     } else {
 362         return $message;
 363     }
 364 }
 365
 366 sub any_flags_used {
 367     my ($line, @flags) = @_;
 368
 369     foreach my $flag (@flags) {
 370         return 1 if $line =~ /$flag/;
 371     }
 372
 373     return 0;
 374 }
 375 sub all_flags_used {
 376     my ($line, $missing_flags_ref, @flags) = @_;
 377
 378     my @missing_flags = ();
 379     foreach my $flag (@flags) {
 380         if (not $line =~ /$flag/) {
 381             push @missing_flags, $flag;
 382         }
 383     }
 384
 385     return 1 if scalar @missing_flags == 0;
 386
 387     @{$missing_flags_ref} = @missing_flags;
 388     return 0;
 389 }
 390
 391 sub cppflags_fortify_broken {
 392     my ($line, $missing_flags) = @_;
 393
 394     # This doesn't take the position into account, but is a simple solution.
 395     # And if the build system tries to force -D_FORTIFY_SOURCE=0/1, something
 396     # is wrong anyway.
 397
 398     if (any_flags_used($line, @def_cppflags_fortify_bad)) {
 399         # $def_cppflags_fortify[0] must be -D_FORTIFY_SOURCE=2!
 400         push @{$missing_flags}, $def_cppflags_fortify[0];
 401         return 1;
 402     }
 403
 404     return 0;
 405 }
 406
 407 # Modifies $missing_flags_ref array.
 408 sub pic_pie_conflict {
 409     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 410
 411     return 0 if not $pie;
 412     return 0 if not any_flags_used($line, @def_ldflags_pic);
 413
 414     my %flags = map { $_ => 1 } @flags_pie;
 415
 416     # Remove all PIE flags from @missing_flags as they are not required with
 417     # -fPIC.
 418     my @result = grep {
 419         not exists $flags{$_}
 420     } @{$missing_flags_ref};
 421     @{$missing_flags_ref} = @result;
 422
 423     # We got a conflict when no flags are left, thus only PIE flags were
 424     # missing. If other flags were missing abort because the conflict is not
 425     # the problem.
 426     return scalar @result == 0;
 427 }
 428
 429 sub is_non_verbose_build {
 430     my ($line, $next_line, $skip_ref) = @_;
 431
 432     if (not (index($line, 'checking if you want to see long compiling messages... no') == 0
 433                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 434                 or $line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/
 435                 or $line =~ /^\s*[Bb]uilding (?:program|shared library)\s+(.+?)$/
 436                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 437         return 0;
 438     }
 439
 440     # False positives.
 441     #
 442     # C++ compiler setting.
 443     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 444     return 0 if $line =~ /^\s*C\+\+ Library: stdc\+\+$/;
 445     # "Compiling" with no file name.
 446     if ($line =~ /^\s*[Cc]ompiling\s+(.+?)(?:\.\.\.)?$/) {
 447         # $file_extension_regex may need spaces around the filename.
 448         return 0 if not " $1 " =~ /$file_extension_regex/o;
 449     }
 450
 451     my $file = $1;
 452
 453     # On the first pass we only check if this line is verbose or not.
 454     return 1 if not defined $next_line;
 455
 456     # Second pass, we have access to the next line.
 457     ${$skip_ref} = 0;
 458
 459     # CMake and other build systems print the non-verbose messages also when
 460     # building verbose. If a compiler and the file name occurs in the next
 461     # line, treat it as verbose build.
 462     if (defined $file) {
 463         # Get filename, we can't use the complete path as only parts of it are
 464         # used in the real compiler command.
 465         $file =~ m{/([^/\s]+)$};
 466         $file = $1;
 467
 468         if (index($next_line, $file) != -1 and $next_line =~ /$cc_regex/o) {
 469             # Not a non-verbose line, but we still have to skip the current line
 470             # as it doesn't contain any compiler commands.
 471             ${$skip_ref} = 1;
 472             return 0;
 473         }
 474     }
 475
 476     return 1;
 477 }
 478
 479 # Remove @flags from $flag_refs_ref, and $flag_renames_ref.
 480 sub remove_flags {
 481     my ($flag_refs_ref, $flag_renames_ref, @flags) = @_;
 482
 483     my %removes = map { $_ => 1 } @flags;
 484     foreach my $flags (@{$flag_refs_ref}) {
 485         @{$flags} = grep {
 486             # Flag found as string.
 487             not exists $removes{$_}
 488             # Flag found as string representation of regexp.
 489                 and (not defined $flag_renames_ref->{$_}
 490                         or not exists $removes{$flag_renames_ref->{$_}})
 491         } @{$flags};
 492     }
 493
 494     return;
 495 }
 496
 497 # Modifies $flag_renames_ref hash.
 498 sub compile_flag_regexp {
 499     my ($flag_renames_ref, @flags) = @_;
 500
 501     my @result = ();
 502     foreach my $flag (@flags) {
 503         # Compile flag regexp for faster execution.
 504         my $regex = qr/\s$flag(?:\s|\\)/;
 505
 506         # Store flag name in replacement string for correct flags in messages
 507         # with qr//ed flag regexps.
 508         $flag_renames_ref->{$regex}
 509             = (exists $flag_renames_ref->{$flag})
 510                 ? $flag_renames_ref->{$flag}
 511                 : $flag;
 512
 513         push @result, $regex;
 514     }
 515     return @result;
 516 }
 517
 518 # Does any extension in @extensions exist in %{$extensions_ref}?
 519 sub extension_found {
 520     my ($extensions_ref, @extensions) = @_;
 521
 522     foreach my $extension (@extensions) {
 523         if (exists $extensions_ref->{$extension}) {
 524             return 1;
 525         }
 526     }
 527     return 0;
 528 }
 529
 530
 531 # MAIN
 532
 533 # Parse command line arguments.
 534 my $option_help             = 0;
 535 my $option_version          = 0;
 536 my $option_pie              = 0;
 537 my $option_bindnow          = 0;
 538 my @option_ignore_arch      = ();
 539 my @option_ignore_flag      = ();
 540 my @option_ignore_arch_flag = ();
 541 my @option_ignore_line      = ();
 542 my @option_ignore_arch_line = ();
 543 my $option_all              = 0;
 544 my $option_arch             = undef;
 545 my $option_buildd           = 0;
 546    $option_color            = 0;
 547 if (not Getopt::Long::GetOptions(
 548             'help|h|?'           => \$option_help,
 549             'version'            => \$option_version,
 550             # Hardening options.
 551             'pie'                => \$option_pie,
 552             'bindnow'            => \$option_bindnow,
 553             'all'                => \$option_all,
 554             # Ignore.
 555             'ignore-arch=s'      => \@option_ignore_arch,
 556             'ignore-flag=s'      => \@option_ignore_flag,
 557             'ignore-arch-flag=s' => \@option_ignore_arch_flag,
 558             'ignore-line=s'      => \@option_ignore_line,
 559             'ignore-arch-line=s' => \@option_ignore_arch_line,
 560             # Misc.
 561             'color'              => \$option_color,
 562             'arch=s'             => \$option_arch,
 563             'buildd'             => \$option_buildd,
 564         )) {
 565     require Pod::Usage;
 566     Pod::Usage::pod2usage(2);
 567 }
 568 if ($option_help) {
 569     require Pod::Usage;
 570     Pod::Usage::pod2usage(1);
 571 }
 572 if ($option_version) {
 573     print <<"EOF";
 574 blhc $VERSION  Copyright (C) 2012-2013  Simon Ruderich
 575
 576 This program is free software: you can redistribute it and/or modify
 577 it under the terms of the GNU General Public License as published by
 578 the Free Software Foundation, either version 3 of the License, or
 579 (at your option) any later version.
 580
 581 This program is distributed in the hope that it will be useful,
 582 but WITHOUT ANY WARRANTY; without even the implied warranty of
 583 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 584 GNU General Public License for more details.
 585
 586 You should have received a copy of the GNU General Public License
 587 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 588 EOF
 589     exit 0;
 590 }
 591
 592 # Arguments missing.
 593 if (scalar @ARGV == 0) {
 594     require Pod::Usage;
 595     Pod::Usage::pod2usage(2);
 596 }
 597
 598 # Don't load Term::ANSIColor in buildd mode because Term::ANSIColor is not
 599 # installed on Debian's buildds.
 600 if (not $option_buildd) {
 601     require Term::ANSIColor;
 602 }
 603
 604 if ($option_all) {
 605     $option_pie     = 1;
 606     $option_bindnow = 1;
 607 }
 608
 609 # Precompiled ignores for faster lookup.
 610 my %option_ignore_arch_flag = ();
 611 my %option_ignore_arch_line = ();
 612
 613 # Strip flags which should be ignored.
 614 if (scalar @option_ignore_flag > 0) {
 615     remove_flags(\@flag_refs, \%flag_renames, @option_ignore_flag);
 616 }
 617 # Same for arch specific ignore flags, but only prepare here.
 618 if (scalar @option_ignore_arch_flag > 0) {
 619     foreach my $ignore (@option_ignore_arch_flag) {
 620         my ($ignore_arch, $ignore_flag) = split /:/, $ignore, 2;
 621
 622         if (not $ignore_arch or not $ignore_flag) {
 623             printf STDERR 'Value "%s" invalid for option ignore-arch-flag '
 624                         . '("arch:flag" expected)' . "\n", $ignore;
 625             require Pod::Usage;
 626             Pod::Usage::pod2usage(2);
 627         }
 628
 629         push @{$option_ignore_arch_flag{$ignore_arch}}, $ignore_flag;
 630     }
 631 }
 632
 633 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 634 # faster with this.
 635 foreach my $flags (@flag_refs_all) {
 636     @{$flags} = compile_flag_regexp(\%flag_renames, @{$flags});
 637 }
 638
 639 # Precompile ignore line regexps, also anchor at beginning and end of line.
 640 foreach my $ignore (@option_ignore_line) {
 641     $ignore = qr/^$ignore$/;
 642 }
 643 # Same for arch specific ignore lines.
 644 if (scalar @option_ignore_arch_line > 0) {
 645     foreach my $ignore (@option_ignore_arch_line) {
 646         my ($ignore_arch, $ignore_line) = split /:/, $ignore, 2;
 647
 648         if (not $ignore_arch or not $ignore_line) {
 649             printf STDERR 'Value "%s" invalid for option ignore-arch-line '
 650                         . '("arch:line" expected)' . "\n", $ignore;
 651             require Pod::Usage;
 652             Pod::Usage::pod2usage(2);
 653         }
 654
 655         push @{$option_ignore_arch_line{$ignore_arch}}, qr/^$ignore_line$/;
 656     }
 657 }
 658
 659 # Final exit code.
 660 my $exit = 0;
 661
 662 FILE:
 663 foreach my $file (@ARGV) {
 664     print "checking '$file'...\n" if scalar @ARGV > 1;
 665
 666     -f $file or die "No such file: $file";
 667
 668     open my $fh, '<', $file or die $!;
 669
 670     # Architecture of this file.
 671     my $arch = $option_arch;
 672
 673     # Hardening options. Not all architectures support all hardening options.
 674     my $harden_format  = 1;
 675     my $harden_fortify = 1;
 676     my $harden_stack   = 1;
 677     my $harden_relro   = 1;
 678     my $harden_bindnow = $option_bindnow; # defaults to 0
 679     my $harden_pie     = $option_pie;     # defaults to 0
 680
 681     # Does this build log use ada? Ada also uses gcc as compiler but uses
 682     # different CFLAGS. But only perform ada checks if an ada compiler used
 683     # for performance reasons.
 684     my $ada = 0;
 685
 686     while (my $line = <$fh>) {
 687         # Detect architecture automatically unless overridden. For buildd logs
 688         # only, doesn't use the dpkg-buildpackage header. Necessary to ignore
 689         # build logs which aren't built (wrong architecture, build error,
 690         # etc.).
 691         if (not $arch and index($line, 'Architecture: ') == 0) {
 692             $arch = substr $line, 14, -1; # -1 to ignore '\n' at the end
 693         }
 694
 695         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 696         # check for hardening flags in buildd mode if an older dpkg-dev is
 697         # used. Default flags (-g -O2) are still checked.
 698         #
 699         # Packages which were built before 1.16.1 but used their own hardening
 700         # flags are not checked.
 701         if ($option_buildd
 702                 and index($line, 'Toolchain package versions: ') == 0) {
 703             require Dpkg::Version;
 704             if (not $line =~ /\bdpkg-dev_(\S+)/
 705                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 706                 $harden_format  = 0;
 707                 $harden_fortify = 0;
 708                 $harden_stack   = 0;
 709                 $harden_relro   = 0;
 710                 $harden_bindnow = 0;
 711                 $harden_pie     = 0;
 712             }
 713         }
 714
 715         # The following two versions of CMake in Debian obeyed CPPFLAGS, but
 716         # this was later dropped because upstream rejected the patch. Thus
 717         # build logs with these versions will have fortify hardening flags
 718         # enabled, even though they may be not correctly set and are missing
 719         # when build with later CMake versions. Thanks to Aron Xu for letting
 720         # me know.
 721         if (index($line, 'Package versions: ') == 0
 722                 and $line =~ /\bcmake_(\S+)/
 723                 and ($1 eq '2.8.7-1' or $1 eq '2.8.7-2')) {
 724             if (not $option_buildd) {
 725                 error_invalid_cmake($1);
 726                 $exit |= $exit_code{invalid_cmake};
 727             } else {
 728                 print "$buildd_tag{invalid_cmake}|$1|\n";
 729             }
 730         }
 731
 732         # Debian's build daemons use "Filtered Build-Depends:" (or just
 733         # "Build-Depends:" in older versions) for the build dependencies, but
 734         # pbuilder uses "Depends:"; support both.
 735         if (index($line, 'Filtered Build-Depends: ') == 0
 736                 or index($line, 'Build-Depends: ') == 0
 737                 or index($line, 'Depends: ') == 0) {
 738             # If hardening wrapper is used (wraps calls to gcc and adds
 739             # hardening flags automatically) we can't perform any checks,
 740             # abort.
 741             if ($line =~ /\bhardening-wrapper\b/) {
 742                 if (not $option_buildd) {
 743                     error_hardening_wrapper();
 744                     $exit |= $exit_code{hardening_wrapper};
 745                 } else {
 746                     print "$buildd_tag{hardening_wrapper}||\n";
 747                 }
 748                 next FILE;
 749             }
 750
 751             # Ada compiler.
 752             if ($line =~ /\bgnat\b/) {
 753                 $ada = 1;
 754             }
 755         }
 756
 757         # We skip over unimportant lines at the beginning of the log to
 758         # prevent false positives.
 759         last if index($line, 'dpkg-buildpackage: ') == 0;
 760     }
 761
 762     # Input lines, contain only the lines with compiler commands.
 763     my @input = ();
 764     # Non-verbose lines in the input. Used to reduce calls to
 765     # is_non_verbose_build() (which is quite slow) in the second loop when
 766     # it's already clear if a line is non-verbose or not.
 767     my @input_nonverbose = ();
 768
 769     my $continuation = 0;
 770     my $complete_line = undef;
 771     while (my $line = <$fh>) {
 772         # And stop at the end of the build log. Package details (reported by
 773         # the buildd logs) are not important for us. This also prevents false
 774         # positives.
 775         last if index($line, 'Build finished at ') == 0
 776                 and $line =~ /^Build finished at \d{8}-\d{4}$/;
 777
 778         # Detect architecture automatically unless overridden.
 779         if (not $arch
 780                 and index($line, 'dpkg-buildpackage: host architecture ') == 0) {
 781             $arch = substr $line, 37, -1; # -1 to ignore '\n' at the end
 782
 783             # Old buildd logs use e.g. "host architecture is alpha", remove
 784             # the "is", otherwise debarch_to_debtriplet() will not detect the
 785             # architecture.
 786             if (index($arch, 'is ') == 0) {
 787                 $arch = substr $arch, 3;
 788             }
 789         }
 790
 791         # Ignore compiler warnings for now.
 792         next if $line =~ /$warning_regex/o;
 793
 794         if (not $option_buildd and index($line, "\033") != -1) { # \033 = esc
 795             # Remove all ANSI color sequences which are sometimes used in
 796             # non-verbose builds.
 797             $line = Term::ANSIColor::colorstrip($line);
 798             # Also strip '\0xf' (delete previous character), used by Elinks'
 799             # build system.
 800             $line =~ s/\x0f//g;
 801             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 802             # what it does).
 803             $line =~ s/\033\(B//g;
 804         }
 805
 806         # Check if this line indicates a non verbose build.
 807         my $non_verbose = is_non_verbose_build($line);
 808
 809         # One line may contain multiple commands (";"). Treat each one as
 810         # single line. parse_line() is slow, only use it when necessary.
 811         my @line = (index($line, ';') == -1)
 812                  ? ($line)
 813                  : map {
 814                        # Ensure newline at the line end - necessary for
 815                        # correct parsing later.
 816                        $_ =~ s/\s+$//;
 817                        $_ .= "\n";
 818                    } Text::ParseWords::parse_line(';', 1, $line);
 819         foreach my $line (@line) {
 820             if ($continuation) {
 821                 $continuation = 0;
 822
 823                 # Join lines, but leave the "\" in place so it's clear where
 824                 # the original line break was.
 825                 chomp $complete_line;
 826                 $complete_line .= ' ' . $line;
 827             }
 828             # Line continuation, line ends with "\".
 829             if ($line =~ /\\$/) {
 830                 $continuation = 1;
 831                 # Start line continuation.
 832                 if (not defined $complete_line) {
 833                     $complete_line = $line;
 834                 }
 835                 next;
 836             }
 837
 838             # Use the complete line if a line continuation occurred.
 839             if (defined $complete_line) {
 840                 $line = $complete_line;
 841                 $complete_line = undef;
 842             }
 843
 844             # Ignore lines with no compiler commands.
 845             next if not $non_verbose
 846                     and not $line =~ /$cc_regex_normal/o;
 847             # Ignore lines with no filenames with extensions. May miss some
 848             # non-verbose builds (e.g. "gcc -o test" [sic!]), but shouldn't be
 849             # a problem as the log will most likely contain other non-verbose
 850             # commands which are detected.
 851             next if not $non_verbose
 852                     and not $line =~ /$file_extension_regex/o;
 853
 854             # Ignore false positives.
 855             #
 856             # `./configure` output.
 857             next if not $non_verbose
 858                     and $line =~ /^(?:checking|[Cc]onfigure:) /;
 859             next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 860                                 [Cc]ompiler[\s.]*:?\s+
 861                                 /x;
 862             next if $line =~ m{^\s*(?:-\s)?(?:HOST_)?(?:CC|CXX)
 863                                 \s*=\s*$cc_regex_full
 864                                 # optional compiler options, don't allow
 865                                 # "everything" here to prevent false negatives
 866                                 \s*(?:\s-\S+)*\s*$}xo;
 867             # `moc-qt4`/`moc-qt5` contain '-I.../linux-g++' in their command
 868             # line (or similar for other architectures) which gets recognized
 869             # as a compiler line, but `moc-qt*` is only a preprocessor for Qt
 870             # C++ files. No hardening flags are relevant during this step,
 871             # thus ignore `moc-qt*` lines. The resulting files will be
 872             # compiled in a separate step (and therefore checked).
 873             next if $line =~ m{^\S+/bin/moc(?:-qt[45])?
 874                                \s.+\s
 875                                -I\S+/mkspecs/[a-z]+-g\++(?:-64)?
 876                                \s}x;
 877             # Ignore false positives when the line contains only CC=gcc but no
 878             # other gcc command.
 879             if ($line =~ /(.*)CC=$cc_regex_full(.*)/o) {
 880                 my $before = $1;
 881                 my $after  = $2;
 882                 next if     not $before =~ /$cc_regex_normal/o
 883                         and not $after  =~ /$cc_regex_normal/o;
 884             }
 885
 886             # Check if additional hardening options were used. Used to ensure
 887             # they are used for the complete build.
 888             $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie,
 889                                                          @def_ldflags_pie);
 890             $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 891
 892             push @input, $line;
 893             push @input_nonverbose, $non_verbose;
 894         }
 895     }
 896
 897     close $fh or die $!;
 898
 899     # Ignore arch if requested.
 900     if (scalar @option_ignore_arch > 0 and $arch) {
 901         foreach my $ignore (@option_ignore_arch) {
 902             if ($arch eq $ignore) {
 903                 print "ignoring architecture '$arch'\n";
 904                 next FILE;
 905             }
 906         }
 907     }
 908
 909     if (scalar @input == 0) {
 910         if (not $option_buildd) {
 911             print "No compiler commands!\n";
 912             $exit |= $exit_code{no_compiler_commands};
 913         } else {
 914             print "$buildd_tag{no_compiler_commands}||\n";
 915         }
 916         next FILE;
 917     }
 918
 919     if ($option_buildd) {
 920         $statistics{commands} += scalar @input;
 921     }
 922
 923     # Option or auto detected.
 924     if ($arch) {
 925         # The following was partially copied from dpkg-dev 1.17.1
 926         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 927         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 928         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 929         # later. Keep it in sync.
 930
 931         require Dpkg::Arch;
 932         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($arch);
 933
 934         # Disable unsupported hardening options.
 935         if ($os !~ /^(?:linux|knetbsd|hurd)$/ or
 936                 $cpu =~ /^(?:hppa|mips|mipsel|avr32)$/) {
 937             $harden_pie = 0;
 938         }
 939         if ($cpu =~ /^(?:ia64|alpha|mips|mipsel|hppa|arm64)$/
 940                 or $arch eq 'arm') {
 941             $harden_stack = 0;
 942         }
 943         if ($cpu =~ /^(?:ia64|hppa|avr32)$/) {
 944             $harden_relro   = 0;
 945             $harden_bindnow = 0;
 946         }
 947     }
 948
 949     # Default values.
 950     my @cflags   = @def_cflags;
 951     my @cxxflags = @def_cxxflags;
 952     my @cppflags = @def_cppflags;
 953     my @ldflags  = @def_ldflags;
 954     # Check the specified hardening options, same order as dpkg-buildflags.
 955     if ($harden_pie) {
 956         @cflags   = (@cflags,   @def_cflags_pie);
 957         @cxxflags = (@cxxflags, @def_cflags_pie);
 958         @ldflags  = (@ldflags,  @def_ldflags_pie);
 959     }
 960     if ($harden_stack) {
 961         @cflags   = (@cflags,   @def_cflags_stack);
 962         @cxxflags = (@cxxflags, @def_cflags_stack);
 963     }
 964     if ($harden_fortify) {
 965         @cflags   = (@cflags,   @def_cflags_fortify);
 966         @cxxflags = (@cxxflags, @def_cflags_fortify);
 967         @cppflags = (@cppflags, @def_cppflags_fortify);
 968     }
 969     if ($harden_format) {
 970         @cflags   = (@cflags,   @def_cflags_format);
 971         @cxxflags = (@cxxflags, @def_cflags_format);
 972     }
 973     if ($harden_relro) {
 974         @ldflags = (@ldflags, @def_ldflags_relro);
 975     }
 976     if ($harden_bindnow) {
 977         @ldflags = (@ldflags, @def_ldflags_bindnow);
 978     }
 979
 980     # Stores normal CFLAGS when @cflags_ada are temporarily used.
 981     my @cflags_backup;
 982     # Ada CFLAGS, only set if ada is used.
 983     my @cflags_ada;
 984     # Ada doesn't support format hardening flags, see #680117 for more
 985     # information. Filter them out if ada is used.
 986     if ($ada and $harden_format) {
 987         @cflags_ada = grep {
 988             my $ok = 1;
 989             foreach my $flag (@def_cflags_format) {
 990                 $ok = 0 if $_ eq $flag;
 991             }
 992             $ok;
 993         } @cflags;
 994     }
 995
 996     # Hack to fix cppflags_fortify_broken() if --ignore-flag
 997     # -D_FORTIFY_SOURCE=2 is used to ignore missing fortification. Only works
 998     # as long as @def_cppflags_fortify contains only one variable.
 999     if (scalar @def_cppflags_fortify == 0) {
1000         $harden_fortify = 0;
1001     }
1002
1003     # Ignore flags for this arch if requested.
1004     if ($arch and exists $option_ignore_arch_flag{$arch}) {
1005         my @local_flag_refs = (\@cflags, \@cxxflags, \@cppflags, \@ldflags);
1006
1007         remove_flags(\@local_flag_refs,
1008                      \%flag_renames,
1009                      @{$option_ignore_arch_flag{$arch}});
1010     }
1011
1012     my @ignore_line = @option_ignore_line;
1013     # Ignore lines for this arch if requested.
1014     if ($arch and exists $option_ignore_arch_line{$arch}) {
1015         @ignore_line = (@ignore_line, @{$option_ignore_arch_line{$arch}});
1016     }
1017
1018 LINE:
1019     for (my $i = 0; $i < scalar @input; $i++) {
1020         my $line = $input[$i];
1021
1022         # Ignore line if requested.
1023         foreach my $ignore (@ignore_line) {
1024             next LINE if $line =~ /$ignore/;
1025         }
1026
1027         my $skip = 0;
1028         if ($input_nonverbose[$i]
1029                 and is_non_verbose_build($line, $input[$i + 1], \$skip)) {
1030             if (not $option_buildd) {
1031                 error_non_verbose_build($line);
1032                 $exit |= $exit_code{non_verbose_build};
1033             } else {
1034                 $statistics{commands_nonverbose}++;
1035             }
1036             next;
1037         }
1038         # Even if it's a verbose build, we might have to skip this line (see
1039         # is_non_verbose_build()).
1040         next if $skip;
1041
1042         # Remove everything until and including the compiler command. Makes
1043         # checks easier and faster.
1044         $line =~ s/^.*?$cc_regex//o;
1045         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
1046         # the brace and similar characters at the line end.
1047         $line =~ s/['")]+$//;
1048
1049         # Skip unnecessary tests when only preprocessing.
1050         my $flag_preprocess = 0;
1051
1052         my $dependency = 0;
1053         my $preprocess = 0;
1054         my $compile    = 0;
1055         my $link       = 0;
1056
1057         # Preprocess, compile, assemble.
1058         if ($line =~ /\s(-E|-S|-c)\b/) {
1059             $preprocess      = 1;
1060             $flag_preprocess = 1 if $1 eq '-E';
1061             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
1062         # Dependency generation for Makefiles. The other flags (-MF -MG -MP
1063         # -MT -MQ) are always used with -M/-MM.
1064         } elsif ($line =~ /\s(?:-M|-MM)\b/) {
1065             $dependency = 1;
1066         # Otherwise assume we are linking.
1067         } else {
1068             $link = 1;
1069         }
1070
1071         # -MD/-MMD also cause dependency generation, but they don't imply -E!
1072         if ($line =~ /\s(?:-MD|-MMD)\b/) {
1073             $dependency      = 0;
1074             $flag_preprocess = 0;
1075         }
1076
1077         # Dependency generation for Makefiles, no preprocessing or other flags
1078         # needed.
1079         next if $dependency;
1080
1081         # Get all file extensions on this line.
1082         my @extensions = $line =~ /$file_extension_regex/go;
1083         # Ignore all unknown extensions to speedup the search below.
1084         @extensions = grep { exists $extension{$_} } @extensions;
1085
1086         # These file types don't require preprocessing.
1087         if (extension_found(\%extensions_no_preprocess, @extensions)) {
1088             $preprocess = 0;
1089         }
1090         # These file types require preprocessing.
1091         if (extension_found(\%extensions_preprocess, @extensions)) {
1092             $preprocess = 1;
1093         }
1094
1095         if (not $flag_preprocess) {
1096             # If there are source files then it's compiling/linking in one
1097             # step and we must check both. We only check for source files
1098             # here, because header files cause too many false positives.
1099             if (extension_found(\%extensions_compile_link, @extensions)) {
1100                 # Assembly files don't need CFLAGS.
1101                 if (not extension_found(\%extensions_compile, @extensions)
1102                         and extension_found(\%extensions_no_compile, @extensions)) {
1103                     $compile = 0;
1104                 # But the rest does.
1105                 } else {
1106                     $compile = 1;
1107                 }
1108             # No compilable extensions found, either linking or compiling
1109             # header flags.
1110             #
1111             # If there are also no object files we are just compiling headers
1112             # (.h -> .h.gch). Don't check for linker flags in this case. Due
1113             # to our liberal checks for compiler lines, this also reduces the
1114             # number of false positives considerably.
1115             } elsif ($link
1116                     and not extension_found(\%extensions_object, @extensions)) {
1117                 $link = 0;
1118             }
1119         }
1120
1121         my $compile_cpp = 0;
1122         my $compile_ada = 0;
1123         # Assume CXXFLAGS are required when a C++ file is specified in the
1124         # compiler line.
1125         if ($compile
1126                 and extension_found(\%extensions_compile_cpp, @extensions)) {
1127             $compile     = 0;
1128             $compile_cpp = 1;
1129         # Ada needs special CFLAGS, use them if only ada files are compiled.
1130         } elsif ($ada
1131                     and $compile
1132                     and array_equal(\@extensions,
1133                                     \@source_no_preprocess_compile_ada)) {
1134             $compile_ada = 1;
1135             @cflags_backup = @cflags;
1136             @cflags        = @cflags_ada;
1137         }
1138
1139         if ($option_buildd) {
1140             $statistics{preprocess}++  if $preprocess;
1141             $statistics{compile}++     if $compile;
1142             $statistics{compile_cpp}++ if $compile_cpp;
1143             $statistics{link}++        if $link;
1144         }
1145
1146         # Check hardening flags.
1147         my @missing;
1148         if ($compile and not all_flags_used($line, \@missing, @cflags)
1149                 # Libraries linked with -fPIC don't have to (and can't) be
1150                 # linked with -fPIE as well. It's no error if only PIE flags
1151                 # are missing.
1152                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1153                 # Assume dpkg-buildflags returns the correct flags.
1154                 and index($line, '`dpkg-buildflags --get CFLAGS`') == -1) {
1155             if (not $option_buildd) {
1156                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1157                 $exit |= $exit_code{flags_missing};
1158             } else {
1159                 $statistics{compile_missing}++;
1160             }
1161         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
1162                 # Libraries linked with -fPIC don't have to (and can't) be
1163                 # linked with -fPIE as well. It's no error if only PIE flags
1164                 # are missing.
1165                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
1166                 # Assume dpkg-buildflags returns the correct flags.
1167                 and index($line, '`dpkg-buildflags --get CXXFLAGS`') == -1) {
1168             if (not $option_buildd) {
1169                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1170                 $exit |= $exit_code{flags_missing};
1171             } else {
1172                 $statistics{compile_cpp_missing}++;
1173             }
1174         }
1175         if ($preprocess
1176                 and (not all_flags_used($line, \@missing, @cppflags)
1177                     # The fortify flag might be overwritten, detect that.
1178                      or ($harden_fortify
1179                          and cppflags_fortify_broken($line, \@missing)))
1180                 # Assume dpkg-buildflags returns the correct flags.
1181                 and index($line, '`dpkg-buildflags --get CPPFLAGS`') == -1) {
1182             if (not $option_buildd) {
1183                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1184                 $exit |= $exit_code{flags_missing};
1185             } else {
1186                 $statistics{preprocess_missing}++;
1187             }
1188         }
1189         if ($link and not all_flags_used($line, \@missing, @ldflags)
1190                 # Same here, -fPIC conflicts with -fPIE.
1191                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
1192                 # Assume dpkg-buildflags returns the correct flags.
1193                 and index($line, '`dpkg-buildflags --get LDFLAGS`') == -1) {
1194             if (not $option_buildd) {
1195                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
1196                 $exit |= $exit_code{flags_missing};
1197             } else {
1198                 $statistics{link_missing}++;
1199             }
1200         }
1201
1202         # Restore normal CFLAGS.
1203         if ($compile_ada) {
1204             @cflags = @cflags_backup;
1205         }
1206     }
1207 }
1208
1209 # Print statistics for buildd mode, only output in this mode.
1210 if ($option_buildd) {
1211     my @warning;
1212
1213     if ($statistics{preprocess_missing}) {
1214         push @warning, sprintf 'CPPFLAGS %d (of %d)',
1215                                $statistics{preprocess_missing},
1216                                $statistics{preprocess};
1217     }
1218     if ($statistics{compile_missing}) {
1219         push @warning, sprintf 'CFLAGS %d (of %d)',
1220                                $statistics{compile_missing},
1221                                $statistics{compile};
1222     }
1223     if ($statistics{compile_cpp_missing}) {
1224         push @warning, sprintf 'CXXFLAGS %d (of %d)',
1225                                $statistics{compile_cpp_missing},
1226                                $statistics{compile_cpp};
1227     }
1228     if ($statistics{link_missing}) {
1229         push @warning, sprintf 'LDFLAGS %d (of %d)',
1230                                $statistics{link_missing},
1231                                $statistics{link};
1232     }
1233     if (scalar @warning) {
1234         local $" = ', '; # array join string
1235         print "$buildd_tag{flags_missing}|@warning missing|\n";
1236     }
1237
1238     if ($statistics{commands_nonverbose}) {
1239         printf "$buildd_tag{non_verbose_build}|%d (of %d) hidden|\n",
1240                $statistics{commands_nonverbose},
1241                $statistics{commands},
1242     }
1243 }
1244
1245
1246 exit $exit;
1247
1248
1249 __END__
1250
1251 =head1 NAME
1252
1253 blhc - build log hardening check, checks build logs for missing hardening flags
1254
1255 =head1 SYNOPSIS
1256
1257 B<blhc> [I<options>] I<< <dpkg-buildpackage build log file>.. >>
1258
1259 =head1 DESCRIPTION
1260
1261 blhc is a small tool which checks build logs for missing hardening flags. It's
1262 licensed under the GPL 3 or later.
1263
1264 It's designed to check build logs generated by Debian's dpkg-buildpackage (or
1265 tools using dpkg-buildpackage like pbuilder or the official buildd build logs)
1266 to help maintainers detect missing hardening flags in their packages.
1267
1268 Only gcc is detected as compiler at the moment. If other compilers support
1269 hardening flags as well, please report them.
1270
1271 If there's no output, no flags are missing and the build log is fine.
1272
1273 =head1 OPTIONS
1274
1275 =over 8
1276
1277 =item B<--all>
1278
1279 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
1280 auto detected.
1281
1282 =item B<--arch> I<architecture>
1283
1284 Set the specific architecture (e.g. amd64, armel, etc.), automatically
1285 disables hardening flags not available on this architecture. Is detected
1286 automatically if dpkg-buildpackage is used.
1287
1288 =item B<--bindnow>
1289
1290 Force check for all +bindnow hardening flags. By default it's auto detected.
1291
1292 =item B<--buildd>
1293
1294 Special mode for buildds when automatically parsing log files. The following
1295 changes are in effect:
1296
1297 =over 2
1298
1299 =item *
1300
1301 Print tags instead of normal warnings, see L</"BUILDD TAGS"> for a list of
1302 possible tags.
1303
1304 =item *
1305
1306 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
1307 detected).
1308
1309 =item *
1310
1311 Don't require Term::ANSIColor.
1312
1313 =item *
1314
1315 Return exit code 0, unless there was a error (-I, -W messages don't count as
1316 error).
1317
1318 =back
1319
1320 =item B<--color>
1321
1322 Use colored (ANSI) output for warning messages.
1323
1324 =item B<--ignore-arch> I<arch>
1325
1326 Ignore build logs from architectures matching I<arch>. I<arch> is a string.
1327
1328 Used to prevent false positives. This option can be specified multiple times.
1329
1330 =item B<--ignore-arch-flag> I<arch>:I<flag>
1331
1332 Like B<--ignore-flag>, but only ignore flag on I<arch>.
1333
1334 =item B<--ignore-arch-line> I<arch>:I<line>
1335
1336 Like B<--ignore-line>, but only ignore line on I<arch>.
1337
1338 =item B<--ignore-flag> I<flag>
1339
1340 Don't print an error when the specific flag is missing in a compiler line.
1341 I<flag> is a string.
1342
1343 Used to prevent false positives. This option can be specified multiple times.
1344
1345 =item B<--ignore-line> I<regex>
1346
1347 Ignore lines matching the given Perl regex. I<regex> is automatically anchored
1348 at the beginning and end of the line to prevent false negatives.
1349
1350 B<NOTE>: Not the input lines are checked, but the lines which are displayed in
1351 warnings (which have line continuation resolved).
1352
1353 Used to prevent false positives. This option can be specified multiple times.
1354
1355 =item B<--pie>
1356
1357 Force check for all +pie hardening flags. By default it's auto detected.
1358
1359 =item B<-h -? --help>
1360
1361 Print available options.
1362
1363 =item B<--version>
1364
1365 Print version number and license.
1366
1367 =back
1368
1369 Auto detection for B<--pie> and B<--bindnow> only works if at least one
1370 command uses the required hardening flag (e.g. -fPIE). Then it's required for
1371 all other commands as well.
1372
1373 =head1 EXAMPLES
1374
1375 Normal usage, parse a single log file.
1376
1377     blhc path/to/log/file
1378
1379 If there's no output, no flags are missing and the build log is fine.
1380
1381 Parse multiple log files. The exit code is ORed over all files.
1382
1383     blhc path/to/directory/with/log/files/*
1384
1385 Don't treat missing C<-g> as error:
1386
1387     blhc --ignore-flag -g path/to/log/file
1388
1389 Don't treat missing C<-pie> on kfreebsd-amd64 as error:
1390
1391     blhc --ignore-arch-flag kfreebsd-amd64:-pie path/to/log/file
1392
1393 Ignore lines consisting exactly of C<./script gcc file> which would cause a
1394 false positive.
1395
1396     blhc --ignore-line '\./script gcc file' path/to/log/file
1397
1398 Ignore lines matching C<./script gcc file> somewhere in the line.
1399
1400     blhc --ignore-line '.*\./script gcc file.*' path/to/log/file
1401
1402 Use blhc with pbuilder.
1403
1404     pbuilder path/to/package.dsc | tee path/log/file
1405     blhc path/to/file || echo flags missing
1406
1407 =head1 BUILDD TAGS
1408
1409 The following tags are used in I<--buildd> mode. In braces the additional data
1410 which is displayed.
1411
1412 =over 2
1413
1414 =item B<I-hardening-wrapper-used>
1415
1416 The package uses hardening-wrapper which intercepts calls to gcc and adds
1417 hardening flags. The build log doesn't contain any hardening flags and thus
1418 can't be checked by blhc.
1419
1420 =item B<W-compiler-flags-hidden> (summary of hidden lines)
1421
1422 Build log contains lines which hide the real compiler flags. For example:
1423
1424     CC test-a.c
1425     CC test-b.c
1426     CC test-c.c
1427     LD test
1428
1429 Most of the time either C<export V=1> or C<export verbose=1> in
1430 F<debian/rules> fixes builds with hidden compiler flags. Sometimes C<.SILENT>
1431 in a F<Makefile> must be removed. And as last resort the F<Makefile> must be
1432 patched to remove the C<@>s hiding the real compiler commands.
1433
1434 =item B<W-dpkg-buildflags-missing> (summary of missing flags)
1435
1436 CPPFLAGS, CFLAGS, CXXFLAGS, LDFLAGS missing.
1437
1438 =item B<I-invalid-cmake-used> (version)
1439
1440 By default CMake ignores CPPFLAGS thus missing those hardening flags. Debian
1441 patched CMake in versions 2.8.7-1 and 2.8.7-2 to respect CPPFLAGS, but this
1442 patch was rejected by upstream and later reverted in Debian. Thus those two
1443 versions show correct usage of CPPFLAGS even if the package doesn't correctly
1444 handle them (for example by passing them to CFLAGS). To prevent false
1445 negatives just blacklist those two versions.
1446
1447 =item B<I-no-compiler-commands>
1448
1449 No compiler commands were detected. Either the log contains none or they were
1450 not correctly detected by blhc (please report the bug in this case).
1451
1452 =back
1453
1454 =head1 EXIT STATUS
1455
1456 The exit status is a "bit mask", each listed status is ORed when the error
1457 condition occurs to get the result.
1458
1459 =over 4
1460
1461 =item B<0>
1462
1463 Success.
1464
1465 =item B<1>
1466
1467 No compiler commands were found.
1468
1469 =item B<2>
1470
1471 Invalid arguments/options given to blhc.
1472
1473 =item B<4>
1474
1475 Non verbose build.
1476
1477 =item B<8>
1478
1479 Missing hardening flags.
1480
1481 =item B<16>
1482
1483 Hardening wrapper detected, no tests performed.
1484
1485 =item B<32>
1486
1487 Invalid CMake version used. See B<I-invalid-cmake-used> under L</"BUILDD
1488 TAGS"> for a detailed explanation.
1489
1490 =back
1491
1492 =head1 AUTHOR
1493
1494 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
1495
1496 Thanks to to Bernhard R. Link E<lt>brlink@debian.orgE<gt> and Jaria Alto
1497 E<lt>jari.aalto@cante.netE<gt> for their valuable input and suggestions.
1498
1499 =head1 LICENSE AND COPYRIGHT
1500
1501 Copyright (C) 2012-2013 by Simon Ruderich
1502
1503 This program is free software: you can redistribute it and/or modify
1504 it under the terms of the GNU General Public License as published by
1505 the Free Software Foundation, either version 3 of the License, or
1506 (at your option) any later version.
1507
1508 This program is distributed in the hope that it will be useful,
1509 but WITHOUT ANY WARRANTY; without even the implied warranty of
1510 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1511 GNU General Public License for more details.
1512
1513 You should have received a copy of the GNU General Public License
1514 along with this program.  If not, see <http://www.gnu.org/licenses/>.
1515
1516 =head1 SEE ALSO
1517
1518 L<hardening-check(1)>, L<dpkg-buildflags(1)>
1519
1520 =cut