bin/blhc

   1 #!/usr/bin/perl
   2
   3 # Build log hardening check, checks build logs for missing hardening flags.
   4
   5 # Copyright (C) 2012  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use Getopt::Long ();
  25 use Term::ANSIColor ();
  26 use Text::ParseWords ();
  27
  28 our $VERSION = '0.01';
  29
  30
  31 # CONSTANTS/VARIABLES
  32
  33 # Regex to catch compiler commands.
  34 my $cc_regex = qr/
  35     (?<!\.)(?:cc|gcc|g\+\+|c\+\+)
  36     (?:-[\d.]+)?
  37     /x;
  38 # Full regex which matches the complete compiler name. Used in a few places to
  39 # prevent false negatives.
  40 my $cc_regex_full = qr/
  41     (?:[a-z0-9_]+-(?:linux-|kfreebsd-)?gnu(?:eabi|eabihf)?-)?
  42     $cc_regex
  43     /x;
  44 # Regex to catch (GCC) compiler warnings.
  45 my $warning_regex = qr/^(.+?):([0-9]+):[0-9]+: warning: (.+?) \[(.+?)\]$/;
  46
  47 # List of source file extensions which require preprocessing.
  48 my @source_preprocess_compile_cpp = (
  49     # C++
  50     qw( cc cp cxx cpp CPP c++ C ),
  51     # Objective-C++
  52     qw( mm Mr),
  53 );
  54 my @source_preprocess_compile = (
  55     # C
  56     qw( c ),
  57     # Objective-C
  58     qw( m ),
  59     # (Objective-)C++
  60     @source_preprocess_compile_cpp,
  61     # Fortran
  62     qw( F FOR fpp FPP FTN F90 F95 F03 F08 ),
  63 );
  64 my @source_preprocess_no_compile = (
  65     # Assembly
  66     qw( s ),
  67 );
  68 my @source_preprocess = (
  69     @source_preprocess_compile,
  70     @source_preprocess_no_compile,
  71 );
  72 # List of source file extensions which don't require preprocessing.
  73 my @source_no_preprocess_compile_cpp = (
  74     # C++
  75     qw( ii ),
  76     # Objective-C++
  77     qw( mii ),
  78 );
  79 my @source_no_preprocess_compile = (
  80     # C
  81     qw( i ),
  82     # (Objective-)C++
  83     @source_no_preprocess_compile_cpp,
  84     # Objective-C
  85     qw( mi ),
  86     # Fortran
  87     qw( f for ftn f90 f95 f03 f08 ),
  88 );
  89 my @source_no_preprocess_no_compile = (
  90     # Assembly
  91     qw( S sx ),
  92 );
  93 my @source_no_preprocess = (
  94     @source_no_preprocess_compile,
  95     @source_no_preprocess_no_compile,
  96 );
  97 # List of header file extensions which require preprocessing.
  98 my @header_preprocess = (
  99     # C, C++, Objective-C, Objective-C++
 100     qw( h ),
 101     # C++
 102     qw( hh H hp hxx hpp HPP h++ tcc ),
 103 );
 104
 105 # Hashes for fast extensions lookup to check if a file falls in one of these
 106 # categories.
 107 my %extensions_no_preprocess = map { $_ => 1 } (
 108     @source_no_preprocess,
 109 );
 110 my %extensions_preprocess = map { $_ => 1 } (
 111     @header_preprocess,
 112     @source_preprocess,
 113 );
 114 my %extensions_compile_link = map { $_ => 1 } (
 115     @source_preprocess,
 116     @source_no_preprocess,
 117 );
 118 my %extensions_compile = map { $_ => 1 } (
 119     @source_preprocess_compile,
 120     @source_no_preprocess_compile,
 121 );
 122 my %extensions_no_compile = map { $_ => 1 } (
 123     @source_preprocess_no_compile,
 124     @source_no_preprocess_no_compile,
 125 );
 126 my %extensions_compile_cpp = map { $_ => 1 } (
 127     @source_preprocess_compile_cpp,
 128     @source_no_preprocess_compile_cpp,
 129 );
 130 my %extension = map { $_ => 1 } (
 131     @source_no_preprocess,
 132     @source_no_preprocess_compile,
 133     @source_no_preprocess_compile_cpp,
 134     @source_no_preprocess_no_compile,
 135     @header_preprocess,
 136     @source_preprocess,
 137     @source_preprocess_compile,
 138     @source_preprocess_compile_cpp,
 139     @source_preprocess_no_compile,
 140 );
 141
 142 # Regexp to match file extensions.
 143 my $file_extension_regex = qr/
 144     \s
 145     \S+             # Filename without extension.
 146     \.
 147     ([^\\.,;:\s]+)  # File extension.
 148     (?=\s|\\)       # At end of word. Can't use \b because some files have non
 149                     # word characters at the end and because \b matches double
 150                     # extensions (like .cpp.o). Works always as all lines are
 151                     # terminated with "\n".
 152     /x;
 153
 154 # Expected (hardening) flags. All flags are used as regexps.
 155 my @def_cflags = (
 156     '-g',
 157     '-O(?:2|3)',
 158 );
 159 my @def_cflags_format = (
 160     '-Wformat',
 161     '-Wformat-security',
 162     '-Werror=format-security',
 163 );
 164 my @def_cflags_fortify = (
 165     # fortify needs at least -O1, but -O2 is recommended anyway
 166 );
 167 my @def_cflags_stack = (
 168     '-fstack-protector',
 169     '--param=ssp-buffer-size=4',
 170 );
 171 my @def_cflags_pie = (
 172     '-fPIE',
 173 );
 174 my @def_cxxflags = (
 175     @def_cflags,
 176 );
 177 # @def_cxxflags_* is the same as @def_cflags_*.
 178 my @def_cppflags = ();
 179 my @def_cppflags_fortify = (
 180     '-D_FORTIFY_SOURCE=2',
 181 );
 182 my @def_ldflags = ();
 183 my @def_ldflags_relro = (
 184     '-Wl,(-z,)?relro',
 185 );
 186 my @def_ldflags_bindnow = (
 187     '-Wl,(-z,)?now',
 188 );
 189 my @def_ldflags_pie = (
 190     '-fPIE',
 191     '-pie',
 192 );
 193 my @def_ldflags_pic = (
 194     '-fPIC',
 195     '-fpic',
 196     '-shared',
 197 );
 198 # Renaming rules for the output so the regex parts are not visible. Also
 199 # stores string values of flag regexps above, see compile_flag_regexp().
 200 my %flag_renames = (
 201     '-O(?:2|3)'       => '-O2',
 202     '-Wl,(-z,)?relro' => '-Wl,-z,relro',
 203     '-Wl,(-z,)?now'   => '-Wl,-z,now',
 204 );
 205
 206 # Statistics of missing flags and non-verbose build commands. Used for
 207 # $option_buildd.
 208 my %statistics = (
 209     preprocess          => 0,
 210     preprocess_missing  => 0,
 211     compile             => 0,
 212     compile_missing     => 0,
 213     compile_cpp         => 0,
 214     compile_cpp_missing => 0,
 215     link                => 0,
 216     link_missing        => 0,
 217     commands            => 0,
 218     commands_nonverbose => 0,
 219 );
 220
 221 # Use colored (ANSI) output?
 222 my $option_color;
 223
 224
 225 # FUNCTIONS
 226
 227 sub error_flags {
 228     my ($message, $missing_flags_ref, $flag_renames_ref, $line) = @_;
 229
 230     # Get string value of qr//-escaped regexps and if requested rename them.
 231     my @missing_flags = map {
 232             $flag_renames_ref->{$_}
 233         } @{$missing_flags_ref};
 234
 235     my $flags = join ' ', @missing_flags;
 236     printf "%s (%s)%s %s",
 237            error_color($message, 'red'), $flags, error_color(':', 'yellow'),
 238            $line;
 239 }
 240 sub error_non_verbose_build {
 241     my ($line) = @_;
 242
 243     printf "%s%s %s",
 244            error_color('NONVERBOSE BUILD', 'red'),
 245            error_color(':', 'yellow'),
 246            $line;
 247 }
 248 sub error_hardening_wrapper {
 249     printf "%s%s %s\n",
 250             error_color('HARDENING WRAPPER', 'red'),
 251             error_color(':', 'yellow'),
 252             'no checks possible, aborting';
 253 }
 254 sub error_color {
 255     my ($message, $color) = @_;
 256
 257     if ($option_color) {
 258         return Term::ANSIColor::colored($message, $color);
 259     } else {
 260         return $message;
 261     }
 262 }
 263
 264 sub any_flags_used {
 265     my ($line, @flags) = @_;
 266
 267     foreach my $flag (@flags) {
 268         return 1 if $line =~ /$flag/;
 269     }
 270
 271     return 0;
 272 }
 273 sub all_flags_used {
 274     my ($line, $missing_flags_ref, @flags) = @_;
 275
 276     my @missing_flags = ();
 277     foreach my $flag (@flags) {
 278         if (not $line =~ /$flag/) {
 279             push @missing_flags, $flag;
 280         }
 281     }
 282
 283     return 1 if scalar @missing_flags == 0;
 284
 285     @{$missing_flags_ref} = @missing_flags;
 286     return 0;
 287 }
 288
 289 # Modifies $missing_flags_ref array.
 290 sub pic_pie_conflict {
 291     my ($line, $pie, $missing_flags_ref, @flags_pie) = @_;
 292
 293     return 0 if not $pie;
 294     return 0 if not any_flags_used($line, @def_ldflags_pic);
 295
 296     my %flags = map { $_ => 1 } @flags_pie;
 297
 298     # Remove all PIE flags from @missing_flags as they are not required with
 299     # -fPIC.
 300     my @result = grep {
 301         not exists $flags{$_}
 302     } @{$missing_flags_ref};
 303     @{$missing_flags_ref} = @result;
 304
 305     # We got a conflict when no flags are left, thus only PIE flags were
 306     # missing. If other flags were missing abort because the conflict is not
 307     # the problem.
 308     return scalar @result == 0;
 309 }
 310
 311 sub is_non_verbose_build {
 312     my ($line, $next_line, $skip_ref) = @_;
 313
 314     if (not ($line =~ /^checking if you want to see long compiling messages\.\.\. no/
 315                 or $line =~ /^\s*\[?(?:CC|CCLD|C\+\+|CXX|CXXLD|LD|LINK)\]?\s+(.+?)$/
 316                 or $line =~ /^\s*(?:C|c)ompiling\s+(.+?)(?:\.\.\.)?$/
 317                 or $line =~ /^\s*(?:B|b)uilding (?:program|shared library)\s+(.+?)$/
 318                 or $line =~ /^\s*\[[\d ]+%\] Building (?:C|CXX) object (.+?)$/)) {
 319         return 0;
 320     }
 321
 322     # False positives.
 323     return 0 if $line =~ /^\s*C\+\+.+?:\s+(?:yes|no)\s*$/;
 324
 325     my $file = $1;
 326
 327     # On the first pass we only check if this line is verbose or not.
 328     return 1 if not defined $next_line;
 329
 330     # Second pass, we have access to the next line.
 331     ${$skip_ref} = 0;
 332
 333     # CMake and other build systems print the non-verbose messages also when
 334     # building verbose. If a compiler and the file name occurs in the next
 335     # line, treat it as verbose build.
 336     if (defined $file) {
 337         # Get filename, we can't use the complete path as only parts of it are
 338         # used in the real compiler command.
 339         $file =~ m{/([^/\s]+)$};
 340         $file = $1;
 341
 342         if ($next_line =~ /\Q$file\E/ and $next_line =~ /$cc_regex/o) {
 343             # We still have to skip the current line as it doesn't contain any
 344             # compiler commands.
 345             ${$skip_ref} = 1;
 346             return 0;
 347         }
 348     }
 349
 350     return 1;
 351 }
 352
 353 sub compile_flag_regexp {
 354     my ($flag_renames_ref, @flags) = @_;
 355
 356     my @result = ();
 357     foreach my $flag (@flags) {
 358         # Store flag name in replacement string for correct flags in messages
 359         # with qr//ed flag regexps.
 360         $flag_renames_ref->{qr/\s$flag(?:\s|\\)/}
 361             = (exists $flag_renames_ref->{$flag})
 362                 ? $flag_renames_ref->{$flag}
 363                 : $flag;
 364
 365         # Compile flag regexp for faster execution.
 366         push @result, qr/\s$flag(?:\s|\\)/;
 367     }
 368     return @result;
 369 }
 370
 371 sub extension_found {
 372     my ($extensions_ref, @extensions) = @_;
 373
 374     my $found = 0;
 375     foreach my $extension (@extensions) {
 376         if (exists $extensions_ref->{$extension}) {
 377             $found = 1;
 378             last;
 379         }
 380     }
 381     return $found;
 382 }
 383
 384
 385 # MAIN
 386
 387 # Parse command line arguments.
 388 my $option_help    = 0;
 389 my $option_version = 0;
 390 my $option_pie     = 0;
 391 my $option_bindnow = 0;
 392 my $option_all     = 0;
 393 my $option_arch    = undef;
 394 my $option_buildd  = 0;
 395    $option_color   = 0;
 396 if (not Getopt::Long::GetOptions(
 397             'help|h|?' => \$option_help,
 398             'version'  => \$option_version,
 399             # Hardening options.
 400             'pie'      => \$option_pie,
 401             'bindnow'  => \$option_bindnow,
 402             'all'      => \$option_all,
 403             # Misc.
 404             'color'    => \$option_color,
 405             'arch=s'   => \$option_arch,
 406             'buildd'   => \$option_buildd,
 407         )) {
 408     require Pod::Usage;
 409     Pod::Usage::pod2usage(2);
 410 }
 411 if ($option_help) {
 412     require Pod::Usage;
 413     Pod::Usage::pod2usage(1);
 414 }
 415 if ($option_version) {
 416     print "blhc $VERSION  Copyright (C) 2012  Simon Ruderich
 417
 418 This program is free software: you can redistribute it and/or modify
 419 it under the terms of the GNU General Public License as published by
 420 the Free Software Foundation, either version 3 of the License, or
 421 (at your option) any later version.
 422
 423 This program is distributed in the hope that it will be useful,
 424 but WITHOUT ANY WARRANTY; without even the implied warranty of
 425 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 426 GNU General Public License for more details.
 427
 428 You should have received a copy of the GNU General Public License
 429 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 430 ";
 431     exit 0;
 432 }
 433
 434 if ($option_all) {
 435     $option_pie     = 1;
 436     $option_bindnow = 1;
 437 }
 438
 439 # Precompile all flag regexps. any_flags_used(), all_flags_used() get a lot
 440 # faster with this.
 441 @def_cflags           = compile_flag_regexp(\%flag_renames, @def_cflags);
 442 @def_cflags_format    = compile_flag_regexp(\%flag_renames, @def_cflags_format);
 443 @def_cflags_fortify   = compile_flag_regexp(\%flag_renames, @def_cflags_fortify);
 444 @def_cflags_stack     = compile_flag_regexp(\%flag_renames, @def_cflags_stack);
 445 @def_cflags_pie       = compile_flag_regexp(\%flag_renames, @def_cflags_pie);
 446 @def_cxxflags         = compile_flag_regexp(\%flag_renames, @def_cxxflags);
 447 @def_cppflags         = compile_flag_regexp(\%flag_renames, @def_cppflags);
 448 @def_cppflags_fortify = compile_flag_regexp(\%flag_renames, @def_cppflags_fortify);
 449 @def_ldflags          = compile_flag_regexp(\%flag_renames, @def_ldflags);
 450 @def_ldflags_relro    = compile_flag_regexp(\%flag_renames, @def_ldflags_relro);
 451 @def_ldflags_bindnow  = compile_flag_regexp(\%flag_renames, @def_ldflags_bindnow);
 452 @def_ldflags_pie      = compile_flag_regexp(\%flag_renames, @def_ldflags_pie);
 453 @def_ldflags_pic      = compile_flag_regexp(\%flag_renames, @def_ldflags_pic);
 454
 455 # Final exit code.
 456 my $exit = 0;
 457
 458 FILE: foreach my $file (@ARGV) {
 459     open my $fh, '<', $file or die "$!: $file";
 460
 461     # Hardening options. Not all architectures support all hardening options.
 462     my $harden_format  = 1;
 463     my $harden_fortify = 1;
 464     my $harden_stack   = 1;
 465     my $harden_relro   = 1;
 466     my $harden_bindnow = $option_bindnow; # defaults to 0
 467     my $harden_pie     = $option_pie;     # defaults to 0
 468
 469     while (my $line = <$fh>) {
 470         # dpkg-buildflags only provides hardening flags since 1.16.1, don't
 471         # check for hardening flags in buildd mode if an older dpkg-dev is
 472         # used. Default flags (-g -O2) are still checked.
 473         #
 474         # Packages which were built before 1.16.1 but used their own hardening
 475         # flags are not checked.
 476         if ($option_buildd and $line =~ /^Toolchain package versions: /) {
 477             require Dpkg::Version;
 478             if ($line !~ /dpkg-dev_(\S+)/
 479                     or Dpkg::Version::version_compare($1, '1.16.1') < 0) {
 480                 $harden_format  = 0;
 481                 $harden_fortify = 0;
 482                 $harden_stack   = 0;
 483                 $harden_relro   = 0;
 484                 $harden_bindnow = 0;
 485                 $harden_pie     = 0;
 486             }
 487         }
 488
 489         # If hardening wrapper is used (wraps calls to gcc and adds hardening
 490         # flags automatically) we can't perform any checks, abort.
 491         if ($line =~ /^Build-Depends: .*\bhardening-wrapper\b/) {
 492             if (not $option_buildd) {
 493                 error_hardening_wrapper();
 494             } else {
 495                 print "I-hardening-wrapper-used\n";
 496             }
 497             $exit |= 1 << 4;
 498             next FILE;
 499         }
 500
 501         # We skip over unimportant lines at the beginning of the log to
 502         # prevent false positives.
 503         last if $line =~ /^dpkg-buildpackage:/;
 504     }
 505
 506     # Input lines, contain only the lines with compiler commands.
 507     my @input = ();
 508
 509     my $continuation = 0;
 510     my $complete_line = undef;
 511     while (my $line = <$fh>) {
 512         # And stop at the end of the build log. Package details (reported by
 513         # the buildd logs) are not important for us. This also prevents false
 514         # positives.
 515         last if $line =~ /^Build finished at \d{8}-\d{4}$/;
 516
 517         # Detect architecture automatically unless overridden.
 518         if (not $option_arch
 519                 and $line =~ /^dpkg-buildpackage: host architecture (.+)$/) {
 520             $option_arch = $1;
 521         }
 522
 523         # Ignore compiler warnings for now.
 524         next if $line =~ /$warning_regex/o;
 525
 526         if ($line =~ /\033/) { # esc
 527             # Remove all ANSI color sequences which are sometimes used in
 528             # non-verbose builds.
 529             $line = Term::ANSIColor::colorstrip($line);
 530             # Also strip '\0xf' (delete previous character), used by Elinks'
 531             # build system.
 532             $line =~ s/\x0f//g;
 533             # And "ESC(B" which seems to be used on armhf and hurd (not sure
 534             # what it does).
 535             $line =~ s/\033\(B//g;
 536         }
 537
 538         # Check if this line indicates a non verbose build.
 539         my $non_verbose = is_non_verbose_build($line);
 540
 541         # One line may contain multiple commands (";"). Treat each one as
 542         # single line. parse_line() is slow, only use it when necessary.
 543         my @line = (not $line =~ /;/)
 544                  ? ($line)
 545                  : map {
 546                        # Ensure newline at the line end - necessary for
 547                        # correct parsing later.
 548                        $_ =~ s/\s+$//;
 549                        $_ .= "\n";
 550                    } Text::ParseWords::parse_line(';', 1, $line);
 551         foreach $line (@line) {
 552             if ($continuation) {
 553                 $continuation = 0;
 554
 555                 # Join lines, but leave the "\" in place so it's clear where
 556                 # the original line break was.
 557                 chomp $complete_line;
 558                 $complete_line .= ' ' . $line;
 559             }
 560             # Line continuation, line ends with "\".
 561             if ($line =~ /\\\s*$/) {
 562                 $continuation = 1;
 563                 # Start line continuation.
 564                 if (not defined $complete_line) {
 565                     $complete_line = $line;
 566                 }
 567                 next;
 568             }
 569
 570             if (not $continuation) {
 571                 # Use the complete line if a line continuation occurred.
 572                 if (defined $complete_line) {
 573                     $line = $complete_line;
 574                     $complete_line = undef;
 575                 }
 576
 577                 # Ignore lines with no compiler commands.
 578                 next if not $non_verbose
 579                         and not $line =~ /\b$cc_regex(?:\s|\\)/o;
 580                 # Ignore lines with no filenames with extensions. May miss
 581                 # some non-verbose builds (e.g. "gcc -o test" [sic!]), but
 582                 # shouldn't be a problem as the log will most likely contain
 583                 # other non-verbose commands which are detected.
 584                 next if not $non_verbose
 585                         and not $line =~ /$file_extension_regex/o;
 586
 587                 # Ignore false positives.
 588                 #
 589                 # `./configure` output.
 590                 next if not $non_verbose
 591                         and $line =~ /^(?:checking|(?:C|c)onfigure:) /;
 592                 next if $line =~ /^\s*(?:Host\s+)?(?:C(?:\+\+)?\s+)?
 593                                    (?:C|c)ompiler[\s.]*:?\s+
 594                                  /xo;
 595                 next if $line =~ /^\s*(?:- )?(?:HOST_)?(?:CC|CXX)\s*=\s*$cc_regex_full\s*$/o;
 596
 597                 # Check if additional hardening options were used. Used to
 598                 # ensure they are used for the complete build.
 599                 $harden_pie     = 1 if any_flags_used($line, @def_cflags_pie, @def_ldflags_pie);
 600                 $harden_bindnow = 1 if any_flags_used($line, @def_ldflags_bindnow);
 601
 602                 push @input, $line;
 603             }
 604         }
 605     }
 606
 607     close $fh;
 608
 609     if (scalar @input == 0) {
 610         if (not $option_buildd) {
 611             print "No compiler commands!\n";
 612         } else {
 613             print "W-no-compiler-commands\n";
 614         }
 615         $exit |= 1;
 616         next FILE;
 617     }
 618
 619     if ($option_buildd) {
 620         $statistics{commands} += scalar @input;
 621     }
 622
 623     # Option or auto detected.
 624     if ($option_arch) {
 625         # The following was partially copied from dpkg-dev 1.16.1.2
 626         # (/usr/share/perl5/Dpkg/Vendor/Debian.pm, add_hardening_flags()),
 627         # copyright Raphaël Hertzog <hertzog@debian.org>, Kees Cook
 628         # <kees@debian.org>, Canonical, Ltd. licensed under GPL version 2 or
 629         # later. Keep it in sync.
 630
 631         require Dpkg::Arch;
 632         my ($abi, $os, $cpu) = Dpkg::Arch::debarch_to_debtriplet($option_arch);
 633
 634         # Disable unsupported hardening options.
 635         if ($cpu =~ /^(ia64|alpha|mips|mipsel|hppa)$/ or $option_arch eq 'arm') {
 636             $harden_stack = 0;
 637         }
 638         if ($cpu =~ /^(ia64|hppa|avr32)$/) {
 639             $harden_relro   = 0;
 640             $harden_bindnow = 0;
 641         }
 642     }
 643
 644     # Default values.
 645     my @cflags   = @def_cflags;
 646     my @cxxflags = @def_cxxflags;
 647     my @cppflags = @def_cppflags;
 648     my @ldflags  = @def_ldflags;
 649     # Check the specified hardening options, same order as dpkg-buildflags.
 650     if ($harden_pie) {
 651         @cflags   = (@cflags,   @def_cflags_pie);
 652         @cxxflags = (@cxxflags, @def_cflags_pie);
 653         @ldflags  = (@ldflags,  @def_ldflags_pie);
 654     }
 655     if ($harden_stack) {
 656         @cflags   = (@cflags,   @def_cflags_stack);
 657         @cxxflags = (@cxxflags, @def_cflags_stack);
 658     }
 659     if ($harden_fortify) {
 660         @cflags   = (@cflags,   @def_cflags_fortify);
 661         @cxxflags = (@cxxflags, @def_cflags_fortify);
 662         @cppflags = (@cppflags, @def_cppflags_fortify);
 663     }
 664     if ($harden_format) {
 665         @cflags   = (@cflags,   @def_cflags_format);
 666         @cxxflags = (@cxxflags, @def_cflags_format);
 667     }
 668     if ($harden_relro) {
 669         @ldflags = (@ldflags, @def_ldflags_relro);
 670     }
 671     if ($harden_bindnow) {
 672         @ldflags = (@ldflags, @def_ldflags_bindnow);
 673     }
 674
 675     for (my $i = 0; $i < scalar @input; $i++) {
 676         my $line = $input[$i];
 677
 678         my $skip = 0;
 679         if (is_non_verbose_build($line, $input[$i + 1], \$skip)) {
 680             if (not $option_buildd) {
 681                 error_non_verbose_build($line);
 682             } else {
 683                 $statistics{commands_nonverbose}++;
 684             }
 685             $exit |= 1 << 2;
 686             next;
 687         }
 688         # Even if it's a verbose build, we might have to skip this line.
 689         next if $skip;
 690
 691         # Remove everything until and including the compiler command. Makes
 692         # checks easier and faster.
 693         $line =~ s/^.*?$cc_regex//o;
 694         # "([...] test.c)" is not detected as 'test.c' - fix this by removing
 695         # the brace and similar characters.
 696         $line =~ s/['")]+$//;
 697
 698         # Skip unnecessary tests when only preprocessing.
 699         my $flag_preprocess = 0;
 700
 701         my $preprocess = 0;
 702         my $compile    = 0;
 703         my $link       = 0;
 704
 705         # Preprocess, compile, assemble.
 706         if ($line =~ /\s(-E|-S|-c)\b/) {
 707             $preprocess      = 1;
 708             $flag_preprocess = 1 if $1 eq '-E';
 709             $compile         = 1 if $1 eq '-S' or $1 eq '-c';
 710         # Otherwise assume we are linking.
 711         } else {
 712             $link = 1;
 713         }
 714
 715         # Get all file extensions on this line.
 716         my @extensions = $line =~ /$file_extension_regex/go;
 717         # Ignore all unknown extensions to speedup the search below.
 718         @extensions = grep { exists $extension{$_} } @extensions;
 719
 720         # These file types don't require preprocessing.
 721         if (extension_found(\%extensions_no_preprocess, @extensions)) {
 722             $preprocess = 0;
 723         }
 724         # These file types require preprocessing.
 725         if (extension_found(\%extensions_preprocess, @extensions)) {
 726             $preprocess = 1;
 727         }
 728
 729         # If there are source files then it's compiling/linking in one step
 730         # and we must check both. We only check for source files here, because
 731         # header files cause too many false positives.
 732         if (not $flag_preprocess
 733                 and extension_found(\%extensions_compile_link, @extensions)) {
 734             # Assembly files don't need CFLAGS.
 735             if (not extension_found(\%extensions_compile, @extensions)
 736                     and extension_found(\%extensions_no_compile, @extensions)) {
 737                 $compile = 0;
 738             # But the rest does.
 739             } else {
 740                 $compile = 1;
 741             }
 742         }
 743
 744         # Assume CXXFLAGS are required when a C++ file is specified in the
 745         # compiler line.
 746         my $compile_cpp = 0;
 747         if ($compile
 748                 and extension_found(\%extensions_compile_cpp, @extensions)) {
 749             $compile     = 0;
 750             $compile_cpp = 1;
 751         }
 752
 753         if ($option_buildd) {
 754             $statistics{preprocess}++  if $preprocess;
 755             $statistics{compile}++     if $compile;
 756             $statistics{compile_cpp}++ if $compile_cpp;
 757             $statistics{link}++        if $link;
 758         }
 759
 760         # Check hardening flags.
 761         my @missing;
 762         if ($compile and not all_flags_used($line, \@missing, @cflags)
 763                 # Libraries linked with -fPIC don't have to (and can't) be
 764                 # linked with -fPIE as well. It's no error if only PIE flags
 765                 # are missing.
 766                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 767                 # Assume dpkg-buildflags returns the correct flags.
 768                 and not $line =~ /`dpkg-buildflags --get CFLAGS`/) {
 769             if (not $option_buildd) {
 770                 error_flags('CFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 771             } else {
 772                 $statistics{compile_missing}++;
 773             }
 774             $exit |= 1 << 3;
 775         } elsif ($compile_cpp and not all_flags_used($line, \@missing, @cflags)
 776                 # Libraries linked with -fPIC don't have to (and can't) be
 777                 # linked with -fPIE as well. It's no error if only PIE flags
 778                 # are missing.
 779                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_cflags_pie)
 780                 # Assume dpkg-buildflags returns the correct flags.
 781                 and not $line =~ /`dpkg-buildflags --get CXXFLAGS`/) {
 782             if (not $option_buildd) {
 783                 error_flags('CXXFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 784             } else {
 785                 $statistics{compile_cpp_missing}++;
 786             }
 787             $exit |= 1 << 3;
 788         }
 789         if ($preprocess and not all_flags_used($line, \@missing, @cppflags)
 790                 # Assume dpkg-buildflags returns the correct flags.
 791                 and not $line =~ /`dpkg-buildflags --get CPPFLAGS`/) {
 792             if (not $option_buildd) {
 793                 error_flags('CPPFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 794             } else {
 795                 $statistics{preprocess_missing}++;
 796             }
 797             $exit |= 1 << 3;
 798         }
 799         if ($link and not all_flags_used($line, \@missing, @ldflags)
 800                 # Same here, -fPIC conflicts with -fPIE.
 801                 and not pic_pie_conflict($line, $harden_pie, \@missing, @def_ldflags_pie)
 802                 # Assume dpkg-buildflags returns the correct flags.
 803                 and not $line =~ /`dpkg-buildflags --get LDFLAGS`/) {
 804             if (not $option_buildd) {
 805                 error_flags('LDFLAGS missing', \@missing, \%flag_renames, $input[$i]);
 806             } else {
 807                 $statistics{link_missing}++;
 808             }
 809             $exit |= 1 << 3;
 810         }
 811     }
 812 }
 813
 814 # Print statistics for buildd mode, only output in this mode.
 815 if ($option_buildd) {
 816     my @warning;
 817
 818     if ($statistics{preprocess_missing}) {
 819         push @warning, sprintf "CPPFLAGS %d (of %d)",
 820                                $statistics{preprocess_missing},
 821                                $statistics{preprocess};
 822     }
 823     if ($statistics{compile_missing}) {
 824         push @warning, sprintf "CFLAGS %d (of %d)",
 825                                $statistics{compile_missing},
 826                                $statistics{compile};
 827     }
 828     if ($statistics{compile_cpp_missing}) {
 829         push @warning, sprintf "CXXFLAGS %d (of %d)",
 830                                $statistics{compile_cpp_missing},
 831                                $statistics{compile_cpp};
 832     }
 833     if ($statistics{link_missing}) {
 834         push @warning, sprintf "LDFLAGS %d (of %d)",
 835                                $statistics{link_missing},
 836                                $statistics{link};
 837     }
 838     if (scalar @warning) {
 839         local $" = ', '; # array join string
 840         print "W-dpkg-buildflags-missing @warning missing\n";
 841     }
 842
 843     if ($statistics{commands_nonverbose}) {
 844         printf "W-compiler-flags-hidden %d (of %d) hidden\n",
 845                $statistics{commands_nonverbose},
 846                $statistics{commands},
 847     }
 848 }
 849
 850
 851 exit $exit;
 852
 853
 854 __END__
 855
 856 =head1 NAME
 857
 858 blhc - build log hardening check, checks build logs for missing hardening flags
 859
 860 =head1 SYNOPSIS
 861
 862 B<blhc> [I<options>] I<E<lt>dpkg-buildpackage build log fileE<gt>..>
 863
 864 =head1 DESCRIPTION
 865
 866 blhc is a small tool which checks build logs for missing hardening flags and
 867 other important warnings. It's licensed under the GPL 3 or later.
 868
 869 =head1 OPTIONS
 870
 871 =over 8
 872
 873 =item B<--all>
 874
 875 Force check for all +all (+pie, +bindnow) hardening flags. By default it's
 876 auto detected.
 877
 878 =item B<--arch> I<architecture>
 879
 880 Set the specific architecture (e.g. amd64, armel, etc.), automatically
 881 disables hardening flags not available on this architecture. Is detected
 882 automatically if dpkg-buildpackage is used.
 883
 884 =item B<--bindnow>
 885
 886 Force check for all +bindnow hardening flags. By default it's auto detected.
 887
 888 =item B<--buildd>
 889
 890 Special mode for buildds when automatically parsing log files. The following
 891 changes are in effect:
 892
 893 =over 2
 894
 895 =item
 896
 897 Don't check hardening flags in old log files (if dpkg-dev << 1.16.1 is
 898 detected).
 899
 900 =back
 901
 902 =item B<--color>
 903
 904 Use colored (ANSI) output for warning messages.
 905
 906 =item B<--pie>
 907
 908 Force check for all +pie hardening flags. By default it's auto detected.
 909
 910 =item B<-h -? --help>
 911
 912 Print available options.
 913
 914 =item B<--version>
 915
 916 Print version number and license.
 917
 918 =back
 919
 920 Auto detection for B<--pie> and B<--bindnow> only works if at least one
 921 command uses the required hardening flag (e.g. -fPIE). Then it's required for
 922 all other commands as well.
 923
 924 =head1 EXIT STATUS
 925
 926 The exit status is a "bit mask", each listed status is ORed when the error
 927 condition occurs to get the result.
 928
 929 =over 4
 930
 931 =item B<0>
 932
 933 Success.
 934
 935 =item B<1>
 936
 937 No compiler commands were found.
 938
 939 =item B<2>
 940
 941 Invalid arguments/options given to blhc.
 942
 943 =item B<4>
 944
 945 Non verbose build.
 946
 947 =item B<8>
 948
 949 Missing hardening flags.
 950
 951 =item B<16>
 952
 953 Hardening wrapper detected, no tests performed.
 954
 955 =back
 956
 957 =head1 AUTHOR
 958
 959 Simon Ruderich, E<lt>simon@ruderich.orgE<gt>
 960
 961 =head1 COPYRIGHT AND LICENSE
 962
 963 Copyright (C) 2012 by Simon Ruderich
 964
 965 This program is free software: you can redistribute it and/or modify
 966 it under the terms of the GNU General Public License as published by
 967 the Free Software Foundation, either version 3 of the License, or
 968 (at your option) any later version.
 969
 970 This program is distributed in the hope that it will be useful,
 971 but WITHOUT ANY WARRANTY; without even the implied warranty of
 972 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 973 GNU General Public License for more details.
 974
 975 You should have received a copy of the GNU General Public License
 976 along with this program.  If not, see <http://www.gnu.org/licenses/>.
 977
 978 =cut