mapping_mode_search: add debug output
[fcscs/fcscs.git] / bin / fcscs
1 #!/usr/bin/perl
2
3 # fcscs - fast curses screen content select
4
5 # Copyright (C) 2013-2016  Simon Ruderich
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20
21 use strict;
22 use warnings;
23
24 use v5.10; # say, state
25
26 use Encode ();
27 use Fcntl ();
28 use I18N::Langinfo ();
29
30 use Curses ();
31
32 our $VERSION = '0.01';
33
34
35 =head1 NAME
36
37 fcscs - fast curses screen content select
38
39 =head1 SYNOPSIS
40
41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
42
43 =head1 DESCRIPTION
44
45 B<fcscs> is a small tool which allows quick selection of terminal screen
46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
47 GNU Screen's or Tmux's buffer or any other program. The selection can then
48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
49 licensed under the GPL 3 or later.
50
51 =head1 OPTIONS
52
53 None so far.
54
55 =head1 USAGE
56
57 Short overview of the general usage, details below:
58
59     - start fcscs
60     - configure actions (optional)
61         - enable pasting
62         - ...
63     - select mode (optional, URL mode is used on startup):
64         - f: file paths
65         - u: URLs
66         - ...
67         - /: search mode
68     - for `normal' modes:
69         - select match by displayed number or <return> for lowest numbered
70           match
71         - configured action is run, e.g. URL is opened with browser
72     - for `search' mode:
73         - perform incremental search
74         - on <return> go to `normal' mode to select a match
75         - after the match is selected wait for confirmation or extension
76         - confirmation: <return> run previously selected action
77         - extension: change match, e.g. select complete word or line
78
79 GNU Screen setup (add to F<~/.screenrc>):
80
81     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
82
83 Tmux setup (add to F<~/.tmux.conf>):
84
85     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
86
87 This requires a writable ~/.tmp directory. Adapt the mapping according to your
88 preferences. Ensure these files are not readable by others as they can contain
89 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
90 for the above mappings to work.
91
92 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
93 in a new GNU screen/Tmux window. After selection, the content is either passed
94 to external programs (e.g. for URLs) or copied to the paste buffer or directly
95 pasted in your previous window and the new window is closed.
96
97 To select a match just type its number. If the match is unique, the entry is
98 automatically selected (e.g. you press 2 and there are only 19 matches). If
99 there are multiple matches left (e.g. you press 1 and there are more than ten
100 matches available), press return to select the current match (1 in this case)
101 or another number to select the longer match. Use backspace to remove the last
102 entered number.
103
104 Press return before entering a number to select the last (lowest numbered)
105 match (underlined by default). To abort without selecting any match use "q".
106
107 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
108 explained below. Per default URLs are selected, see options for a way to
109 change this.
110
111 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
112 leaks URLs to other users on the current system via C<ps aux> or C<top>.
113
114 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
115 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
116 leak data if those temporary files are written to disk. To prevent this change
117 your C<$TMP> to point to a memory-only location or encrypted storage.
118
119 If no window appears, try running B<fcscs> manually to catch the error message
120 and please report the bug:
121
122     fcscs /path/to/screen-or-tmux-fcscs-file
123
124
125 =head1 MODES
126
127 =cut
128
129
130 # CLASSES
131
132 # Helper class for drawing on the screen using Curses.
133 package Screen {
134     sub init {
135         my ($class, $encoding) = @_;
136
137         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
138         if (lc $encoding eq 'utf8') {
139             $encoding = 'UTF-8';
140         }
141         # Get Encode object to speed up decode()/encode().
142         my $encoding_object = Encode::find_encoding($encoding);
143         die "unsupported encoding '$encoding'" unless ref $encoding_object;
144
145         my $curses = Curses->new or die $!;
146
147         my $self = {
148             encoding        => $encoding,
149             encoding_object => $encoding_object,
150             curses          => $curses,
151             debug           => 0,
152             prompt          => {
153                 flags => undef,
154                 name  => undef,
155                 value => undef,
156             },
157         };
158         bless $self, $class;
159
160         Curses::start_color;
161         # Allow default colors by passing -1 to init_pair. A default color is
162         # not drawn on screen thus allowing terminals with pseudo-transparency
163         # to use the transparent background in place of the default color.
164         Curses::use_default_colors;
165
166         Curses::cbreak;
167         Curses::noecho;
168         $self->cursor(0);
169
170         return $self;
171     }
172     sub deinit {
173         my ($self) = @_;
174
175         Curses::nocbreak;
176         Curses::echo;
177         $self->cursor(1);
178
179         Curses::endwin;
180         return;
181     }
182
183     # Convert between Perl's internal encoding and the terminal's encoding.
184     sub encode {
185         my ($self, $string) = @_;
186         return $self->{encoding_object}->encode($string);
187     }
188     sub decode {
189         my ($self, $string) = @_;
190         return eval { # returns undef on decode failure
191             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
192         };
193     }
194
195     # Create attribute for the given fore-/background colors.
196     sub color_pair {
197         my ($self, $fg, $bg) = @_;
198
199         state $next_color_pair = 1; # must start at 1 for init_pair()
200
201         Curses::init_pair($next_color_pair, $fg, $bg);
202         return Curses::COLOR_PAIR($next_color_pair++);
203     }
204
205     # Draw a string which must fit in the current line. Wrapping/clipping is
206     # not supported and must be handled by the caller.
207     sub draw_simple {
208         my ($self, $y, $x, $attributes, $string) = @_;
209
210         die if $string =~ /\n/;
211         # FIXME: wide characters
212         die if $x + length $string > $self->width;
213
214         $self->{curses}->attron($attributes) if defined $attributes;
215         $self->{curses}->addstr($y, $x, $self->encode($string));
216         $self->{curses}->attroff($attributes) if defined $attributes;
217         return;
218     }
219     # Like draw_simple(), but the string is automatically clipped.
220     sub draw_clipped {
221         my ($self, $y, $x, $attributes, $string) = @_;
222
223         # FIXME: wide characters
224         $string = substr $string, 0, $self->width - $x;
225         $self->draw_simple($y, $x, $attributes, $string);
226         return;
227     }
228     sub draw {
229         my ($self, $y, $x, $attributes, $string) = @_;
230
231         die unless defined $string;
232
233         while (1) {
234             my $offset;
235             # We must print each line separately. Search for next newline or
236             # line end, whichever is closer.
237             if ($string =~ /\n/) {
238                 $offset = $-[0];
239             }
240             # FIXME: wide characters
241             if ($x + length $string > $self->width) {
242                 my $new_offset = $self->width - $x;
243                 if (not defined $offset or $offset > $new_offset) {
244                     $offset = $new_offset;
245                 }
246             }
247             last unless defined $offset;
248
249             # FIXME: wide characters
250             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
251
252             # Don't draw "\n" itself.
253             if ("\n" eq substr $string, $offset, 1) {
254                 $offset++;
255             }
256
257             $string = substr $string, $offset;
258
259             $y++;
260             $x = 0;
261         }
262
263         $self->draw_simple($y, $x, $attributes, $string);
264         return $y;
265     }
266
267     sub draw_prompt {
268         my ($self, $config) = @_;
269
270         $self->debug('draw_prompt', 'started');
271
272         my $x = 0;
273         my $y = $self->height - 1;
274
275         # Clear line for better visibility.
276         $self->draw_simple($y, $x, undef, ' ' x $self->width);
277
278         # Draw prompt flags.
279         if (defined (my $s = $self->{prompt}{flags})) {
280             $s = "[$s]";
281             $self->debug('draw_prompt', $s);
282             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
283             $x += length($s) + 1; # space between next element
284         }
285         # Draw prompt name.
286         if (defined (my $s = $self->{prompt}{name})) {
287             $s = "[$s]";
288             $self->debug('draw_prompt', $s);
289             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
290             $x += length($s) + 1;
291         }
292         # Draw prompt value, e.g. a search field.
293         if (defined (my $s = $self->{prompt}{value})) {
294             $self->debug('draw_prompt', $s);
295             $self->draw_clipped($y, $x, undef, $s);
296             $x += length($s) + 1;
297         }
298         return;
299     }
300
301     sub draw_matches {
302         my ($self, $config, $matches_remove, $matches_add) = @_;
303
304         foreach (@{$matches_remove}) {
305             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
306         }
307
308         my $attr_id     = $config->{attribute}{match_id};
309         my $attr_string = $config->{attribute}{match_string};
310         my $attr_last   = $config->{attribute}{match_last};
311
312         foreach (@{$matches_add}) {
313             my $attr = (defined $_->{id} and $_->{id} == 1)
314                      ? $attr_last
315                      : $attr_string;
316             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
317             if (defined $_->{id}) {
318                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
319             }
320         }
321         return;
322     }
323
324     sub die {
325         my ($self, @args) = @_;
326
327         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
328
329         # Clear the screen to improve visibility of the error message.
330         $self->{curses}->clear;
331
332         my $y = $self->draw(0, 0, $attr, "@args");
333
334         if ($self->{debug}) {
335             my $msg;
336             eval {
337                 require Devel::StackTrace;
338             };
339             if ($@) {
340                 $msg = "Devel::StackTrace missing, no stack trace.\n";
341             } else {
342                 my $trace = Devel::StackTrace->new;
343                 $msg = "Stack trace:\n" . $trace->as_string;
344             }
345             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
346         }
347
348         $self->draw($y + 1, 0, Curses::A_NORMAL,
349                     'Press any key to terminate fcscs.');
350         $self->refresh;
351
352         $self->getch;
353         $self->deinit;
354         exit 1;
355     }
356     sub debug {
357         my ($self, $module, @args) = @_;
358
359         return if not $self->{debug};
360
361         state $fh; # only open the file once per run
362         if (not defined $fh) {
363             # Ignore errors if the directory doesn't exist.
364             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
365                 $fh = undef; # a failed open still writes a value to $fh
366                 return;
367             }
368         }
369
370         foreach (@args) {
371             $_ = $self->encode($_);
372         }
373         say $fh "$module: @args";
374         return;
375     }
376
377
378     sub prompt {
379         my ($self, %settings) = @_;
380
381         foreach (keys %settings) {
382             CORE::die if not exists $self->{prompt}{$_};
383             $self->{prompt}{$_} = $settings{$_};
384         }
385         return;
386     }
387
388     # Wrapper for Curses.
389     sub width   { return $Curses::COLS; }
390     sub height  { return $Curses::LINES; }
391     sub refresh { return $_[0]->{curses}->refresh; }
392     sub getch   { return $_[0]->{curses}->getch; }
393     sub cursor  { Curses::curs_set($_[1]); return; }
394 }
395
396
397
398 # FUNCTIONS
399
400 sub prepare_input {
401     my ($screen, $input_ref) = @_;
402
403     # Make sure the input fits on the screen by removing the top lines if
404     # necessary.
405     splice @{$input_ref}, 0, -$screen->height;
406
407     # Pad each line with spaces to the screen width to correctly handle
408     # multi-line regexes.
409     # FIXME: wide characters
410     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
411
412     my $string = join "\n", @padded;
413     return {
414         string => $string,
415         lines  => $input_ref,
416         width  => $screen->width + 1,
417                   # + 1 = "\n", used in input_match_offset_to_coordinates
418     };
419 }
420
421 sub input_match_offset_to_coordinates {
422     my ($width, $offset) = @_;
423
424     die unless defined $offset;
425
426     my $y = int($offset / $width);
427     my $x = $offset - $y * $width;
428     return ($x, $y);
429 }
430
431 sub get_regex_matches {
432     my ($input, $regex) = @_;
433
434     my @matches;
435     while ($input->{string} =~ /$regex/g) {
436         my $offset = $-[1];
437         die "Match group required in regex '$regex'" if not defined $offset;
438
439         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
440                                                         $offset);
441         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
442     }
443     return @matches;
444 }
445
446
447 sub run_command {
448     my ($screen, $config, $cmd) = @_;
449
450     $screen->debug('run_command', "running @{$cmd}");
451
452     my $exit = do {
453         # Perl's system() combined with a $SIG{__WARN__} which die()s has
454         # issues due to the fork. The die() in the __WARN__ handler doesn't
455         # die but the program continues after the system().
456         #
457         # If the forked process fails to exec (e.g. program not found) then
458         # the __WARN__ handler is called (because a warning is about to be
459         # displayed) and the die() should display a message and terminate the
460         # process. But due to the fork it doesn't terminate the parent process
461         # and instead changes the return value of system(); it's no longer -1
462         # which makes it impossible to detect that case.
463         #
464         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
465         # makes it impossible to detect if the handler was called from inside
466         # the child.
467         #
468         # Instead, just ignore any warnings during the system(). Thanks to
469         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
470         # use no warnings and anno for testing a more recent Perl version with
471         # a working $$.
472         no warnings;
473
474         my @cmd = map { $screen->encode($_) } @{$cmd};
475         system { $cmd[0] } @cmd;
476     };
477     if ($exit != 0) {
478         my $msg;
479         if ($? == -1) {
480             $msg = 'failed to execute: ' . $!;
481         } elsif ($? & 127) {
482             $msg = 'killed by signal ' . ($? & 127);
483         } else {
484             $msg = 'exited with code ' . ($? >> 8);
485         }
486         die "system(@{$cmd}) $msg.";
487     }
488     return;
489 }
490 sub run_in_background {
491     my ($screen, $sub) = @_;
492
493     $screen->debug('run_in_background', "running $sub");
494
495     my $pid = fork;
496     defined $pid or die $!;
497
498     if ($pid == 0) {
499         # The terminal multiplexer sends a SIGHUP to the process when it
500         # closes the window (because the parent process has exited).
501         local $SIG{HUP} = 'IGNORE';
502
503         # Necessary for GNU screen or it'll keep the window open until an
504         # external command has run.
505         close STDIN  or die $!;
506         close STDOUT or die $!;
507         close STDERR or die $!;
508
509         # Double-fork to prevent zombies.
510         my $pid = fork;
511         defined $pid or die $!;
512         if ($pid == 0) { # child
513             $sub->();
514         }
515         exit;
516     }
517     waitpid $pid, 0 or die $!;
518     return;
519 }
520
521
522 sub select_match {
523     my ($name, $screen, $config, $input, $matches) = @_;
524
525     $screen->debug('select_match', 'started');
526
527     return if @{$matches} == 0;
528     # Don't return on initial run to give the user a chance to select another
529     # mode, e.g. to switch from URL selection to search selection.
530     if (@{$matches} == 1 and not $config->{state}{initial}) {
531         return { match => $matches->[0] };
532     }
533     $config->{state}{initial} = 0;
534
535     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
536
537     my $i = 1;
538     foreach (@sorted) {
539         $_->{id} = $i++;
540     }
541
542     $screen->prompt(name => $name, value => undef);
543     $screen->draw_prompt($config);
544
545     $screen->draw_matches($config, [], $matches);
546     $screen->refresh;
547
548     my $number = 0;
549     while (1) {
550         my $char = $screen->getch;
551         if ($char =~ /^\d$/) {
552             $number = $number * 10 + $char;
553         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
554             $number = int($number / 10);
555         } elsif ($char eq "\n"
556                 or $char eq $config->{setting}{alternative_return}) {
557             if ($number == 0) { # number without selection matches last entry
558                 $number = 1;
559             }
560             last;
561
562         # Selecting a new mode requires falling through into the main input
563         # loop and then starting the new mode.
564         } elsif (defined $config->{mapping}{mode}{$char}) {
565             $screen->draw_matches($config, $matches, []); # clear matches
566             return { key => $char };
567         # All other mappings stay in the current mode.
568         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
569             $m->($char, $screen, $config, $input);
570             next;
571
572         } else {
573             next; # ignore unknown mappings
574         }
575
576         last if $number > 0 and $number * 10 > @{$matches}; # unique match
577
578         my @remaining = $number == 0
579                       ? @{$matches}
580                       : grep { $_->{id} =~ /^$number/ } @{$matches};
581         $screen->draw_matches($config, $matches, \@remaining);
582         $screen->refresh;
583     }
584
585     $screen->draw_matches($config, $matches, []); # remove matches
586
587     foreach (@{$matches}) {
588         return { match => $_ } if $_->{id} == $number;
589     }
590     $screen->debug('select_match', 'no match selected');
591     return { match => undef };
592 }
593
594 sub extend_match_regex_left {
595     my ($line, $match, $regex) = @_;
596
597     my $s = reverse substr $line, 0, $match->{x};
598     if ($s =~ /^($regex)/) {
599         $match->{string}  = reverse($1) . $match->{string};
600         $match->{x}      -= length $1;
601         $match->{offset} -= length $1;
602     }
603     return;
604 }
605 sub extend_match_regex_right {
606     my ($line, $match, $regex) = @_;
607
608     my $s = substr $line, $match->{x} + length $match->{string};
609     if ($s =~ /^($regex)/) {
610         $match->{string} .= $1;
611     }
612     return;
613 }
614 sub extend_match {
615     my ($screen, $config, $input, $match) = @_;
616
617     $screen->debug('extend_match', 'started');
618
619     return if not defined $match;
620
621     $screen->prompt(name => 'extend', value => undef);
622     $screen->draw_prompt($config);
623
624     delete $match->{id}; # don't draw any match ids
625     $screen->draw_matches($config, [], [$match]);
626     $screen->refresh;
627
628     my $line = $input->{lines}[$match->{y}];
629
630     while (1) {
631         my $match_old = \%{$match};
632
633         my $char = $screen->getch;
634         if ($char eq "\n"
635                 or $char eq $config->{setting}{alternative_return}) {
636             last; # accept match
637
638         } elsif ($char eq 'w') { # select current word (both directions)
639             extend_match_regex_left($line,  $match, qr/\w+/);
640             extend_match_regex_right($line, $match, qr/\w+/);
641         } elsif ($char eq 'b') { # select current word (only left)
642             extend_match_regex_left($line,  $match, qr/\w+/);
643         } elsif ($char eq 'e') { # select current word (only right)
644             extend_match_regex_right($line, $match, qr/\w+/);
645
646         } elsif ($char eq 'W') { # select current WORD (both directions)
647             extend_match_regex_left($line,  $match, qr/\S+/);
648             extend_match_regex_right($line, $match, qr/\S+/);
649         } elsif ($char eq 'B') { # select current WORD (only left)
650             extend_match_regex_left($line,  $match, qr/\S+/);
651         } elsif ($char eq 'E') { # select current WORD (only right)
652             extend_match_regex_right($line, $match, qr/\S+/);
653
654         } elsif ($char eq '0') { # select to beginning of line
655             extend_match_regex_left($line, $match, qr/.+/);
656         } elsif ($char eq '$') { # select to end of line
657             extend_match_regex_right($line, $match, qr/.+/);
658
659         # Allow mode changes if not overwritten by local mappings.
660         } elsif (defined $config->{mapping}{mode}{$char}) {
661             $screen->draw_matches($config, [$match_old], []); # clear match
662             return { key => $char };
663
664         } else {
665             next; # ignore unknown mappings
666         }
667
668         $screen->draw_matches($config, [$match_old], [$match]);
669         $screen->refresh;
670     }
671
672     $screen->debug('extend_match', 'done');
673
674     return { match => $match };
675 }
676
677
678 sub mapping_paste {
679     my ($key, $screen, $config, $input) = @_;
680
681     $screen->debug('mapping_paste', 'started');
682
683     $config->{state}{handler} = $config->{handler}{paste};
684
685     $screen->prompt(flags => 'P'); # paste
686     $screen->draw_prompt($config);
687     $screen->refresh;
688
689     return {};
690 }
691 sub mapping_yank {
692     my ($key, $screen, $config, $input) = @_;
693
694     $screen->debug('mapping_yank', 'started');
695
696     $config->{state}{handler} = $config->{handler}{yank};
697
698     $screen->prompt(flags => 'Y'); # yank
699     $screen->draw_prompt($config);
700     $screen->refresh;
701
702     return {};
703 }
704
705
706 =head2 NORMAL MODES
707
708 Normal modes select matches by calling a function which returns them, e.g. by
709 using a regex.
710
711 The following normal modes are available:
712
713 =over 4
714
715 =item B<path mode> select relative/absolute paths
716
717 =item B<url mode>  select URLs
718
719 =back
720
721 =cut
722 sub mapping_mode_path {
723     my ($key, $screen, $config, $input) = @_;
724
725     $screen->debug('mapping_mode_path', 'started');
726
727     my @matches = get_regex_matches($input, $config->{regex}{path});
728     return {
729         select  => 'path select',
730         matches => \@matches,
731         handler => $config->{handler}{yank},
732     };
733 }
734 sub mapping_mode_url {
735     my ($key, $screen, $config, $input) = @_;
736
737     $screen->debug('mapping_mode_url', 'started');
738
739     my @matches = get_regex_matches($input, $config->{regex}{url});
740     return {
741         select  => 'url select',
742         matches => \@matches,
743         handler => $config->{handler}{url},
744     };
745 }
746
747 =head2 SEARCH MODE (AND EXTEND MODE)
748
749 Search mode is a special mode which lets you type a search string (a Perl
750 regex) and then select one of the matches. Afterwards you can extend the
751 match. For example select the complete word or to the end of the line. This
752 allows quick selection of arbitrary text.
753
754 The following mappings are available during the extension mode (not
755 configurable at the moment):
756
757 =over 4
758
759 =item B<w> select current word
760
761 =item B<b> extend word to the left
762
763 =item B<e> extend word to the right
764
765 =item B<W> select current WORD
766
767 =item B<B> extend WORD to the left
768
769 =item B<E> extend WORD to the right
770
771 =item B<0> extend to beginning of line
772
773 =item B<$> extend to end of line
774
775 =back
776
777 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
778 characters (C<\S+>), just like in Vim.
779
780 =cut
781 sub mapping_mode_search {
782     my ($key, $screen, $config, $input) = @_;
783
784     $screen->debug('mapping_mode_search', 'started');
785
786     $screen->cursor(1);
787
788     my $search = ''; # encoded
789     my @last_matches;
790     while (1) {
791         # getch doesn't return decoded characters but raw input bytes. Wait
792         # until the input character is complete.
793         my $value = $screen->decode($search);
794         $value = '' unless defined $value; # undef on decode failure
795
796         $screen->prompt(name => 'search', value => $value);
797         $screen->draw_prompt($config);
798         $screen->refresh;
799
800         my $char = $screen->getch;
801         # TODO: readline editing support
802         if ($char eq "\n") {
803             last;
804         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
805             # Remove a character, not a byte.
806             $search = $screen->decode($search);
807             chop $search;
808             $search = $screen->encode($search);
809         } else {
810             $search .= $char;
811             next unless defined $screen->decode($search);
812         }
813
814         my @matches;
815         if ($search ne '') {
816             my $case = '';
817             if (($config->{setting}{smartcase} and $search eq lc $search)
818                     or $config->{setting}{ignorecase}) {
819                 $case = '(?i)';
820             }
821             # Ignore invalid regexps.
822             # TODO: display warning on error?
823             eval {
824                 @matches = get_regex_matches($input, qr/($case$search)/);
825             };
826         }
827         $screen->draw_matches($config, \@last_matches, \@matches);
828         @last_matches = @matches;
829     }
830
831     $screen->cursor(0);
832
833     $screen->prompt(name => undef, value => undef); # clear prompt
834     $screen->draw_prompt($config);
835
836     $screen->debug('mapping_mode_search', 'done');
837
838     return {
839         select  => 'search',
840         matches => \@last_matches,
841         extend  => 1,
842         handler => $config->{handler}{yank},
843     };
844 }
845
846 sub mapping_quit {
847     my ($key, $screen, $config, $input) = @_;
848
849     # Key is necessary to fall through to main event loop which then quits.
850     return { key => $key, quit => 1 };
851 }
852
853
854 sub handler_yank {
855     my ($screen, $config, $match) = @_;
856
857     $screen->debug('handler_yank', 'started');
858
859     require File::Temp;
860
861     # Use a temporary file to prevent leaking the yanked data to other users
862     # with the command line, e.g. ps aux or top.
863     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
864     print $fh $screen->encode($match->{value});
865     close $fh or die $!;
866
867     if ($config->{setting}{multiplexer} eq 'screen') {
868         $screen->debug('handler_yank', 'using screen');
869
870         # GNU screen displays an annoying "Slurping X characters into buffer".
871         # Use 'msgwait 0' as a hack to disable it.
872         my $msgwait = $config->{setting}{screen_msgwait};
873         run_command($screen, $config, ['screen', '-X', 'msgwait', 0]);
874         run_command($screen, $config, ['screen', '-X', 'readbuf', $tmp]);
875         run_command($screen, $config, ['screen', '-X', 'msgwait', $msgwait]);
876     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
877         $screen->debug('handler_yank', 'using tmux');
878
879         run_command($screen, $config, ['tmux', 'load-buffer', $tmp]);
880     } else {
881         die 'unsupported multiplexer';
882     }
883
884     unlink $tmp or die $!;
885     return;
886 }
887 sub handler_paste {
888     my ($screen, $config, $match) = @_;
889
890     $screen->debug('handler_paste', 'started');
891
892     require Time::HiRes;
893
894     my @cmd;
895     if ($config->{setting}{multiplexer} eq 'screen') {
896         $screen->debug('handler_paste', 'using screen');
897         @cmd = qw( screen -X paste . );
898     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
899         $screen->debug('handler_paste', 'using tmux');
900         @cmd = qw( tmux paste-buffer );
901     } else {
902         die 'unsupported multiplexer';
903     }
904
905     run_in_background($screen, sub {
906         # We need to get the data in the paste buffer before we can paste
907         # it.
908         handler_yank($screen, $config, $match);
909
910         # Sleep until we switch back to the current window.
911         Time::HiRes::usleep($config->{setting}{paste_sleep});
912
913         run_command($screen, $config, \@cmd);
914     });
915     return;
916 }
917 sub handler_url {
918     my ($screen, $config, $match) = @_;
919
920     $screen->debug('handler_url', "opening $match->{value}");
921
922     run_in_background($screen, sub {
923         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
924         run_command($screen, $config, \@cmd);
925     });
926     return;
927 }
928
929
930
931 # CONFIGURATION DEFAULTS
932
933 =head1 CONFIGURATION
934
935 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
936 is a normal Perl script with all of Perl's usual features.
937
938 All configuration values are stored in the hash C<%config>. All manually
939 defined keys overwrite the default settings.
940
941 A simple F<~/.fcscsrc> could look like this (for details about the used
942 settings see below):
943
944     use strict;
945     use warnings;
946
947     use Curses; # for COLOR_* and A_* constants
948
949     our %config;
950
951     # Draw matches in blue.
952     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
953     # Enable Vim-like 'smartcase', ignore case until an upper character is
954     # searched.
955     $config{setting}{smartcase} = 1;
956
957     # Use chromium to open URLs if running under X, elinks otherwise.
958     if (defined $ENV{DISPLAY}) {
959         $config{setting}{browser} = ['chromium'];
960     } else {
961         $config{setting}{browser} = ['elinks'];
962     }
963
964     # Let fcscs know the file was loaded successfully.
965     1;
966
967 =cut
968
969
970 if (@ARGV != 1) {
971     require Pod::Usage;
972     Pod::Usage::pod2usage(2);
973 }
974
975
976 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
977 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
978
979 my $screen = Screen->init($encoding);
980
981 # We must restore the screen before exiting.
982 local $SIG{INT} = sub {
983     $screen->deinit;
984     exit 128 + 2;
985 };
986 # Make all warnings fatal to make sure they don't get lost (stderr is normally
987 # not displayed).
988 local $SIG{__WARN__} = sub {
989     $screen->die('warning', @_);
990 };
991
992
993
994 =head2 MAPPINGS
995
996 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
997 selection and may receive additional input (e.g. a search string) and simple
998 mappings which only change some value. Mode mappings are configured via
999 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1000
1001 The following mode mappings are available by default (the function to remap
1002 them in parentheses):
1003
1004 =over
1005
1006 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1007
1008 =item B<u> select URLs (C<\&mapping_mode_url>)
1009
1010 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1011
1012 =item B<q> quit fcscs (C<\&mapping_quit>)
1013
1014 =back
1015
1016 The following simple mappings are available by default:
1017
1018 =over
1019
1020 =item B<p> enable pasting (C<\&mapping_paste>)
1021
1022 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1023
1024 =back
1025
1026 The following additional mappings are available by default:
1027
1028 =over
1029
1030 =item B<\n> accept current selection (not customizable)
1031
1032 =item B<s>  additional key to accept selection (B<alternative_return> option)
1033
1034 =back
1035
1036 All (single-byte) keys except numbers, backspace and return can be mapped.
1037
1038 Unknown mappings are ignored when pressing keys.
1039
1040 To remove a default mapping, delete it from the mapping hash.
1041
1042 Example:
1043
1044     # Map 'p' to select paths, 'P' to enable pasting.
1045     $config{mapping}{mode}{p} = \&mapping_mode_path;
1046     $config{mapping}{simple}{P} = \&mapping_paste;
1047
1048     # Disable 'f' mapping.
1049     delete $config{mapping}{mode}{f};
1050
1051 =cut
1052 my %mapping_mode = (
1053     f   => \&mapping_mode_path,
1054     u   => \&mapping_mode_url,
1055     '/' => \&mapping_mode_search,
1056     q   => \&mapping_quit,
1057 );
1058 my %mapping_simple = (
1059     p => \&mapping_paste,
1060     y => \&mapping_yank,
1061 );
1062
1063 =head2 ATTRIBUTES
1064
1065 Attributes are used to style the output. They must be Curses attributes.
1066 Defaults in parentheses (foreground, background, attribute).
1067
1068 =over
1069
1070 =item B<match_id>      attribute for match numbers (red, default, bold)
1071
1072 =item B<match_string>  attribute for matches (yellow, default, normal)
1073
1074 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1075
1076 =item B<prompt_name>   attribute for prompt name (standout)
1077
1078 =item B<prompt_flags>  attribute for prompt flags (standout)
1079
1080 =back
1081
1082 Example:
1083
1084     # Draw prompt flags in bold red with default background color.
1085     $config{attribute}{prompt_flags}
1086         = Curses::A_BOLD
1087         | color_pair(Curses::COLOR_RED, -1);
1088
1089 =cut
1090 my %attribute = (
1091     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1092                     | Curses::A_BOLD,
1093     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1094     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1095                     | Curses::A_UNDERLINE,
1096     prompt_name  => Curses::A_STANDOUT,
1097     prompt_flags => Curses::A_STANDOUT,
1098 );
1099
1100 =head2 SETTINGS
1101
1102 Defaults in parentheses.
1103
1104 =over
1105
1106 =item B<debug>              enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1107
1108 =item B<initial_mode>       start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1109
1110 =item B<multiplexer>        set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1111
1112 =item B<ignorecase>         ignore case when searching (C<0>)
1113
1114 =item B<smartcase>          ignore case unless one uppercase character is searched (C<1>)
1115
1116 =item B<paste_sleep>        sleep x us before running paste command (C<100_000>)
1117
1118 =item B<screen_msgwait>     GNU Screen's msgwait variable, used when yanking (C<5>)
1119
1120 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1121
1122 =item B<browser>            browser command as array reference (C<['x-www-browser']>)
1123
1124 =back
1125
1126 Example:
1127
1128     # Select paths on startup instead of URLs.
1129     $config{setting}{initial_mode} = \&mapping_mode_path;
1130
1131 =cut
1132 my %setting = (
1133     # options
1134     debug              => 0,
1135     initial_mode       => \&mapping_mode_url,
1136     multiplexer        => undef,
1137     ignorecase         => 0,
1138     smartcase          => 1,
1139     paste_sleep        => 100_000,
1140     screen_msgwait     => 5,
1141     # global mappings
1142     alternative_return => 's',
1143     # commands
1144     browser            => ['x-www-browser'],
1145 );
1146
1147 =head2 REGEXPS
1148
1149 =over
1150
1151 =item B<url>  used by C<\&mapping_mode_url()>
1152
1153 =item B<path> used by C<\&mapping_mode_path()>
1154
1155 =back
1156
1157 Example:
1158
1159     # Select all non-whitespace characters when searching for paths.
1160     $config{regex}{path} = qr{(\S+)};
1161
1162 =cut
1163 my %regex = (
1164     # Taken from urlview's default configuration file, thanks.
1165     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1166     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1167 );
1168
1169 =head2 HANDLERS
1170
1171 Handlers are used to perform actions on the selected string.
1172
1173 The following handlers are available, defaults in parentheses.
1174
1175 =over
1176
1177 =item B<yank>  used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1178
1179 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1180
1181 =item B<url>   used to open URLs (e.g. in a browser) (C<\&handler_url>)
1182
1183 =back
1184
1185 Example:
1186
1187     # Download YouTube videos with a custom wrapper, handle all other URLs
1188     # with the default URL handler.
1189     $config{handler}{url} = sub {
1190         my ($screen, $config, $match) = @_;
1191
1192         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1193             return run_in_background($screen, sub {
1194                 run_command($screen, $config,
1195                             ['youtube-dl-wrapper', $match->{value}]);
1196             });
1197         }
1198         handler_url(@_);
1199     };
1200
1201 =cut
1202 my %handler = (
1203     yank  => \&handler_yank,
1204     paste => \&handler_paste,
1205     url   => \&handler_url,
1206 );
1207
1208 my %state = (
1209     initial => 1, # used by select_match() for 'initial_mode'
1210     handler => undef,
1211 );
1212
1213
1214
1215 # CONFIGURATION "API"
1216
1217 =head2 FUNCTIONS
1218
1219 The following functions are available:
1220
1221     color_pair($fg, $bg)
1222
1223 Create a new Curses attribute with the given fore- and background color.
1224
1225     mapping_mode_path()
1226     mapping_mode_url()
1227     mapping_mode_search()
1228
1229     mapping_paste()
1230     mapping_yank()
1231     mapping_quit()
1232
1233 Used as mappings, see L</MAPPINGS> above.
1234
1235     handler_yank()
1236     handler_paste()
1237     handler_url()
1238
1239 Used as handler to yank, paste selection or open URL in browser.
1240
1241     debug()
1242     get_regex_matches()
1243     select_match()
1244     run_command()
1245     run_in_background()
1246
1247 Helper functions when writing custom mappings, see the source for details.
1248
1249 Example:
1250
1251     TODO
1252
1253 =cut
1254
1255 # All variables and functions which are usable by ~/.fcscsrc.
1256 package Fcscs {
1257     our $screen; # "private"
1258     our %config;
1259
1260     sub color_pair { return $screen->color_pair(@_); }
1261
1262     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1263     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1264     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1265
1266     sub mapping_paste { return main::mapping_paste(@_); }
1267     sub mapping_yank { return main::mapping_yank(@_); }
1268     sub mapping_quit { return main::mapping_quit(@_); }
1269
1270     sub handler_yank { return main::handler_yank(@_); }
1271     sub handler_paste { return main::handler_paste(@_); }
1272     sub handler_url { return main::handler_url(@_); }
1273
1274     sub debug { return main::debug(@_); }
1275
1276     sub get_regex_matches { return main::get_regex_matches(@_); }
1277     sub select_match { return main::select_match(@_); }
1278
1279     sub run_command { return main::run_command(@_); }
1280     sub run_in_background { return main::run_in_background(@_); }
1281 }
1282 $Fcscs::screen = $screen;
1283
1284
1285
1286 # LOAD USER CONFIG
1287
1288 # Alias %config and %Fcscs::config. %config is less to type.
1289 our %config;
1290 local *config = \%Fcscs::config;
1291
1292 $config{mapping}{mode}   = \%mapping_mode;
1293 $config{mapping}{simple} = \%mapping_simple;
1294 $config{attribute}       = \%attribute;
1295 $config{setting}         = \%setting;
1296 $config{regex}           = \%regex;
1297 $config{handler}         = \%handler;
1298 $config{state}           = \%state;
1299
1300 package Fcscs {
1301     my @configs = ("$ENV{HOME}/.fcscsrc",
1302                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1303     foreach my $path (@configs) {
1304         my $decoded = $screen->decode($path);
1305
1306         # Load configuration file. Checks have a race condition if the home
1307         # directory is writable by an attacker (but then the user is screwed
1308         # anyway).
1309         next unless -e $path;
1310         if (not -O $path) {
1311             $screen->die("Config '$decoded' not owned by current user!");
1312         }
1313         # Make sure the file is not writable by other users. Doesn't handle
1314         # ACLs and see comment above about race conditions.
1315         my @stat = stat $path or die $!;
1316         my $mode = $stat[2];
1317         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1318             die "Config '$decoded' must not be writable by other users.";
1319         }
1320
1321         my $result = do $path;
1322         if (not $result) {
1323             $screen->die("Failed to parse '$decoded': $@") if $@;
1324             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1325             $screen->die("Failed to run '$decoded'.");
1326         }
1327
1328         last; # success, don't load more files
1329     }
1330 }
1331 $screen->{debug} = $config{setting}{debug};
1332
1333
1334 # MAIN
1335
1336 eval {
1337     # Auto-detect current multiplexer.
1338     if (not defined $config{setting}{multiplexer}) {
1339         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1340             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1341         } elsif (defined $ENV{STY}) {
1342             $config{setting}{multiplexer} = 'screen';
1343         } elsif (defined $ENV{TMUX}) {
1344             $config{setting}{multiplexer} = 'tmux';
1345         } else {
1346             die 'No multiplexer found.';
1347         }
1348     }
1349
1350     my $binmode = $encoding;
1351     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1352     # instead of the currently active encoding.
1353     if ($config{setting}{multiplexer} eq 'screen') {
1354         $binmode = 'ISO-8859-1';
1355     }
1356
1357     my @input_lines;
1358     open my $fh, '<', $ARGV[0] or die $!;
1359     binmode $fh, ":encoding($binmode)" or die $!;
1360     while (<$fh>) {
1361         chomp;
1362         push @input_lines, $_;
1363     }
1364     close $fh or die $!;
1365
1366     my $input = prepare_input($screen, \@input_lines);
1367
1368     # Display original screen content.
1369     my $y = 0;
1370     foreach (@{$input->{lines}}) {
1371         $screen->draw_simple($y++, 0, undef, $_);
1372     }
1373     $screen->refresh;
1374
1375
1376     my $mapping = $config{setting}{initial_mode};
1377
1378     my $key;
1379     while (1) {
1380         if (not defined $mapping) {
1381             $key = $screen->getch unless defined $key;
1382             $screen->debug('input', "got key '$key'");
1383
1384             $mapping = $config{mapping}{mode}{$key};
1385             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1386             if (not defined $mapping) { # ignore unknown mappings
1387                 $key = undef;
1388                 next;
1389             }
1390         }
1391
1392         $screen->debug('input', 'running mapping');
1393         my $result = $mapping->($key, $screen, \%config, $input);
1394         $mapping = undef;
1395
1396 RESULT:
1397         if (defined $result->{quit}) {
1398             $screen->debug('input', 'quitting');
1399             last;
1400         }
1401         if (defined $result->{key}) {
1402             $key = $result->{key}; # lookup another mapping
1403             $screen->debug('input', "processing new key: '$key'");
1404             next;
1405         }
1406         if (defined $result->{select}) {
1407             $screen->debug('input', 'selecting match');
1408             my $tmp = $result;
1409             $result = select_match($result->{select},
1410                                    $screen, \%config, $input,
1411                                    $result->{matches});
1412             $result->{handler} = $tmp->{handler};
1413             $result->{extend}  = $tmp->{extend};
1414             goto RESULT; # reprocess special entries in result
1415         }
1416         if (defined $result->{extend}) {
1417             $screen->debug('input', 'extending match');
1418             $result = extend_match($screen, \%config, $input,
1419                                    $result->{match});
1420             goto RESULT; # reprocess special entries in result
1421         }
1422         if (defined $result->{match}) {
1423             if (not defined $result->{match}{value}) {
1424                 $result->{match}{value} = $result->{match}{string};
1425             }
1426
1427             $screen->debug('input', 'running handler');
1428
1429             # Choose handler with falling priority.
1430             my @handlers = (
1431                 $config{state}{handler},     # set by user
1432                 $result->{match}{handler},   # set by match
1433                 $result->{handler},          # set by mapping
1434                 $config{handler}{yank},      # fallback
1435             );
1436             foreach my $handler (@handlers) {
1437                 next unless defined $handler;
1438
1439                 $handler->($screen, \%config, $result->{match});
1440                 last;
1441             }
1442             last;
1443         }
1444
1445         $key = undef; # get next key from user
1446     }
1447 };
1448 if ($@) {
1449     $screen->die("$@");
1450 }
1451
1452 $screen->deinit;
1453
1454 __END__
1455
1456 =head1 EXIT STATUS
1457
1458 =over 4
1459
1460 =item B<0>
1461
1462 Success.
1463
1464 =item B<1>
1465
1466 An error occurred.
1467
1468 =item B<2>
1469
1470 Invalid arguments/options.
1471
1472 =back
1473
1474 =head1 AUTHOR
1475
1476 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1477
1478 =head1 LICENSE AND COPYRIGHT
1479
1480 Copyright (C) 2013-2016 by Simon Ruderich
1481
1482 This program is free software: you can redistribute it and/or modify
1483 it under the terms of the GNU General Public License as published by
1484 the Free Software Foundation, either version 3 of the License, or
1485 (at your option) any later version.
1486
1487 This program is distributed in the hope that it will be useful,
1488 but WITHOUT ANY WARRANTY; without even the implied warranty of
1489 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1490 GNU General Public License for more details.
1491
1492 You should have received a copy of the GNU General Public License
1493 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1494
1495 =head1 SEE ALSO
1496
1497 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1498
1499 =cut