3 # fcscs - fast curses screen content select
5 # Copyright (C) 2013-2016 Simon Ruderich
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 # GNU General Public License for more details.
17 # You should have received a copy of the GNU General Public License
18 # along with this program. If not, see <http://www.gnu.org/licenses/>.
24 use v5.10; # say, state
28 use I18N::Langinfo ();
32 our $VERSION = '0.01';
37 fcscs - fast curses screen content select
41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
45 B<fcscs> is a small tool which allows quick selection of terminal screen
46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
47 GNU Screen's or Tmux's buffer or any other program. The selection can then
48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
49 licensed under the GPL 3 or later.
57 Short overview of the general usage, details below:
60 - configure actions (optional)
63 - select mode (optional, URL mode is used on startup):
69 - select match by displayed number or <return> for lowest numbered
71 - configured action is run, e.g. URL is opened with browser
73 - perform incremental search
74 - on <return> go to `normal' mode to select a match
75 - after the match is selected wait for confirmation or extension
76 - confirmation: <return> run previously selected action
77 - extension: change match, e.g. select complete word or line
79 GNU Screen setup (add to F<~/.screenrc>):
81 bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
83 Tmux setup (add to F<~/.tmux.conf>):
85 bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
87 This requires a writable ~/.tmp directory. Adapt the mapping according to your
88 preferences. Ensure these files are not readable by others as they can contain
89 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
90 for the above mappings to work.
92 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
93 in a new GNU screen/Tmux window. After selection, the content is either passed
94 to external programs (e.g. for URLs) or copied to the paste buffer or directly
95 pasted in your previous window and the new window is closed.
97 To select a match just type its number. If the match is unique, the entry is
98 automatically selected (e.g. you press 2 and there are only 19 matches). If
99 there are multiple matches left (e.g. you press 1 and there are more than ten
100 matches available), press return to select the current match (1 in this case)
101 or another number to select the longer match. Use backspace to remove the last
104 Press return before entering a number to select the last (lowest numbered)
105 match. To abort without selecting any match either use "q".
107 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
108 explained below. Per default URLs are selected, see options for a way to
111 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
112 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
113 leak data if those temporary files are written to disk. To prevent this change
114 your C<$TMP> to point to a memory-only location or encrypted storage.
116 If no window appears, try running B<fcscs> manually to catch the error message
117 and please report the bug:
119 fcscs /path/to/screen-or-tmux-fcscs-file
129 # Helper class for drawing on the screen using Curses.
132 my ($class, $encoding) = @_;
134 # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
135 if (lc $encoding eq 'utf8') {
138 # Get Encode object to speed up decode()/encode().
139 my $encoding_object = Encode::find_encoding($encoding);
140 die "unsupported encoding '$encoding'" unless ref $encoding_object;
142 my $curses = Curses->new or die $!;
145 encoding => $encoding,
146 encoding_object => $encoding_object,
158 # Allow default colors by passing -1 to init_pair. A default color is
159 # not drawn on screen thus allowing terminals with pseudo-transparency
160 # to use the transparent background in place of the default color.
161 Curses::use_default_colors;
180 # Convert between Perl's internal encoding and the terminal's encoding.
182 my ($self, $string) = @_;
183 return $self->{encoding_object}->encode($string);
186 my ($self, $string) = @_;
187 return eval { # returns undef on decode failure
188 $self->{encoding_object}->decode($string, Encode::FB_CROAK);
192 # Create attribute for the given fore-/background colors.
194 my ($self, $fg, $bg) = @_;
196 state $next_color_pair = 1; # must start at 1 for init_pair()
198 Curses::init_pair($next_color_pair, $fg, $bg);
199 return Curses::COLOR_PAIR($next_color_pair++);
202 # Draw a string which must fit in the current line. Wrapping/clipping is
203 # not supported and must be handled by the caller.
205 my ($self, $y, $x, $attributes, $string) = @_;
207 die if $string =~ /\n/;
208 # FIXME: wide characters
209 die if $x + length $string > $self->width;
211 $self->{curses}->attron($attributes) if defined $attributes;
212 $self->{curses}->addstr($y, $x, $self->encode($string));
213 $self->{curses}->attroff($attributes) if defined $attributes;
216 # Like draw_simple(), but the string is automatically clipped.
218 my ($self, $y, $x, $attributes, $string) = @_;
220 # FIXME: wide characters
221 $string = substr $string, 0, $self->width - $x;
222 $self->draw_simple($y, $x, $attributes, $string);
226 my ($self, $y, $x, $attributes, $string) = @_;
228 die unless defined $string;
232 # We must print each line separately. Search for next newline or
233 # line end, whichever is closer.
234 if ($string =~ /\n/) {
237 # FIXME: wide characters
238 if ($x + length $string > $self->width) {
239 my $new_offset = $self->width - $x;
240 if (not defined $offset or $offset > $new_offset) {
241 $offset = $new_offset;
244 last unless defined $offset;
246 # FIXME: wide characters
247 $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
249 # Don't draw "\n" itself.
250 if ("\n" eq substr $string, $offset, 1) {
254 $string = substr $string, $offset;
260 $self->draw_simple($y, $x, $attributes, $string);
265 my ($self, $config) = @_;
267 $self->debug('draw_prompt', 'started');
270 my $y = $self->height - 1;
272 # Clear line for better visibility.
273 $self->draw_simple($y, $x, undef, ' ' x $self->width);
276 if (defined (my $s = $self->{prompt}{flags})) {
278 $self->debug('draw_prompt', $s);
279 $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
280 $x += length($s) + 1; # space between next element
283 if (defined (my $s = $self->{prompt}{name})) {
285 $self->debug('draw_prompt', $s);
286 $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
287 $x += length($s) + 1;
289 # Draw prompt value, e.g. a search field.
290 if (defined (my $s = $self->{prompt}{value})) {
291 $self->debug('draw_prompt', $s);
292 $self->draw_clipped($y, $x, undef, $s);
293 $x += length($s) + 1;
299 my ($self, $config, $matches_remove, $matches_add) = @_;
301 foreach (@{$matches_remove}) {
302 $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
305 my $attr_id = $config->{attribute}{match_id};
306 my $attr_string = $config->{attribute}{match_string};
308 foreach (@{$matches_add}) {
309 $self->draw($_->{y}, $_->{x}, $attr_string, $_->{string});
310 if (defined $_->{id}) {
311 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
318 my ($self, @args) = @_;
320 my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
322 # Clear the screen to improve visibility of the error message.
323 $self->{curses}->clear;
325 my $y = $self->draw(0, 0, $attr, "@args");
327 if ($self->{debug}) {
330 require Devel::StackTrace;
333 $msg = "Devel::StackTrace missing, no stack trace.\n";
335 my $trace = Devel::StackTrace->new;
336 $msg = "Stack trace:\n" . $trace->as_string;
338 $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
341 $self->draw($y + 1, 0, Curses::A_NORMAL,
342 'Press any key to terminate fcscs.');
350 my ($self, $module, @args) = @_;
352 return if not $self->{debug};
354 state $fh; # only open the file once per run
355 if (not defined $fh) {
356 # Ignore errors if the directory doesn't exist.
357 if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
358 $fh = undef; # a failed open still writes a value to $fh
364 $_ = $self->encode($_);
366 say $fh "$module: @args";
372 my ($self, %settings) = @_;
374 foreach (keys %settings) {
375 CORE::die if not exists $self->{prompt}{$_};
376 $self->{prompt}{$_} = $settings{$_};
381 # Wrapper for Curses.
382 sub width { return $Curses::COLS; }
383 sub height { return $Curses::LINES; }
384 sub refresh { return $_[0]->{curses}->refresh; }
385 sub getch { return $_[0]->{curses}->getch; }
386 sub cursor { Curses::curs_set($_[1]); return; }
394 my ($screen, $input_ref) = @_;
396 # Make sure the input fits on the screen by removing the top lines if
398 splice @{$input_ref}, 0, -$screen->height;
400 # Pad each line with spaces to the screen width to correctly handle
401 # multi-line regexes.
402 # FIXME: wide characters
403 my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
405 my $string = join "\n", @padded;
409 width => $screen->width + 1,
410 # + 1 = "\n", used in input_match_offset_to_coordinates
414 sub input_match_offset_to_coordinates {
415 my ($width, $offset) = @_;
417 die unless defined $offset;
419 my $y = int($offset / $width);
420 my $x = $offset - $y * $width;
424 sub get_regex_matches {
425 my ($input, $regex) = @_;
428 while ($input->{string} =~ /$regex/g) {
430 die "Match group required in regex '$regex'" if not defined $offset;
432 my ($x, $y) = input_match_offset_to_coordinates($input->{width},
434 push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
441 my ($screen, $config, $cmd) = @_;
443 $screen->debug('run_command', "running @{$cmd}");
446 # Perl's system() combined with a $SIG{__WARN__} which die()s has
447 # issues due to the fork. The die() in the __WARN__ handler doesn't
448 # die but the program continues after the system().
450 # If the forked process fails to exec (e.g. program not found) then
451 # the __WARN__ handler is called (because a warning is about to be
452 # displayed) and the die() should display a message and terminate the
453 # process. But due to the fork it doesn't terminate the parent process
454 # and instead changes the return value of system(); it's no longer -1
455 # which makes it impossible to detect that case.
457 # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
458 # makes it impossible to detect if the handler was called from inside
461 # Instead, just ignore any warnings during the system(). Thanks to
462 # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
463 # use no warnings and anno for testing a more recent Perl version with
467 my @cmd = map { $screen->encode($_) } @{$cmd};
468 system { $cmd[0] } @cmd;
473 $msg = 'failed to execute: ' . $!;
475 $msg = 'killed by signal ' . ($? & 127);
477 $msg = 'exited with code ' . ($? >> 8);
479 die "system(@{$cmd}) $msg.";
483 sub run_in_background {
484 my ($screen, $sub) = @_;
486 $screen->debug('run_in_background', "running $sub");
489 defined $pid or die $!;
492 # The terminal multiplexer sends a SIGHUP to the process when it
493 # closes the window (because the parent process has exited).
494 local $SIG{HUP} = 'IGNORE';
496 # Necessary for GNU screen or it'll keep the window open until the
497 # paste command has run.
498 close STDIN or die $!;
499 close STDOUT or die $!;
500 close STDERR or die $!;
502 # Double-fork to prevent zombies.
504 defined $pid or die $!;
505 if ($pid == 0) { # child
510 waitpid $pid, 0 or die $!;
516 my ($name, $screen, $config, $input, $matches) = @_;
518 $screen->debug('select_match', 'started');
520 return if @{$matches} == 0;
521 # Don't return on initial run to give the user a chance to select another
522 # mode, e.g. to switch from URL selection to search selection.
523 if (@{$matches} == 1 and not $config->{state}{initial}) {
524 return { match => $matches->[0] };
526 $config->{state}{initial} = 0;
528 my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
535 $screen->prompt(name => $name, value => undef);
536 $screen->draw_prompt($config);
538 $screen->draw_matches($config, [], $matches);
543 my $char = $screen->getch;
544 if ($char =~ /^\d$/) {
545 $number = $number * 10 + $char;
546 } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
547 $number = int($number / 10);
548 } elsif ($char eq "\n") {
549 if ($number == 0) { # number without selection matches last entry
554 # Selecting a new mode requires falling through into the main input
555 # loop and then starting the new mode.
556 } elsif (defined $config->{mapping}{mode}{$char}) {
557 $screen->draw_matches($config, $matches, []); # clear matches
558 return { key => $char };
559 # All other mappings stay in the current mode.
560 } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
561 $m->($char, $screen, $config, $input);
565 next; # ignore unknown mappings
568 last if $number > 0 and $number * 10 > @{$matches}; # unique match
570 my @remaining = $number == 0
572 : grep { $_->{id} =~ /^$number/ } @{$matches};
573 $screen->draw_matches($config, $matches, \@remaining);
577 $screen->draw_matches($config, $matches, []); # remove matches
579 foreach (@{$matches}) {
580 return { match => $_ } if $_->{id} == $number;
582 $screen->debug('select_match', 'no match selected');
583 return { match => undef };
586 sub extend_match_regex_left {
587 my ($line, $match, $regex) = @_;
589 my $s = reverse substr $line, 0, $match->{x};
590 if ($s =~ /^($regex)/) {
591 $match->{string} = reverse($1) . $match->{string};
592 $match->{x} -= length $1;
593 $match->{offset} -= length $1;
597 sub extend_match_regex_right {
598 my ($line, $match, $regex) = @_;
600 my $s = substr $line, $match->{x} + length $match->{string};
601 if ($s =~ /^($regex)/) {
602 $match->{string} .= $1;
607 my ($screen, $config, $input, $match) = @_;
609 $screen->debug('extend_match', 'started');
611 $screen->prompt(name => 'extend', value => undef);
612 $screen->draw_prompt($config);
614 delete $match->{id}; # don't draw any match ids
615 $screen->draw_matches($config, [], [$match]);
618 my $line = $input->{lines}[$match->{y}];
621 my $match_old = \%{$match};
623 my $char = $screen->getch;
624 if ($char eq "\n") { # accept match
627 } elsif ($char eq 'w') { # select current word (both directions)
628 extend_match_regex_left($line, $match, qr/\w+/);
629 extend_match_regex_right($line, $match, qr/\w+/);
630 } elsif ($char eq 'b') { # select current word (only left)
631 extend_match_regex_left($line, $match, qr/\w+/);
632 } elsif ($char eq 'e') { # select current word (only right)
633 extend_match_regex_right($line, $match, qr/\w+/);
635 } elsif ($char eq 'W') { # select current WORD (both directions)
636 extend_match_regex_left($line, $match, qr/\S+/);
637 extend_match_regex_right($line, $match, qr/\S+/);
638 } elsif ($char eq 'B') { # select current WORD (only left)
639 extend_match_regex_left($line, $match, qr/\S+/);
640 } elsif ($char eq 'E') { # select current WORD (only right)
641 extend_match_regex_right($line, $match, qr/\S+/);
643 } elsif ($char eq '^') { # select to beginning of line
644 extend_match_regex_left($line, $match, qr/.+/);
645 } elsif ($char eq '$') { # select to end of line
646 extend_match_regex_right($line, $match, qr/.+/);
648 # Allow mode changes if not overwritten by local mappings.
649 } elsif (defined $config->{mapping}{mode}{$char}) {
650 $screen->draw_matches($config, [$match_old], []); # clear match
651 return { key => $char };
654 next; # ignore unknown mappings
657 $screen->draw_matches($config, [$match_old], [$match]);
661 $screen->debug('extend_match', 'done');
663 return { match => $match };
668 my ($key, $screen, $config, $input) = @_;
670 $screen->debug('mapping_paste', 'started');
672 $config->{state}{handler} = $config->{handler}{paste};
674 $screen->prompt(flags => 'P'); # paste
675 $screen->draw_prompt($config);
681 my ($key, $screen, $config, $input) = @_;
683 $screen->debug('mapping_yank', 'started');
685 $config->{state}{handler} = $config->{handler}{yank};
687 $screen->prompt(flags => 'Y'); # yank
688 $screen->draw_prompt($config);
697 Normal modes select matches by calling a function which returns them, e.g. by
700 The following normal modes are available:
704 =item B<path mode> select relative/absolute paths
706 =item B<url mode> select URLs
711 sub mapping_mode_path {
712 my ($key, $screen, $config, $input) = @_;
714 $screen->debug('mapping_mode_path', 'started');
716 my @matches = get_regex_matches($input, $config->{regex}{path});
718 select => 'path select',
719 matches => \@matches,
720 handler => $config->{handler}{yank},
723 sub mapping_mode_url {
724 my ($key, $screen, $config, $input) = @_;
726 $screen->debug('mapping_mode_url', 'started');
728 my @matches = get_regex_matches($input, $config->{regex}{url});
730 select => 'url select',
731 matches => \@matches,
732 handler => $config->{handler}{url},
736 =head2 SEARCH MODE (AND EXTEND MODE)
738 Search mode is a special mode which lets you type a search string (a Perl
739 regex) and then select one of the matches. Afterwards you can extend the
740 match. For example select the complete word or to the end of the line. This
741 allows quick selection of arbitrary text.
743 The following mappings are available during the extension mode (not
744 configurable at the moment):
748 =item B<w> select current word
750 =item B<b> extend word to the left
752 =item B<e> extend word to the right
754 =item B<W> select current WORD
756 =item B<B> extend WORD to the left
758 =item B<E> extend WORD to the right
760 =item B<^> extend to beginning of line
762 =item B<$> extend to end of line
766 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
767 characters (C<\S+>), just like in Vim.
770 sub mapping_mode_search {
771 my ($key, $screen, $config, $input) = @_;
773 $screen->debug('mapping_mode_search', 'started');
777 my $search = ''; # encoded
780 # getch doesn't return decoded characters but raw input bytes. Wait
781 # until the input character is complete.
782 my $value = $screen->decode($search);
783 $value = '' unless defined $value; # undef on decode failure
785 $screen->prompt(name => 'search', value => $value);
786 $screen->draw_prompt($config);
789 my $char = $screen->getch;
790 # TODO: readline editing support
793 } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
794 # Remove a character, not a byte.
795 $search = $screen->decode($search);
797 $search = $screen->encode($search);
800 next unless defined $screen->decode($search);
806 if (($config->{setting}{smartcase} and $search eq lc $search)
807 or $config->{setting}{ignorecase}) {
810 # Ignore invalid regexps.
811 # TODO: display warning on error?
813 @matches = get_regex_matches($input, qr/($case$search)/);
816 $screen->draw_matches($config, \@last_matches, \@matches);
817 @last_matches = @matches;
824 matches => \@last_matches,
826 handler => $config->{handler}{yank},
831 my ($key, $screen, $config, $input) = @_;
833 # Key is necessary to fall through to main event loop which then quits.
834 return { key => $key, quit => 1 };
839 my ($screen, $config, $match) = @_;
841 $screen->debug('handler_yank', 'started');
845 # Use a temporary file to prevent leaking the yanked data to other users
846 # with the command line, e.g. ps aux or top.
847 my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
848 print $fh $screen->encode($match->{value});
851 if ($config->{setting}{multiplexer} eq 'screen') {
852 $screen->debug('handler_yank', 'using screen');
854 # GNU screen displays an annoying "Slurping X characters into buffer".
855 # Use 'msgwait 0' as a hack to disable it.
856 my $msgwait = $config->{setting}{screen_msgwait};
857 run_command($screen, $config, ['screen', '-X', 'msgwait', 0]);
858 run_command($screen, $config, ['screen', '-X', 'readbuf', $tmp]);
859 run_command($screen, $config, ['screen', '-X', 'msgwait', $msgwait]);
860 } elsif ($config->{setting}{multiplexer} eq 'tmux') {
861 $screen->debug('handler_yank', 'using tmux');
863 run_command($screen, $config, ['tmux', 'load-buffer', $tmp]);
865 die 'unsupported multiplexer';
868 unlink $tmp or die $!;
872 my ($screen, $config, $match) = @_;
874 $screen->debug('handler_paste', 'started');
879 if ($config->{setting}{multiplexer} eq 'screen') {
880 $screen->debug('handler_paste', 'using screen');
881 @cmd = qw( screen -X paste . );
882 } elsif ($config->{setting}{multiplexer} eq 'tmux') {
883 $screen->debug('handler_paste', 'using tmux');
884 @cmd = qw( tmux paste-buffer );
886 die 'unsupported multiplexer';
889 run_in_background($screen, sub {
890 # We need to get the data in the paste buffer before we can paste
892 handler_yank($screen, $config, $match);
894 # Sleep until we switch back to the current window.
895 Time::HiRes::usleep($config->{setting}{paste_sleep});
897 run_command($screen, $config, \@cmd);
902 my ($screen, $config, $match) = @_;
904 $screen->debug('handler_url', "opening $match->{value}");
906 run_in_background($screen, sub {
907 my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
908 run_command($screen, $config, \@cmd);
915 # CONFIGURATION DEFAULTS
919 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
920 is a normal Perl script with all of Perl's usual features.
922 All configuration values are stored in the hash C<%config>. All manually
923 defined keys overwrite the default settings.
925 A simple F<~/.fcscsrc> could look like this (for details about the used
931 use Curses; # for COLOR_* and A_* constants
935 # Draw matches in blue.
936 $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
937 # Enable Vim-like 'smartcase', ignore case until an upper character is
939 $config{setting}{smartcase} = 1;
941 # Use chromium to open URLs if running under X, elinks otherwise.
942 if (defined $ENV{DISPLAY}) {
943 $config{setting}{browser} = ['chromium'];
945 $config{setting}{browser} = ['elinks'];
948 # Let fcscs know the file was loaded successfully.
956 Pod::Usage::pod2usage(2);
960 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
961 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
963 my $screen = Screen->init($encoding);
965 # We must restore the screen before exiting.
966 local $SIG{INT} = sub {
970 # Make all warnings fatal to make sure they don't get lost (stderr is normally
972 local $SIG{__WARN__} = sub {
973 $screen->die('warning', @_);
980 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
981 selection and may receive additional input (e.g. a search string) and simple
982 mappings which only change some value. Mode mappings are configured via
983 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
985 The following mode mappings are available by default (the function to remap
986 them in parentheses):
990 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
992 =item B<u> select URLs (C<\&mapping_mode_url>)
994 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
996 =item B<q> quit fcscs (C<\&mapping_quit>)
1000 The following simple mappings are available by default:
1004 =item B<p> enable pasting (C<\&mapping_paste>)
1006 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1010 All (single-byte) keys except numbers, backspace and return can be mapped.
1012 Unknown mappings are ignored when pressing keys.
1014 To remove a default mapping, delete it from the mapping hash.
1018 # Map 'p' to select paths, 'P' to enable pasting.
1019 $config{mapping}{mode}{p} = \&mapping_mode_path;
1020 $config{mapping}{simple}{P} = \&mapping_paste;
1022 # Disable 'f' mapping.
1023 delete $config{mapping}{mode}{f};
1026 my %mapping_mode = (
1027 f => \&mapping_mode_path,
1028 u => \&mapping_mode_url,
1029 '/' => \&mapping_mode_search,
1030 q => \&mapping_quit,
1032 my %mapping_simple = (
1033 p => \&mapping_paste,
1034 y => \&mapping_yank,
1039 Attributes are used to style the output. They must be Curses attributes.
1040 Defaults in parentheses (foreground, background, attribute).
1044 =item B<match_id> attribute for match numbers (red, default, bold)
1046 =item B<match_string> attribute for matches (yellow, default, normal)
1048 =item B<prompt_name> attribute for prompt name (standout)
1050 =item B<prompt_flags> attribute for prompt flags (standout)
1056 # Draw prompt flags in bold red with default background color.
1057 $config{attribute}{prompt_flags}
1059 | color_pair(Curses::COLOR_RED, -1);
1063 match_id => $screen->color_pair(Curses::COLOR_RED, -1)
1065 match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1066 prompt_name => Curses::A_STANDOUT,
1067 prompt_flags => Curses::A_STANDOUT,
1072 Defaults in parentheses.
1076 =item B<debug> enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1078 =item B<initial_mode> start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1080 =item B<multiplexer> set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1082 =item B<ignorecase> ignore case when searching (C<0>)
1084 =item B<smartcase> ignore case unless one uppercase character is searched (C<1>)
1086 =item B<paste_sleep> sleep x us before running paste command (C<100_000>)
1088 =item B<screen_msgwait> GNU Screen's msgwait variable, used when yanking (C<5>)
1090 =item B<browser> browser command as array reference (C<['x-www-browser']>)
1096 # Select paths on startup instead of URLs.
1097 $config{setting}{initial_mode} = \&mapping_mode_path;
1103 initial_mode => \&mapping_mode_url,
1104 multiplexer => undef,
1107 paste_sleep => 100_000,
1108 screen_msgwait => 5,
1110 browser => ['x-www-browser'],
1117 =item B<url> used by C<\&mapping_mode_url()>
1119 =item B<path> used by C<\&mapping_mode_path()>
1125 # Select all non-whitespace characters when searching for paths.
1126 $config{regex}{path} = qr{(\S+)};
1130 # Taken from urlview's default configuration file, thanks.
1131 url => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1132 path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1137 Handlers are used to perform actions on the selected string.
1139 The following handlers are available, defaults in parentheses.
1143 =item B<yank> used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1145 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1147 =item B<url> used to open URLs (e.g. in a browser) (C<\&handler_url>)
1153 # Download YouTube videos with a custom wrapper, handle all other URLs
1154 # with the default URL handler.
1155 $config{handler}{url} = sub {
1156 my ($screen, $config, $match) = @_;
1158 if ($match->{value} =~ m{^https://www.youtube.com/}) {
1159 return run_in_background($screen, sub {
1160 run_command($screen, $config,
1161 ['youtube-dl-wrapper', $match->{value}]);
1169 yank => \&handler_yank,
1170 paste => \&handler_paste,
1171 url => \&handler_url,
1175 initial => 1, # used by select_match() for 'initial_mode'
1181 # CONFIGURATION "API"
1185 The following functions are available:
1187 color_pair($fg, $bg)
1189 Create a new Curses attribute with the given fore- and background color.
1193 mapping_mode_search()
1199 Used as mappings, see L</MAPPINGS> above.
1205 Used as handler to yank, paste selection or open URL in browser.
1213 Helper functions when writing custom mappings, see the source for details.
1221 # All variables and functions which are usable by ~/.fcscsrc.
1223 our $screen; # "private"
1226 sub color_pair { return $screen->color_pair(@_); }
1228 sub mapping_mode_path { return main::mapping_mode_path(@_); }
1229 sub mapping_mode_url { return main::mapping_mode_url(@_); }
1230 sub mapping_mode_search { return main::mapping_mode_search(@_); }
1232 sub mapping_paste { return main::mapping_paste(@_); }
1233 sub mapping_yank { return main::mapping_yank(@_); }
1234 sub mapping_quit { return main::mapping_quit(@_); }
1236 sub handler_yank { return main::handler_yank(@_); }
1237 sub handler_paste { return main::handler_paste(@_); }
1238 sub handler_url { return main::handler_url(@_); }
1240 sub debug { return main::debug(@_); }
1242 sub get_regex_matches { return main::get_regex_matches(@_); }
1243 sub select_match { return main::select_match(@_); }
1245 sub run_command { return main::run_command(@_); }
1246 sub run_in_background { return main::run_in_background(@_); }
1248 $Fcscs::screen = $screen;
1254 # Alias %config and %Fcscs::config. %config is less to type.
1256 local *config = \%Fcscs::config;
1258 $config{mapping}{mode} = \%mapping_mode;
1259 $config{mapping}{simple} = \%mapping_simple;
1260 $config{attribute} = \%attribute;
1261 $config{setting} = \%setting;
1262 $config{regex} = \%regex;
1263 $config{handler} = \%handler;
1264 $config{state} = \%state;
1267 my @configs = ("$ENV{HOME}/.fcscsrc",
1268 "$ENV{HOME}/.config/fcscs/fcscsrc");
1269 foreach my $path (@configs) {
1270 my $decoded = $screen->decode($path);
1272 # Load configuration file. Checks have a race condition if the home
1273 # directory is writable by an attacker (but then the user is screwed
1275 next unless -e $path;
1277 $screen->die("Config '$decoded' not owned by current user!");
1279 # Make sure the file is not writable by other users. Doesn't handle
1280 # ACLs and see comment above about race conditions.
1281 my @stat = stat $path or die $!;
1282 my $mode = $stat[2];
1283 if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1284 die "Config '$decoded' must not be writable by other users.";
1287 my $result = do $path;
1289 $screen->die("Failed to parse '$decoded': $@") if $@;
1290 $screen->die("Failed to do '$decoded': $!") unless defined $result;
1291 $screen->die("Failed to run '$decoded'.");
1294 last; # success, don't load more files
1297 $screen->{debug} = $config{setting}{debug};
1303 # Auto-detect current multiplexer.
1304 if (not defined $config{setting}{multiplexer}) {
1305 if (defined $ENV{STY} and defined $ENV{TMUX}) {
1306 die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1307 } elsif (defined $ENV{STY}) {
1308 $config{setting}{multiplexer} = 'screen';
1309 } elsif (defined $ENV{TMUX}) {
1310 $config{setting}{multiplexer} = 'tmux';
1312 die 'No multiplexer found.';
1316 my $binmode = $encoding;
1317 # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1318 # instead of the currently active encoding.
1319 if ($config{setting}{multiplexer} eq 'screen') {
1320 $binmode = 'ISO-8859-1';
1324 open my $fh, '<', $ARGV[0] or die $!;
1325 binmode $fh, ":encoding($binmode)" or die $!;
1328 push @input_lines, $_;
1330 close $fh or die $!;
1332 my $input = prepare_input($screen, \@input_lines);
1334 # Display original screen content.
1336 foreach (@{$input->{lines}}) {
1337 $screen->draw_simple($y++, 0, undef, $_);
1342 my $mapping = $config{setting}{initial_mode};
1346 if (not defined $mapping) {
1347 $key = $screen->getch unless defined $key;
1348 $screen->debug('input', "got key '$key'");
1350 $mapping = $config{mapping}{mode}{$key};
1351 $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1352 if (not defined $mapping) { # ignore unknown mappings
1358 $screen->debug('input', 'running mapping');
1359 my $result = $mapping->($key, $screen, \%config, $input);
1363 if (defined $result->{quit}) {
1364 $screen->debug('input', 'quitting');
1367 if (defined $result->{key}) {
1368 $key = $result->{key}; # lookup another mapping
1369 $screen->debug('input', "processing new key: '$key'");
1372 if (defined $result->{select}) {
1373 $screen->debug('input', 'selecting match');
1375 $result = select_match($result->{select},
1376 $screen, \%config, $input,
1377 $result->{matches});
1378 $result->{handler} = $tmp->{handler};
1379 $result->{extend} = $tmp->{extend};
1380 goto RESULT; # reprocess special entries in result
1382 if (defined $result->{extend}) {
1383 $screen->debug('input', 'extending match');
1384 $result = extend_match($screen, \%config, $input,
1386 goto RESULT; # reprocess special entries in result
1388 if (defined $result->{match}) {
1389 if (not defined $result->{match}{value}) {
1390 $result->{match}{value} = $result->{match}{string};
1393 $screen->debug('input', 'running handler');
1395 # Choose handler with falling priority.
1397 $config{state}{handler}, # set by user
1398 $result->{match}{handler}, # set by match
1399 $result->{handler}, # set by mapping
1400 $config{handler}{yank}, # fallback
1402 foreach my $handler (@handlers) {
1403 next unless defined $handler;
1405 $handler->($screen, \%config, $result->{match});
1411 $key = undef; # get next key from user
1436 Invalid arguments/options.
1442 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1444 =head1 LICENSE AND COPYRIGHT
1446 Copyright (C) 2013-2016 by Simon Ruderich
1448 This program is free software: you can redistribute it and/or modify
1449 it under the terms of the GNU General Public License as published by
1450 the Free Software Foundation, either version 3 of the License, or
1451 (at your option) any later version.
1453 This program is distributed in the hope that it will be useful,
1454 but WITHOUT ANY WARRANTY; without even the implied warranty of
1455 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
1456 GNU General Public License for more details.
1458 You should have received a copy of the GNU General Public License
1459 along with this program. If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1463 L<screen(1)>, L<tmux(1)>, L<urlview(1)>