3 # fcscs - fast curses screen content select
5 # Copyright (C) 2013-2016 Simon Ruderich
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 # GNU General Public License for more details.
17 # You should have received a copy of the GNU General Public License
18 # along with this program. If not, see <http://www.gnu.org/licenses/>.
24 use v5.10; # say, state
28 use I18N::Langinfo ();
32 our $VERSION = '0.01';
37 fcscs - fast curses screen content select
41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
45 B<fcscs> is a small tool which allows quick selection of terminal screen
46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
47 GNU Screen's or Tmux's buffer or any other program. The selection can then
48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
49 licensed under the GPL 3 or later.
57 Short overview of the general usage, details below:
60 - configure actions (optional)
63 - select mode (optional, URL mode is used on startup):
70 - select match by displayed number or <return> for lowest numbered
72 - configured action is run, e.g. URL is opened with browser
74 - perform incremental search
75 - on <return> go to `normal' mode to select a match
76 - after the match is selected wait for confirmation or extension
77 - confirmation: <return> run previously selected action
78 - extension: change match, e.g. select complete word or line
80 GNU Screen setup (add to F<~/.screenrc>):
82 bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
84 Tmux setup (add to F<~/.tmux.conf>):
86 bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
88 This requires a writable ~/.tmp directory. Adapt the mapping according to your
89 preferences. Ensure these files are not readable by others as they can contain
90 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
91 for the above mappings to work.
93 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
94 in a new GNU screen/Tmux window. After selection, the content is either passed
95 to external programs (e.g. for URLs) or copied to the paste buffer or directly
96 pasted in your previous window and the new window is closed.
98 To select a match just type its number. If the match is unique, the entry is
99 automatically selected (e.g. you press 2 and there are only 19 matches). If
100 there are multiple matches left (e.g. you press 1 and there are more than ten
101 matches available), press return to select the current match (1 in this case)
102 or another number to select the longer match. Use backspace to remove the last
105 Press return before entering a number to select the last (lowest numbered)
106 match (underlined by default). To abort without selecting any match use "q".
108 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
109 explained below. Per default URLs are selected, see options for a way to
112 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
113 leaks URLs to other users on the current system via C<ps aux> or C<top>.
115 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
116 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
117 leak data if those temporary files are written to disk. To prevent this change
118 your C<$TMP> to point to a memory-only location or encrypted storage.
120 If no window appears, try running B<fcscs> manually to catch the error message
121 and please report the bug:
123 fcscs /path/to/screen-or-tmux-fcscs-file
133 # Helper class for drawing on the screen using Curses.
136 my ($class, $encoding) = @_;
138 # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
139 if (lc $encoding eq 'utf8') {
142 # Get Encode object to speed up decode()/encode().
143 my $encoding_object = Encode::find_encoding($encoding);
144 die "unsupported encoding '$encoding'" unless ref $encoding_object;
146 my $curses = Curses->new or die $!;
149 encoding => $encoding,
150 encoding_object => $encoding_object,
162 # Allow default colors by passing -1 to init_pair. A default color is
163 # not drawn on screen thus allowing terminals with pseudo-transparency
164 # to use the transparent background in place of the default color.
165 Curses::use_default_colors;
184 # Convert between Perl's internal encoding and the terminal's encoding.
186 my ($self, $string) = @_;
187 return $self->{encoding_object}->encode($string);
190 my ($self, $string) = @_;
191 return eval { # returns undef on decode failure
192 $self->{encoding_object}->decode($string, Encode::FB_CROAK);
196 # Create attribute for the given fore-/background colors.
198 my ($self, $fg, $bg) = @_;
200 state $next_color_pair = 1; # must start at 1 for init_pair()
202 Curses::init_pair($next_color_pair, $fg, $bg);
203 return Curses::COLOR_PAIR($next_color_pair++);
206 # Draw a string which must fit in the current line. Wrapping/clipping is
207 # not supported and must be handled by the caller.
209 my ($self, $y, $x, $attributes, $string) = @_;
211 die if $string =~ /\n/;
212 # FIXME: wide characters
213 die if $x + length $string > $self->width;
215 $self->{curses}->attron($attributes) if defined $attributes;
216 $self->{curses}->addstr($y, $x, $self->encode($string));
217 $self->{curses}->attroff($attributes) if defined $attributes;
220 # Like draw_simple(), but the string is automatically clipped.
222 my ($self, $y, $x, $attributes, $string) = @_;
224 # FIXME: wide characters
225 $string = substr $string, 0, $self->width - $x;
226 $self->draw_simple($y, $x, $attributes, $string);
230 my ($self, $y, $x, $attributes, $string) = @_;
232 die unless defined $string;
236 # We must print each line separately. Search for next newline or
237 # line end, whichever is closer.
238 if ($string =~ /\n/) {
241 # FIXME: wide characters
242 if ($x + length $string > $self->width) {
243 my $new_offset = $self->width - $x;
244 if (not defined $offset or $offset > $new_offset) {
245 $offset = $new_offset;
248 last unless defined $offset;
250 # FIXME: wide characters
251 $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
253 # Don't draw "\n" itself.
254 if ("\n" eq substr $string, $offset, 1) {
258 $string = substr $string, $offset;
264 $self->draw_simple($y, $x, $attributes, $string);
269 my ($self, $config) = @_;
271 $self->debug('draw_prompt', 'started');
274 my $y = $self->height - 1;
276 # Clear line for better visibility.
277 $self->draw_simple($y, $x, undef, ' ' x $self->width);
280 if (defined (my $s = $self->{prompt}{flags})) {
282 $self->debug('draw_prompt', $s);
283 $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
284 $x += length($s) + 1; # space between next element
287 if (defined (my $s = $self->{prompt}{name})) {
289 $self->debug('draw_prompt', $s);
290 $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
291 $x += length($s) + 1;
293 # Draw prompt value, e.g. a search field.
294 if (defined (my $s = $self->{prompt}{value})) {
295 $self->debug('draw_prompt', $s);
296 $self->draw_clipped($y, $x, undef, $s);
297 $x += length($s) + 1;
303 my ($self, $config, $matches_remove, $matches_add) = @_;
305 foreach (@{$matches_remove}) {
306 $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
309 my $attr_id = $config->{attribute}{match_id};
310 my $attr_string = $config->{attribute}{match_string};
311 my $attr_last = $config->{attribute}{match_last};
313 foreach (@{$matches_add}) {
314 my $attr = (defined $_->{id} and $_->{id} == 1)
317 $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
318 if (defined $_->{id}) {
319 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
326 my ($self, @args) = @_;
328 my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
330 # Clear the screen to improve visibility of the error message.
331 $self->{curses}->clear;
333 my $y = $self->draw(0, 0, $attr, "@args");
335 if ($self->{debug}) {
338 require Devel::StackTrace;
341 $msg = "Devel::StackTrace missing, no stack trace.\n";
343 my $trace = Devel::StackTrace->new;
344 $msg = "Stack trace:\n" . $trace->as_string;
346 $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
349 $self->draw($y + 1, 0, Curses::A_NORMAL,
350 'Press any key to terminate fcscs.');
358 my ($self, $module, @args) = @_;
360 return if not $self->{debug};
362 state $fh; # only open the file once per run
363 if (not defined $fh) {
364 # Ignore errors if the directory doesn't exist.
365 if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
366 $fh = undef; # a failed open still writes a value to $fh
372 $_ = $self->encode($_);
374 say $fh "$module: @args" or CORE::die $!;
380 my ($self, %settings) = @_;
382 foreach (keys %settings) {
383 CORE::die if not exists $self->{prompt}{$_};
384 $self->{prompt}{$_} = $settings{$_};
389 # Wrapper for Curses.
390 sub width { return $Curses::COLS; }
391 sub height { return $Curses::LINES; }
392 sub refresh { return $_[0]->{curses}->refresh; }
393 sub getch { return $_[0]->{curses}->getch; }
394 sub cursor { Curses::curs_set($_[1]); return; }
402 my ($screen, $input_ref) = @_;
404 # Make sure the input fits on the screen by removing the top lines if
406 splice @{$input_ref}, 0, -$screen->height;
408 # Pad each line with spaces to the screen width to correctly handle
409 # multi-line regexes.
410 # FIXME: wide characters
411 my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
413 my $string = join "\n", @padded;
417 width => $screen->width + 1,
418 # + 1 = "\n", used in input_match_offset_to_coordinates
422 sub input_match_offset_to_coordinates {
423 my ($width, $offset) = @_;
425 die unless defined $offset;
427 my $y = int($offset / $width);
428 my $x = $offset - $y * $width;
432 sub get_regex_matches {
433 my ($input, $regex) = @_;
436 while ($input->{string} =~ /$regex/g) {
438 die "Match group required in regex '$regex'" if not defined $offset;
440 my ($x, $y) = input_match_offset_to_coordinates($input->{width},
442 push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
449 my ($screen, $cmd) = @_;
451 $screen->debug('run_command', "running @{$cmd}");
454 # Perl's system() combined with a $SIG{__WARN__} which die()s has
455 # issues due to the fork. The die() in the __WARN__ handler doesn't
456 # die but the program continues after the system().
458 # If the forked process fails to exec (e.g. program not found) then
459 # the __WARN__ handler is called (because a warning is about to be
460 # displayed) and the die() should display a message and terminate the
461 # process. But due to the fork it doesn't terminate the parent process
462 # and instead changes the return value of system(); it's no longer -1
463 # which makes it impossible to detect that case.
465 # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
466 # makes it impossible to detect if the handler was called from inside
469 # Instead, just ignore any warnings during the system(). Thanks to
470 # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
471 # use no warnings and anno for testing a more recent Perl version with
475 my @cmd = map { $screen->encode($_) } @{$cmd};
476 system { $cmd[0] } @cmd;
481 $msg = 'failed to execute: ' . $!;
483 $msg = 'killed by signal ' . ($? & 127);
485 $msg = 'exited with code ' . ($? >> 8);
487 die "system(@{$cmd}) $msg.";
491 sub run_in_background {
492 my ($screen, $sub) = @_;
494 $screen->debug('run_in_background', "running $sub");
497 defined $pid or die $!;
500 # The terminal multiplexer sends a SIGHUP to the process when it
501 # closes the window (because the parent process has exited).
502 local $SIG{HUP} = 'IGNORE';
504 # Necessary for GNU screen or it'll keep the window open until an
505 # external command has run.
507 my $devnull = File::Spec->devnull();
508 open STDIN, '<', $devnull or die $!;
509 open STDOUT, '>', $devnull or die $!;
510 open STDERR, '>', $devnull or die $!;
512 # Double-fork to prevent zombies.
514 defined $pid or die $!;
515 if ($pid == 0) { # child
520 waitpid $pid, 0 or die $!;
526 my ($name, $screen, $config, $input, $matches) = @_;
528 $screen->debug('select_match', 'started');
530 return if @{$matches} == 0;
531 # Don't return on initial run to give the user a chance to select another
532 # mode, e.g. to switch from URL selection to search selection.
533 if (@{$matches} == 1 and not $config->{state}{initial}) {
534 return { match => $matches->[0] };
536 $config->{state}{initial} = 0;
538 my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
545 $screen->prompt(name => $name, value => undef);
546 $screen->draw_prompt($config);
548 $screen->draw_matches($config, [], $matches);
553 my $char = $screen->getch;
554 if ($char =~ /^\d$/) {
555 $number = $number * 10 + $char;
556 } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
557 $number = int($number / 10);
558 } elsif ($char eq "\n"
559 or $char eq $config->{setting}{alternative_return}) {
560 if ($number == 0) { # number without selection matches last entry
565 # Selecting a new mode requires falling through into the main input
566 # loop and then starting the new mode.
567 } elsif (defined $config->{mapping}{mode}{$char}) {
568 $screen->draw_matches($config, $matches, []); # clear matches
569 return { key => $char };
570 # All other mappings stay in the current mode.
571 } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
572 $m->($char, $screen, $config, $input);
576 next; # ignore unknown mappings
579 last if $number > 0 and $number * 10 > @{$matches}; # unique match
581 my @remaining = $number == 0
583 : grep { $_->{id} =~ /^$number/ } @{$matches};
584 $screen->draw_matches($config, $matches, \@remaining);
588 $screen->draw_matches($config, $matches, []); # remove matches
590 foreach (@{$matches}) {
591 return { match => $_ } if $_->{id} == $number;
593 $screen->debug('select_match', 'no match selected');
594 return { match => undef };
597 sub extend_match_regex_left {
598 my ($line, $match, $regex) = @_;
600 my $s = reverse substr $line, 0, $match->{x};
601 if ($s =~ /^($regex)/) {
602 $match->{string} = reverse($1) . $match->{string};
603 $match->{x} -= length $1;
604 $match->{offset} -= length $1;
608 sub extend_match_regex_right {
609 my ($line, $match, $regex) = @_;
611 my $s = substr $line, $match->{x} + length $match->{string};
612 if ($s =~ /^($regex)/) {
613 $match->{string} .= $1;
618 my ($screen, $config, $input, $match) = @_;
620 $screen->debug('extend_match', 'started');
622 return if not defined $match;
624 $screen->prompt(name => 'extend', value => undef);
625 $screen->draw_prompt($config);
627 delete $match->{id}; # don't draw any match ids
628 $screen->draw_matches($config, [], [$match]);
631 my $line = $input->{lines}[$match->{y}];
634 my $match_old = \%{$match};
636 my $char = $screen->getch;
638 or $char eq $config->{setting}{alternative_return}) {
641 } elsif ($char eq 'w') { # select current word (both directions)
642 extend_match_regex_left($line, $match, qr/\w+/);
643 extend_match_regex_right($line, $match, qr/\w+/);
644 } elsif ($char eq 'b') { # select current word (only left)
645 extend_match_regex_left($line, $match, qr/\w+/);
646 } elsif ($char eq 'e') { # select current word (only right)
647 extend_match_regex_right($line, $match, qr/\w+/);
649 } elsif ($char eq 'W') { # select current WORD (both directions)
650 extend_match_regex_left($line, $match, qr/\S+/);
651 extend_match_regex_right($line, $match, qr/\S+/);
652 } elsif ($char eq 'B') { # select current WORD (only left)
653 extend_match_regex_left($line, $match, qr/\S+/);
654 } elsif ($char eq 'E') { # select current WORD (only right)
655 extend_match_regex_right($line, $match, qr/\S+/);
657 } elsif ($char eq '0') { # select to beginning of line
658 extend_match_regex_left($line, $match, qr/.+/);
659 } elsif ($char eq '$') { # select to end of line
660 extend_match_regex_right($line, $match, qr/.+/);
662 # Allow mode changes if not overwritten by local mappings.
663 } elsif (defined $config->{mapping}{mode}{$char}) {
664 $screen->draw_matches($config, [$match_old], []); # clear match
665 return { key => $char };
668 next; # ignore unknown mappings
671 $screen->draw_matches($config, [$match_old], [$match]);
675 $screen->debug('extend_match', 'done');
677 return { match => $match };
682 my ($key, $screen, $config, $input) = @_;
684 $screen->debug('mapping_paste', 'started');
686 $config->{state}{handler} = $config->{handler}{paste};
688 $screen->prompt(flags => 'P'); # paste
689 $screen->draw_prompt($config);
695 my ($key, $screen, $config, $input) = @_;
697 $screen->debug('mapping_yank', 'started');
699 $config->{state}{handler} = $config->{handler}{yank};
701 $screen->prompt(flags => 'Y'); # yank
702 $screen->draw_prompt($config);
711 Normal modes select matches by calling a function which returns them, e.g. by
714 The following normal modes are available:
718 =item B<path mode> select relative/absolute paths
720 =item B<url mode> select URLs
722 =item B<ip mode> select IPv4 and IPv6 addresses
727 sub mapping_mode_path {
728 my ($key, $screen, $config, $input) = @_;
730 $screen->debug('mapping_mode_path', 'started');
732 my @matches = get_regex_matches($input, $config->{regex}{path});
734 select => 'path select',
735 matches => \@matches,
736 handler => $config->{handler}{yank},
739 sub mapping_mode_url {
740 my ($key, $screen, $config, $input) = @_;
742 $screen->debug('mapping_mode_url', 'started');
744 my @matches = get_regex_matches($input, $config->{regex}{url});
746 select => 'url select',
747 matches => \@matches,
748 handler => $config->{handler}{url},
751 sub mapping_mode_ip {
752 my ($key, $screen, $config, $input) = @_;
754 $screen->debug('mapping_mode_ip', 'started');
756 my @ipv4 = get_regex_matches($input, $config->{regex}{ipv4});
757 my @ipv6 = get_regex_matches($input, $config->{regex}{ipv6});
759 select => 'ip select',
760 matches => [@ipv4, @ipv6],
761 handler => $config->{handler}{ip},
765 =head2 SEARCH MODE (AND EXTEND MODE)
767 Search mode is a special mode which lets you type a search string (a Perl
768 regex) and then select one of the matches. Afterwards you can extend the
769 match. For example select the complete word or to the end of the line. This
770 allows quick selection of arbitrary text.
772 The following mappings are available during the extension mode (not
773 configurable at the moment):
777 =item B<w> select current word
779 =item B<b> extend word to the left
781 =item B<e> extend word to the right
783 =item B<W> select current WORD
785 =item B<B> extend WORD to the left
787 =item B<E> extend WORD to the right
789 =item B<0> extend to beginning of line
791 =item B<$> extend to end of line
795 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
796 characters (C<\S+>), just like in Vim.
799 sub mapping_mode_search {
800 my ($key, $screen, $config, $input) = @_;
802 $screen->debug('mapping_mode_search', 'started');
806 my $search = ''; # encoded
809 # getch doesn't return decoded characters but raw input bytes. Wait
810 # until the input character is complete.
811 my $value = $screen->decode($search);
812 $value = '' unless defined $value; # undef on decode failure
814 $screen->prompt(name => 'search', value => $value);
815 $screen->draw_prompt($config);
818 my $char = $screen->getch;
819 # TODO: readline editing support
822 } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
823 # Remove a character, not a byte.
824 $search = $screen->decode($search);
826 $search = $screen->encode($search);
829 next unless defined $screen->decode($search);
835 if (($config->{setting}{smartcase} and $search eq lc $search)
836 or $config->{setting}{ignorecase}) {
839 # Ignore invalid regexps.
840 # TODO: display warning on error?
842 @matches = get_regex_matches($input, qr/($case$search)/);
845 $screen->draw_matches($config, \@last_matches, \@matches);
846 @last_matches = @matches;
851 $screen->prompt(name => undef, value => undef); # clear prompt
852 $screen->draw_prompt($config);
854 $screen->debug('mapping_mode_search', 'done');
858 matches => \@last_matches,
860 handler => $config->{handler}{yank},
865 my ($key, $screen, $config, $input) = @_;
867 # Key is necessary to fall through to main event loop which then quits.
868 return { key => $key, quit => 1 };
873 my ($screen, $config, $match) = @_;
875 $screen->debug('handler_yank', 'started');
879 # Use a temporary file to prevent leaking the yanked data to other users
880 # with the command line, e.g. ps aux or top.
881 my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
882 print $fh $screen->encode($match->{value}) or die $!;
885 if ($config->{setting}{multiplexer} eq 'screen') {
886 $screen->debug('handler_yank', 'using screen');
888 # GNU screen displays an annoying "Slurping X characters into buffer".
889 # Use 'msgwait 0' as a hack to disable it.
890 my $msgwait = $config->{setting}{screen_msgwait};
891 run_command($screen, ['screen', '-X', 'msgwait', 0]);
892 run_command($screen, ['screen', '-X', 'readbuf', $tmp]);
893 run_command($screen, ['screen', '-X', 'msgwait', $msgwait]);
894 } elsif ($config->{setting}{multiplexer} eq 'tmux') {
895 $screen->debug('handler_yank', 'using tmux');
897 run_command($screen, ['tmux', 'load-buffer', $tmp]);
899 die 'unsupported multiplexer';
902 unlink $tmp or die $!;
904 if ($config->{setting}{yank_x11}) {
905 $screen->debug('handler_yank', 'setting X11 selection');
907 my @xsel_cmd = qw( xsel --input --primary );
908 my @xclip_cmd = qw( xclip -in -selection primary );
912 # We don't care if a program doesn't exist.
915 if (not open $fh, '|-', @xsel_cmd) {
916 if (not open $fh, '|-', @xclip_cmd) {
917 die "install xsel or xlip to yank to X11 selection\n";
921 print $fh $match->{value} or die $!;
928 my ($screen, $config, $match) = @_;
930 $screen->debug('handler_paste', 'started');
935 if ($config->{setting}{multiplexer} eq 'screen') {
936 $screen->debug('handler_paste', 'using screen');
937 @cmd = qw( screen -X paste . );
938 } elsif ($config->{setting}{multiplexer} eq 'tmux') {
939 $screen->debug('handler_paste', 'using tmux');
940 @cmd = qw( tmux paste-buffer );
942 die 'unsupported multiplexer';
945 run_in_background($screen, sub {
946 # We need to get the data in the paste buffer before we can paste
948 handler_yank($screen, $config, $match);
950 # Sleep until we switch back to the current window.
951 Time::HiRes::usleep($config->{setting}{paste_sleep});
953 run_command($screen, \@cmd);
958 my ($screen, $config, $match) = @_;
960 $screen->debug('handler_url', "opening $match->{value}");
962 run_in_background($screen, sub {
963 my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
964 run_command($screen, \@cmd);
971 # CONFIGURATION DEFAULTS
975 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
976 is a normal Perl script with all of Perl's usual features.
978 All configuration values are stored in the hash C<%config>. All manually
979 defined keys overwrite the default settings.
981 A simple F<~/.fcscsrc> could look like this (for details about the used
987 use Curses; # for COLOR_* and A_* constants
991 # Draw matches in blue.
992 $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
993 # Draw numbers in bold yellow.
994 $config{attribute}{match_id} = color_pair(COLOR_YELLOW, -1)
996 # Disable Vim-like 'smartcase', ignore case until an upper character is
998 $config{setting}{smartcase} = 0;
1000 # Use chromium to open URLs if running under X, elinks otherwise.
1001 if (defined $ENV{DISPLAY}) {
1002 $config{setting}{browser} = ['chromium'];
1004 $config{setting}{browser} = ['elinks', '-remote'];
1007 # Let fcscs know the file was loaded successfully.
1015 Pod::Usage::pod2usage(2);
1019 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
1020 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
1022 my $screen = Screen->init($encoding);
1024 # We must restore the screen before exiting.
1025 local $SIG{INT} = sub {
1029 # Make all warnings fatal to make sure they don't get lost (stderr is normally
1031 local $SIG{__WARN__} = sub {
1032 $screen->die('warning', @_);
1039 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
1040 selection and may receive additional input (e.g. a search string) and simple
1041 mappings which only change some config value. Mode mappings are configured via
1042 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
1044 The following mode mappings are available by default (the function to remap
1045 them in parentheses):
1049 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1051 =item B<u> select URLs (C<\&mapping_mode_url>)
1053 =item B<i> select IPv4 and IPv6 addresses (C<\&mapping_mode_ip>)
1055 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1057 =item B<q> quit fcscs (C<\&mapping_quit>)
1061 The following simple mappings are available by default:
1065 =item B<p> enable pasting (C<\&mapping_paste>)
1067 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1071 Note that yanking only uses the GNU screen or Tmux paste buffer by default. To
1072 also copy to X11 selection, enable the B<yank_x11> option.
1074 The following additional mappings are available by default:
1078 =item B<\n> accept current selection (not customizable)
1080 =item B<s> additional key to accept selection (B<alternative_return> option)
1084 All (single-byte) keys except numbers, backspace and return can be mapped.
1086 Unknown mappings are ignored when pressing keys.
1088 To remove a default mapping, delete it from the mapping hash.
1092 # Map 'p' to select paths, 'P' to enable pasting.
1093 $config{mapping}{mode}{p} = \&mapping_mode_path;
1094 $config{mapping}{simple}{P} = \&mapping_paste;
1096 # Disable 'f' mapping.
1097 delete $config{mapping}{mode}{f};
1100 my %mapping_mode = (
1101 f => \&mapping_mode_path,
1102 u => \&mapping_mode_url,
1103 i => \&mapping_mode_ip,
1104 '/' => \&mapping_mode_search,
1105 q => \&mapping_quit,
1107 my %mapping_simple = (
1108 p => \&mapping_paste,
1109 y => \&mapping_yank,
1114 Attributes are used to style the output. They must be Curses attributes.
1115 Defaults in parentheses (foreground, background, attribute).
1119 =item B<match_id> attribute for match numbers (red, default, bold)
1121 =item B<match_string> attribute for matches (yellow, default, normal)
1123 =item B<match_last> attribute for the match selected by return (yellow, default, underline)
1125 =item B<prompt_name> attribute for prompt name (standout)
1127 =item B<prompt_flags> attribute for prompt flags (standout)
1133 # Draw prompt flags in bold red with default background color.
1134 $config{attribute}{prompt_flags}
1136 | color_pair(Curses::COLOR_RED, -1);
1140 match_id => $screen->color_pair(Curses::COLOR_RED, -1)
1142 match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1143 match_last => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1144 | Curses::A_UNDERLINE,
1145 prompt_name => Curses::A_STANDOUT,
1146 prompt_flags => Curses::A_STANDOUT,
1151 Defaults in parentheses.
1155 =item B<debug> enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1157 =item B<initial_mode> start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1159 =item B<multiplexer> set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1161 =item B<ignorecase> ignore case when searching (C<0>)
1163 =item B<smartcase> ignore case unless one uppercase character is searched (C<1>)
1165 =item B<yank_x11> copy selection also to X11 primary selection when yanking (C<0>)
1167 =item B<paste_sleep> sleep x us before running paste command (C<100_000>)
1169 =item B<screen_msgwait> GNU Screen's msgwait variable, used when yanking (C<5>)
1171 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1173 =item B<browser> browser command as array reference (C<['x-www-browser']>)
1179 # Select paths on startup instead of URLs.
1180 $config{setting}{initial_mode} = \&mapping_mode_path;
1186 initial_mode => \&mapping_mode_url,
1187 multiplexer => undef,
1191 paste_sleep => 100_000,
1192 screen_msgwait => 5,
1194 alternative_return => 's',
1196 browser => ['x-www-browser'],
1203 =item B<url> used by C<\&mapping_mode_url>
1205 =item B<path> used by C<\&mapping_mode_path>
1207 =item B<ipv4> used by C<\&mapping_mode_ip>
1209 =item B<ipv6> used by C<\&mapping_mode_ip>
1215 # Select all non-whitespace characters when searching for paths.
1216 $config{regex}{path} = qr{(\S+)};
1220 # Taken from urlview's default configuration file, thanks.
1221 url => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1222 path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1223 # IP addresses with optional prefix. Not perfectly accurate but good
1225 ipv4 => qr!\b(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}(?:/\d{1,2})?)\b!,
1226 ipv6 => qr!\b((?:[0-9a-fA-F]{1,4})?(?::+[0-9a-fA-F]{1,4})+(?:/\d{1,3})?)\b!,
1231 Handlers are used to perform actions on the selected string.
1233 The following handlers are available, defaults in parentheses.
1237 =item B<yank> used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1239 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1241 =item B<url> used to open URLs (e.g. in a browser) (C<\&handler_url>)
1243 =item B<ip> used to handle IPs (C<\&handler_yank>)
1249 # Download YouTube videos with a custom wrapper, handle all other URLs
1250 # with the default URL handler.
1251 $config{handler}{url} = sub {
1252 my ($screen, $config, $match) = @_;
1254 if ($match->{value} =~ m{^https://www.youtube.com/}) {
1255 return run_in_background($screen, sub {
1256 run_command($screen, ['youtube-dl-wrapper', $match->{value}]);
1264 yank => \&handler_yank,
1265 paste => \&handler_paste,
1266 url => \&handler_url,
1267 ip => \&handler_yank,
1271 initial => 1, # used by select_match() for 'initial_mode'
1277 # CONFIGURATION "API"
1281 The following functions are available:
1283 color_pair($fg, $bg)
1285 Create a new Curses attribute with the given fore- and background color.
1290 mapping_mode_search()
1296 Used as mappings, see L</MAPPINGS> above.
1302 Used as handler to yank, paste selection or open URL in browser.
1309 Helper functions when writing custom mappings, see the source for details.
1313 # Enhance URL mode by updating the mapping.
1314 $config{mapping}{mode}{u} = sub {
1315 my ($key, $screen, $config, $input) = @_;
1317 # First get matches of normal URL mode.
1318 my $result = mapping_mode_url(@_);
1320 # Add all strings matching "CVE-1234-1234" with URLs pointing to the
1321 # Debian security tracker. "->{value}" is the string which is used as
1322 # result of the match (e.g. the URL in this case).
1323 my @matches = get_regex_matches($input, qr/\b(CVE-\d+-\d+)\b/);
1324 foreach (@matches) {
1325 $_->{value} = "https://security-tracker.debian.org/$_->{string}";
1327 push @{$result->{matches}}, @matches;
1329 # Change all YouTube links to use the custom "youtube" handler (see
1330 # below). This will allow us to automatically open YouTube URLs with a
1331 # custom program, like `youtube-dl` or `mpv`.
1332 foreach (@{$result->{matches}}) {
1333 if ($_->{string} =~ m{^https://www.youtube.com/}) {
1334 $_->{handler} = $config{handler}{youtube};
1340 # Also update initial mode to use our new "URL mode".
1341 $config{setting}{initial_mode} = $config{mapping}{mode}{u};
1343 # Special handler to download YouTube URLs with `youtube-dl`. You could
1344 # also use `mpv` here to immediately play them.
1345 $config{handler}{youtube} = sub {
1346 my ($screen, $config, $match) = @_;
1348 return run_in_background($screen, sub {
1349 run_command($screen, ['youtube-dl', $match->{value}]);
1357 # All variables and functions which are usable by ~/.fcscsrc.
1359 our $screen; # "private"
1362 sub color_pair { return $screen->color_pair(@_); }
1364 sub mapping_mode_path { return main::mapping_mode_path(@_); }
1365 sub mapping_mode_url { return main::mapping_mode_url(@_); }
1366 sub mapping_mode_ip { return main::mapping_mode_ip(@_); }
1367 sub mapping_mode_search { return main::mapping_mode_search(@_); }
1369 sub mapping_paste { return main::mapping_paste(@_); }
1370 sub mapping_yank { return main::mapping_yank(@_); }
1371 sub mapping_quit { return main::mapping_quit(@_); }
1373 sub handler_yank { return main::handler_yank(@_); }
1374 sub handler_paste { return main::handler_paste(@_); }
1375 sub handler_url { return main::handler_url(@_); }
1377 sub debug { return main::debug(@_); }
1379 sub get_regex_matches { return main::get_regex_matches(@_); }
1380 sub select_match { return main::select_match(@_); }
1382 sub run_command { return main::run_command(@_); }
1383 sub run_in_background { return main::run_in_background(@_); }
1385 $Fcscs::screen = $screen;
1391 # Alias %config and %Fcscs::config. %config is less to type.
1393 local *config = \%Fcscs::config;
1395 $config{mapping}{mode} = \%mapping_mode;
1396 $config{mapping}{simple} = \%mapping_simple;
1397 $config{attribute} = \%attribute;
1398 $config{setting} = \%setting;
1399 $config{regex} = \%regex;
1400 $config{handler} = \%handler;
1401 $config{state} = \%state;
1404 my @configs = ("$ENV{HOME}/.fcscsrc",
1405 "$ENV{HOME}/.config/fcscs/fcscsrc");
1406 foreach my $path (@configs) {
1407 my $decoded = $screen->decode($path);
1409 # Load configuration file. Checks have a race condition if the home
1410 # directory is writable by an attacker (but then the user is screwed
1412 next unless -e $path;
1414 $screen->die("Config '$decoded' not owned by current user!");
1416 # Make sure the file is not writable by other users. Doesn't handle
1417 # ACLs and see comment above about race conditions.
1418 my @stat = stat $path or die $!;
1419 my $mode = $stat[2];
1420 if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1421 die "Config '$decoded' must not be writable by other users.";
1424 my $result = do $path;
1426 $screen->die("Failed to parse '$decoded': $@") if $@;
1427 $screen->die("Failed to do '$decoded': $!") unless defined $result;
1428 $screen->die("Failed to run '$decoded'.");
1431 last; # success, don't load more files
1434 $screen->{debug} = $config{setting}{debug};
1440 # Auto-detect current multiplexer.
1441 if (not defined $config{setting}{multiplexer}) {
1442 if (defined $ENV{STY} and defined $ENV{TMUX}) {
1443 die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1444 } elsif (defined $ENV{STY}) {
1445 $config{setting}{multiplexer} = 'screen';
1446 } elsif (defined $ENV{TMUX}) {
1447 $config{setting}{multiplexer} = 'tmux';
1449 die 'No multiplexer found.';
1453 my $binmode = $encoding;
1454 # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1455 # instead of the currently active encoding.
1456 if ($config{setting}{multiplexer} eq 'screen') {
1457 $binmode = 'ISO-8859-1';
1461 open my $fh, '<', $ARGV[0] or die $!;
1462 binmode $fh, ":encoding($binmode)" or die $!;
1465 push @input_lines, $_;
1467 close $fh or die $!;
1469 my $input = prepare_input($screen, \@input_lines);
1471 # Display original screen content.
1473 foreach (@{$input->{lines}}) {
1474 $screen->draw_simple($y++, 0, undef, $_);
1479 my $mapping = $config{setting}{initial_mode};
1483 if (not defined $mapping) {
1484 $key = $screen->getch unless defined $key;
1485 $screen->debug('input', "got key '$key'");
1487 $mapping = $config{mapping}{mode}{$key};
1488 $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1489 if (not defined $mapping) { # ignore unknown mappings
1495 $screen->debug('input', 'running mapping');
1496 my $result = $mapping->($key, $screen, \%config, $input);
1500 if (defined $result->{quit}) {
1501 $screen->debug('input', 'quitting');
1504 if (defined $result->{key}) {
1505 $key = $result->{key}; # lookup another mapping
1506 $screen->debug('input', "processing new key: '$key'");
1509 if (defined $result->{select}) {
1510 $screen->debug('input', 'selecting match');
1512 $result = select_match($result->{select},
1513 $screen, \%config, $input,
1514 $result->{matches});
1515 $result->{handler} = $tmp->{handler};
1516 $result->{extend} = $tmp->{extend};
1517 goto RESULT; # reprocess special entries in result
1519 if (defined $result->{extend}) {
1520 $screen->debug('input', 'extending match');
1521 $result = extend_match($screen, \%config, $input,
1523 goto RESULT; # reprocess special entries in result
1525 if (defined $result->{match}) {
1526 if (not defined $result->{match}{value}) {
1527 $result->{match}{value} = $result->{match}{string};
1530 $screen->debug('input', 'running handler');
1532 # Choose handler with falling priority.
1534 $config{state}{handler}, # set by user
1535 $result->{match}{handler}, # set by match
1536 $result->{handler}, # set by mapping
1537 $config{handler}{yank}, # fallback
1539 foreach my $handler (@handlers) {
1540 next unless defined $handler;
1542 $handler->($screen, \%config, $result->{match});
1548 $key = undef; # get next key from user
1573 Invalid arguments/options.
1579 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1581 =head1 LICENSE AND COPYRIGHT
1583 Copyright (C) 2013-2016 by Simon Ruderich
1585 This program is free software: you can redistribute it and/or modify
1586 it under the terms of the GNU General Public License as published by
1587 the Free Software Foundation, either version 3 of the License, or
1588 (at your option) any later version.
1590 This program is distributed in the hope that it will be useful,
1591 but WITHOUT ANY WARRANTY; without even the implied warranty of
1592 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
1593 GNU General Public License for more details.
1595 You should have received a copy of the GNU General Public License
1596 along with this program. If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1600 L<screen(1)>, L<tmux(1)>, L<urlview(1)>