bin/fcscs

   1 #!/usr/bin/perl
   2
   3 # fcscs - fast curses screen content select
   4
   5 # Copyright (C) 2013-2016  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use v5.10; # say, state
  25
  26 use Encode ();
  27 use Fcntl ();
  28 use I18N::Langinfo ();
  29
  30 use Curses ();
  31
  32 our $VERSION = '0.01';
  33
  34
  35 =head1 NAME
  36
  37 fcscs - fast curses screen content select
  38
  39 =head1 SYNOPSIS
  40
  41 B<fcscs> [I<options>] I<path/to/screen/capture/file>
  42
  43 =head1 DESCRIPTION
  44
  45 B<fcscs> is a small tool which allows quick selection of terminal screen
  46 contents (like URLs, paths, regex matches, etc.) and passes the selection to
  47 GNU Screen's or Tmux's buffer or any other program. The selection can then
  48 quickly be pasted, e.g. in the shell. Requires GNU Screen or Tmux. It's
  49 licensed under the GPL 3 or later.
  50
  51 =head1 OPTIONS
  52
  53 None so far.
  54
  55 =head1 USAGE
  56
  57 Short overview of the general usage, details below:
  58
  59     - start fcscs
  60     - configure actions (optional)
  61         - enable pasting
  62         - ...
  63     - select mode (optional, URL mode is used on startup):
  64         - f: file paths
  65         - u: URLs
  66         - ...
  67         - /: search mode
  68     - for `normal' modes:
  69         - select match by displayed number or <return> for lowest numbered
  70           match
  71         - configured action is run, e.g. URL is opened with browser
  72     - for `search' mode:
  73         - perform incremental search
  74         - on <return> go to `normal' mode to select a match
  75         - after the match is selected wait for confirmation or extension
  76         - confirmation: <return> run previously selected action
  77         - extension: change match, e.g. select complete word or line
  78
  79 GNU Screen setup (add to F<~/.screenrc>):
  80
  81     bind ^B eval "hardcopy $HOME/.tmp/screen-fcscs" "screen fcscs $HOME/.tmp/screen-fcscs"
  82
  83 Tmux setup (add to F<~/.tmux.conf>):
  84
  85     bind-key C-b capture-pane \; save-buffer ~/.tmp/tmux-fcscs \; delete-buffer \; new-window "fcscs ~/.tmp/tmux-fcscs"
  86
  87 This requires a writable ~/.tmp directory. Adapt the mapping according to your
  88 preferences. Ensure these files are not readable by others as they can contain
  89 private data (umask or protected directory). B<fcscs> must be in your C<$PATH>
  90 for the above mappings to work.
  91
  92 Pressing the configured mapping (Prefix Ctrl-B in this example) opens B<fcscs>
  93 in a new GNU screen/Tmux window. After selection, the content is either passed
  94 to external programs (e.g. for URLs) or copied to the paste buffer or directly
  95 pasted in your previous window and the new window is closed.
  96
  97 To select a match just type its number. If the match is unique, the entry is
  98 automatically selected (e.g. you press 2 and there are only 19 matches). If
  99 there are multiple matches left (e.g. you press 1 and there are more than ten
 100 matches available), press return to select the current match (1 in this case)
 101 or another number to select the longer match. Use backspace to remove the last
 102 entered number.
 103
 104 Press return before entering a number to select the last (lowest numbered)
 105 match (underlined by default). To abort without selecting any match use "q".
 106
 107 To change the selection mode (e.g. paths, files, etc.) use one of the mappings
 108 explained below. Per default URLs are selected, see options for a way to
 109 change this.
 110
 111 I<NOTE>: Opening URLs in the browser passes the URL via the command line which
 112 leaks URLs to other users on the current system via C<ps aux> or C<top>.
 113
 114 I<NOTE>: When yanking (copying) a temporary file is used to pass the data to
 115 GNU screen/Tmux without exposing it to C<ps aux> or C<top>. However this may
 116 leak data if those temporary files are written to disk. To prevent this change
 117 your C<$TMP> to point to a memory-only location or encrypted storage.
 118
 119 If no window appears, try running B<fcscs> manually to catch the error message
 120 and please report the bug:
 121
 122     fcscs /path/to/screen-or-tmux-fcscs-file
 123
 124
 125 =head1 MODES
 126
 127 =cut
 128
 129
 130 # CLASSES
 131
 132 # Helper class for drawing on the screen using Curses.
 133 package Screen {
 134     sub init {
 135         my ($class, $encoding) = @_;
 136
 137         # Prefer strict UTF-8 handling (see perldoc Encode); just in case.
 138         if (lc $encoding eq 'utf8') {
 139             $encoding = 'UTF-8';
 140         }
 141         # Get Encode object to speed up decode()/encode().
 142         my $encoding_object = Encode::find_encoding($encoding);
 143         die "unsupported encoding '$encoding'" unless ref $encoding_object;
 144
 145         my $curses = Curses->new or die $!;
 146
 147         my $self = {
 148             encoding        => $encoding,
 149             encoding_object => $encoding_object,
 150             curses          => $curses,
 151             debug           => 0,
 152             prompt          => {
 153                 flags => undef,
 154                 name  => undef,
 155                 value => undef,
 156             },
 157         };
 158         bless $self, $class;
 159
 160         Curses::start_color;
 161         # Allow default colors by passing -1 to init_pair. A default color is
 162         # not drawn on screen thus allowing terminals with pseudo-transparency
 163         # to use the transparent background in place of the default color.
 164         Curses::use_default_colors;
 165
 166         Curses::cbreak;
 167         Curses::noecho;
 168         $self->cursor(0);
 169
 170         return $self;
 171     }
 172     sub deinit {
 173         my ($self) = @_;
 174
 175         Curses::nocbreak;
 176         Curses::echo;
 177         $self->cursor(1);
 178
 179         Curses::endwin;
 180         return;
 181     }
 182
 183     # Convert between Perl's internal encoding and the terminal's encoding.
 184     sub encode {
 185         my ($self, $string) = @_;
 186         return $self->{encoding_object}->encode($string);
 187     }
 188     sub decode {
 189         my ($self, $string) = @_;
 190         return eval { # returns undef on decode failure
 191             $self->{encoding_object}->decode($string, Encode::FB_CROAK);
 192         };
 193     }
 194
 195     # Create attribute for the given fore-/background colors.
 196     sub color_pair {
 197         my ($self, $fg, $bg) = @_;
 198
 199         state $next_color_pair = 1; # must start at 1 for init_pair()
 200
 201         Curses::init_pair($next_color_pair, $fg, $bg);
 202         return Curses::COLOR_PAIR($next_color_pair++);
 203     }
 204
 205     # Draw a string which must fit in the current line. Wrapping/clipping is
 206     # not supported and must be handled by the caller.
 207     sub draw_simple {
 208         my ($self, $y, $x, $attributes, $string) = @_;
 209
 210         die if $string =~ /\n/;
 211         # FIXME: wide characters
 212         die if $x + length $string > $self->width;
 213
 214         $self->{curses}->attron($attributes) if defined $attributes;
 215         $self->{curses}->addstr($y, $x, $self->encode($string));
 216         $self->{curses}->attroff($attributes) if defined $attributes;
 217         return;
 218     }
 219     # Like draw_simple(), but the string is automatically clipped.
 220     sub draw_clipped {
 221         my ($self, $y, $x, $attributes, $string) = @_;
 222
 223         # FIXME: wide characters
 224         $string = substr $string, 0, $self->width - $x;
 225         $self->draw_simple($y, $x, $attributes, $string);
 226         return;
 227     }
 228     sub draw {
 229         my ($self, $y, $x, $attributes, $string) = @_;
 230
 231         die unless defined $string;
 232
 233         while (1) {
 234             my $offset;
 235             # We must print each line separately. Search for next newline or
 236             # line end, whichever is closer.
 237             if ($string =~ /\n/) {
 238                 $offset = $-[0];
 239             }
 240             # FIXME: wide characters
 241             if ($x + length $string > $self->width) {
 242                 my $new_offset = $self->width - $x;
 243                 if (not defined $offset or $offset > $new_offset) {
 244                     $offset = $new_offset;
 245                 }
 246             }
 247             last unless defined $offset;
 248
 249             # FIXME: wide characters
 250             $self->draw_simple($y, $x, $attributes, substr $string, 0, $offset);
 251
 252             # Don't draw "\n" itself.
 253             if ("\n" eq substr $string, $offset, 1) {
 254                 $offset++;
 255             }
 256
 257             $string = substr $string, $offset;
 258
 259             $y++;
 260             $x = 0;
 261         }
 262
 263         $self->draw_simple($y, $x, $attributes, $string);
 264         return $y;
 265     }
 266
 267     sub draw_prompt {
 268         my ($self, $config) = @_;
 269
 270         $self->debug('draw_prompt', 'started');
 271
 272         my $x = 0;
 273         my $y = $self->height - 1;
 274
 275         # Clear line for better visibility.
 276         $self->draw_simple($y, $x, undef, ' ' x $self->width);
 277
 278         # Draw prompt flags.
 279         if (defined (my $s = $self->{prompt}{flags})) {
 280             $s = "[$s]";
 281             $self->debug('draw_prompt', $s);
 282             $self->draw_clipped($y, $x, $config->{attribute}{prompt_flags}, $s);
 283             $x += length($s) + 1; # space between next element
 284         }
 285         # Draw prompt name.
 286         if (defined (my $s = $self->{prompt}{name})) {
 287             $s = "[$s]";
 288             $self->debug('draw_prompt', $s);
 289             $self->draw_clipped($y, $x, $config->{attribute}{prompt_name}, $s);
 290             $x += length($s) + 1;
 291         }
 292         # Draw prompt value, e.g. a search field.
 293         if (defined (my $s = $self->{prompt}{value})) {
 294             $self->debug('draw_prompt', $s);
 295             $self->draw_clipped($y, $x, undef, $s);
 296             $x += length($s) + 1;
 297         }
 298         return;
 299     }
 300
 301     sub draw_matches {
 302         my ($self, $config, $matches_remove, $matches_add) = @_;
 303
 304         foreach (@{$matches_remove}) {
 305             $self->draw($_->{y}, $_->{x}, Curses::A_NORMAL, $_->{string});
 306         }
 307
 308         my $attr_id     = $config->{attribute}{match_id};
 309         my $attr_string = $config->{attribute}{match_string};
 310         my $attr_last   = $config->{attribute}{match_last};
 311
 312         foreach (@{$matches_add}) {
 313             my $attr = (defined $_->{id} and $_->{id} == 1)
 314                      ? $attr_last
 315                      : $attr_string;
 316             $self->draw($_->{y}, $_->{x}, $attr, $_->{string});
 317             if (defined $_->{id}) {
 318                 $self->draw($_->{y}, $_->{x}, $attr_id, $_->{id});
 319             }
 320         }
 321         return;
 322     }
 323
 324     sub die {
 325         my ($self, @args) = @_;
 326
 327         my $attr = $self->color_pair(Curses::COLOR_RED, -1) | Curses::A_BOLD;
 328
 329         # Clear the screen to improve visibility of the error message.
 330         $self->{curses}->clear;
 331
 332         my $y = $self->draw(0, 0, $attr, "@args");
 333
 334         if ($self->{debug}) {
 335             my $msg;
 336             eval {
 337                 require Devel::StackTrace;
 338             };
 339             if ($@) {
 340                 $msg = "Devel::StackTrace missing, no stack trace.\n";
 341             } else {
 342                 my $trace = Devel::StackTrace->new;
 343                 $msg = "Stack trace:\n" . $trace->as_string;
 344             }
 345             $y = $self->draw($y + 1, 0, Curses::A_NORMAL, $msg);
 346         }
 347
 348         $self->draw($y + 1, 0, Curses::A_NORMAL,
 349                     'Press any key to terminate fcscs.');
 350         $self->refresh;
 351
 352         $self->getch;
 353         $self->deinit;
 354         exit 1;
 355     }
 356     sub debug {
 357         my ($self, $module, @args) = @_;
 358
 359         return if not $self->{debug};
 360
 361         state $fh; # only open the file once per run
 362         if (not defined $fh) {
 363             # Ignore errors if the directory doesn't exist.
 364             if (not open $fh, '>', "$ENV{HOME}/.config/fcscs/log") {
 365                 $fh = undef; # a failed open still writes a value to $fh
 366                 return;
 367             }
 368         }
 369
 370         foreach (@args) {
 371             $_ = $self->encode($_);
 372         }
 373         say $fh "$module: @args";
 374         return;
 375     }
 376
 377
 378     sub prompt {
 379         my ($self, %settings) = @_;
 380
 381         foreach (keys %settings) {
 382             CORE::die if not exists $self->{prompt}{$_};
 383             $self->{prompt}{$_} = $settings{$_};
 384         }
 385         return;
 386     }
 387
 388     # Wrapper for Curses.
 389     sub width   { return $Curses::COLS; }
 390     sub height  { return $Curses::LINES; }
 391     sub refresh { return $_[0]->{curses}->refresh; }
 392     sub getch   { return $_[0]->{curses}->getch; }
 393     sub cursor  { Curses::curs_set($_[1]); return; }
 394 }
 395
 396
 397
 398 # FUNCTIONS
 399
 400 sub prepare_input {
 401     my ($screen, $input_ref) = @_;
 402
 403     # Make sure the input fits on the screen by removing the top lines if
 404     # necessary.
 405     splice @{$input_ref}, 0, -$screen->height;
 406
 407     # Pad each line with spaces to the screen width to correctly handle
 408     # multi-line regexes.
 409     # FIXME: wide characters
 410     my @padded = map { sprintf '%-*s', $screen->width, $_ } @{$input_ref};
 411
 412     my $string = join "\n", @padded;
 413     return {
 414         string => $string,
 415         lines  => $input_ref,
 416         width  => $screen->width + 1,
 417                   # + 1 = "\n", used in input_match_offset_to_coordinates
 418     };
 419 }
 420
 421 sub input_match_offset_to_coordinates {
 422     my ($width, $offset) = @_;
 423
 424     die unless defined $offset;
 425
 426     my $y = int($offset / $width);
 427     my $x = $offset - $y * $width;
 428     return ($x, $y);
 429 }
 430
 431 sub get_regex_matches {
 432     my ($input, $regex) = @_;
 433
 434     my @matches;
 435     while ($input->{string} =~ /$regex/g) {
 436         my $offset = $-[1];
 437         die "Match group required in regex '$regex'" if not defined $offset;
 438
 439         my ($x, $y) = input_match_offset_to_coordinates($input->{width},
 440                                                         $offset);
 441         push @matches, { x => $x, y => $y, offset => $offset, string => $1 };
 442     }
 443     return @matches;
 444 }
 445
 446
 447 sub run_command {
 448     my ($screen, $config, $cmd) = @_;
 449
 450     $screen->debug('run_command', "running @{$cmd}");
 451
 452     my $exit = do {
 453         # Perl's system() combined with a $SIG{__WARN__} which die()s has
 454         # issues due to the fork. The die() in the __WARN__ handler doesn't
 455         # die but the program continues after the system().
 456         #
 457         # If the forked process fails to exec (e.g. program not found) then
 458         # the __WARN__ handler is called (because a warning is about to be
 459         # displayed) and the die() should display a message and terminate the
 460         # process. But due to the fork it doesn't terminate the parent process
 461         # and instead changes the return value of system(); it's no longer -1
 462         # which makes it impossible to detect that case.
 463         #
 464         # Perl < 5.18 (found in 5.14) doesn't setup $$ during system() which
 465         # makes it impossible to detect if the handler was called from inside
 466         # the child.
 467         #
 468         # Instead, just ignore any warnings during the system(). Thanks to
 469         # mauke in #perl on Freenode (2013-10-29 23:30 CET) for the idea to
 470         # use no warnings and anno for testing a more recent Perl version with
 471         # a working $$.
 472         no warnings;
 473
 474         my @cmd = map { $screen->encode($_) } @{$cmd};
 475         system { $cmd[0] } @cmd;
 476     };
 477     if ($exit != 0) {
 478         my $msg;
 479         if ($? == -1) {
 480             $msg = 'failed to execute: ' . $!;
 481         } elsif ($? & 127) {
 482             $msg = 'killed by signal ' . ($? & 127);
 483         } else {
 484             $msg = 'exited with code ' . ($? >> 8);
 485         }
 486         die "system(@{$cmd}) $msg.";
 487     }
 488     return;
 489 }
 490 sub run_in_background {
 491     my ($screen, $sub) = @_;
 492
 493     $screen->debug('run_in_background', "running $sub");
 494
 495     my $pid = fork;
 496     defined $pid or die $!;
 497
 498     if ($pid == 0) {
 499         # The terminal multiplexer sends a SIGHUP to the process when it
 500         # closes the window (because the parent process has exited).
 501         local $SIG{HUP} = 'IGNORE';
 502
 503         # Necessary for GNU screen or it'll keep the window open until an
 504         # external command has run.
 505         close STDIN  or die $!;
 506         close STDOUT or die $!;
 507         close STDERR or die $!;
 508
 509         # Double-fork to prevent zombies.
 510         my $pid = fork;
 511         defined $pid or die $!;
 512         if ($pid == 0) { # child
 513             $sub->();
 514         }
 515         exit;
 516     }
 517     waitpid $pid, 0 or die $!;
 518     return;
 519 }
 520
 521
 522 sub select_match {
 523     my ($name, $screen, $config, $input, $matches) = @_;
 524
 525     $screen->debug('select_match', 'started');
 526
 527     return if @{$matches} == 0;
 528     # Don't return on initial run to give the user a chance to select another
 529     # mode, e.g. to switch from URL selection to search selection.
 530     if (@{$matches} == 1 and not $config->{state}{initial}) {
 531         return { match => $matches->[0] };
 532     }
 533     $config->{state}{initial} = 0;
 534
 535     my @sorted = sort { $b->{y} <=> $a->{y} or $b->{x} <=> $a->{x} } @{$matches};
 536
 537     my $i = 1;
 538     foreach (@sorted) {
 539         $_->{id} = $i++;
 540     }
 541
 542     $screen->prompt(name => $name, value => undef);
 543     $screen->draw_prompt($config);
 544
 545     $screen->draw_matches($config, [], $matches);
 546     $screen->refresh;
 547
 548     my $number = 0;
 549     while (1) {
 550         my $char = $screen->getch;
 551         if ($char =~ /^\d$/) {
 552             $number = $number * 10 + $char;
 553         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 554             $number = int($number / 10);
 555         } elsif ($char eq "\n"
 556                 or $char eq $config->{setting}{alternative_return}) {
 557             if ($number == 0) { # number without selection matches last entry
 558                 $number = 1;
 559             }
 560             last;
 561
 562         # Selecting a new mode requires falling through into the main input
 563         # loop and then starting the new mode.
 564         } elsif (defined $config->{mapping}{mode}{$char}) {
 565             $screen->draw_matches($config, $matches, []); # clear matches
 566             return { key => $char };
 567         # All other mappings stay in the current mode.
 568         } elsif (defined (my $m = $config->{mapping}{simple}{$char})) {
 569             $m->($char, $screen, $config, $input);
 570             next;
 571
 572         } else {
 573             next; # ignore unknown mappings
 574         }
 575
 576         last if $number > 0 and $number * 10 > @{$matches}; # unique match
 577
 578         my @remaining = $number == 0
 579                       ? @{$matches}
 580                       : grep { $_->{id} =~ /^$number/ } @{$matches};
 581         $screen->draw_matches($config, $matches, \@remaining);
 582         $screen->refresh;
 583     }
 584
 585     $screen->draw_matches($config, $matches, []); # remove matches
 586
 587     foreach (@{$matches}) {
 588         return { match => $_ } if $_->{id} == $number;
 589     }
 590     $screen->debug('select_match', 'no match selected');
 591     return { match => undef };
 592 }
 593
 594 sub extend_match_regex_left {
 595     my ($line, $match, $regex) = @_;
 596
 597     my $s = reverse substr $line, 0, $match->{x};
 598     if ($s =~ /^($regex)/) {
 599         $match->{string}  = reverse($1) . $match->{string};
 600         $match->{x}      -= length $1;
 601         $match->{offset} -= length $1;
 602     }
 603     return;
 604 }
 605 sub extend_match_regex_right {
 606     my ($line, $match, $regex) = @_;
 607
 608     my $s = substr $line, $match->{x} + length $match->{string};
 609     if ($s =~ /^($regex)/) {
 610         $match->{string} .= $1;
 611     }
 612     return;
 613 }
 614 sub extend_match {
 615     my ($screen, $config, $input, $match) = @_;
 616
 617     $screen->debug('extend_match', 'started');
 618
 619     return if not defined $match;
 620
 621     $screen->prompt(name => 'extend', value => undef);
 622     $screen->draw_prompt($config);
 623
 624     delete $match->{id}; # don't draw any match ids
 625     $screen->draw_matches($config, [], [$match]);
 626     $screen->refresh;
 627
 628     my $line = $input->{lines}[$match->{y}];
 629
 630     while (1) {
 631         my $match_old = \%{$match};
 632
 633         my $char = $screen->getch;
 634         if ($char eq "\n"
 635                 or $char eq $config->{setting}{alternative_return}) {
 636             last; # accept match
 637
 638         } elsif ($char eq 'w') { # select current word (both directions)
 639             extend_match_regex_left($line,  $match, qr/\w+/);
 640             extend_match_regex_right($line, $match, qr/\w+/);
 641         } elsif ($char eq 'b') { # select current word (only left)
 642             extend_match_regex_left($line,  $match, qr/\w+/);
 643         } elsif ($char eq 'e') { # select current word (only right)
 644             extend_match_regex_right($line, $match, qr/\w+/);
 645
 646         } elsif ($char eq 'W') { # select current WORD (both directions)
 647             extend_match_regex_left($line,  $match, qr/\S+/);
 648             extend_match_regex_right($line, $match, qr/\S+/);
 649         } elsif ($char eq 'B') { # select current WORD (only left)
 650             extend_match_regex_left($line,  $match, qr/\S+/);
 651         } elsif ($char eq 'E') { # select current WORD (only right)
 652             extend_match_regex_right($line, $match, qr/\S+/);
 653
 654         } elsif ($char eq '0') { # select to beginning of line
 655             extend_match_regex_left($line, $match, qr/.+/);
 656         } elsif ($char eq '$') { # select to end of line
 657             extend_match_regex_right($line, $match, qr/.+/);
 658
 659         # Allow mode changes if not overwritten by local mappings.
 660         } elsif (defined $config->{mapping}{mode}{$char}) {
 661             $screen->draw_matches($config, [$match_old], []); # clear match
 662             return { key => $char };
 663
 664         } else {
 665             next; # ignore unknown mappings
 666         }
 667
 668         $screen->draw_matches($config, [$match_old], [$match]);
 669         $screen->refresh;
 670     }
 671
 672     $screen->debug('extend_match', 'done');
 673
 674     return { match => $match };
 675 }
 676
 677
 678 sub mapping_paste {
 679     my ($key, $screen, $config, $input) = @_;
 680
 681     $screen->debug('mapping_paste', 'started');
 682
 683     $config->{state}{handler} = $config->{handler}{paste};
 684
 685     $screen->prompt(flags => 'P'); # paste
 686     $screen->draw_prompt($config);
 687     $screen->refresh;
 688
 689     return {};
 690 }
 691 sub mapping_yank {
 692     my ($key, $screen, $config, $input) = @_;
 693
 694     $screen->debug('mapping_yank', 'started');
 695
 696     $config->{state}{handler} = $config->{handler}{yank};
 697
 698     $screen->prompt(flags => 'Y'); # yank
 699     $screen->draw_prompt($config);
 700     $screen->refresh;
 701
 702     return {};
 703 }
 704
 705
 706 =head2 NORMAL MODES
 707
 708 Normal modes select matches by calling a function which returns them, e.g. by
 709 using a regex.
 710
 711 The following normal modes are available:
 712
 713 =over 4
 714
 715 =item B<path mode> select relative/absolute paths
 716
 717 =item B<url mode>  select URLs
 718
 719 =back
 720
 721 =cut
 722 sub mapping_mode_path {
 723     my ($key, $screen, $config, $input) = @_;
 724
 725     $screen->debug('mapping_mode_path', 'started');
 726
 727     my @matches = get_regex_matches($input, $config->{regex}{path});
 728     return {
 729         select  => 'path select',
 730         matches => \@matches,
 731         handler => $config->{handler}{yank},
 732     };
 733 }
 734 sub mapping_mode_url {
 735     my ($key, $screen, $config, $input) = @_;
 736
 737     $screen->debug('mapping_mode_url', 'started');
 738
 739     my @matches = get_regex_matches($input, $config->{regex}{url});
 740     return {
 741         select  => 'url select',
 742         matches => \@matches,
 743         handler => $config->{handler}{url},
 744     };
 745 }
 746
 747 =head2 SEARCH MODE (AND EXTEND MODE)
 748
 749 Search mode is a special mode which lets you type a search string (a Perl
 750 regex) and then select one of the matches. Afterwards you can extend the
 751 match. For example select the complete word or to the end of the line. This
 752 allows quick selection of arbitrary text.
 753
 754 The following mappings are available during the extension mode (not
 755 configurable at the moment):
 756
 757 =over 4
 758
 759 =item B<w> select current word
 760
 761 =item B<b> extend word to the left
 762
 763 =item B<e> extend word to the right
 764
 765 =item B<W> select current WORD
 766
 767 =item B<B> extend WORD to the left
 768
 769 =item B<E> extend WORD to the right
 770
 771 =item B<0> extend to beginning of line
 772
 773 =item B<$> extend to end of line
 774
 775 =back
 776
 777 C<word> includes any characters matching C<\w+>, C<WORD> any non-whitespace
 778 characters (C<\S+>), just like in Vim.
 779
 780 =cut
 781 sub mapping_mode_search {
 782     my ($key, $screen, $config, $input) = @_;
 783
 784     $screen->debug('mapping_mode_search', 'started');
 785
 786     $screen->cursor(1);
 787
 788     my $search = ''; # encoded
 789     my @last_matches;
 790     while (1) {
 791         # getch doesn't return decoded characters but raw input bytes. Wait
 792         # until the input character is complete.
 793         my $value = $screen->decode($search);
 794         $value = '' unless defined $value; # undef on decode failure
 795
 796         $screen->prompt(name => 'search', value => $value);
 797         $screen->draw_prompt($config);
 798         $screen->refresh;
 799
 800         my $char = $screen->getch;
 801         # TODO: readline editing support
 802         if ($char eq "\n") {
 803             last;
 804         } elsif ($char eq "\b" or $char eq "\x7f") { # backspace
 805             # Remove a character, not a byte.
 806             $search = $screen->decode($search);
 807             chop $search;
 808             $search = $screen->encode($search);
 809         } else {
 810             $search .= $char;
 811             next unless defined $screen->decode($search);
 812         }
 813
 814         my @matches;
 815         if ($search ne '') {
 816             my $case = '';
 817             if (($config->{setting}{smartcase} and $search eq lc $search)
 818                     or $config->{setting}{ignorecase}) {
 819                 $case = '(?i)';
 820             }
 821             # Ignore invalid regexps.
 822             # TODO: display warning on error?
 823             eval {
 824                 @matches = get_regex_matches($input, qr/($case$search)/);
 825             };
 826         }
 827         $screen->draw_matches($config, \@last_matches, \@matches);
 828         @last_matches = @matches;
 829     }
 830
 831     $screen->cursor(0);
 832
 833     return {
 834         select  => 'search',
 835         matches => \@last_matches,
 836         extend  => 1,
 837         handler => $config->{handler}{yank},
 838     };
 839 }
 840
 841 sub mapping_quit {
 842     my ($key, $screen, $config, $input) = @_;
 843
 844     # Key is necessary to fall through to main event loop which then quits.
 845     return { key => $key, quit => 1 };
 846 }
 847
 848
 849 sub handler_yank {
 850     my ($screen, $config, $match) = @_;
 851
 852     $screen->debug('handler_yank', 'started');
 853
 854     require File::Temp;
 855
 856     # Use a temporary file to prevent leaking the yanked data to other users
 857     # with the command line, e.g. ps aux or top.
 858     my ($fh, $tmp) = File::Temp::tempfile(); # dies on its own
 859     print $fh $screen->encode($match->{value});
 860     close $fh or die $!;
 861
 862     if ($config->{setting}{multiplexer} eq 'screen') {
 863         $screen->debug('handler_yank', 'using screen');
 864
 865         # GNU screen displays an annoying "Slurping X characters into buffer".
 866         # Use 'msgwait 0' as a hack to disable it.
 867         my $msgwait = $config->{setting}{screen_msgwait};
 868         run_command($screen, $config, ['screen', '-X', 'msgwait', 0]);
 869         run_command($screen, $config, ['screen', '-X', 'readbuf', $tmp]);
 870         run_command($screen, $config, ['screen', '-X', 'msgwait', $msgwait]);
 871     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 872         $screen->debug('handler_yank', 'using tmux');
 873
 874         run_command($screen, $config, ['tmux', 'load-buffer', $tmp]);
 875     } else {
 876         die 'unsupported multiplexer';
 877     }
 878
 879     unlink $tmp or die $!;
 880     return;
 881 }
 882 sub handler_paste {
 883     my ($screen, $config, $match) = @_;
 884
 885     $screen->debug('handler_paste', 'started');
 886
 887     require Time::HiRes;
 888
 889     my @cmd;
 890     if ($config->{setting}{multiplexer} eq 'screen') {
 891         $screen->debug('handler_paste', 'using screen');
 892         @cmd = qw( screen -X paste . );
 893     } elsif ($config->{setting}{multiplexer} eq 'tmux') {
 894         $screen->debug('handler_paste', 'using tmux');
 895         @cmd = qw( tmux paste-buffer );
 896     } else {
 897         die 'unsupported multiplexer';
 898     }
 899
 900     run_in_background($screen, sub {
 901         # We need to get the data in the paste buffer before we can paste
 902         # it.
 903         handler_yank($screen, $config, $match);
 904
 905         # Sleep until we switch back to the current window.
 906         Time::HiRes::usleep($config->{setting}{paste_sleep});
 907
 908         run_command($screen, $config, \@cmd);
 909     });
 910     return;
 911 }
 912 sub handler_url {
 913     my ($screen, $config, $match) = @_;
 914
 915     $screen->debug('handler_url', "opening $match->{value}");
 916
 917     run_in_background($screen, sub {
 918         my @cmd = ( @{$config->{setting}{browser}}, $match->{value} );
 919         run_command($screen, $config, \@cmd);
 920     });
 921     return;
 922 }
 923
 924
 925
 926 # CONFIGURATION DEFAULTS
 927
 928 =head1 CONFIGURATION
 929
 930 fcscs is configured through F<~/.fcscsrc> or F<~/.config/fcscs/fcscsrc> which
 931 is a normal Perl script with all of Perl's usual features.
 932
 933 All configuration values are stored in the hash C<%config>. All manually
 934 defined keys overwrite the default settings.
 935
 936 A simple F<~/.fcscsrc> could look like this (for details about the used
 937 settings see below):
 938
 939     use strict;
 940     use warnings;
 941
 942     use Curses; # for COLOR_* and A_* constants
 943
 944     our %config;
 945
 946     # Draw matches in blue.
 947     $config{attribute}{match_string} = color_pair(COLOR_BLUE, -1);
 948     # Enable Vim-like 'smartcase', ignore case until an upper character is
 949     # searched.
 950     $config{setting}{smartcase} = 1;
 951
 952     # Use chromium to open URLs if running under X, elinks otherwise.
 953     if (defined $ENV{DISPLAY}) {
 954         $config{setting}{browser} = ['chromium'];
 955     } else {
 956         $config{setting}{browser} = ['elinks'];
 957     }
 958
 959     # Let fcscs know the file was loaded successfully.
 960     1;
 961
 962 =cut
 963
 964
 965 if (@ARGV != 1) {
 966     require Pod::Usage;
 967     Pod::Usage::pod2usage(2);
 968 }
 969
 970
 971 # Determine terminal encoding from the environment ($ENV{LANG} or similar).
 972 my $encoding = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET);
 973
 974 my $screen = Screen->init($encoding);
 975
 976 # We must restore the screen before exiting.
 977 local $SIG{INT} = sub {
 978     $screen->deinit;
 979     exit 128 + 2;
 980 };
 981 # Make all warnings fatal to make sure they don't get lost (stderr is normally
 982 # not displayed).
 983 local $SIG{__WARN__} = sub {
 984     $screen->die('warning', @_);
 985 };
 986
 987
 988
 989 =head2 MAPPINGS
 990
 991 I<NOTE>: Mappings are split in two categories: Mode mappings which change the
 992 selection and may receive additional input (e.g. a search string) and simple
 993 mappings which only change some value. Mode mappings are configured via
 994 C<$config{mapping}{mode}>, simple mappings via C<$config{mapping}{simple}>.
 995
 996 The following mode mappings are available by default (the function to remap
 997 them in parentheses):
 998
 999 =over
1000
1001 =item B<f> select absolute/relative paths (C<\&mapping_mode_path>)
1002
1003 =item B<u> select URLs (C<\&mapping_mode_url>)
1004
1005 =item B</> search for regex to get selection (C<\&mapping_mode_search>)
1006
1007 =item B<q> quit fcscs (C<\&mapping_quit>)
1008
1009 =back
1010
1011 The following simple mappings are available by default:
1012
1013 =over
1014
1015 =item B<p> enable pasting (C<\&mapping_paste>)
1016
1017 =item B<y> enable yanking (copying) (C<\&mapping_yank>)
1018
1019 =back
1020
1021 The following additional mappings are available by default:
1022
1023 =over
1024
1025 =item B<\n> accept current selection (not customizable)
1026
1027 =item B<s>  additional key to accept selection (B<alternative_return> option)
1028
1029 =back
1030
1031 All (single-byte) keys except numbers, backspace and return can be mapped.
1032
1033 Unknown mappings are ignored when pressing keys.
1034
1035 To remove a default mapping, delete it from the mapping hash.
1036
1037 Example:
1038
1039     # Map 'p' to select paths, 'P' to enable pasting.
1040     $config{mapping}{mode}{p} = \&mapping_mode_path;
1041     $config{mapping}{simple}{P} = \&mapping_paste;
1042
1043     # Disable 'f' mapping.
1044     delete $config{mapping}{mode}{f};
1045
1046 =cut
1047 my %mapping_mode = (
1048     f   => \&mapping_mode_path,
1049     u   => \&mapping_mode_url,
1050     '/' => \&mapping_mode_search,
1051     q   => \&mapping_quit,
1052 );
1053 my %mapping_simple = (
1054     p => \&mapping_paste,
1055     y => \&mapping_yank,
1056 );
1057
1058 =head2 ATTRIBUTES
1059
1060 Attributes are used to style the output. They must be Curses attributes.
1061 Defaults in parentheses (foreground, background, attribute).
1062
1063 =over
1064
1065 =item B<match_id>      attribute for match numbers (red, default, bold)
1066
1067 =item B<match_string>  attribute for matches (yellow, default, normal)
1068
1069 =item B<match_last>    attribute for the match selected by return (yellow, default, underline)
1070
1071 =item B<prompt_name>   attribute for prompt name (standout)
1072
1073 =item B<prompt_flags>  attribute for prompt flags (standout)
1074
1075 =back
1076
1077 Example:
1078
1079     # Draw prompt flags in bold red with default background color.
1080     $config{attribute}{prompt_flags}
1081         = Curses::A_BOLD
1082         | color_pair(Curses::COLOR_RED, -1);
1083
1084 =cut
1085 my %attribute = (
1086     match_id     => $screen->color_pair(Curses::COLOR_RED, -1)
1087                     | Curses::A_BOLD,
1088     match_string => $screen->color_pair(Curses::COLOR_YELLOW, -1),
1089     match_last   => $screen->color_pair(Curses::COLOR_YELLOW, -1)
1090                     | Curses::A_UNDERLINE,
1091     prompt_name  => Curses::A_STANDOUT,
1092     prompt_flags => Curses::A_STANDOUT,
1093 );
1094
1095 =head2 SETTINGS
1096
1097 Defaults in parentheses.
1098
1099 =over
1100
1101 =item B<debug>          enable debug mode, writes to I<~/.config/fcscs/log> (C<0>)
1102
1103 =item B<initial_mode>   start in this mode, must be a valid mode mapping (C<\&mapping_mode_url>)
1104
1105 =item B<multiplexer>    set multiplexer ("screen" or "tmux") if not autodetected (C<undef>)
1106
1107 =item B<ignorecase>     ignore case when searching (C<0>)
1108
1109 =item B<smartcase>      ignore case unless one uppercase character is searched (C<1>)
1110
1111 =item B<paste_sleep>    sleep x us before running paste command (C<100_000>)
1112
1113 =item B<screen_msgwait> GNU Screen's msgwait variable, used when yanking (C<5>)
1114
1115 =item B<alternative_return> additional accept key like return, set to C<\n> to disable (C<s>)
1116
1117 =item B<browser>        browser command as array reference (C<['x-www-browser']>)
1118
1119 =back
1120
1121 Example:
1122
1123     # Select paths on startup instead of URLs.
1124     $config{setting}{initial_mode} = \&mapping_mode_path;
1125
1126 =cut
1127 my %setting = (
1128     # options
1129     debug          => 0,
1130     initial_mode   => \&mapping_mode_url,
1131     multiplexer    => undef,
1132     ignorecase     => 0,
1133     smartcase      => 1,
1134     paste_sleep    => 100_000,
1135     screen_msgwait => 5,
1136     # global mappings
1137     alternative_return => 's',
1138     # commands
1139     browser        => ['x-www-browser'],
1140 );
1141
1142 =head2 REGEXPS
1143
1144 =over
1145
1146 =item B<url>  used by C<\&mapping_mode_url()>
1147
1148 =item B<path> used by C<\&mapping_mode_path()>
1149
1150 =back
1151
1152 Example:
1153
1154     # Select all non-whitespace characters when searching for paths.
1155     $config{regex}{path} = qr{(\S+)};
1156
1157 =cut
1158 my %regex = (
1159     # Taken from urlview's default configuration file, thanks.
1160     url  => qr{((?:(?:(?:http|https|ftp|gopher)|mailto):(?://)?[^ <>"\t]*|(?:www|ftp)[0-9]?\.[-a-z0-9.]+)[^ .,;\t\n\r<">\):]?[^, <>"\t]*[^ .,;\t\n\r<">\):])},
1161     path => qr{(~?[a-zA-Z0-9_./-]*/[a-zA-Z0-9_./-]+)},
1162 );
1163
1164 =head2 HANDLERS
1165
1166 Handlers are used to perform actions on the selected string.
1167
1168 The following handlers are available, defaults in parentheses.
1169
1170 =over
1171
1172 =item B<yank>  used to yank (copy) selection to paste buffer (C<\&handler_yank>)
1173
1174 =item B<paste> used to paste selection into window (C<\&handler_paste>)
1175
1176 =item B<url>   used to open URLs (e.g. in a browser) (C<\&handler_url>)
1177
1178 =back
1179
1180 Example:
1181
1182     # Download YouTube videos with a custom wrapper, handle all other URLs
1183     # with the default URL handler.
1184     $config{handler}{url} = sub {
1185         my ($screen, $config, $match) = @_;
1186
1187         if ($match->{value} =~ m{^https://www.youtube.com/}) {
1188             return run_in_background($screen, sub {
1189                 run_command($screen, $config,
1190                             ['youtube-dl-wrapper', $match->{value}]);
1191             });
1192         }
1193         handler_url(@_);
1194     };
1195
1196 =cut
1197 my %handler = (
1198     yank  => \&handler_yank,
1199     paste => \&handler_paste,
1200     url   => \&handler_url,
1201 );
1202
1203 my %state = (
1204     initial => 1, # used by select_match() for 'initial_mode'
1205     handler => undef,
1206 );
1207
1208
1209
1210 # CONFIGURATION "API"
1211
1212 =head2 FUNCTIONS
1213
1214 The following functions are available:
1215
1216     color_pair($fg, $bg)
1217
1218 Create a new Curses attribute with the given fore- and background color.
1219
1220     mapping_mode_path()
1221     mapping_mode_url()
1222     mapping_mode_search()
1223
1224     mapping_paste()
1225     mapping_yank()
1226     mapping_quit()
1227
1228 Used as mappings, see L</MAPPINGS> above.
1229
1230     handler_yank()
1231     handler_paste()
1232     handler_url()
1233
1234 Used as handler to yank, paste selection or open URL in browser.
1235
1236     debug()
1237     get_regex_matches()
1238     select_match()
1239     run_command()
1240     run_in_background()
1241
1242 Helper functions when writing custom mappings, see the source for details.
1243
1244 Example:
1245
1246     TODO
1247
1248 =cut
1249
1250 # All variables and functions which are usable by ~/.fcscsrc.
1251 package Fcscs {
1252     our $screen; # "private"
1253     our %config;
1254
1255     sub color_pair { return $screen->color_pair(@_); }
1256
1257     sub mapping_mode_path { return main::mapping_mode_path(@_); }
1258     sub mapping_mode_url { return main::mapping_mode_url(@_); }
1259     sub mapping_mode_search { return main::mapping_mode_search(@_); }
1260
1261     sub mapping_paste { return main::mapping_paste(@_); }
1262     sub mapping_yank { return main::mapping_yank(@_); }
1263     sub mapping_quit { return main::mapping_quit(@_); }
1264
1265     sub handler_yank { return main::handler_yank(@_); }
1266     sub handler_paste { return main::handler_paste(@_); }
1267     sub handler_url { return main::handler_url(@_); }
1268
1269     sub debug { return main::debug(@_); }
1270
1271     sub get_regex_matches { return main::get_regex_matches(@_); }
1272     sub select_match { return main::select_match(@_); }
1273
1274     sub run_command { return main::run_command(@_); }
1275     sub run_in_background { return main::run_in_background(@_); }
1276 }
1277 $Fcscs::screen = $screen;
1278
1279
1280
1281 # LOAD USER CONFIG
1282
1283 # Alias %config and %Fcscs::config. %config is less to type.
1284 our %config;
1285 local *config = \%Fcscs::config;
1286
1287 $config{mapping}{mode}   = \%mapping_mode;
1288 $config{mapping}{simple} = \%mapping_simple;
1289 $config{attribute}       = \%attribute;
1290 $config{setting}         = \%setting;
1291 $config{regex}           = \%regex;
1292 $config{handler}         = \%handler;
1293 $config{state}           = \%state;
1294
1295 package Fcscs {
1296     my @configs = ("$ENV{HOME}/.fcscsrc",
1297                    "$ENV{HOME}/.config/fcscs/fcscsrc");
1298     foreach my $path (@configs) {
1299         my $decoded = $screen->decode($path);
1300
1301         # Load configuration file. Checks have a race condition if the home
1302         # directory is writable by an attacker (but then the user is screwed
1303         # anyway).
1304         next unless -e $path;
1305         if (not -O $path) {
1306             $screen->die("Config '$decoded' not owned by current user!");
1307         }
1308         # Make sure the file is not writable by other users. Doesn't handle
1309         # ACLs and see comment above about race conditions.
1310         my @stat = stat $path or die $!;
1311         my $mode = $stat[2];
1312         if (($mode & Fcntl::S_IWGRP) or ($mode & Fcntl::S_IWOTH)) {
1313             die "Config '$decoded' must not be writable by other users.";
1314         }
1315
1316         my $result = do $path;
1317         if (not $result) {
1318             $screen->die("Failed to parse '$decoded': $@") if $@;
1319             $screen->die("Failed to do '$decoded': $!") unless defined $result;
1320             $screen->die("Failed to run '$decoded'.");
1321         }
1322
1323         last; # success, don't load more files
1324     }
1325 }
1326 $screen->{debug} = $config{setting}{debug};
1327
1328
1329 # MAIN
1330
1331 eval {
1332     # Auto-detect current multiplexer.
1333     if (not defined $config{setting}{multiplexer}) {
1334         if (defined $ENV{STY} and defined $ENV{TMUX}) {
1335             die 'Found both $STY and $TMUX, set $config{setting}{multiplexer}.';
1336         } elsif (defined $ENV{STY}) {
1337             $config{setting}{multiplexer} = 'screen';
1338         } elsif (defined $ENV{TMUX}) {
1339             $config{setting}{multiplexer} = 'tmux';
1340         } else {
1341             die 'No multiplexer found.';
1342         }
1343     }
1344
1345     my $binmode = $encoding;
1346     # GNU screen stores the screen dump for unknown reasons as ISO-8859-1
1347     # instead of the currently active encoding.
1348     if ($config{setting}{multiplexer} eq 'screen') {
1349         $binmode = 'ISO-8859-1';
1350     }
1351
1352     my @input_lines;
1353     open my $fh, '<', $ARGV[0] or die $!;
1354     binmode $fh, ":encoding($binmode)" or die $!;
1355     while (<$fh>) {
1356         chomp;
1357         push @input_lines, $_;
1358     }
1359     close $fh or die $!;
1360
1361     my $input = prepare_input($screen, \@input_lines);
1362
1363     # Display original screen content.
1364     my $y = 0;
1365     foreach (@{$input->{lines}}) {
1366         $screen->draw_simple($y++, 0, undef, $_);
1367     }
1368     $screen->refresh;
1369
1370
1371     my $mapping = $config{setting}{initial_mode};
1372
1373     my $key;
1374     while (1) {
1375         if (not defined $mapping) {
1376             $key = $screen->getch unless defined $key;
1377             $screen->debug('input', "got key '$key'");
1378
1379             $mapping = $config{mapping}{mode}{$key};
1380             $mapping = $config{mapping}{simple}{$key} unless defined $mapping;
1381             if (not defined $mapping) { # ignore unknown mappings
1382                 $key = undef;
1383                 next;
1384             }
1385         }
1386
1387         $screen->debug('input', 'running mapping');
1388         my $result = $mapping->($key, $screen, \%config, $input);
1389         $mapping = undef;
1390
1391 RESULT:
1392         if (defined $result->{quit}) {
1393             $screen->debug('input', 'quitting');
1394             last;
1395         }
1396         if (defined $result->{key}) {
1397             $key = $result->{key}; # lookup another mapping
1398             $screen->debug('input', "processing new key: '$key'");
1399             next;
1400         }
1401         if (defined $result->{select}) {
1402             $screen->debug('input', 'selecting match');
1403             my $tmp = $result;
1404             $result = select_match($result->{select},
1405                                    $screen, \%config, $input,
1406                                    $result->{matches});
1407             $result->{handler} = $tmp->{handler};
1408             $result->{extend}  = $tmp->{extend};
1409             goto RESULT; # reprocess special entries in result
1410         }
1411         if (defined $result->{extend}) {
1412             $screen->debug('input', 'extending match');
1413             $result = extend_match($screen, \%config, $input,
1414                                    $result->{match});
1415             goto RESULT; # reprocess special entries in result
1416         }
1417         if (defined $result->{match}) {
1418             if (not defined $result->{match}{value}) {
1419                 $result->{match}{value} = $result->{match}{string};
1420             }
1421
1422             $screen->debug('input', 'running handler');
1423
1424             # Choose handler with falling priority.
1425             my @handlers = (
1426                 $config{state}{handler},     # set by user
1427                 $result->{match}{handler},   # set by match
1428                 $result->{handler},          # set by mapping
1429                 $config{handler}{yank},      # fallback
1430             );
1431             foreach my $handler (@handlers) {
1432                 next unless defined $handler;
1433
1434                 $handler->($screen, \%config, $result->{match});
1435                 last;
1436             }
1437             last;
1438         }
1439
1440         $key = undef; # get next key from user
1441     }
1442 };
1443 if ($@) {
1444     $screen->die("$@");
1445 }
1446
1447 $screen->deinit;
1448
1449 __END__
1450
1451 =head1 EXIT STATUS
1452
1453 =over 4
1454
1455 =item B<0>
1456
1457 Success.
1458
1459 =item B<1>
1460
1461 An error occurred.
1462
1463 =item B<2>
1464
1465 Invalid arguments/options.
1466
1467 =back
1468
1469 =head1 AUTHOR
1470
1471 Simon Ruderich E<lt>simon@ruderich.orgE<gt>
1472
1473 =head1 LICENSE AND COPYRIGHT
1474
1475 Copyright (C) 2013-2016 by Simon Ruderich
1476
1477 This program is free software: you can redistribute it and/or modify
1478 it under the terms of the GNU General Public License as published by
1479 the Free Software Foundation, either version 3 of the License, or
1480 (at your option) any later version.
1481
1482 This program is distributed in the hope that it will be useful,
1483 but WITHOUT ANY WARRANTY; without even the implied warranty of
1484 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
1485 GNU General Public License for more details.
1486
1487 You should have received a copy of the GNU General Public License
1488 along with this program.  If not, see E<lt>http://www.gnu.org/licenses/E<gt>.
1489
1490 =head1 SEE ALSO
1491
1492 L<screen(1)>, L<tmux(1)>, L<urlview(1)>
1493
1494 =cut