vim/vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2016  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " HELPER FUNCTIONS
  20
  21 if has('eval')
  22 " Check if the given syntax group is available. Thanks to bairui in #vim on
  23 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  24     function! s:HasSyntaxGroup(group)
  25         try
  26             execute 'silent highlight ' . a:group
  27         " \a = [A-Za-z]
  28         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
  29             return 0
  30         endtry
  31         return 1
  32     endfunction
  33
  34 " Check if the given Vim version and patch is available.
  35     function! s:HasVersionAndPatch(version, patch)
  36         return v:version > a:version
  37             \ || (v:version == a:version && has('patch' . a:patch))
  38     endfunction
  39 endif
  40
  41
  42 " EDITOR SETTINGS
  43
  44 " Save 'runtimepath' in case it was changed by the system's configuration
  45 " files. Also save 'diff' as set all& resets it; but somehow later (after
  46 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  47 " automagically restored to the correct value. Not sure what exactly Vim is
  48 " doing there.
  49 if has('eval')
  50     let s:save_runtimepath = &runtimepath
  51     let s:save_diff = &diff
  52 endif
  53 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  54 " system wide configuration file doesn't change default values.
  55 set all&
  56 " And restore it after all other options were reset.
  57 if has('eval')
  58     let &runtimepath = s:save_runtimepath
  59     let &diff = s:save_diff
  60     unlet s:save_runtimepath
  61     unlet s:save_diff
  62 endif
  63
  64 " Make sure Vim (and not Vi) settings are used.
  65 set nocompatible
  66
  67 " Disallow :autocmd, shell and write commands in .vimrc and .exrc files in the
  68 " current directory. Only used if 'exrc' is enabled (off by default),
  69 " precaution just in case somebody enables 'exrc'.
  70 set secure
  71
  72 " Try to use pipes instead of temporary files. Prevents some auto commands
  73 " from running for temporary files but also prevents the file's content to be
  74 " written to disk.
  75 set noshelltemp
  76
  77 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  78 " affect reading files in different encodings, see 'fileencodings' for that.
  79 set encoding=utf-8
  80
  81 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  82 " runtime files) if available.
  83 set runtimepath-=~/.vim
  84 set runtimepath^=~/.vim,~/.vim/runtime
  85
  86 " Don't store swap files in the same directory as the edited file, but only if
  87 " we have a "safe" writable directory available.
  88 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  89     set directory-=.
  90 endif
  91 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  92 set directory^=~/.tmp
  93 " Never use /tmp which gets cleaned on reboot.
  94 set directory-=/tmp
  95
  96 " Disable modelines as they may cause security problems. Instead use
  97 " securemodelines (Vim script #1876).
  98 set nomodeline
  99
 100 " Complete to longest common string (list:longest) and then complete all full
 101 " matches after another (full). Thanks to pbrisbin
 102 " (http://pbrisbin.com:8080/dotfiles/vimrc).
 103 set wildmode=list:longest,full
 104 " Ignore case when completing files/directories.
 105 if exists('+wildignorecase')
 106     set wildignorecase
 107 endif
 108
 109 " Ignore files with the following extensions because I almost never want to
 110 " edit them in Vim (specifying them manually still works of course).
 111 set wildignore=
 112 " C
 113 set wildignore+=*.o,*.d,*.so
 114 " Java
 115 set wildignore+=*.class
 116 " LaTeX
 117 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
 118 " Python
 119 set wildignore+=*.pyc
 120
 121 " Show completion menu even if only one entry matches.
 122 if exists('+completeopt')
 123     set completeopt+=menuone
 124 endif
 125
 126 " Increase history of executed commands (:) and search patterns (/).
 127 set history=1000
 128
 129 " Increase number of possible undos.
 130 set undolevels=1000
 131
 132 " Remember marks (including the last cursor position) for more files. ^= is
 133 " necessary because 'viminfo' is parsed from the beginning and the first match
 134 " is used.
 135 if has('viminfo')
 136     set viminfo^='1000
 137 endif
 138
 139 " Use strong(er) encryption if possible, also used for swap/undo files.
 140 if exists('+cryptmethod')
 141     if s:HasVersionAndPatch(704, 399)
 142         set cryptmethod=blowfish2
 143     else
 144         set cryptmethod=blowfish
 145     endif
 146 endif
 147
 148 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 149 " is used multiple times. Necessary to support reloading the vimrc.
 150 if has('autocmd')
 151     augroup vimrc
 152         autocmd!
 153     augroup END
 154 endif
 155
 156
 157 " TERMINAL SETTINGS
 158
 159 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 160 " connections.
 161 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 162     set ttyfast
 163 endif
 164
 165
 166 " EDIT SETTINGS
 167
 168 " Enable automatic file detection, plugin and indention support.
 169 if has('autocmd')
 170     filetype off " necessary for pathogen to force a reload of ftplugins
 171     filetype plugin indent on
 172 endif
 173
 174 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 175 " existing files.
 176 set fileencodings=utf-8,latin1
 177
 178 " Always use unix line-endings for new files. DOS line endings in existing
 179 " files are recognized.
 180 set fileformats=unix,dos
 181
 182 " Wrap text after 78 characters.
 183 set textwidth=78
 184
 185 " Set tabs to 4 spaces, use softtabs.
 186 set shiftwidth=4
 187 set softtabstop=4
 188 set expandtab
 189 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 190 set shiftround
 191 " Use the default value for real tabs.
 192 set tabstop=8
 193
 194 " Enable auto indention.
 195 set autoindent
 196
 197 " When joining lines only add one space after a sentence.
 198 set nojoinspaces
 199
 200 " Allow backspacing over autoindent and line breaks.
 201 set backspace=indent,eol
 202
 203 " Start a comment when hitting enter after a commented line (r) and when using
 204 " o or O around a commented line (o).
 205 set formatoptions+=ro
 206 " Don't break a line if was already longer then 'textwidth' when insert mode
 207 " started.
 208 set formatoptions+=l
 209 " Remove comment leader when joining lines where it makes sense.
 210 if s:HasVersionAndPatch(703, 541)
 211     set formatoptions+=j
 212 endif
 213
 214 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 215 " no character) in visual block mode.
 216 set virtualedit=block
 217
 218 " Already display matches while typing the search command. This makes spotting
 219 " typos easy and searching faster.
 220 set incsearch
 221
 222 " Activate syntax folding.
 223 if has('folding')
 224     set foldmethod=syntax
 225     " Only use fold column if we have enough space (for example not in a
 226     " (virtual) terminal which has only 80 columns).
 227     if &columns > 80
 228         set foldcolumn=2
 229     endif
 230     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 231                      " folding which is not what I want
 232     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 233     set foldopen-=block
 234 endif
 235
 236 " Only check case if the searched word contains a capital character.
 237 set ignorecase
 238 set smartcase
 239
 240 " Activate spell checking, use English as default.
 241 if exists('+spell') && has('syntax')
 242     " But not when diffing because spell checking is distracting in this case.
 243     if !&diff
 244         set spell
 245     endif
 246     set spelllang=en_us
 247 endif
 248
 249 " Allow buffers with changes to be hidden. Very important for efficient
 250 " editing with multiple buffers. Prevents the "E37: No write since last change
 251 " (add ! to override)" warning when switching modified buffers.
 252 set hidden
 253
 254 " When splitting vertically put the new window right of the current one.
 255 if has('vertsplit')
 256     set splitright
 257 endif
 258
 259
 260 " DISPLAY SETTINGS
 261
 262 " Use a dark background. Doesn't change the background color, only sets text
 263 " colors for a dark terminal.
 264 set background=dark
 265
 266 " Use my color scheme if 256 colors are available.
 267 if &t_Co == 256 || has('gui_running')
 268     colorscheme simon
 269 endif
 270
 271 " Display line numbers.
 272 set number
 273 " But use as little space as possible for the numbers column. Thanks to James
 274 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 275 if exists('+numberwidth')
 276     set numberwidth=1
 277 endif
 278 " Display the ruler with current line/file position. If 'statusline' is used,
 279 " then this only affects <C-G>.
 280 set ruler
 281 " Display partial commands in the status line.
 282 set showcmd
 283
 284 " Don't redraw screen when executing macros; increases speed. Thanks to James
 285 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 286 set lazyredraw
 287
 288 " Visualize the line the cursor is currently in.
 289 if exists('+cursorline')
 290     set cursorline
 291 endif
 292
 293 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 294 " remove the highlighting until the next search.
 295 set hlsearch
 296
 297 " Display some special characters.
 298 set list
 299 set listchars=
 300 " Display tabs as ">--------".
 301 set listchars+=tab:>-
 302 " Display trailing whitespace as "-".
 303 set listchars+=trail:-
 304 " Display markers for long lines when wrapping is disabled.
 305 set listchars+=extends:>,precedes:<
 306 " Display non-breakable space as "!".
 307 if v:version >= 700
 308     set listchars+=nbsp:!
 309 endif
 310
 311 " Don't draw the vertical split separator by using space as character. Thanks
 312 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 313 " non-breakable space. But a simple space works as well, as long as the
 314 " current color scheme is not reset.
 315 if has('windows') && has('folding')
 316     set fillchars+=vert:\  " comment to prevent trailing whitespace
 317 endif
 318
 319 if has('statusline')
 320     " Always display the status line even if there is only one window.
 321     set laststatus=2
 322
 323     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 324     " is the highest buffer number, otherwise return nothing. Used in
 325     " 'statusline' to get an overview of available buffer numbers.
 326     function! s:StatuslineBufferCount()
 327         let l:bufnr = bufnr('$')
 328         if l:bufnr > 1
 329             let l:result = '/'
 330             if exists('*printf')
 331                 let l:result .= printf('%02d', l:bufnr)
 332             else
 333                 " Older Vims don't have printf() (and no .= either). Emulate
 334                 " "%02d".
 335                 if l:bufnr < 10
 336                     let l:result = l:result . '0'
 337                 endif
 338                 let l:result = l:result . l:bufnr
 339             endif
 340             return l:result
 341         else
 342             return ''
 343         endif
 344     endfunction
 345
 346     " Like %f but use relative filename if it's shorter than the absolute path
 347     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 348     " not enough because it doesn't create '../'s.
 349     function! s:StatuslineRelativeFilename()
 350         " Display only filename for help files.
 351         if &buftype == 'help'
 352             return expand('%:t')
 353         endif
 354         " Special case for scratch files.
 355         if &buftype == 'nofile'
 356             return '[Scratch]'
 357         endif
 358
 359         let l:path = expand('%')
 360         " No file.
 361         if l:path == ''
 362             return '[No Name]'
 363         endif
 364         " Path is already relative, nothing to do.
 365         if stridx(l:path, '/') != 0
 366             return l:path
 367         endif
 368
 369         " Absolute path to this file.
 370         let l:path = expand('%:p')
 371         " Shortened path to this file, thanks to bairui in #vim on Freenode
 372         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 373         " Vim normally uses as %f (minus some exceptions).
 374         let l:original_path = fnamemodify(l:path, ':~')
 375         " Absolute path to the current working directory.
 376         let l:cwd = getcwd()
 377
 378         " Working directory completely contained in path, replace it with a
 379         " relative path. Happens for example when opening a file with netrw.
 380         " %f displays this as absolute path, but we want a relative path of
 381         " course.
 382         if stridx(l:path, l:cwd) == 0
 383             return strpart(l:path, strlen(l:cwd) + 1)
 384         endif
 385
 386         let l:path_list = split(l:path, '/')
 387         let l:cwd_list  = split(l:cwd,  '/')
 388
 389         " Remove the common path.
 390         while l:path_list[0] == l:cwd_list[0]
 391             call remove(l:path_list, 0)
 392             call remove(l:cwd_list,  0)
 393         endwhile
 394
 395         " Add as many '..' as necessary for the relative path and join the
 396         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 397         " the hint to use repeat() instead of a loop.
 398         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 399
 400         " Use the shorter path, either relative or absolute.
 401         if strlen(l:path) < strlen(l:original_path)
 402             return l:path
 403         else
 404             return l:original_path
 405         endif
 406     endfunction
 407
 408     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 409     function! s:StatuslineFileFormat()
 410         if &fileformat != 'unix'
 411             return '[' . &fileformat . ']'
 412         else
 413             return ''
 414         endif
 415     endfunction
 416     function! s:StatuslineFileEncoding()
 417         if &fileencoding != '' && &fileencoding != 'utf-8'
 418                 \ && &filetype != 'help'
 419             return '[' . &fileencoding . ']'
 420         else
 421             return ''
 422         endif
 423     endfunction
 424     function! s:StatuslineFileBOMB()
 425         if exists('+bomb') && &bomb
 426             return '[BOM]'
 427         else
 428             return ''
 429         endif
 430     endfunction
 431
 432     " Return current syntax group in brackets or nothing if there's none.
 433     function! s:StatuslineSyntaxGroup()
 434         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 435         if l:group != ''
 436             return '[' . l:group . '] '
 437         else
 438             return ''
 439         endif
 440     endfunction
 441
 442     " Short function names to make 'statusline' more readable.
 443     function! SBC()
 444         return s:StatuslineBufferCount()
 445     endfunction
 446     function! SRF()
 447         return s:StatuslineRelativeFilename()
 448     endfunction
 449     function! SFF()
 450         return s:StatuslineFileFormat()
 451     endfunction
 452     function! SFE()
 453         return s:StatuslineFileEncoding()
 454     endfunction
 455     function! SFB()
 456         return s:StatuslineFileBOMB()
 457     endfunction
 458     function! SSG()
 459         return s:StatuslineSyntaxGroup()
 460     endfunction
 461
 462     set statusline=
 463     " on the left
 464     set statusline+=%02n              " buffer number
 465     set statusline+=%{SBC()}          " highest buffer number
 466     set statusline+=:
 467     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 468         set statusline+=%{SRF()}      " path to current file
 469     else
 470         set statusline+=%f            " path to current file in buffer
 471     endif
 472     set statusline+=\                 " space after path
 473     set statusline+=%h                " [help] if buffer is help file
 474     set statusline+=%w                " [Preview] if buffer is preview buffer
 475     set statusline+=%m                " [+] if buffer was modified,
 476                                       " [-] if 'modifiable' is off
 477     set statusline+=%r                " [RO] if buffer is read only
 478     if v:version >= 700               " %#..# needs 7.0
 479         set statusline+=%#Error#      " display warnings
 480         set statusline+=%{SFF()}      "   - unexpected file format
 481         set statusline+=%{SFE()}      "   - unexpected file encoding
 482         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 483         set statusline+=%##           " continue with normal colors
 484     endif
 485
 486     " on the right
 487     set statusline+=%=                " right align
 488     set statusline+=0x%-8B\           " current character under cursor as hex
 489     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 490                                       " column number (%c),
 491                                       " virtual column number if different
 492                                       "                       than %c (%V)
 493     set statusline+=%P                " position in file in percent
 494 endif
 495
 496
 497 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 498
 499 " noremap is used to make sure the right side is executed as is and can't be
 500 " modified by a plugin or other settings. Except for <Nop> which isn't
 501 " affected by mappings.
 502
 503 " Easy way to exit insert mode (jj is too slow).
 504 inoremap jk <Esc>
 505 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 506 " (2010-10-15).
 507 cnoremap jk <C-C>
 508 " And fix my typos ...
 509 inoremap JK <Esc>
 510 inoremap Jk <Esc>
 511 inoremap jK <Esc>
 512 cnoremap JK <C-C>
 513 cnoremap Jk <C-C>
 514 cnoremap jK <C-C>
 515
 516 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 517 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 518 map <Right>  <Nop>
 519 map <Left>   <Nop>
 520 map <Up>     <Nop>
 521 map <Down>   <Nop>
 522 imap <Right> <Nop>
 523 imap <Left>  <Nop>
 524 imap <Up>    <Nop>
 525 imap <Down>  <Nop>
 526 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 527 " below).
 528 cmap <Up>    <Nop>
 529 cmap <Down>  <Nop>
 530 cmap <Right> <Nop>
 531 cmap <Left>  <Nop>
 532
 533 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 534 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 535 cnoremap <C-P> <Up>
 536 cnoremap <C-N> <Down>
 537
 538 " Use :tjump to lookup tags (instead of :tag) which lists all available tags
 539 " if there's more than one match. This is really helpful in larger projects
 540 " where tags may occur multiple times.
 541 nnoremap <C-]> g<C-]>
 542
 543 if has('eval')
 544 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 545 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 546 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 547 " directly because it also enables that feature for other commands which I
 548 " don't want.
 549
 550     " Set 'nostartofline' for a single movement.
 551     function! s:TemporaryNostartofline(movement)
 552         let l:startofline = &startofline
 553         set nostartofline
 554         execute 'normal! ' . a:movement
 555         let &startofline = l:startofline
 556     endfunction
 557
 558     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 559     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 560     nnoremap <silent> <C-F>
 561         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 562     nnoremap <silent> <C-B>
 563         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 564     nnoremap <silent> <C-D>
 565         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 566     nnoremap <silent> <C-U>
 567         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 568 endif
 569
 570 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 571 " yank a line. This fixes a weird inconsistency in Vi(m).
 572 nnoremap Y y$
 573
 574 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 575 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 576 " Only the current buffer is written, thus switching to another buffer works
 577 " too.
 578 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 579
 580 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 581 " in #vim on Freenode (2011-08-15 00:17 CEST).
 582 nnoremap <C-G> 2<C-G>
 583
 584 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 585 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 586 nmap <Space> <C-F>
 587 nmap - <C-B>
 588
 589 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 590 " (2010-05-16 18:38 CEST) for this idea.
 591 nnoremap <silent> gb :bnext<CR>
 592 nnoremap <silent> gB :bprevious<CR>
 593 if has('eval')
 594     " But when starting again at the first buffer, print a warning which
 595     " reminds me that I've already seen that buffer.
 596     function! s:NextBuffer()
 597         " Are we currently on the last buffer and moving to the first?
 598         let l:last_buffer = 0
 599         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 600             let l:last_buffer = 1
 601         endif
 602
 603         " Go to the next buffer.
 604         if !l:last_buffer
 605             bnext
 606
 607         " Go to the first buffer, silent is necessary or the following message
 608         " won't be displayed because it's overwritten by the status message
 609         " displayed when entering a buffer.
 610         else
 611             silent bnext
 612
 613             echohl WarningMsg
 614             echo 'Starting again at first buffer.'
 615             echohl None
 616         endif
 617     endfunction
 618     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 619 endif
 620
 621 " Fast access to buffers.
 622 nnoremap <silent> <Leader>1 :1buffer<CR>
 623 nnoremap <silent> <Leader>2 :2buffer<CR>
 624 nnoremap <silent> <Leader>3 :3buffer<CR>
 625 nnoremap <silent> <Leader>4 :4buffer<CR>
 626 nnoremap <silent> <Leader>5 :5buffer<CR>
 627 nnoremap <silent> <Leader>6 :6buffer<CR>
 628 nnoremap <silent> <Leader>7 :7buffer<CR>
 629 nnoremap <silent> <Leader>8 :8buffer<CR>
 630 nnoremap <silent> <Leader>9 :9buffer<CR>
 631 nnoremap <silent> <Leader>0 :10buffer<CR>
 632
 633 " Use real tabs instead of soft tabs.
 634 if has('eval')
 635 " Switch from soft tabs to real tabs.
 636     function! s:UseTabs()
 637         setlocal noexpandtab shiftwidth=8 softtabstop=8
 638     endfunction
 639     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 640 endif
 641 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 642 " coloring. 'list' is not changed, see next mapping.
 643 nnoremap <silent> <Leader>v :setlocal nowrap nospell synmaxcol=0<CR>
 644                           \ :2match<CR>
 645 " Toggle 'list'.
 646 nnoremap <silent> <Leader>l :set invlist<CR>
 647
 648 " Make last active window the only window. Similar to <C-W> o.
 649 nnoremap <C-W>O <C-W>p<C-W>o
 650
 651 " Maps to change spell language between English and German and disable spell
 652 " checking.
 653 if exists('+spell')
 654     nnoremap <silent> <Leader>sn :set nospell<CR>
 655     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 656     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 657 " If no spell support is available, these mappings do nothing.
 658 else
 659     nmap <Leader>sn <Nop>
 660     nmap <Leader>se <Nop>
 661     nmap <Leader>sd <Nop>
 662 endif
 663
 664 if has('eval')
 665 " * and # for selections in visual mode. Thanks to
 666 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 667 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 668     function! s:VSetSearch()
 669         let l:temp = @@ " unnamed register
 670         normal! gvy
 671         " Added \C to force 'noignorecase' while searching the current visual
 672         " selection. I want to search for the exact string in this case.
 673         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 674         let @@ = l:temp
 675     endfunction
 676     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 677     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 678
 679 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 680 " Thanks to the writers of s:VSetSearch(), see above.
 681     function! s:NSetSearch()
 682         let l:cword = expand('<cword>')
 683         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 684         let @/ = '\C\V'. '\<' . l:regex . '\>'
 685     endfunction
 686     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 687     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 688 endif
 689
 690 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 691 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 692 " mailing list for the commands.
 693 if v:version < 700
 694     cnoreabbrev W w
 695     cnoreabbrev Wa wa
 696     cnoreabbrev Wq wq
 697     cnoreabbrev Wqa wqa
 698 else
 699     cnoreabbrev <expr> W
 700         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 701     cnoreabbrev <expr> Wa
 702         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 703     cnoreabbrev <expr> Wq
 704         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 705     cnoreabbrev <expr> Wqa
 706         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 707 endif
 708 " Also fix my typo with "Q".
 709 if v:version < 700
 710     cnoreabbrev Q q
 711     cnoreabbrev Qa qa
 712 else
 713     cnoreabbrev <expr> Q
 714         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 715     cnoreabbrev <expr> Qa
 716         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 717 endif
 718
 719 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 720 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 721 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 722
 723 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 724 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 725 " Vim's source.
 726 inoremap <C-U> <C-G>u<C-U>
 727 " Same for <C-@> (insert previously inserted text and leave insert mode).
 728 inoremap <C-@> <C-G>u<C-@>
 729 " And for <C-A> (insert previously inserted text).
 730 inoremap <C-A> <C-G>u<C-A>
 731 " And for <C-W> (delete word before cursor).
 732 inoremap <C-W> <C-G>u<C-W>
 733
 734 if has('eval')
 735 " New text-objects ii and ai to work on text with the same indentation. Thanks
 736 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 737 " (visited on 2011-11-19).
 738     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 739     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 740     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 741     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 742
 743     function! s:IndTxtObj(inner)
 744         let curline = line(".")
 745         let lastline = line("$")
 746         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 747         let i = i < 0 ? 0 : i
 748         if getline(".") !~ "^\\s*$"
 749             let p = line(".") - 1
 750             let nextblank = getline(p) =~ "^\\s*$"
 751             while p > 0
 752                     \ && ((i == 0 && !nextblank)
 753                         \ || (i > 0 && ((indent(p) >= i
 754                             \ && !(nextblank && a:inner))
 755                             \ || (nextblank && !a:inner))))
 756                 -
 757                 let p = line(".") - 1
 758                 let nextblank = getline(p) =~ "^\\s*$"
 759             endwhile
 760             normal! 0V
 761             call cursor(curline, 0)
 762             let p = line(".") + 1
 763             let nextblank = getline(p) =~ "^\\s*$"
 764             while p <= lastline
 765                     \ && ((i == 0 && !nextblank)
 766                         \ || (i > 0 && ((indent(p) >= i
 767                             \ && !(nextblank && a:inner))
 768                             \ || (nextblank && !a:inner))))
 769                 +
 770                 let p = line(".") + 1
 771                 let nextblank = getline(p) =~ "^\\s*$"
 772             endwhile
 773             normal! $
 774         endif
 775     endfunction
 776 endif
 777
 778
 779 " ABBREVIATIONS
 780
 781 " Fix some of my spelling mistakes (German).
 782 inoreabbrev relle reelle
 783 inoreabbrev reele reelle
 784 " Fix some of my spelling mistakes (English).
 785 inoreabbrev completly completely
 786
 787
 788 " SYNTAX SETTINGS
 789
 790 " Activate syntax coloring.
 791 if has('syntax')
 792     " But only if it wasn't already active. Prevents breaking the syntax
 793     " coloring when reloading the vimrc. Thanks to johnLate for the idea.
 794     if !exists('g:syntax_on')
 795         syntax enable
 796     endif
 797
 798 " Don't highlight more than 500 columns as I normally don't have that long
 799 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 800 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 801     if exists('+synmaxcol')
 802         set synmaxcol=500
 803     endif
 804
 805 " Use (limited) syntax based omni completion if no other omni completion is
 806 " available. Taken from :help ft-syntax-omni.
 807     if has('autocmd') && exists('+omnifunc')
 808         augroup vimrc
 809             autocmd FileType *
 810                 \ if &omnifunc == '' |
 811                 \     setlocal omnifunc=syntaxcomplete#Complete |
 812                 \ endif
 813         augroup END
 814     endif
 815
 816 " Function to enable all custom highlights. Necessary as highlights are
 817 " window-local and thus must be set for each new window.
 818     function! s:CustomSyntaxHighlights()
 819         " Not the first time called, nothing to do.
 820         if exists('w:vimrc_syntax_run')
 821             return
 822         endif
 823         let w:vimrc_syntax_run = 1
 824
 825 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 826 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 827 " disabled when necessary with :2match (in Vim >= 700).
 828         if !&diff && exists(':2match')
 829             " Use ColorColumn for overlong lines if available and my color
 830             " scheme is used.
 831             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 832                 2match ColorColumn /\%>78v./
 833             else
 834                 2match Todo /\%>78v./
 835             endif
 836         elseif !&diff
 837             match Todo /\%>78v./
 838         endif
 839
 840         if exists('*matchadd')
 841 " Highlight some important keywords in all documents.
 842             let l:todos = ['TODO', 'XXX', 'FIXME', 'NOTE',
 843                          \ 'CHANGED', 'REMOVED', 'DELETED']
 844             " Compatibility fix for Vim 6.4 which can't parse for in functions
 845             " (without function it's ignored).
 846             execute '  for l:x in l:todos'
 847                   \ '|     call matchadd("Todo", l:x)'
 848                   \ '| endfor'
 849
 850 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 851             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 852                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 853                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 854                           \ '205f', '2060', '3000', 'feff']
 855             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 856             " it won't work!
 857             execute '  for l:x in l:spaces'
 858                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 859                   \ '| endfor'
 860
 861 " Special highlight for tabs to reduce their visibility in contrast to other
 862 " SpecialKey characters (e.g. ^L).
 863             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 864                 call matchadd('specialKeyTab', '\t')
 865             endif
 866         endif
 867     endfunction
 868 " Enable highlights for the current and all new windows. Thanks to bairui in
 869 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 870     call s:CustomSyntaxHighlights()
 871     if has('autocmd')
 872         augroup vimrc
 873             autocmd WinEnter * call s:CustomSyntaxHighlights()
 874         augroup END
 875     endif
 876
 877 " Settings for specific filetypes.
 878
 879     " C
 880     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 881     " Haskell
 882     let g:hs_highlight_delimiters = 1
 883     let g:hs_highlight_boolean = 1
 884     let g:hs_highlight_types = 1
 885     let g:hs_highlight_more_types = 1
 886     " Java
 887     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 888     " Perl
 889     let g:perl_fold = 1
 890     let g:perl_fold_blocks = 1
 891     let g:perl_nofold_packages = 1
 892     let g:perl_include_pod = 1 " syntax coloring for PODs
 893     " PHP
 894     let g:php_folding = 3    " fold functions
 895     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 896     let g:php_sql_query = 1  " highlight SQL queries in strings
 897     " Python
 898     let g:python_highlight_all = 1
 899     " Shell
 900     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 901     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 902     let g:is_posix = 1        " POSIX shell (e.g. dash) is compatible enough
 903     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 904     " Vim
 905     let g:vimsyn_embed = 0      " don't highlight embedded languages
 906     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 907     " XML
 908     let g:xml_syntax_folding = 1
 909 endif
 910
 911
 912 " PLUGIN SETTINGS
 913
 914 if has('eval')
 915 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 916 " installing/removing/updating plugins simple. (Used for plugins with more
 917 " than one file.) Ignore errors in case pathogen is not installed.
 918     if v:version >= 700
 919         silent! execute 'call pathogen#infect()'
 920     endif
 921
 922 " Settings for securemodelines.
 923     " Only allow items I need (also includes spl which is not enabled by
 924     " default).
 925     if v:version >= 700 " need lists
 926         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 927                                               \ 'sw', 'sts', 'noet']
 928     endif
 929
 930 " Settings for gnupg.
 931     " Don't use temporary files for sensitive data.
 932     let g:GPGUsePipes = 1
 933
 934 " Settings for the NERD commenter.
 935     " Don't create any mappings I don't want to use.
 936     let g:NERDCreateDefaultMappings = 0
 937     " Map toggle comment.
 938     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 939
 940 " XPTemplate settings.
 941     " Try to maintain snippet rendering even after editing outside of a
 942     " snippet.
 943     let g:xptemplate_strict = 0
 944     " Don't complete any braces automatically.
 945     let g:xptemplate_brace_complete = 0
 946     " Only highlight the current placeholder.
 947     let g:xptemplate_highlight = 'current'
 948
 949 " CtrlP settings.
 950     " Don't manage the working directory (the default setting is too slow for
 951     " me).
 952     let g:ctrlp_working_path_mode = 0
 953
 954     " Path to cache directory. I prefer to keep generated files as local as
 955     " possible.
 956     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 957     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 958     " cache manually.
 959     let g:ctrlp_clear_cache_on_exit = 0
 960
 961     " Don't switch the window if the selected buffer is already open. I want
 962     " to open another view on this buffer in most cases.
 963     let g:ctrlp_switch_buffer = 0
 964
 965 " FSWitch settings.
 966     " Defaults don't work well for my projects.
 967     augroup vimrc
 968         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 969                           \ | let b:fswitchlocs = './'
 970         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 971                           \ | let b:fswitchlocs = './'
 972     augroup END
 973
 974     " Switch to corresponding header/source file.
 975     nnoremap <silent> <Leader>h :FSHere<CR>
 976
 977 " netrw settings.
 978     " Don't create ~/.vim/.netrwhist history file.
 979     let g:netrw_dirhistmax = 0
 980 endif
 981
 982
 983 " AUTO COMMANDS
 984
 985 " Use a custom auto group to prevent problems when the vimrc files is sourced
 986 " multiple times.
 987 if has('autocmd')
 988     augroup vimrc
 989
 990 " Go to last position of opened files. Taken from :help last-position-jump.
 991         autocmd BufReadPost *
 992             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 993             \     execute "normal! g'\"" |
 994             \ endif
 995 " But not for Git commits, go to beginning of the file.
 996         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 997
 998 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 999 " when switching to a help buffer which is in the background with :buffer as
1000 " these options are local to windows (and not only to buffers). This happens
1001 " because I often want to use only one window and thus the help buffer is in
1002 " the background.
1003         autocmd BufWinEnter *.txt
1004             \ if &filetype == 'help' |
1005             \     setlocal nolist |
1006             \     setlocal nonumber |
1007             \ endif
1008
1009 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
1010 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
1011 " want to paste once and then 'paste' gets automatically unset. InsertLeave
1012 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
1013 " 'paste' in this case.
1014         if exists('##InsertLeave')
1015             autocmd InsertLeave * set nopaste
1016         endif
1017
1018 " Write all files when running :mak[e] before 'makeprg' is called.
1019 " QuickFixCmdPre doesn't exist in older Vims.
1020         if exists('##QuickFixCmdPre')
1021             autocmd QuickFixCmdPre * wall
1022         endif
1023
1024 " Don't ignore case while in insert mode, but ignore case in all other modes.
1025 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
1026 " capitalization. But while searching (/) 'ignorecase' is used.
1027 " InsertEnter/InsertLeave doesn't exist in older Vims.
1028         if exists('##InsertEnter') && exists('##InsertLeave')
1029             autocmd InsertEnter * set noignorecase
1030             autocmd InsertLeave * set   ignorecase
1031         endif
1032
1033 " Display a warning when editing a file which contains "do not edit" (ignoring
1034 " the case) and similar messages in the first lines of the file, for example
1035 " template files which were preprocessed or auto-generated files. Especially
1036 " useful when the header is not displayed on the first screen, e.g. when the
1037 " old position is restored.
1038         function! s:SearchForDoNotEditHeader()
1039             " Only search the first 20 lines to prevent false positives, e.g.
1040             " in scripts which write files containing this warning and ignore
1041             " the case (\c). (Can't use search()'s {stopline} as we might not
1042             " start searching from the top.)
1043             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1044             let l:match = search(l:search, 'n')
1045             if l:match == 0 || l:match > 20
1046                 return
1047             endif
1048
1049             echoerr 'Do not edit this file! (Maybe a template file.)'
1050         endfunction
1051         autocmd BufRead * call s:SearchForDoNotEditHeader()
1052
1053 " AFTER/FTPLUGIN AUTO COMMANDS
1054
1055 " Disable spell checking for files which don't need it.
1056         autocmd FileType deb  setlocal nospell
1057         autocmd FileType diff setlocal nospell
1058         autocmd FileType tar  setlocal nospell
1059 " Fix to allow Vim edit crontab files as crontab doesn't work with
1060 " backupcopy=auto.
1061         autocmd FileType crontab setlocal backupcopy=yes
1062 " Don't use the modeline in git commits as the diff created by `git commit -v`
1063 " may contain one which could change the filetype or other settings of the
1064 " commit buffer. Also make sure we use only 72 characters per line which is
1065 " the recommendation for git commit messages (http://tpope.net/node/106).
1066         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1067                                  \ setlocal textwidth=72
1068 " Fix 'include' setting for shell files to recognize '.' and 'source'
1069 " commands.
1070         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1071 " Use the same comment string as for Vim files in Vimperator files.
1072         autocmd FileType vimperator setlocal commentstring=\"%s
1073 " Use TeX compiler for (La)TeX files.
1074         autocmd FileType tex compiler tex
1075
1076 " FTDETECT AUTO COMMANDS
1077
1078 " Recognize .test as Tcl files.
1079         autocmd BufRead,BufNewFile *.test set filetype=tcl
1080
1081 " OTHER AUTO COMMANDS
1082
1083 " Disable spell checking, displaying of list characters and long lines when
1084 " viewing documentation.
1085         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1086     augroup END
1087 endif
1088
1089
1090 " CUSTOM FUNCTIONS AND COMMANDS
1091
1092 if has('eval')
1093 " Convenient command to see the difference between the current buffer and the
1094 " file it was loaded from, thus the changes you made. Thanks to the
1095 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1096 " for the diffed file as the filetype for the original file.
1097     if !exists(':DiffOrig')
1098         command DiffOrig
1099             \ let s:diff_orig_filetype = &filetype
1100             \ | vertical new
1101             \ | let &filetype = s:diff_orig_filetype
1102             \ | unlet s:diff_orig_filetype
1103             \ | set buftype=nofile
1104             \ | read ++edit #
1105             \ | 0d_
1106             \ | diffthis
1107             \ | wincmd p
1108             \ | diffthis
1109     endif
1110 endif