vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2013  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Disallow :autocmd, shell and write commands in .vimrc and .exrc files in the
  45 " current directory. Only used if 'exrc' is enabled (off by default),
  46 " precaution just in case somebody enables 'exrc'.
  47 set secure
  48
  49 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  50 " affect reading files in different encodings, see 'fileencodings' for that.
  51 set encoding=utf-8
  52
  53 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  54 " runtime files) if available.
  55 set runtimepath-=~/.vim
  56 set runtimepath^=~/.vim,~/.vim/runtime
  57
  58 " Don't store swap files in the same directory as the edited file, but only if
  59 " we have a "safe" writable directory available.
  60 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  61     set directory-=.
  62 endif
  63 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  64 set directory^=~/.tmp
  65
  66 " Disable modelines as they may cause security problems. Instead use
  67 " securemodelines (Vim script #1876).
  68 set nomodeline
  69
  70 " Complete to longest common string (list:longest) and then complete all full
  71 " matches after another (full). Thanks to pbrisbin
  72 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  73 set wildmode=list:longest,full
  74 " Ignore case when completing files/directories.
  75 if exists('+wildignorecase')
  76     set wildignorecase
  77 endif
  78
  79 " Ignore files with the following extensions because I almost never want to
  80 " edit them in Vim (specifying them manually still works of course).
  81 set wildignore=
  82 " C
  83 set wildignore+=*.o,*.d,*.so
  84 " Java
  85 set wildignore+=*.class
  86 " LaTeX
  87 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  88 " Python
  89 set wildignore+=*.pyc
  90
  91 " Show completion menu even if only one entry matches.
  92 if exists('+completeopt')
  93     set completeopt+=menuone
  94 endif
  95
  96 " Increase history of executed commands (:) and search patterns (/).
  97 set history=1000
  98
  99 " Increase number of possible undos.
 100 set undolevels=1000
 101
 102 " Remember marks (including the last cursor position) for more files. ^= is
 103 " necessary because 'viminfo' is parsed from the beginning and the first match
 104 " is used.
 105 if has('viminfo')
 106     set viminfo^='1000
 107 endif
 108
 109 " Use strong encryption if possible, also used for swap/undo files.
 110 if exists('+cryptmethod')
 111     set cryptmethod=blowfish
 112 endif
 113
 114 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 115 " is used multiple times. Necessary to support reloading the vimrc.
 116 if has('autocmd')
 117     augroup vimrc
 118         autocmd!
 119     augroup END
 120 endif
 121
 122
 123 " HELPER FUNCTIONS
 124
 125 if has('eval')
 126 " Check if the given syntax group is available. Thanks to bairui in #vim on
 127 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 128     function! s:HasSyntaxGroup(group)
 129         try
 130             execute 'silent highlight ' . a:group
 131         " \a = [A-Za-z]
 132         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 133             return 0
 134         endtry
 135         return 1
 136     endfunction
 137
 138 " Check if the given Vim version and patch is available.
 139     function! s:HasVersionAndPatch(version, patch)
 140         return v:version > a:version
 141             \ || (v:version == a:version && has('patch' . a:patch))
 142     endfunction
 143 endif
 144
 145
 146 " TERMINAL SETTINGS
 147
 148 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 149 " connections.
 150 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 151     set ttyfast
 152 endif
 153
 154
 155 " EDIT SETTINGS
 156
 157 " Enable automatic file detection, plugin and indention support.
 158 if has('autocmd')
 159     filetype off " necessary for pathogen to force a reload of ftplugins
 160     filetype plugin indent on
 161 endif
 162
 163 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 164 " existing files.
 165 set fileencodings=utf-8,latin1
 166
 167 " Always use unix line-endings for new files. DOS line endings in existing
 168 " files are recognized.
 169 set fileformats=unix,dos
 170
 171 " Wrap text after 78 characters.
 172 set textwidth=78
 173
 174 " Set tabs to 4 spaces, use softtabs.
 175 set shiftwidth=4
 176 set softtabstop=4
 177 set expandtab
 178 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 179 set shiftround
 180 " Use the default value for real tabs.
 181 set tabstop=8
 182
 183 " Enable auto indention.
 184 set autoindent
 185
 186 " When joining lines only add one space after a sentence.
 187 set nojoinspaces
 188
 189 " Allow backspacing over autoindent and line breaks.
 190 set backspace=indent,eol
 191
 192 " Start a comment when hitting enter after a commented line (r) and when using
 193 " o or O around a commented line (o).
 194 set formatoptions+=ro
 195 " Don't break a line if was already longer then 'textwidth' when insert mode
 196 " started.
 197 set formatoptions+=l
 198 " Remove comment leader when joining lines where it makes sense.
 199 if s:HasVersionAndPatch(703, 541)
 200     set formatoptions+=j
 201 endif
 202
 203 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 204 " no character) in visual block mode.
 205 set virtualedit=block
 206
 207 " Already display matches while typing the search command. This makes spotting
 208 " typos easy and searching faster.
 209 set incsearch
 210
 211 " Activate syntax folding.
 212 if has('folding')
 213     set foldmethod=syntax
 214     " Only use fold column if we have enough space (for example not in a
 215     " (virtual) terminal which has only 80 columns).
 216     if &columns > 80
 217         set foldcolumn=2
 218     endif
 219     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 220                      " folding which is not what I want
 221     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 222     set foldopen-=block
 223 endif
 224
 225 " Only check case if the searched word contains a capital character.
 226 set ignorecase
 227 set smartcase
 228
 229 " Activate spell checking, use English as default.
 230 if exists('+spell') && has('syntax')
 231     " But not when diffing because spell checking is distracting in this case.
 232     if !&diff
 233         set spell
 234     endif
 235     set spelllang=en_us
 236 endif
 237
 238 " Allow buffers with changes to be hidden. Very important for efficient
 239 " editing with multiple buffers. Prevents the "E37: No write since last change
 240 " (add ! to override)" warning when switching modified buffers.
 241 set hidden
 242
 243 " When splitting vertically put the new window right of the current one.
 244 if has('vertsplit')
 245     set splitright
 246 endif
 247
 248
 249 " DISPLAY SETTINGS
 250
 251 " Use a dark background. Doesn't change the background color, only sets text
 252 " colors for a dark terminal.
 253 set background=dark
 254
 255 " Use my color scheme if 256 colors are available.
 256 if &t_Co == 256 || has('gui_running')
 257     colorscheme simon
 258 endif
 259
 260 " Display line numbers.
 261 set number
 262 " But use as little space as possible for the numbers column. Thanks to James
 263 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 264 if exists('+numberwidth')
 265     set numberwidth=1
 266 endif
 267 " Display the ruler with current line/file position. If 'statusline' is used,
 268 " then this only affects <C-G>.
 269 set ruler
 270 " Display partial commands in the status line.
 271 set showcmd
 272
 273 " Don't redraw screen when executing macros; increases speed. Thanks to James
 274 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 275 set lazyredraw
 276
 277 " Visualize the line the cursor is currently in.
 278 if exists('+cursorline')
 279     set cursorline
 280 endif
 281
 282 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 283 " remove the highlighting until the next search.
 284 set hlsearch
 285
 286 " Display some special characters.
 287 set list
 288 set listchars=
 289 " Display tabs as ">--------".
 290 set listchars+=tab:>-
 291 " Display trailing whitespace as "-".
 292 set listchars+=trail:-
 293 " Display markers for long lines when wrapping is disabled.
 294 set listchars+=extends:>,precedes:<
 295 " Display non-breakable space as "!".
 296 if v:version >= 700
 297     set listchars+=nbsp:!
 298 endif
 299
 300 " Don't draw the vertical split separator by using space as character. Thanks
 301 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 302 " non-breakable space. But a simple space works as well, as long as the
 303 " current color scheme is not reset.
 304 if has('windows') && has('folding')
 305     set fillchars+=vert:\  " comment to prevent trailing whitespace
 306 endif
 307
 308 if has('statusline')
 309     " Always display the status line even if there is only one window.
 310     set laststatus=2
 311
 312     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 313     " is the highest buffer number, otherwise return nothing. Used in
 314     " 'statusline' to get an overview of available buffer numbers.
 315     function! s:StatuslineBufferCount()
 316         let l:bufnr = bufnr('$')
 317         if l:bufnr > 1
 318             let l:result = '/'
 319             if exists('*printf')
 320                 let l:result .= printf('%02d', l:bufnr)
 321             else
 322                 " Older Vims don't have printf() (and no .= either). Emulate
 323                 " "%02d".
 324                 if l:bufnr < 10
 325                     let l:result = l:result . '0'
 326                 endif
 327                 let l:result = l:result . l:bufnr
 328             endif
 329             return l:result
 330         else
 331             return ''
 332         endif
 333     endfunction
 334
 335     " Like %f but use relative filename if it's shorter than the absolute path
 336     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 337     " not enough because it doesn't create '../'s.
 338     function! s:StatuslineRelativeFilename()
 339         " Display only filename for help files.
 340         if &buftype == 'help'
 341             return expand('%:t')
 342         endif
 343         " Special case for scratch files.
 344         if &buftype == 'nofile'
 345             return '[Scratch]'
 346         endif
 347
 348         let l:path = expand('%')
 349         " No file.
 350         if l:path == ''
 351             return '[No Name]'
 352         endif
 353         " Path is already relative, nothing to do.
 354         if stridx(l:path, '/') != 0
 355             return l:path
 356         endif
 357
 358         " Absolute path to this file.
 359         let l:path = expand('%:p')
 360         " Shortened path to this file, thanks to bairui in #vim on Freenode
 361         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 362         " Vim normally uses as %f (minus some exceptions).
 363         let l:original_path = fnamemodify(l:path, ':~')
 364         " Absolute path to the current working directory.
 365         let l:cwd = getcwd()
 366
 367         " Working directory completely contained in path, replace it with a
 368         " relative path. Happens for example when opening a file with netrw.
 369         " %f displays this as absolute path, but we want a relative path of
 370         " course.
 371         if stridx(l:path, l:cwd) == 0
 372             return strpart(l:path, strlen(l:cwd) + 1)
 373         endif
 374
 375         let l:path_list = split(l:path, '/')
 376         let l:cwd_list  = split(l:cwd,  '/')
 377
 378         " Remove the common path.
 379         while l:path_list[0] == l:cwd_list[0]
 380             call remove(l:path_list, 0)
 381             call remove(l:cwd_list,  0)
 382         endwhile
 383
 384         " Add as many '..' as necessary for the relative path and join the
 385         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 386         " the hint to use repeat() instead of a loop.
 387         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 388
 389         " Use the shorter path, either relative or absolute.
 390         if strlen(l:path) < strlen(l:original_path)
 391             return l:path
 392         else
 393             return l:original_path
 394         endif
 395     endfunction
 396
 397     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 398     function! s:StatuslineFileFormat()
 399         if &fileformat != 'unix'
 400             return '[' . &fileformat . ']'
 401         else
 402             return ''
 403         endif
 404     endfunction
 405     function! s:StatuslineFileEncoding()
 406         if &fileencoding != '' && &fileencoding != 'utf-8'
 407                 \ && &filetype != 'help'
 408             return '[' . &fileencoding . ']'
 409         else
 410             return ''
 411         endif
 412     endfunction
 413     function! s:StatuslineFileBOMB()
 414         if exists('+bomb') && &bomb
 415             return '[BOM]'
 416         else
 417             return ''
 418         endif
 419     endfunction
 420
 421     " Return current syntax group in brackets or nothing if there's none.
 422     function! s:StatuslineSyntaxGroup()
 423         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 424         if l:group != ''
 425             return '[' . l:group . '] '
 426         else
 427             return ''
 428         endif
 429     endfunction
 430
 431     " Short function names to make 'statusline' more readable.
 432     function! SBC()
 433         return s:StatuslineBufferCount()
 434     endfunction
 435     function! SRF()
 436         return s:StatuslineRelativeFilename()
 437     endfunction
 438     function! SFF()
 439         return s:StatuslineFileFormat()
 440     endfunction
 441     function! SFE()
 442         return s:StatuslineFileEncoding()
 443     endfunction
 444     function! SFB()
 445         return s:StatuslineFileBOMB()
 446     endfunction
 447     function! SSG()
 448         return s:StatuslineSyntaxGroup()
 449     endfunction
 450
 451     set statusline=
 452     " on the left
 453     set statusline+=%02n              " buffer number
 454     set statusline+=%{SBC()}          " highest buffer number
 455     set statusline+=:
 456     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 457         set statusline+=%{SRF()}      " path to current file
 458     else
 459         set statusline+=%f            " path to current file in buffer
 460     endif
 461     set statusline+=\                 " space after path
 462     set statusline+=%h                " [help] if buffer is help file
 463     set statusline+=%w                " [Preview] if buffer is preview buffer
 464     set statusline+=%m                " [+] if buffer was modified,
 465                                       " [-] if 'modifiable' is off
 466     set statusline+=%r                " [RO] if buffer is read only
 467     if v:version >= 700               " %#..# needs 7.0
 468         set statusline+=%#Error#      " display warnings
 469         set statusline+=%{SFF()}      "   - unexpected file format
 470         set statusline+=%{SFE()}      "   - unexpected file encoding
 471         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 472         set statusline+=%##           " continue with normal colors
 473     endif
 474
 475     " on the right
 476     set statusline+=%=                " right align
 477     set statusline+=0x%-8B\           " current character under cursor as hex
 478     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 479                                       " column number (%c),
 480                                       " virtual column number if different
 481                                       "                       than %c (%V)
 482     set statusline+=%P                " position in file in percent
 483 endif
 484
 485
 486 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 487
 488 " noremap is used to make sure the right side is executed as is and can't be
 489 " modified by a plugin or other settings. Except for <Nop> which isn't
 490 " affected by mappings.
 491
 492 " Easy way to exit insert mode (jj is too slow).
 493 inoremap jk <Esc>
 494 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 495 " (2010-10-15).
 496 cnoremap jk <C-C>
 497 " And fix my typos ...
 498 inoremap JK <Esc>
 499 inoremap Jk <Esc>
 500 inoremap jK <Esc>
 501 cnoremap JK <C-C>
 502 cnoremap Jk <C-C>
 503 cnoremap jK <C-C>
 504
 505 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 506 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 507 map <Right>  <Nop>
 508 map <Left>   <Nop>
 509 map <Up>     <Nop>
 510 map <Down>   <Nop>
 511 imap <Right> <Nop>
 512 imap <Left>  <Nop>
 513 imap <Up>    <Nop>
 514 imap <Down>  <Nop>
 515 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 516 " below).
 517 cmap <Up>    <Nop>
 518 cmap <Down>  <Nop>
 519 cmap <Right> <Nop>
 520 cmap <Left>  <Nop>
 521
 522 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 523 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 524 cnoremap <C-P> <Up>
 525 cnoremap <C-N> <Down>
 526
 527 if has('eval')
 528 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 529 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 530 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 531 " directly because it also enables that feature for other commands which I
 532 " don't want.
 533
 534     " Set 'nostartofline' for a single movement.
 535     function! s:TemporaryNostartofline(movement)
 536         let l:startofline = &startofline
 537         set nostartofline
 538         execute 'normal! ' . a:movement
 539         let &startofline = l:startofline
 540     endfunction
 541
 542     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 543     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 544     nnoremap <silent> <C-F>
 545         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 546     nnoremap <silent> <C-B>
 547         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 548     nnoremap <silent> <C-D>
 549         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 550     nnoremap <silent> <C-U>
 551         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 552 endif
 553
 554 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 555 " yank a line. This fixes a weird inconsistency in Vi(m).
 556 nnoremap Y y$
 557
 558 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 559 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 560 " Only the current buffer is written, thus switching to another buffer works
 561 " too.
 562 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 563
 564 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 565 " in #vim on Freenode (2011-08-15 00:17 CEST).
 566 nnoremap <C-G> 2<C-G>
 567
 568 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 569 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 570 nmap <Space> <C-F>
 571 nmap - <C-B>
 572
 573 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 574 " (2010-05-16 18:38 CEST) for this idea.
 575 nnoremap <silent> gb :bnext<CR>
 576 nnoremap <silent> gB :bprevious<CR>
 577 if has('eval')
 578     " But when starting again at the first buffer, print a warning which
 579     " reminds me that I've already seen that buffer.
 580     function! s:NextBuffer()
 581         " Are we currently on the last buffer and moving to the first?
 582         let l:last_buffer = 0
 583         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 584             let l:last_buffer = 1
 585         endif
 586
 587         " Go to the next buffer.
 588         if !l:last_buffer
 589             bnext
 590
 591         " Go to the first buffer, silent is necessary or the following message
 592         " won't be displayed because it's overwritten by the status message
 593         " displayed when entering a buffer.
 594         else
 595             silent bnext
 596
 597             echohl WarningMsg
 598             echo 'Starting again at first buffer.'
 599             echohl None
 600         endif
 601     endfunction
 602     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 603 endif
 604
 605 " Fast access to buffers.
 606 nnoremap <silent> <Leader>1 :1buffer<CR>
 607 nnoremap <silent> <Leader>2 :2buffer<CR>
 608 nnoremap <silent> <Leader>3 :3buffer<CR>
 609 nnoremap <silent> <Leader>4 :4buffer<CR>
 610 nnoremap <silent> <Leader>5 :5buffer<CR>
 611 nnoremap <silent> <Leader>6 :6buffer<CR>
 612 nnoremap <silent> <Leader>7 :7buffer<CR>
 613 nnoremap <silent> <Leader>8 :8buffer<CR>
 614 nnoremap <silent> <Leader>9 :9buffer<CR>
 615 nnoremap <silent> <Leader>0 :10buffer<CR>
 616
 617 " Use real tabs instead of soft tabs.
 618 if has('eval')
 619 " Switch from soft tabs to real tabs.
 620     function! s:UseTabs()
 621         setlocal noexpandtab shiftwidth=8 softtabstop=8
 622     endfunction
 623     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 624 endif
 625 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 626 " coloring. 'list' is not changed, see next mapping.
 627 nnoremap <silent> <Leader>v :setlocal nowrap nospell synmaxcol=0<CR>
 628                           \ :2match<CR>
 629 " Toggle 'list'.
 630 nnoremap <silent> <Leader>l :set invlist<CR>
 631
 632 " Make last active window the only window. Similar to <C-W> o.
 633 nnoremap <C-W>O <C-W>p<C-W>o
 634
 635 " Maps to change spell language between English and German and disable spell
 636 " checking.
 637 if exists('+spell')
 638     nnoremap <silent> <Leader>sn :set nospell<CR>
 639     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 640     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 641 " If no spell support is available, these mappings do nothing.
 642 else
 643     nmap <Leader>sn <Nop>
 644     nmap <Leader>se <Nop>
 645     nmap <Leader>sd <Nop>
 646 endif
 647
 648 if has('eval')
 649 " * and # for selections in visual mode. Thanks to
 650 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 651 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 652     function! s:VSetSearch()
 653         let l:temp = @@ " unnamed register
 654         normal! gvy
 655         " Added \C to force 'noignorecase' while searching the current visual
 656         " selection. I want to search for the exact string in this case.
 657         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 658         let @@ = l:temp
 659     endfunction
 660     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 661     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 662
 663 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 664 " Thanks to the writers of s:VSetSearch(), see above.
 665     function! s:NSetSearch()
 666         let l:cword = expand('<cword>')
 667         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 668         let @/ = '\C\V'. '\<' . l:regex . '\>'
 669     endfunction
 670     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 671     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 672 endif
 673
 674 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 675 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 676 " mailing list for the commands.
 677 if v:version < 700
 678     cnoreabbrev W w
 679     cnoreabbrev Wa wa
 680     cnoreabbrev Wq wq
 681     cnoreabbrev Wqa wqa
 682 else
 683     cnoreabbrev <expr> W
 684         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 685     cnoreabbrev <expr> Wa
 686         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 687     cnoreabbrev <expr> Wq
 688         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 689     cnoreabbrev <expr> Wqa
 690         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 691 endif
 692 " Also fix my typo with "Q".
 693 if v:version < 700
 694     cnoreabbrev Q q
 695     cnoreabbrev Qa qa
 696 else
 697     cnoreabbrev <expr> Q
 698         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 699     cnoreabbrev <expr> Qa
 700         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 701 endif
 702
 703 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 704 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 705 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 706
 707 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 708 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 709 " Vim's source.
 710 inoremap <C-U> <C-G>u<C-U>
 711 " Same for <C-@> (insert previously inserted text and leave insert mode).
 712 inoremap <C-@> <C-G>u<C-@>
 713 " And for <C-A> (insert previously inserted text).
 714 inoremap <C-A> <C-G>u<C-A>
 715 " And for <C-W> (delete word before cursor).
 716 inoremap <C-W> <C-G>u<C-W>
 717
 718 if has('eval')
 719 " New text-objects ii and ai to work on text with the same indentation. Thanks
 720 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 721 " (visited on 2011-11-19).
 722     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 723     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 724     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 725     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 726
 727     function! s:IndTxtObj(inner)
 728         let curline = line(".")
 729         let lastline = line("$")
 730         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 731         let i = i < 0 ? 0 : i
 732         if getline(".") !~ "^\\s*$"
 733             let p = line(".") - 1
 734             let nextblank = getline(p) =~ "^\\s*$"
 735             while p > 0
 736                     \ && ((i == 0 && !nextblank)
 737                         \ || (i > 0 && ((indent(p) >= i
 738                             \ && !(nextblank && a:inner))
 739                             \ || (nextblank && !a:inner))))
 740                 -
 741                 let p = line(".") - 1
 742                 let nextblank = getline(p) =~ "^\\s*$"
 743             endwhile
 744             normal! 0V
 745             call cursor(curline, 0)
 746             let p = line(".") + 1
 747             let nextblank = getline(p) =~ "^\\s*$"
 748             while p <= lastline
 749                     \ && ((i == 0 && !nextblank)
 750                         \ || (i > 0 && ((indent(p) >= i
 751                             \ && !(nextblank && a:inner))
 752                             \ || (nextblank && !a:inner))))
 753                 +
 754                 let p = line(".") + 1
 755                 let nextblank = getline(p) =~ "^\\s*$"
 756             endwhile
 757             normal! $
 758         endif
 759     endfunction
 760 endif
 761
 762
 763 " ABBREVIATIONS
 764
 765 " Fix some of my spelling mistakes (German).
 766 inoreabbrev relle reelle
 767 inoreabbrev reele reelle
 768 " Fix some of my spelling mistakes (English).
 769 inoreabbrev completly completely
 770
 771
 772 " SYNTAX SETTINGS
 773
 774 " Activate syntax coloring.
 775 if has('syntax')
 776     " But only if it wasn't already active. Prevents breaking the syntax
 777     " coloring when reloading the vimrc. Thanks to johnLate for the idea.
 778     if !exists('g:syntax_on')
 779         syntax enable
 780     endif
 781
 782 " Don't highlight more than 500 columns as I normally don't have that long
 783 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 784 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 785     if exists('+synmaxcol')
 786         set synmaxcol=500
 787     endif
 788
 789 " Use (limited) syntax based omni completion if no other omni completion is
 790 " available. Taken from :help ft-syntax-omni.
 791     if has('autocmd') && exists('+omnifunc')
 792         augroup vimrc
 793             autocmd FileType *
 794                 \ if &omnifunc == '' |
 795                 \     setlocal omnifunc=syntaxcomplete#Complete |
 796                 \ endif
 797         augroup END
 798     endif
 799
 800 " Function to enable all custom highlights. Necessary as highlights are
 801 " window-local and thus must be set for each new window.
 802     function! s:CustomSyntaxHighlights()
 803         " Not the first time called, nothing to do.
 804         if exists('w:vimrc_syntax_run')
 805             return
 806         endif
 807         let w:vimrc_syntax_run = 1
 808
 809 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 810 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 811 " disabled when necessary with :2match (in Vim >= 700).
 812         if !&diff && exists(':2match')
 813             " Use ColorColumn for overlong lines if available and my color
 814             " scheme is used.
 815             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 816                 2match ColorColumn /\%>78v./
 817             else
 818                 2match Todo /\%>78v./
 819             endif
 820         elseif !&diff
 821             match Todo /\%>78v./
 822         endif
 823
 824         if exists('*matchadd')
 825 " Highlight some important keywords in all documents.
 826             let l:todos = ['TODO', 'XXX', 'FIXME', 'NOTE',
 827                          \ 'CHANGED', 'REMOVED', 'DELETED']
 828             " Compatibility fix for Vim 6.4 which can't parse for in functions
 829             " (without function it's ignored).
 830             execute '  for l:x in l:todos'
 831                   \ '|     call matchadd("Todo", l:x)'
 832                   \ '| endfor'
 833
 834 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 835             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 836                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 837                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 838                           \ '205f', '2060', '3000', 'feff']
 839             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 840             " it won't work!
 841             execute '  for l:x in l:spaces'
 842                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 843                   \ '| endfor'
 844
 845 " Special highlight for tabs to reduce their visibility in contrast to other
 846 " SpecialKey characters (e.g. ^L).
 847             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 848                 call matchadd('specialKeyTab', '\t')
 849             endif
 850         endif
 851     endfunction
 852 " Enable highlights for the current and all new windows. Thanks to bairui in
 853 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 854     call s:CustomSyntaxHighlights()
 855     if has('autocmd')
 856         augroup vimrc
 857             autocmd WinEnter * call s:CustomSyntaxHighlights()
 858         augroup END
 859     endif
 860
 861 " Settings for specific filetypes.
 862
 863     " C
 864     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 865     " Haskell
 866     let g:hs_highlight_delimiters = 1
 867     let g:hs_highlight_boolean = 1
 868     let g:hs_highlight_types = 1
 869     let g:hs_highlight_more_types = 1
 870     " Java
 871     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 872     " Perl
 873     let g:perl_fold = 1
 874     let g:perl_fold_blocks = 1
 875     let g:perl_nofold_packages = 1
 876     let g:perl_include_pod = 1 " syntax coloring for PODs
 877     " PHP
 878     let g:php_folding = 3    " fold functions
 879     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 880     let g:php_sql_query = 1  " highlight SQL queries in strings
 881     " Python
 882     let g:python_highlight_all = 1
 883     " Shell
 884     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 885     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 886     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 887     " Vim
 888     let g:vimsyn_embed = 0      " don't highlight embedded languages
 889     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 890     " XML
 891     let g:xml_syntax_folding = 1
 892 endif
 893
 894
 895 " PLUGIN SETTINGS
 896
 897 if has('eval')
 898 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 899 " installing/removing/updating plugins simple. (Used for plugins with more
 900 " than one file.) Ignore errors in case pathogen is not installed.
 901     if v:version >= 700
 902         silent! execute 'call pathogen#infect()'
 903     endif
 904
 905 " Settings for securemodelines.
 906     " Only allow items I need (also includes spl which is not enabled by
 907     " default).
 908     if v:version >= 700 " need lists
 909         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 910                                               \ 'sw', 'sts', 'noet']
 911     endif
 912
 913 " Settings for the NERD commenter.
 914     " Don't create any mappings I don't want to use.
 915     let g:NERDCreateDefaultMappings = 0
 916     " Map toggle comment.
 917     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 918
 919 " XPTemplate settings.
 920     " Try to maintain snippet rendering even after editing outside of a
 921     " snippet.
 922     let g:xptemplate_strict = 0
 923     " Don't complete any braces automatically.
 924     let g:xptemplate_brace_complete = 0
 925     " Only highlight the current placeholder.
 926     let g:xptemplate_highlight = 'current'
 927
 928 " CtrlP settings.
 929     " Don't manage the working directory (the default setting is too slow for
 930     " me).
 931     let g:ctrlp_working_path_mode = 0
 932
 933     " Path to cache directory. I prefer to keep generated files as local as
 934     " possible.
 935     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 936     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 937     " cache manually.
 938     let g:ctrlp_clear_cache_on_exit = 0
 939
 940     " Don't switch the window if the selected buffer is already open. I want
 941     " to open another view on this buffer in most cases.
 942     let g:ctrlp_switch_buffer = 0
 943
 944 " FSWitch settings.
 945     " Defaults don't work well for my projects.
 946     augroup vimrc
 947         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 948                           \ | let b:fswitchlocs = './'
 949         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 950                           \ | let b:fswitchlocs = './'
 951     augroup END
 952
 953     " Switch to corresponding header/source file.
 954     nnoremap <silent> <Leader>h :FSHere<CR>
 955
 956 " netrw settings.
 957     " Don't create ~/.vim/.netrwhist history file.
 958     let g:netrw_dirhistmax = 0
 959 endif
 960
 961
 962 " AUTO COMMANDS
 963
 964 " Use a custom auto group to prevent problems when the vimrc files is sourced
 965 " multiple times.
 966 if has('autocmd')
 967     augroup vimrc
 968
 969 " Go to last position of opened files. Taken from :help last-position-jump.
 970         autocmd BufReadPost *
 971             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 972             \     execute "normal! g'\"" |
 973             \ endif
 974 " But not for Git commits, go to beginning of the file.
 975         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 976
 977 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 978 " when switching to a help buffer which is in the background with :buffer as
 979 " these options are local to windows (and not only to buffers). This happens
 980 " because I often want to use only one window and thus the help buffer is in
 981 " the background.
 982         autocmd BufWinEnter *.txt
 983             \ if &filetype == 'help' |
 984             \     setlocal nolist |
 985             \     setlocal nonumber |
 986             \ endif
 987
 988 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 989 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 990 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 991 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
 992 " 'paste' in this case.
 993         if exists('##InsertLeave')
 994             autocmd InsertLeave * set nopaste
 995         endif
 996
 997 " Write all files when running :mak[e] before 'makeprg' is called.
 998 " QuickFixCmdPre doesn't exist in older Vims.
 999         if exists('##QuickFixCmdPre')
1000             autocmd QuickFixCmdPre * wall
1001         endif
1002
1003 " Don't ignore case while in insert mode, but ignore case in all other modes.
1004 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
1005 " capitalization. But while searching (/) 'ignorecase' is used.
1006 " InsertEnter/InsertLeave doesn't exist in older Vims.
1007         if exists('##InsertEnter') && exists('##InsertLeave')
1008             autocmd InsertEnter * set noignorecase
1009             autocmd InsertLeave * set   ignorecase
1010         endif
1011
1012 " Display a warning when editing a file which contains "do not edit" (ignoring
1013 " the case) and similar messages in the first lines of the file, for example
1014 " template files which were preprocessed or auto-generated files. Especially
1015 " useful when the header is not displayed on the first screen, e.g. when the
1016 " old position is restored.
1017         function! s:SearchForDoNotEditHeader()
1018             " Only search the first 20 lines to prevent false positives, e.g.
1019             " in scripts which write files containing this warning and ignore
1020             " the case (\c). (Can't use search()'s {stopline} as we might not
1021             " start searching from the top.)
1022             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1023             let l:match = search(l:search, 'n')
1024             if l:match == 0 || l:match > 20
1025                 return
1026             endif
1027
1028             echoerr 'Do not edit this file! (Maybe a template file.)'
1029         endfunction
1030         autocmd BufRead * call s:SearchForDoNotEditHeader()
1031
1032 " AFTER/FTPLUGIN AUTO COMMANDS
1033
1034 " Disable spell checking for files which don't need it.
1035         autocmd FileType deb  setlocal nospell
1036         autocmd FileType diff setlocal nospell
1037         autocmd FileType tar  setlocal nospell
1038 " Fix to allow Vim edit crontab files as crontab doesn't work with
1039 " backupcopy=auto.
1040         autocmd FileType crontab setlocal backupcopy=yes
1041 " Don't use the modeline in git commits as the diff created by `git commit -v`
1042 " may contain one which could change the filetype or other settings of the
1043 " commit buffer. Also make sure we use only 72 characters per line which is
1044 " the recommendation for git commit messages (http://tpope.net/node/106).
1045         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1046                                  \ setlocal textwidth=72
1047 " Fix 'include' setting for shell files to recognize '.' and 'source'
1048 " commands.
1049         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1050 " Use the same comment string as for Vim files in Vimperator files.
1051         autocmd FileType vimperator setlocal commentstring=\"%s
1052 " Use TeX compiler for (La)TeX files.
1053         autocmd FileType tex compiler tex
1054
1055 " FTDETECT AUTO COMMANDS
1056
1057 " Recognize .md as markdown files (Vim default is .mkd).
1058         autocmd BufRead,BufNewFile *.md set filetype=mkd
1059 " Recognize .test as Tcl files.
1060         autocmd BufRead,BufNewFile *.test set filetype=tcl
1061
1062 " OTHER AUTO COMMANDS
1063
1064 " Disable spell checking, displaying of list characters and long lines when
1065 " viewing documentation.
1066         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1067
1068 " Use diff filetype for mercurial patches in patch queue.
1069         autocmd BufReadPost */.hg/patches/* set filetype=diff
1070
1071     augroup END
1072 endif
1073
1074
1075 " CUSTOM FUNCTIONS AND COMMANDS
1076
1077 if has('eval')
1078 " Convenient command to see the difference between the current buffer and the
1079 " file it was loaded from, thus the changes you made. Thanks to the
1080 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1081 " for the diffed file as the filetype for the original file.
1082     if !exists(':DiffOrig')
1083         command DiffOrig
1084             \ let s:diff_orig_filetype = &filetype
1085             \ | vertical new
1086             \ | let &filetype = s:diff_orig_filetype
1087             \ | unlet s:diff_orig_filetype
1088             \ | set buftype=nofile
1089             \ | read ++edit #
1090             \ | 0d_
1091             \ | diffthis
1092             \ | wincmd p
1093             \ | diffthis
1094     endif
1095 endif