vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37
  38 " Disable modelines as they may cause security problems. Instead use
  39 " securemodelines (Vim script #1876).
  40 set nomodeline
  41
  42 " Complete to longest common string (list:longest) and then complete all full
  43 " matches after another (full). Thanks to pbrisbin
  44 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  45 set wildmode=list:longest,full
  46
  47 " Increase history of executed commands (:).
  48 set history=1000
  49
  50 " Increase number of possible undos.
  51 set undolevels=1000
  52
  53 " Use strong encryption if possible, also used for swap/undo files.
  54 if v:version >= 703
  55     set cryptmethod=blowfish
  56 endif
  57
  58
  59 " EDIT SETTINGS
  60
  61 " Enable automatic file detection, plugin and indention support.
  62 if has('autocmd')
  63     filetype plugin indent on
  64 endif
  65
  66 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  67 " existing files.
  68 set fileencodings=utf-8,latin1
  69
  70 " Wrap text after 78 characters.
  71 set textwidth=78
  72
  73 " Set tabs to 4 spaces, use softtabs.
  74 set shiftwidth=4
  75 set softtabstop=4
  76 set expandtab
  77 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  78 set shiftround
  79 " Use the default value for real tabs.
  80 set tabstop=8
  81
  82 " Enable auto indention.
  83 set autoindent
  84
  85 " When joining lines only add one space after a sentence.
  86 set nojoinspaces
  87
  88 " Allow backspacing over autoindent and line breaks.
  89 set backspace=indent,eol
  90
  91 " Start a comment when hitting enter after a commented line (r) and when using
  92 " o or O around a commented line (o).
  93 set formatoptions+=ro
  94 " Don't break a line if was already longer then 'textwidth' when insert mode
  95 " started.
  96 set formatoptions+=l
  97
  98 " Allow virtual editing (cursor can be positioned anywhere, even when there is
  99 " no character) in visual block mode.
 100 set virtualedit=block
 101
 102 " Already display matches while typing the search command. This makes spotting
 103 " errors easy.
 104 set incsearch
 105
 106 " Activate syntax folding.
 107 if has('folding')
 108     set foldmethod=syntax
 109     set foldcolumn=2
 110     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 111                      " folding which is not what I want
 112 endif
 113
 114 " Only check for case if the searched word contains a capital character.
 115 set ignorecase
 116 set smartcase
 117
 118 " Activate spell checking, use English as default. Don't use spell checking
 119 " when diffing.
 120 if v:version >= 700 && has('syntax') && !&diff
 121     set spell
 122     set spelllang=en_us
 123 endif
 124
 125 " Allow buffers with changes to be hidden. Very important for effective
 126 " editing with multiple buffers.
 127 set hidden
 128
 129
 130 " DISPLAY SETTINGS
 131
 132 " Use a dark background. Doesn't change the background color, only sets text
 133 " colors for a dark terminal.
 134 set background=dark
 135
 136 " Display line numbers.
 137 set number
 138 " But use as little space as necessary for the numbers column. Thanks to James
 139 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 140 if v:version >= 700
 141     set numberwidth=1
 142 endif
 143 " Display the ruler with current line/file position. If 'statusline' is used
 144 " then this only affects <C-G>.
 145 set ruler
 146 " Display partial commands in the status line.
 147 set showcmd
 148
 149 " Don't redraw screen when executing macros; increases speed. Thanks to James
 150 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 151 set lazyredraw
 152
 153 " Visualize the line the cursor is currently in.
 154 if v:version >= 700
 155     set cursorline
 156 endif
 157
 158 " Display tabs, trailing space, non breakable spaces and long lines (when
 159 " wrapping is disabled).
 160 set list
 161 set listchars=trail:-,extends:>
 162 if v:version >= 700
 163     set listchars+=nbsp:!
 164 endif
 165
 166 if has('statusline')
 167     " Always display the status line even if there is only one window.
 168     set laststatus=2
 169
 170     set statusline=
 171     " on the left
 172     set statusline+=%02n: " buffer number
 173     set statusline+=%f\   " path to current file in buffer
 174     set statusline+=%h    " [help] if buffer is help file
 175     set statusline+=%w    " [Preview] if buffer is preview buffer
 176     set statusline+=%m    " [+] if buffer was modified,
 177                           " [-] if 'modifiable' is off
 178     set statusline+=%r    " [RO] if buffer is read only
 179
 180     " on the right
 181     set statusline+=%=                " right align
 182     set statusline+=0x%-8B\           " current character under cursor as hex
 183     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 184                                       " column number (%c),
 185                                       " virtual column number if different
 186                                       "                       than %c (%V)
 187     set statusline+=%P                " position in file in percent
 188 endif
 189
 190
 191 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 192
 193 " Easy way to exit insert mode.
 194 inoremap jj <Esc>
 195 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 196 " (2010-10-15).
 197 cnoremap jj <C-C>
 198
 199 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 200 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 201 map <Right>  <Nop>
 202 map <Left>   <Nop>
 203 map <Up>     <Nop>
 204 map <Down>   <Nop>
 205 imap <Right> <Nop>
 206 imap <Left>  <Nop>
 207 imap <Up>    <Nop>
 208 imap <Down>  <Nop>
 209 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 210 " below).
 211 cmap <Up>    <Nop>
 212 cmap <Down>  <Nop>
 213 cmap <Right> <Nop>
 214 cmap <Left>  <Nop>
 215
 216 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 217 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 218 cnoremap <C-P> <Up>
 219 cnoremap <C-N> <Down>
 220
 221 " Use <Space> to move down a page and - to move up one like in mutt.
 222 nnoremap <Space> <C-F>
 223 nnoremap - <C-B>
 224
 225 " Behave like 'scrolloff' but only while searching. Thanks to "Benjamin R.
 226 " Haskell" <vim@benizi.com> from the Vim mailing list (2010-10-26).
 227 nnoremap n nzv3j3k
 228 nnoremap N Nzv3k3j
 229
 230 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 231 " (2010-05-16 18:38 CEST) for this idea.
 232 nnoremap <silent> gb :bnext<CR>
 233 nnoremap <silent> gB :bprev<CR>
 234
 235 " Fast access to buffers.
 236 nnoremap <Leader>1 :1b<CR>
 237 nnoremap <Leader>2 :2b<CR>
 238 nnoremap <Leader>3 :3b<CR>
 239 nnoremap <Leader>4 :4b<CR>
 240 nnoremap <Leader>5 :5b<CR>
 241 nnoremap <Leader>6 :6b<CR>
 242 nnoremap <Leader>7 :7b<CR>
 243 nnoremap <Leader>8 :8b<CR>
 244 nnoremap <Leader>9 :9b<CR>
 245 nnoremap <Leader>0 :10b<CR>
 246
 247 " Make last active window the only window. Similar to <C-w> o.
 248 nnoremap <C-W>O <C-W>p<C-W>o
 249
 250 " Maps to change spell language between English and German and disable spell
 251 " checking.
 252 if v:version >= 700
 253     noremap <Leader>sn :set nospell<CR>
 254     noremap <Leader>se :set spell spelllang=en_us<CR>
 255     noremap <Leader>sd :set spell spelllang=de_de<CR>
 256 endif
 257
 258 " Add semicolon to the end of the line. Thanks to
 259 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 260 " on Freenode for an improved version which doesn't clobber any marks.
 261 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 262
 263 " * and # for selections in visual mode. Thanks to
 264 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 265 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 266 if has('eval')
 267     function! s:VSetSearch()
 268         let temp = @@
 269         normal! gvy
 270         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 271         let @@ = temp
 272     endfunction
 273     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 274     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 275 endif
 276
 277 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 278 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 279 " mailing list for the commands.
 280 if v:version < 700
 281     cnoreabbrev W w
 282     cnoreabbrev Wa wa
 283     cnoreabbrev Wq wq
 284     cnoreabbrev Wqa wqa
 285 else
 286     cnoreabbrev <expr> W
 287         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 288     cnoreabbrev <expr> Wa
 289         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 290     cnoreabbrev <expr> Wq
 291         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 292     cnoreabbrev <expr> Wqa
 293         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 294 endif
 295 " Also fix my typo with "Q".
 296 if v:version < 700
 297     cnoreabbrev Q q
 298     cnoreabbrev Qa qa
 299 else
 300     cnoreabbrev <expr> Q
 301         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 302     cnoreabbrev <expr> Qa
 303         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 304 endif
 305
 306 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 307 " if pressed accidentally while in insert mode (happens on Mac when alt
 308 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 309 " no longer set on the console.
 310 if has('mac') || filereadable('/Users/.localized')
 311     inoremap <Char-0xa0> <Space>
 312 endif
 313
 314 " Disable Apple style movements in MacVim.
 315 if has('gui_macvim') && has('eval')
 316     let macvim_skip_cmd_opt_movement = 1
 317 endif
 318
 319 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 320 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 321 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 322
 323
 324 " ABBREVIATIONS
 325
 326 " Fix some of my spelling mistakes.
 327 iabbrev relle reelle
 328 iabbrev reele reelle
 329
 330
 331 " SYNTAX SETTINGS
 332
 333 " Activate syntax coloring.
 334 if has('syntax')
 335     syntax enable
 336
 337 " Don't highlight more than 500 columns as I normally don't have that long
 338 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 339 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 340     set synmaxcol=500
 341
 342 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 343 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 344 " disabled when necessary with :2match (in Vim >= 700).
 345     if v:version >= 700
 346         2match Todo /\%>78v./
 347     else
 348         match Todo /\%>78v./
 349     endif
 350
 351 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 352     if v:version > 701 || (v:version == 701 && has('patch42'))
 353         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 354     endif
 355 endif
 356
 357
 358 " PLUGIN SETTINGS
 359
 360 " Settings for the NERD commenter.
 361 " Don't create any mappings I don't want to use.
 362 if has('eval')
 363     let NERDCreateDefaultMappings = 0
 364 endif
 365 " Map toggle comment.
 366 map <Leader><Leader> <Plug>NERDCommenterToggle
 367
 368 " XPTemplate settings.
 369 if has('eval')
 370     " Try to maintain snippet rendering even after editing outside of a
 371     " snippet.
 372     let g:xptemplate_strict = 0
 373     " Don't complete any braces automatically.
 374     let g:xptemplate_brace_complete = 0
 375     " Only highlight the current placeholder.
 376     let g:xptemplate_highlight = 'current'
 377 endif
 378
 379
 380 " AUTO COMMANDS
 381
 382 " Use a custom auto group to prevent problems when the vimrc files is sourced
 383 " twice.
 384 if has('autocmd')
 385     augroup vimrc
 386         autocmd!
 387
 388 " Go to last position of opened files. Taken from :help last-position-jump.
 389         autocmd BufReadPost *
 390             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 391             \     execute "normal! g'\"" |
 392             \ endif
 393 " But not for Git commits, go to beginning of the file.
 394         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 395
 396 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 397 " when switching to a help buffer which is in the background with :buffer as
 398 " these options are local to windows (and not only to buffers). This happens
 399 " because I often want to use only one window and thus the help buffer is in
 400 " the background.
 401         autocmd BufWinEnter *.txt
 402             \ if &filetype == 'help' |
 403             \     setlocal nolist |
 404             \     setlocal nonumber |
 405             \ endif
 406
 407 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 408 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 409 " want to paste once and then 'paste' gets automatically unset.
 410         autocmd InsertLeave * set nopaste
 411
 412 " AFTER/FTPLUGIN AUTO COMMANDS
 413
 414 " Disable spell checking for files which don't need it.
 415         autocmd FileType deb  setlocal nospell
 416         autocmd FileType diff setlocal nospell
 417         autocmd FileType tar  setlocal nospell
 418 " Fix to allow Vim edit crontab files as crontab doesn't work with
 419 " backupcopy=auto.
 420         autocmd FileType crontab setlocal backupcopy=yes
 421 " Don't use the modeline in git commits as the diff created by `git commit -v`
 422 " may contain one which could change the filetype or other settings of the
 423 " commit buffer. Also make sure we use only 72 characters per line which is
 424 " the recommendation for git commit messages (http://tpope.net/node/106).
 425         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 426                                  \ setlocal textwidth=72
 427 " Allow folding in perl.
 428         autocmd FileType perl let perl_fold = 1 |
 429                             \ let perl_fold_blocks = 1
 430 " Use the same comment string as for Vim files in Vimperator files.
 431         autocmd FileType vimperator setlocal commentstring=\"%s
 432
 433 " FTDETECT AUTO COMMANDS
 434
 435 " Recognize .md as markdown files (Vim default is .mkd).
 436         autocmd BufRead,BufNewFile *.md set filetype=mkd
 437 " Recognize .test as Tcl files.
 438         autocmd BufRead,BufNewFile *.test set filetype=tcl
 439
 440 " OTHER AUTO COMMANDS
 441
 442 " Disable spell checking, displaying of list characters and long lines when
 443 " viewing documentation.
 444         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 445
 446 " Use diff filetype for mercurial patches in patch queue.
 447         autocmd BufReadPost */.hg/patches/* set filetype=diff
 448
 449     augroup END
 450 endif