vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2013  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  45 " affect reading files in different encodings, see 'fileencodings' for that.
  46 set encoding=utf-8
  47
  48 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  49 " runtime files) if available.
  50 set runtimepath-=~/.vim
  51 set runtimepath^=~/.vim,~/.vim/runtime
  52
  53 " Don't store swap files in the same directory as the edited file, but only if
  54 " we have a "safe" writable directory available.
  55 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  56     set directory-=.
  57 endif
  58 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  59 set directory^=~/.tmp
  60
  61 " Disable modelines as they may cause security problems. Instead use
  62 " securemodelines (Vim script #1876).
  63 set nomodeline
  64
  65 " Complete to longest common string (list:longest) and then complete all full
  66 " matches after another (full). Thanks to pbrisbin
  67 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  68 set wildmode=list:longest,full
  69 " Ignore case when completing files/directories.
  70 if exists('+wildignorecase')
  71     set wildignorecase
  72 endif
  73
  74 " Ignore files with the following extensions because I almost never want to
  75 " edit them in Vim (specifying them manually still works of course).
  76 set wildignore=
  77 " C
  78 set wildignore+=*.o,*.d,*.so
  79 " Java
  80 set wildignore+=*.class
  81 " LaTeX
  82 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  83 " Python
  84 set wildignore+=*.pyc
  85
  86 " Show completion menu even if only one entry matches.
  87 if exists('+completeopt')
  88     set completeopt+=menuone
  89 endif
  90
  91 " Increase history of executed commands (:) and search patterns (/).
  92 set history=1000
  93
  94 " Increase number of possible undos.
  95 set undolevels=1000
  96
  97 " Remember marks (including the last cursor position) for more files. ^= is
  98 " necessary because 'viminfo' is parsed from the beginning and the first match
  99 " is used.
 100 if has('viminfo')
 101     set viminfo^='1000
 102 endif
 103
 104 " Use strong encryption if possible, also used for swap/undo files.
 105 if exists('+cryptmethod')
 106     set cryptmethod=blowfish
 107 endif
 108
 109 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 110 " is used multiple times. Necessary to support reloading the vimrc.
 111 if has('autocmd')
 112     augroup vimrc
 113         autocmd!
 114     augroup END
 115 endif
 116
 117
 118 " HELPER FUNCTIONS
 119
 120 if has('eval')
 121 " Check if the given syntax group is available. Thanks to bairui in #vim on
 122 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 123     function! s:HasSyntaxGroup(group)
 124         try
 125             execute 'silent highlight ' . a:group
 126         " \a = [A-Za-z]
 127         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 128             return 0
 129         endtry
 130         return 1
 131     endfunction
 132
 133 " Check if the given Vim version and patch is available.
 134     function! s:HasVersionAndPatch(version, patch)
 135         return v:version > a:version
 136             \ || (v:version == a:version && has('patch' . a:patch))
 137     endfunction
 138 endif
 139
 140
 141 " TERMINAL SETTINGS
 142
 143 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 144 " connections.
 145 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 146     set ttyfast
 147 endif
 148
 149
 150 " EDIT SETTINGS
 151
 152 " Enable automatic file detection, plugin and indention support.
 153 if has('autocmd')
 154     filetype off " necessary for pathogen to force a reload of ftplugins
 155     filetype plugin indent on
 156 endif
 157
 158 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 159 " existing files.
 160 set fileencodings=utf-8,latin1
 161
 162 " Always use unix line-endings for new files.
 163 set fileformats=unix,dos
 164
 165 " Wrap text after 78 characters.
 166 set textwidth=78
 167
 168 " Set tabs to 4 spaces, use softtabs.
 169 set shiftwidth=4
 170 set softtabstop=4
 171 set expandtab
 172 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 173 set shiftround
 174 " Use the default value for real tabs.
 175 set tabstop=8
 176
 177 " Enable auto indention.
 178 set autoindent
 179
 180 " When joining lines only add one space after a sentence.
 181 set nojoinspaces
 182
 183 " Allow backspacing over autoindent and line breaks.
 184 set backspace=indent,eol
 185
 186 " Start a comment when hitting enter after a commented line (r) and when using
 187 " o or O around a commented line (o).
 188 set formatoptions+=ro
 189 " Don't break a line if was already longer then 'textwidth' when insert mode
 190 " started.
 191 set formatoptions+=l
 192 " Remove comment leader when joining lines where it makes sense.
 193 if s:HasVersionAndPatch(703, 541)
 194     set formatoptions+=j
 195 endif
 196
 197 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 198 " no character) in visual block mode.
 199 set virtualedit=block
 200
 201 " Already display matches while typing the search command. This makes spotting
 202 " typos easy and searching faster.
 203 set incsearch
 204
 205 " Activate syntax folding.
 206 if has('folding')
 207     set foldmethod=syntax
 208     " Only use fold column if we have enough space (for example not in a
 209     " (virtual) terminal which has only 80 columns).
 210     if &columns > 80
 211         set foldcolumn=2
 212     endif
 213     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 214                      " folding which is not what I want
 215     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 216     set foldopen-=block
 217 endif
 218
 219 " Only check case if the searched word contains a capital character.
 220 set ignorecase
 221 set smartcase
 222
 223 " Activate spell checking, use English as default.
 224 if exists('+spell') && has('syntax')
 225     " But not when diffing because spell checking is distracting in this case.
 226     if !&diff
 227         set spell
 228     endif
 229     set spelllang=en_us
 230 endif
 231
 232 " Allow buffers with changes to be hidden. Very important for efficient
 233 " editing with multiple buffers. Prevents the "E37: No write since last change
 234 " (add ! to override)" warning when switching modified buffers.
 235 set hidden
 236
 237 " When splitting vertically put the new window right of the current one.
 238 if has('vertsplit')
 239     set splitright
 240 endif
 241
 242
 243 " DISPLAY SETTINGS
 244
 245 " Use a dark background. Doesn't change the background color, only sets text
 246 " colors for a dark terminal.
 247 set background=dark
 248
 249 " Use my color scheme if 256 colors are available.
 250 if &t_Co == 256 || has('gui_running')
 251     colorscheme simon
 252 endif
 253
 254 " Display line numbers.
 255 set number
 256 " But use as little space as possible for the numbers column. Thanks to James
 257 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 258 if exists('+numberwidth')
 259     set numberwidth=1
 260 endif
 261 " Display the ruler with current line/file position. If 'statusline' is used
 262 " then this only affects <C-G>.
 263 set ruler
 264 " Display partial commands in the status line.
 265 set showcmd
 266
 267 " Don't redraw screen when executing macros; increases speed. Thanks to James
 268 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 269 set lazyredraw
 270
 271 " Visualize the line the cursor is currently in.
 272 if exists('+cursorline')
 273     set cursorline
 274 endif
 275
 276 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 277 " remove the highlighting until the next search.
 278 set hlsearch
 279
 280 " Display some special characters.
 281 set list
 282 set listchars=
 283 " Display tabs as ">--------".
 284 set listchars+=tab:>-
 285 " Display trailing whitespace as "-".
 286 set listchars+=trail:-
 287 " Display markers for long lines when wrapping is disabled.
 288 set listchars+=extends:>,precedes:<
 289 " Display non-breakable space as "!".
 290 if v:version >= 700
 291     set listchars+=nbsp:!
 292 endif
 293
 294 " Don't draw the vertical split separator by using space as character. Thanks
 295 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 296 " non-breakable space. But a simple space works as well, as long as the
 297 " current color scheme is not reset.
 298 if has('windows') && has('folding')
 299     set fillchars+=vert:\  " comment to prevent trailing whitespace
 300 endif
 301
 302 if has('statusline')
 303     " Always display the status line even if there is only one window.
 304     set laststatus=2
 305
 306     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 307     " is the highest buffer number, otherwise return nothing. Used in
 308     " 'statusline' to get an overview of available buffer numbers.
 309     function! s:StatuslineBufferCount()
 310         let l:bufnr = bufnr('$')
 311         if l:bufnr > 1
 312             let l:result = '/'
 313             if exists('*printf')
 314                 let l:result .= printf('%02d', l:bufnr)
 315             else
 316                 " Older Vims don't have printf() (and no .= either). Emulate
 317                 " "%02d".
 318                 if l:bufnr < 10
 319                     let l:result = l:result . '0'
 320                 endif
 321                 let l:result = l:result . l:bufnr
 322             endif
 323             return l:result
 324         else
 325             return ''
 326         endif
 327     endfunction
 328
 329     " Like %f but use relative filename if it's shorter than the absolute path
 330     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 331     " not enough because it doesn't create '../'s.
 332     function! s:StatuslineRelativeFilename()
 333         " Display only filename for help files.
 334         if &buftype == 'help'
 335             return expand('%:t')
 336         endif
 337         " Special case for scratch files.
 338         if &buftype == 'nofile'
 339             return '[Scratch]'
 340         endif
 341
 342         let l:path = expand('%')
 343         " No file.
 344         if l:path == ''
 345             return '[No Name]'
 346         endif
 347         " Path is already relative, nothing to do.
 348         if stridx(l:path, '/') != 0
 349             return l:path
 350         endif
 351
 352         " Absolute path to this file.
 353         let l:path = expand('%:p')
 354         " Shortened path to this file, thanks to bairui in #vim on Freenode
 355         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 356         " Vim normally uses as %f (minus some exceptions).
 357         let l:original_path = fnamemodify(l:path, ':~')
 358         " Absolute path to the current working directory.
 359         let l:cwd = getcwd()
 360
 361         " Working directory completely contained in path, replace it with a
 362         " relative path. Happens for example when opening a file with netrw.
 363         " %f displays this as absolute path, but we want a relative path of
 364         " course.
 365         if stridx(l:path, l:cwd) == 0
 366             return strpart(l:path, strlen(l:cwd) + 1)
 367         endif
 368
 369         let l:path_list = split(l:path, '/')
 370         let l:cwd_list  = split(l:cwd,  '/')
 371
 372         " Remove the common path.
 373         while l:path_list[0] == l:cwd_list[0]
 374             call remove(l:path_list, 0)
 375             call remove(l:cwd_list,  0)
 376         endwhile
 377
 378         " Add as many '..' as necessary for the relative path and join the
 379         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 380         " the hint to use repeat() instead of a loop.
 381         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 382
 383         " Use the shorter path, either relative or absolute.
 384         if strlen(l:path) < strlen(l:original_path)
 385             return l:path
 386         else
 387             return l:original_path
 388         endif
 389     endfunction
 390
 391     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 392     function! s:StatuslineFileFormat()
 393         if &fileformat != 'unix'
 394             return '[' . &fileformat . ']'
 395         else
 396             return ''
 397         endif
 398     endfunction
 399     function! s:StatuslineFileEncoding()
 400         if &fileencoding != '' && &fileencoding != 'utf-8'
 401                 \ && &filetype != 'help'
 402             return '[' . &fileencoding . ']'
 403         else
 404             return ''
 405         endif
 406     endfunction
 407     function! s:StatuslineFileBOMB()
 408         if exists('+bomb') && &bomb
 409             return '[BOM]'
 410         else
 411             return ''
 412         endif
 413     endfunction
 414
 415     " Return current syntax group in brackets or nothing if there's none.
 416     function! s:StatuslineSyntaxGroup()
 417         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 418         if l:group != ''
 419             return '[' . l:group . '] '
 420         else
 421             return ''
 422         endif
 423     endfunction
 424
 425     " Short function names to make 'statusline' more readable.
 426     function! SBC()
 427         return s:StatuslineBufferCount()
 428     endfunction
 429     function! SRF()
 430         return s:StatuslineRelativeFilename()
 431     endfunction
 432     function! SFF()
 433         return s:StatuslineFileFormat()
 434     endfunction
 435     function! SFE()
 436         return s:StatuslineFileEncoding()
 437     endfunction
 438     function! SFB()
 439         return s:StatuslineFileBOMB()
 440     endfunction
 441     function! SSG()
 442         return s:StatuslineSyntaxGroup()
 443     endfunction
 444
 445     set statusline=
 446     " on the left
 447     set statusline+=%02n              " buffer number
 448     set statusline+=%{SBC()}          " highest buffer number
 449     set statusline+=:
 450     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 451         set statusline+=%{SRF()}      " path to current file
 452         set statusline+=\             " space after path
 453     else
 454         set statusline+=%f\           " path to current file in buffer
 455     endif
 456     set statusline+=%h                " [help] if buffer is help file
 457     set statusline+=%w                " [Preview] if buffer is preview buffer
 458     set statusline+=%m                " [+] if buffer was modified,
 459                                       " [-] if 'modifiable' is off
 460     set statusline+=%r                " [RO] if buffer is read only
 461     if v:version >= 700               " %#..# needs 7.0
 462         set statusline+=%#Error#      " display warnings
 463         set statusline+=%{SFF()}      "   - unexpected file format
 464         set statusline+=%{SFE()}      "   - unexpected file encoding
 465         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 466         set statusline+=%##           " continue with normal colors
 467     endif
 468
 469     " on the right
 470     set statusline+=%=                " right align
 471     set statusline+=0x%-8B\           " current character under cursor as hex
 472     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 473                                       " column number (%c),
 474                                       " virtual column number if different
 475                                       "                       than %c (%V)
 476     set statusline+=%P                " position in file in percent
 477 endif
 478
 479
 480 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 481
 482 " noremap is used to make sure the right side is executed as is and can't be
 483 " modified by a plugin or other settings. Except for <Nop> which isn't
 484 " affected by mappings.
 485
 486 " Easy way to exit insert mode (jj is too slow).
 487 inoremap jk <Esc>
 488 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 489 " (2010-10-15).
 490 cnoremap jk <C-C>
 491 " And fix my typos ...
 492 inoremap JK <Esc>
 493 inoremap Jk <Esc>
 494 cnoremap JK <C-C>
 495 cnoremap Jk <C-C>
 496
 497 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 498 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 499 map <Right>  <Nop>
 500 map <Left>   <Nop>
 501 map <Up>     <Nop>
 502 map <Down>   <Nop>
 503 imap <Right> <Nop>
 504 imap <Left>  <Nop>
 505 imap <Up>    <Nop>
 506 imap <Down>  <Nop>
 507 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 508 " below).
 509 cmap <Up>    <Nop>
 510 cmap <Down>  <Nop>
 511 cmap <Right> <Nop>
 512 cmap <Left>  <Nop>
 513
 514 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 515 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 516 cnoremap <C-P> <Up>
 517 cnoremap <C-N> <Down>
 518
 519 if has('eval')
 520 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 521 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 522 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 523 " directly because it also enables that feature for other commands which I
 524 " don't want.
 525
 526     " Set 'nostartofline' for a single movement.
 527     function! s:TemporaryNostartofline(movement)
 528         let l:startofline = &startofline
 529         set nostartofline
 530         execute 'normal! ' . a:movement
 531         let &startofline = l:startofline
 532     endfunction
 533
 534     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 535     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 536     nnoremap <silent> <C-F>
 537         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 538     nnoremap <silent> <C-B>
 539         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 540     nnoremap <silent> <C-D>
 541         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 542     nnoremap <silent> <C-U>
 543         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 544 endif
 545
 546 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 547 " yank a line. This fixes a weird inconsistency in Vi(m).
 548 nnoremap Y y$
 549
 550 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 551 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 552 " Only the current buffer is written, thus switching to another buffer works
 553 " too.
 554 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 555
 556 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 557 " in #vim on Freenode (2011-08-15 00:17 CEST).
 558 nnoremap <C-G> 2<C-G>
 559
 560 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 561 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 562 nmap <Space> <C-F>
 563 nmap - <C-B>
 564
 565 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 566 " (2010-05-16 18:38 CEST) for this idea.
 567 nnoremap <silent> gb :bnext<CR>
 568 nnoremap <silent> gB :bprevious<CR>
 569 if has('eval')
 570     " But when starting again at the first buffer, print a warning which
 571     " reminds me that I've already seen that buffer.
 572     function! s:NextBuffer()
 573         " Are we currently on the last buffer and moving to the first?
 574         let l:last_buffer = 0
 575         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 576             let l:last_buffer = 1
 577         endif
 578
 579         " Go to the next buffer.
 580         if !l:last_buffer
 581             bnext
 582
 583         " Go to the first buffer, silent is necessary or the following message
 584         " won't be displayed because it's overwritten by the status message
 585         " displayed when entering a buffer.
 586         else
 587             silent bnext
 588
 589             echohl WarningMsg
 590             echo 'Starting again at first buffer.'
 591             echohl None
 592         endif
 593     endfunction
 594     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 595 endif
 596
 597 " Fast access to buffers.
 598 nnoremap <silent> <Leader>1 :1buffer<CR>
 599 nnoremap <silent> <Leader>2 :2buffer<CR>
 600 nnoremap <silent> <Leader>3 :3buffer<CR>
 601 nnoremap <silent> <Leader>4 :4buffer<CR>
 602 nnoremap <silent> <Leader>5 :5buffer<CR>
 603 nnoremap <silent> <Leader>6 :6buffer<CR>
 604 nnoremap <silent> <Leader>7 :7buffer<CR>
 605 nnoremap <silent> <Leader>8 :8buffer<CR>
 606 nnoremap <silent> <Leader>9 :9buffer<CR>
 607 nnoremap <silent> <Leader>0 :10buffer<CR>
 608
 609 " Use real tabs instead of soft tabs.
 610 if has('eval')
 611 " Switch from soft tabs to real tabs.
 612     function! s:UseTabs()
 613         setlocal noexpandtab shiftwidth=8 softtabstop=8
 614     endfunction
 615     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 616 endif
 617 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 618 " coloring.
 619 nnoremap <silent> <Leader>v :set nolist nowrap nospell synmaxcol=0<CR>
 620                           \ :2match<CR>
 621
 622 " Make last active window the only window. Similar to <C-W> o.
 623 nnoremap <C-W>O <C-W>p<C-W>o
 624
 625 " Maps to change spell language between English and German and disable spell
 626 " checking.
 627 if exists('+spell')
 628     nnoremap <silent> <Leader>sn :set nospell<CR>
 629     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 630     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 631 " If no spell support is available, these mappings do nothing.
 632 else
 633     nmap <Leader>sn <Nop>
 634     nmap <Leader>se <Nop>
 635     nmap <Leader>sd <Nop>
 636 endif
 637
 638 if has('eval')
 639 " * and # for selections in visual mode. Thanks to
 640 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 641 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 642     function! s:VSetSearch()
 643         let l:temp = @@ " unnamed register
 644         normal! gvy
 645         " Added \C to force 'noignorecase' while searching the current visual
 646         " selection. I want to search for the exact string in this case.
 647         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 648         let @@ = l:temp
 649     endfunction
 650     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 651     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 652
 653 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 654 " Thanks to the writers of s:VSetSearch(), see above.
 655     function! s:NSetSearch()
 656         let l:cword = expand('<cword>')
 657         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 658         let @/ = '\C\V'. '\<' . l:regex . '\>'
 659     endfunction
 660     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 661     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 662 endif
 663
 664 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 665 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 666 " mailing list for the commands.
 667 if v:version < 700
 668     cnoreabbrev W w
 669     cnoreabbrev Wa wa
 670     cnoreabbrev Wq wq
 671     cnoreabbrev Wqa wqa
 672 else
 673     cnoreabbrev <expr> W
 674         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 675     cnoreabbrev <expr> Wa
 676         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 677     cnoreabbrev <expr> Wq
 678         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 679     cnoreabbrev <expr> Wqa
 680         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 681 endif
 682 " Also fix my typo with "Q".
 683 if v:version < 700
 684     cnoreabbrev Q q
 685     cnoreabbrev Qa qa
 686 else
 687     cnoreabbrev <expr> Q
 688         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 689     cnoreabbrev <expr> Qa
 690         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 691 endif
 692
 693 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 694 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 695 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 696
 697 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 698 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 699 " Vim's source.
 700 inoremap <C-U> <C-G>u<C-U>
 701 " Same for <C-@> (insert previously inserted text and leave insert mode).
 702 inoremap <C-@> <C-G>u<C-@>
 703 " And for <C-A> (insert previously inserted text).
 704 inoremap <C-A> <C-G>u<C-A>
 705 " And for <C-W> (delete word before cursor).
 706 inoremap <C-W> <C-G>u<C-W>
 707
 708 if has('eval')
 709 " New text-objects ii and ai to work on text with the same indentation. Thanks
 710 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 711 " (visited on 2011-11-19).
 712     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 713     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 714     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 715     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 716
 717     function! s:IndTxtObj(inner)
 718         let curline = line(".")
 719         let lastline = line("$")
 720         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 721         let i = i < 0 ? 0 : i
 722         if getline(".") !~ "^\\s*$"
 723             let p = line(".") - 1
 724             let nextblank = getline(p) =~ "^\\s*$"
 725             while p > 0
 726                     \ && ((i == 0 && !nextblank)
 727                         \ || (i > 0 && ((indent(p) >= i
 728                             \ && !(nextblank && a:inner))
 729                             \ || (nextblank && !a:inner))))
 730                 -
 731                 let p = line(".") - 1
 732                 let nextblank = getline(p) =~ "^\\s*$"
 733             endwhile
 734             normal! 0V
 735             call cursor(curline, 0)
 736             let p = line(".") + 1
 737             let nextblank = getline(p) =~ "^\\s*$"
 738             while p <= lastline
 739                     \ && ((i == 0 && !nextblank)
 740                         \ || (i > 0 && ((indent(p) >= i
 741                             \ && !(nextblank && a:inner))
 742                             \ || (nextblank && !a:inner))))
 743                 +
 744                 let p = line(".") + 1
 745                 let nextblank = getline(p) =~ "^\\s*$"
 746             endwhile
 747             normal! $
 748         endif
 749     endfunction
 750 endif
 751
 752
 753 " ABBREVIATIONS
 754
 755 " Fix some of my spelling mistakes (German).
 756 inoreabbrev relle reelle
 757 inoreabbrev reele reelle
 758 " Fix some of my spelling mistakes (English).
 759 inoreabbrev completly completely
 760
 761
 762 " SYNTAX SETTINGS
 763
 764 " Activate syntax coloring.
 765 if has('syntax')
 766     syntax enable
 767
 768 " Don't highlight more than 500 columns as I normally don't have that long
 769 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 770 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 771     if exists('+synmaxcol')
 772         set synmaxcol=500
 773     endif
 774
 775 " Use (limited) syntax based omni completion if no other omni completion is
 776 " available. Taken from :help ft-syntax-omni.
 777     if has('autocmd') && exists('+omnifunc')
 778         augroup vimrc
 779             autocmd FileType *
 780                 \ if &omnifunc == '' |
 781                 \     setlocal omnifunc=syntaxcomplete#Complete |
 782                 \ endif
 783         augroup END
 784     endif
 785
 786 " Function to enable all custom highlights. Necessary as highlights are
 787 " window-local and thus must be set for each new window.
 788     function! s:CustomSyntaxHighlights()
 789         " Not the first time called, nothing to do.
 790         if exists('w:vimrc_syntax_run')
 791             return
 792         endif
 793         let w:vimrc_syntax_run = 1
 794
 795 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 796 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 797 " disabled when necessary with :2match (in Vim >= 700).
 798         if !&diff && exists(':2match')
 799             " Use ColorColumn for overlong lines if available and my color
 800             " scheme is used.
 801             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 802                 2match ColorColumn /\%>78v./
 803             else
 804                 2match Todo /\%>78v./
 805             endif
 806         elseif !&diff
 807             match Todo /\%>78v./
 808         endif
 809
 810         if exists('*matchadd')
 811 " Highlight some important keywords in all documents.
 812             let l:todos = ['TODO', 'XXX', 'FIXME',
 813                          \ 'CHANGED', 'REMOVED', 'DELETED']
 814             " Compatibility fix for Vim 6.4 which can't handle for in function
 815             " (without function it's ignored).
 816             execute '  for l:x in l:todos'
 817                   \ '|     call matchadd("Todo", l:x)'
 818                   \ '| endfor'
 819
 820 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 821             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 822                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 823                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 824                           \ '205f', '2060', '3000', 'feff']
 825             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 826             " it won't work!
 827             execute '  for l:x in l:spaces'
 828                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 829                   \ '| endfor'
 830
 831 " Special highlight for tabs to reduce their visibility in contrast to other
 832 " SpecialKey characters (e.g. ^L).
 833             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 834                 call matchadd('specialKeyTab', '\t')
 835             endif
 836         endif
 837     endfunction
 838 " Enable highlights for the current and all new windows. Thanks to bairui in
 839 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 840     call s:CustomSyntaxHighlights()
 841     if has('autocmd')
 842         augroup vimrc
 843             autocmd WinEnter * call s:CustomSyntaxHighlights()
 844         augroup END
 845     endif
 846
 847 " Settings for specific filetypes.
 848
 849     " C
 850     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 851     " Haskell.
 852     let g:hs_highlight_delimiters = 1
 853     let g:hs_highlight_boolean = 1
 854     let g:hs_highlight_types = 1
 855     let g:hs_highlight_more_types = 1
 856     " Java.
 857     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 858     " Perl.
 859     let g:perl_fold = 1
 860     let g:perl_fold_blocks = 1
 861     let g:perl_nofold_packages = 1
 862     let g:perl_include_pod = 1 " syntax coloring for PODs
 863     " PHP.
 864     let g:php_folding = 3    " fold functions
 865     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 866     let g:php_sql_query = 1  " highlight SQL queries in strings
 867     " Python.
 868     let g:python_highlight_all = 1
 869     " Shell.
 870     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 871     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 872     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 873     " Vim.
 874     let g:vimsyn_embed = 0      " don't highlight embedded languages
 875     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 876     " XML.
 877     let g:xml_syntax_folding = 1
 878 endif
 879
 880
 881 " PLUGIN SETTINGS
 882
 883 if has('eval')
 884 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 885 " installing/removing/updating plugins simple. (Used for plugins with more
 886 " than one file.) Ignore errors in case pathogen is not installed.
 887     if v:version >= 700
 888         silent! execute 'call pathogen#infect()'
 889     endif
 890
 891 " Settings for securemodelines.
 892     " Only allow items I need (also includes spl which is not enabled by
 893     " default).
 894     if v:version >= 700 " need lists
 895         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 896                                               \ 'sw', 'sts', 'noet']
 897     endif
 898
 899 " Settings for the NERD commenter.
 900     " Don't create any mappings I don't want to use.
 901     let g:NERDCreateDefaultMappings = 0
 902     " Map toggle comment.
 903     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 904
 905 " XPTemplate settings.
 906     " Try to maintain snippet rendering even after editing outside of a
 907     " snippet.
 908     let g:xptemplate_strict = 0
 909     " Don't complete any braces automatically.
 910     let g:xptemplate_brace_complete = 0
 911     " Only highlight the current placeholder.
 912     let g:xptemplate_highlight = 'current'
 913
 914 " CtrlP settings.
 915     " Don't manage the working directory (the default setting is too slow for
 916     " me).
 917     let g:ctrlp_working_path_mode = 0
 918
 919     " Path to cache directory. I prefer to keep generated files as local as
 920     " possible.
 921     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 922     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 923     " cache manually.
 924     let g:ctrlp_clear_cache_on_exit = 0
 925
 926     " Don't switch the window if the selected buffer is already open. I want
 927     " to open another view on this buffer in most cases.
 928     let g:ctrlp_switch_buffer = 0
 929
 930 " FSWitch settings.
 931     " Defaults don't work well for my projects.
 932     augroup vimrc
 933         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 934                           \ | let b:fswitchlocs = './'
 935         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 936                           \ | let b:fswitchlocs = './'
 937     augroup END
 938
 939     " Switch to corresponding header/source file.
 940     nnoremap <silent> <Leader>h :FSHere<CR>
 941
 942 " netrw settings.
 943     " Don't create ~/.vim/.netrwhist history file.
 944     let g:netrw_dirhistmax = 0
 945 endif
 946
 947
 948 " AUTO COMMANDS
 949
 950 " Use a custom auto group to prevent problems when the vimrc files is sourced
 951 " twice.
 952 if has('autocmd')
 953     augroup vimrc
 954
 955 " Go to last position of opened files. Taken from :help last-position-jump.
 956         autocmd BufReadPost *
 957             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 958             \     execute "normal! g'\"" |
 959             \ endif
 960 " But not for Git commits, go to beginning of the file.
 961         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 962
 963 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 964 " when switching to a help buffer which is in the background with :buffer as
 965 " these options are local to windows (and not only to buffers). This happens
 966 " because I often want to use only one window and thus the help buffer is in
 967 " the background.
 968         autocmd BufWinEnter *.txt
 969             \ if &filetype == 'help' |
 970             \     setlocal nolist |
 971             \     setlocal nonumber |
 972             \ endif
 973
 974 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 975 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 976 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 977 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
 978 " 'paste' in this case.
 979         if exists('##InsertLeave')
 980             autocmd InsertLeave * set nopaste
 981         endif
 982
 983 " Write all files when running :mak[e] before 'makeprg' is called.
 984 " QuickFixCmdPre doesn't exist in older Vims.
 985         if exists('##QuickFixCmdPre')
 986             autocmd QuickFixCmdPre * wall
 987         endif
 988
 989 " Don't ignore case while in insert mode, but ignore case in all other modes.
 990 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 991 " capitalization. But while searching (/) 'ignorecase' is used.
 992 " InsertEnter/InsertLeave doesn't exist in older Vims.
 993         if exists('##InsertEnter') && exists('##InsertLeave')
 994             autocmd InsertEnter * set noignorecase
 995             autocmd InsertLeave * set   ignorecase
 996         endif
 997
 998 " Display a warning when editing a file which contains "do not edit" (ignoring
 999 " the case) and similar messages in the first lines of the file, for example
1000 " template files which were preprocessed or auto-generated files. Especially
1001 " useful when the header is not displayed on the first screen, e.g. when the
1002 " old position is restored.
1003         function! s:SearchForDoNotEditHeader()
1004             " Only search the first 20 lines to prevent false positives, e.g.
1005             " in scripts which write files containing this warning and ignore
1006             " the case (\c). (Can't use search()'s {stopline} as we might not
1007             " start searching from the top.)
1008             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1009             let l:match = search(l:search, 'n')
1010             if l:match == 0 || l:match > 20
1011                 return
1012             endif
1013
1014             echoerr 'Do not edit this file! (Maybe a template file.)'
1015         endfunction
1016         autocmd BufRead * call s:SearchForDoNotEditHeader()
1017
1018 " AFTER/FTPLUGIN AUTO COMMANDS
1019
1020 " Disable spell checking for files which don't need it.
1021         autocmd FileType deb  setlocal nospell
1022         autocmd FileType diff setlocal nospell
1023         autocmd FileType tar  setlocal nospell
1024 " Fix to allow Vim edit crontab files as crontab doesn't work with
1025 " backupcopy=auto.
1026         autocmd FileType crontab setlocal backupcopy=yes
1027 " Don't use the modeline in git commits as the diff created by `git commit -v`
1028 " may contain one which could change the filetype or other settings of the
1029 " commit buffer. Also make sure we use only 72 characters per line which is
1030 " the recommendation for git commit messages (http://tpope.net/node/106).
1031         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1032                                  \ setlocal textwidth=72
1033 " Fix 'include' setting for shell files to recognize '.' and 'source'
1034 " commands. Use &l:include instead of setlocal which requires excessive
1035 " escaping of \.
1036         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1037 " Use the same comment string as for Vim files in Vimperator files.
1038         autocmd FileType vimperator setlocal commentstring=\"%s
1039 " Use TeX compiler for (La)TeX files.
1040         autocmd FileType tex compiler tex
1041
1042 " FTDETECT AUTO COMMANDS
1043
1044 " Recognize .md as markdown files (Vim default is .mkd).
1045         autocmd BufRead,BufNewFile *.md set filetype=mkd
1046 " Recognize .test as Tcl files.
1047         autocmd BufRead,BufNewFile *.test set filetype=tcl
1048
1049 " OTHER AUTO COMMANDS
1050
1051 " Disable spell checking, displaying of list characters and long lines when
1052 " viewing documentation.
1053         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1054
1055 " Use diff filetype for mercurial patches in patch queue.
1056         autocmd BufReadPost */.hg/patches/* set filetype=diff
1057
1058     augroup END
1059 endif
1060
1061
1062 " CUSTOM FUNCTIONS AND COMMANDS
1063
1064 if has('eval')
1065 " Convenient command to see the difference between the current buffer and the
1066 " file it was loaded from, thus the changes you made. Thanks to the
1067 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1068 " for the diffed file as the filetype for the original file.
1069     if !exists(':DiffOrig')
1070         command DiffOrig
1071             \ let s:diff_orig_filetype = &filetype
1072             \ | vertical new
1073             \ | let &filetype = s:diff_orig_filetype
1074             \ | unlet s:diff_orig_filetype
1075             \ | set buftype=nofile
1076             \ | read ++edit #
1077             \ | 0d_
1078             \ | diffthis
1079             \ | wincmd p
1080             \ | diffthis
1081     endif
1082 endif