zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 # MISCELLANEOUS SETTINGS
   5
   6 # Use Vi(m) style key bindings.
   7 bindkey -v
   8
   9 # Be paranoid, new files are readable/writable by me only.
  10 umask 077
  11
  12 # Make sure core dumps are created.
  13 ulimit -c unlimited
  14
  15 # Prevent overwriting existing files with '> filename', use '>| filename'
  16 # (or >!) instead.
  17 setopt noclobber
  18
  19 # Entering the name of a directory (if it's not a command) will automatically
  20 # cd to that directory.
  21 setopt autocd
  22
  23 # When entering a nonexistent command name automatically try to find a similar
  24 # one.
  25 setopt correct
  26
  27 # Enable zsh's extended glob abilities.
  28 setopt extendedglob
  29
  30 # Don't exit if <C-d> is pressed.
  31 setopt ignoreeof
  32
  33
  34 # HISTORY SETTINGS
  35
  36 # Use history and store it in ~/.zsh/history.
  37 HISTSIZE=1000
  38 SAVEHIST=1000
  39 HISTFILE=~/.zsh/history
  40 # Append to the history file instead of overwriting it and do it immediately
  41 # when a command is executed.
  42 setopt appendhistory
  43 setopt incappendhistory
  44 # If the same command is run multiple times store it only once in the history.
  45 setopt histignoredups
  46 # Vim like completions of previous executed commands.
  47 bindkey "^P" history-beginning-search-backward
  48 bindkey "^N" history-beginning-search-forward
  49
  50
  51 # PROMPT SETTINGS
  52
  53 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  54 autoload -Uz add-zsh-hook
  55
  56 # Use colorized output, necessary for prompts and completions.
  57 autoload -U colors && colors
  58
  59 # Set the default prompt. The current host and working directory is displayed,
  60 # the exit code of the last command if it wasn't 0, the number of running jobs
  61 # if not 0 and a + if this shell is running inside another shell.
  62 # The prompt is in green and blue to make easily detectable, the error exit
  63 # code in red and bold and the job count in yellow.
  64 PROMPT="%{${fg[green]}%}%B%m%b%{${fg[default]}%}:\
  65 %{${fg[blue]}%}%B%~%b%{${fg[default]}%} \
  66 %(1j.%{${fg[yellow]}%}%j%{${fg[default]}%}.)%(2L.+.)%# \
  67 %(?..(%{${fg[red]}%}%B%?%b%{${fg[default]}%}%) )"
  68
  69 # Allow substitutions and expansions in the prompt, necessary for vcs_info.
  70 setopt promptsubst
  71 # Load vcs_info to display information about version control repositories.
  72 autoload -Uz vcs_info
  73 # Only look for git and mercurial repositories; the only I use.
  74 zstyle ':vcs_info:*' enable git hg
  75 # Set style of vcs_info display. The current branch (green) and vcs (blue) is
  76 # displayed. If there is an special action going on (merge, rebase) it's also
  77 # displayed (red).
  78 zstyle ':vcs_info:*' formats \
  79 "(%{${fg[green]}%}%b%{${fg[default]}%}:\
  80 %{${fg[blue]}%}%s%{${fg[default]}%})"
  81 zstyle ':vcs_info:*' actionformats \
  82 "(%{${fg[green]}%}%b%{${fg[default]}%}/\
  83 %{${fg[red]}%}%a%{${fg[default]}%}:\
  84 %{${fg[blue]}%}%s%{${fg[default]}%})"
  85 # Call vcs_info as precmd before every prompt.
  86 prompt_precmd() {
  87     vcs_info
  88 }
  89 add-zsh-hook precmd prompt_precmd
  90
  91 # Display the vcs information in the right prompt.
  92 RPROMPT='${vcs_info_msg_0_}'
  93
  94 # When screen is used set the name of the window to the currently running
  95 # program.
  96 #
  97 # When a program is started preexec() sets the window's name to it; when it
  98 # stops precmd() resets the windows' name to 'zsh'.
  99 if [[ $TERM == screen ]]; then
 100     # Set to a non empty value to reset the window name in the next precmd()
 101     # call.
 102     screen_name_reset=yes
 103
 104     screen_preexec() {
 105         # Ignore often used commands which are only running for a very short
 106         # time. This prevents a "blinking" name when it's changed to "cd" for
 107         # example and then some milliseconds later back to "zsh".
 108         [[ ${1%% *} == (cd*|ls|la|ll|clear) ]] && return
 109
 110         # Set the window name to the currently running program.
 111         print -n "\ek${1%% *}\e\\"
 112
 113         # Tell precmd() to reset the window name when the program stops.
 114         screen_name_reset=yes
 115     }
 116
 117     screen_precmd() {
 118         # Abort if no window name reset is necessary.
 119         [[ -z $screen_name_reset ]] && return
 120
 121         # Reset the window name to 'zsh'.
 122         print -n "\ekzsh\e\\"
 123
 124         # Just reset the name, so no screen reset necessary for the moment.
 125         screen_name_reset=
 126     }
 127
 128     # Add the preexec() and precmd() hooks.
 129     add-zsh-hook preexec screen_preexec
 130     add-zsh-hook precmd screen_precmd
 131 fi
 132
 133
 134 # COMPLETION SETTINGS
 135
 136 # Use new completion system.
 137 autoload -U compinit && compinit
 138 # Load the complist module which provides additions to completion lists
 139 # (coloring, scrollable).
 140 zmodload zsh/complist
 141 # Make sure the list of possible completions is displayed after pressing <TAB>
 142 # the first time.
 143 setopt nolistambiguous
 144 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 145 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 146 bindkey "^I" expand-or-complete-prefix
 147 # Use cache to speed up completions.
 148 zstyle ':completion:*' use-cache on
 149 zstyle ':completion:*' cache-path ~/.zsh/cache
 150 # Try uppercase if the currently typed string doesn't match. This allows
 151 # typing in lowercase most of the time and completion fixes the case.
 152 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 153 # Ignore completion functions.
 154 zstyle ':completion:*:functions' ignored-patterns '_*'
 155 # Ignore parent directory.
 156 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 157 # Use ls like colors for completions.
 158 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 159 # Make completion lists scrollable so "do you wish to see all n possibilities"
 160 # is no longer displayed.
 161 zstyle ':completion:*' list-prompt '%p'
 162 # When unsetting variables make sure every variable name is only suggested
 163 # once.
 164 zstyle ':completion:*:unset:*' ignore-line yes
 165 # When working with Mercurial and Git don't complete the same file multiple
 166 # times. Very useful when completing file names.
 167 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 168
 169
 170 # ALIAS AND FUNCTION SETTINGS
 171
 172 # Simplify calls to less, automatically redirects all output.
 173 alias -g L='2>&1 | less'
 174 # Simplify calls to colordiff, output is also piped through less.
 175 alias -g D='2>&1 | colordiff L'
 176 # Simplify calls to grep.
 177 alias -g G='| grep'
 178
 179 # Automatically use unified diffs.
 180 alias diff='diff -u'
 181
 182 # Display all files and use human readable sizes.
 183 alias du='du -sh'
 184
 185 # Multiple files given to Vim are opened in tabs.
 186 alias vim='vim -p'
 187 # Shortcuts for Vim.
 188 alias v='vim'
 189 alias vi='vim'
 190
 191 # Exit binding like in Vim.
 192 alias :q='exit'
 193
 194 # Edit the mercurial patch queue series file for the current mercurial
 195 # repository in Vim. Also change Vim's pwd to the patches directory so other
 196 # patches can easily be opened.
 197 alias vqs='vim -c "cd $(hg root)/.hg/patches/" "$(hg root)/.hg/patches/series"'
 198
 199 # Make going up directories simple.
 200 alias -g ...='../..'
 201 alias -g ....='../../..'
 202
 203 # Improved ls which displays the files in columns (-C), visualizes directories,
 204 # links and other special files (-F) and pages everything through less (L).
 205 #
 206 # If available use GNU ls with colorized output. If it isn't available use
 207 # normal ls which needs CLICOLOR_FORCE so it displays colors when used with a
 208 # pager.
 209 ls --color &> /dev/null
 210 if [[ $? -eq 0 ]]; then
 211     alias ls='ls --color'
 212 else
 213     alias ls='CLICOLOR_FORCE=1 ls -G'
 214 fi
 215 # Main ls function.
 216 function ls() {
 217     command ls -C -F $* L
 218 }
 219 # Helper function to list all files.
 220 function la() {
 221     ls -a $*
 222 }
 223 # Helper function to list all files in list format with access rights, etc.
 224 function ll() {
 225     la -l $*
 226 }
 227
 228 # If ^C is pressed while typing a command, add it to the history so it can be
 229 # easily retrieved later and then abort like ^C normally does. This is useful
 230 # when I want to abort an command to do something in between and then finish
 231 # typing the command.
 232 TRAPINT() {
 233     # Store the current buffer in the history.
 234     zle && print -s $BUFFER
 235
 236     # Return the default exit code so zsh aborts the current command.
 237     return $1
 238 }
 239
 240 # Execute all periodic functions every hour.
 241 PERIOD=3600
 242 # Display TODOs stored in ~/.todo if this file exists. Run every hour to make
 243 # clear they should be completed ;-).
 244 todo() {
 245     if [[ -f ~/.todo ]]; then
 246         cat ~/.todo | $PAGER
 247     fi
 248 }
 249 add-zsh-hook periodic todo
 250
 251
 252 # Load rc file for current OS.
 253 source_config ~/.zsh os rc $(uname) nolocal
 254 # Load rc file for current hostname (first part before a dot) or rc.local.
 255 source_config ~/.zsh host rc ${$(hostname)//.*/}