zsh/rc: prepend "--" in X alias
[config/dotfiles.git] / shell / zsh / rc
1 # Zsh configuration file.
2
3 # Copyright (C) 2011-2018  Simon Ruderich
4 #
5 # This file is free software: you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation, either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # This file is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 # GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
17
18
19 # Warn when creating global variables from inside a function. Needs to be set
20 # before declaring a function.
21 setopt warn_create_global
22
23
24 # HELPER FUNCTIONS
25
26 # Return the name of the program which is called in the foreground with `fg`.
27 # $1 is the name of the program (optional). If it's not 'fg' or 'fg *' it's
28 # returned unchanged.
29 zshrc_resolve_fg_to_resumed_job_name() {
30     # $REPLY is used by convention for scalars ($reply for arrays) to return
31     # values from functions. unset it here to prevent problems when REPLY is
32     # bound to an integer or similar. Thanks to Mikachu in #zsh on Freenode
33     # (2012-09-27 17:14 CEST) for this hint.
34     unset REPLY
35
36     # Replace fg with the resumed job name.
37     if [[ $1 == fg ]]; then
38         REPLY=${jobtexts[%+]}
39     elif [[ $1 == fg\ * ]]; then
40         REPLY=${jobtexts[${1#fg }]}
41     # Normal program, return as is.
42     else
43         REPLY=$1
44     fi
45 }
46
47
48 # MISCELLANEOUS SETTINGS
49
50 # Prevent warnings.
51 typeset -g TMOUT
52 # Load general shell setup commands. NOTE: Expand this when publishing the
53 # config.
54 source_config ~/.shell/rc
55
56 # Disable beeps.
57 setopt nobeep
58
59 # Prevent overwriting existing files with '> filename', use '>| filename'
60 # (or >!) instead.
61 setopt noclobber
62
63 # Entering the name of a directory (if it's not a command) will automatically
64 # cd to that directory.
65 setopt autocd
66
67 # When entering a nonexistent command name automatically try to find a similar
68 # one.
69 setopt correct
70
71 # Enable zsh's extended glob abilities.
72 setopt extendedglob
73
74 # Don't exit if <C-D> is pressed. Prevents exiting the shell by accident (e.g.
75 # pressing <C-D> twice).
76 setopt ignoreeof
77
78 # Also display PID when suspending a process.
79 setopt longlistjobs
80
81
82 # KEY BINDINGS
83
84 # Not all bindings are done here, only those not specific to a given section.
85
86 # Use Vi(m) style key bindings.
87 bindkey -v
88
89 # Use jk to exit insert mode (jj is too slow to type).
90 bindkey 'jk' vi-cmd-mode
91
92 # I don't need the arrow keys, I use ^N and ^P for this (see below).
93 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
94 # Also not in Vi mode.
95 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
96
97
98 # FUNCTION SETTINGS
99
100 # Make sure every entry in $fpath is unique.
101 typeset -U fpath
102 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
103 # of a Zsh Git checkout. Use it to get the newest completions if available.
104 if [[ -d ~/.zsh/functions/completion ]]; then
105     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
106 fi
107 # Set correct fpath to allow loading my functions (including completion
108 # functions).
109 fpath=(~/.zsh/functions $fpath)
110 # Autoload my functions (except completion functions and hidden files). Thanks
111 # to caphuso from the Zsh example files for this idea. Check if there are any
112 # functions to load or autoload fails; thanks to okdana in #zsh on Freenode
113 # (2018-07-18 09:29 CEST) for the idea to use (#qNY1) for the check.
114 if [[ -d ~/.zsh/functions && -n ${fpath[1]}/^_*(#qNY1^/:t) ]]; then
115     autoload -Uz ${fpath[1]}/^_*(^/:t)
116 fi
117
118 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
119 # the moment only precmd(), preexec() and chpwd() are simulated.
120 if [[ $ZSH_VERSION != (4.3.<4->*|4.<4->*|<5->*) ]]; then
121     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
122     # arrays.
123     function precmd() {
124         for function in $precmd_functions; do
125             $function "$@"
126         done
127     }
128     function preexec() {
129         for function in $preexec_functions; do
130             $function "$@"
131         done
132     }
133     function chpwd() {
134         for function in $chpwd_functions; do
135             $function "$@"
136         done
137     }
138 fi
139
140 # Load zmv (zsh move) which is a powerful file renamer.
141 autoload -Uz zmv
142
143
144 # HISTORY SETTINGS
145
146 # Use history and store it in ~/.zsh/history.
147 HISTSIZE=1000000
148 SAVEHIST=1000000
149 HISTFILE=~/.zsh/history
150 # Append to the history file instead of overwriting it and do it immediately
151 # when a command is executed.
152 setopt appendhistory
153 setopt incappendhistory
154 # If the same command is run multiple times store it only once in the history.
155 setopt histignoredups
156 # Don't add lines starting with a space to the history.
157 setopt histignorespace
158
159 # Vim like completions of previous executed commands (also enter Vi-mode). If
160 # called at the beginning it just recalls old commands (like cursor up), if
161 # called after typing something, only lines starting with the typed text are
162 # returned. Very useful to get old commands quickly - in addition to the
163 # history commands (!..). Thanks to Mikachu in #zsh on Freenode (2010-01-17
164 # 12:47 CET) for the information how to a use function with bindkey.
165 zle -N zshrc-vi-history-beginning-search-backward
166 zshrc-vi-history-beginning-search-backward() {
167     local not_at_beginning_of_line
168     if [[ $CURSOR -ne 0 ]]; then
169         not_at_beginning_of_line=yes
170     fi
171
172     zle history-beginning-search-backward
173
174     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
175     # this counters it).
176     zle vi-cmd-mode
177     if [[ -n $not_at_beginning_of_line ]]; then
178         zle vi-forward-char
179     fi
180 }
181 bindkey '^P' zshrc-vi-history-beginning-search-backward
182 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
183 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
184 # after calling ^P.
185 bindkey -a '^N' history-beginning-search-forward
186
187 # Use current input when pressing Ctrl-R. Thanks to Mikachu in #zsh on
188 # Freenode (2016-07-08 20:54 CEST).
189 zshrc-history-incremental-pattern-search-backward() {
190     zle .history-incremental-pattern-search-backward $BUFFER
191 }
192 zle -N history-incremental-pattern-search-backward \
193     zshrc-history-incremental-pattern-search-backward
194 # Enable incremental search which is especially useful when the string is an
195 # argument and not the command.
196 bindkey '^R' history-incremental-pattern-search-backward
197 # Also enable my usual use of Ctrl-P/Ctrl-N to get the previous/next matching
198 # history entry.
199 if [[ $ZSH_VERSION == (4.<4->*|<5->*) ]]; then
200     bindkey -M isearch '^P' history-incremental-pattern-search-backward
201     bindkey -M isearch '^N' history-incremental-pattern-search-forward
202 fi
203
204 # Automatically push cd-ed directories on the directory stack.
205 setopt autopushd
206 # Don't push duplicates on the directory stack.
207 setopt pushdignoredups
208 # Exchange the meaning of + and - when specifying a directory on the stack.
209 # This way cd -<Tab> lists the last used directory first, which is more
210 # natural because cd - goes to the last directory.
211 setopt pushdminus
212
213
214 # PROMPT SETTINGS
215
216 # Use colorized output, necessary for prompts and completions.
217 autoload -Uz colors; colors
218
219 # Necessary for $EPOCHSECONDS, the UNIX time.
220 zmodload zsh/datetime
221
222 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
223 # doesn't need any space, necessary for correct prompt drawing. Use %F{color}
224 # in more recent zsh versions (here compatibility is important).
225 local red="%{${fg[red]}%}"
226 local blue="%{${fg[blue]}%}"
227 local green="%{${fg[green]}%}"
228 local yellow="%{${fg[yellow]}%}"
229 local default="%{${fg[default]}%}"
230
231 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
232 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
233 # symbolic link to current checkout of Zsh's sources).
234 if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
235       -d ~/.zsh/functions/vcs_info ]]; then
236     # Update fpath to allow loading the vcs_info functions.
237     if [[ -d ~/.zsh/functions/vcs_info ]]; then
238        fpath=(~/.zsh/functions/vcs_info/
239               ~/.zsh/functions/vcs_info/Backends
240               $fpath)
241     fi
242
243     # Load vcs_info to display information about version control repositories.
244     autoload -Uz vcs_info
245     # Only look for certain VCS.
246     zstyle ':vcs_info:*' enable git
247     # Check the repository for changes so they can be used in %u/%c (see
248     # below). This comes with a speed penalty for bigger repositories.
249     zstyle ':vcs_info:*' check-for-changes yes
250
251     # Set style of vcs_info display. The current branch (green) and VCS (blue)
252     # is displayed. If there is an special action going on (merge, rebase)
253     # it's also displayed (red). Also display if there are unstaged or staged
254     # (%u/%c) changes.
255     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
256           -d ~/.zsh/functions/vcs_info ]]; then
257         zstyle ':vcs_info:*' formats \
258             "(${green}%b%u%c${default}:${blue}%s${default}%m)" \
259             "${green}%u%c${default}"
260         zstyle ':vcs_info:*' actionformats \
261             "(${green}%b%u%c${default}/${red}%a${default}:${blue}%s${default}%m)" \
262             "${green}%u%c${default}"
263     else
264         # In older versions %u and %c are not defined yet and are not
265         # correctly expanded.
266         zstyle ':vcs_info:*' formats \
267             "(${green}%b${default}:${blue}%s${default})"
268         zstyle ':vcs_info:*' actionformats \
269             "(${green}%b${default}/${red}%a${default}:${blue}%s${default})"
270     fi
271     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
272     # changes are detected in the repository; check-for-changes must be set to
273     # true for this to work. Thanks to Bart Trojanowski
274     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
275     # (2010-03-11 00:20 CET).
276     zstyle ':vcs_info:*' unstagedstr '¹'
277     zstyle ':vcs_info:*' stagedstr   '²'
278
279     # Default to run vcs_info. If possible we prevent running it later for
280     # speed reasons. If set to a non empty value vcs_info is run.
281     zshrc_force_run_vcs_info=1
282
283     # Cache system inspired by Bart Trojanowski
284     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
285     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
286     +vi-pre-get-data() {
287         # Only Git and Mercurial support and need caching. Abort if any other
288         # VCS is used.
289         [[ $vcs != git && $vcs != hg ]] && return
290
291         # If the shell just started up or we changed directories (or for other
292         # custom reasons) we must run vcs_info.
293         if [[ -n $zshrc_force_run_vcs_info ]]; then
294             zshrc_force_run_vcs_info=
295             return
296         fi
297
298         # Don't run vcs_info by default to speed up the shell.
299         ret=1
300         # If a git/hg command was run then run vcs_info as the status might
301         # need to be updated.
302         case $(fc -ln $(($HISTCMD-1))) in
303             git* | g\ *)
304                 ret=0
305                 ;;
306             hg*)
307                 ret=0
308                 ;;
309         esac
310     }
311
312     # Display number of WIP stashes (this excludes manually named commits
313     # which might be used for something else), thanks to
314     # http://eseth.org/2010/git-in-zsh.html (viewed on 2013-04-27) for the
315     # idea to display the stash count.
316     function +vi-git-stashes() {
317         if [[ -s ${hook_com[base]/.git/refs/stash} ]]; then
318             local -a stashes
319             # Thanks to Valodim in #zsh on Freenode (2013-07-01 14:14 CEST)
320             # for the solution to "grep" the output with (M) and :#(...).
321             stashes=( ${(M)${(f)"$(git stash list 2>/dev/null)"}:#(*WIP*)} )
322
323             if [[ ${#stashes} -gt 0 ]]; then
324                 hook_com[misc]+=" ${yellow}${#stashes}s${default}"
325             fi
326         fi
327     }
328
329     # Apply hooks to Git.
330     zstyle ':vcs_info:git*+set-message:*' hooks git-stashes
331
332     # Must run vcs_info when changing directories.
333     prompt_chpwd() {
334         zshrc_force_run_vcs_info=1
335     }
336     chpwd_functions+=(prompt_chpwd)
337
338     # Used by prompt code below to determine if vcs_info should be run.
339     zshrc_use_vcs_info=1
340 else
341     zshrc_use_vcs_info=
342 fi
343
344 typeset -a zshrc_longrun_data
345 zshrc_longrun_data=()
346 # Display runtime in seconds for long running programs (> 60 seconds) and send
347 # a bell to notify me.
348 zshrc_longrun_preexec() {
349     local program=$3
350
351     # Handle fg.
352     local REPLY
353     zshrc_resolve_fg_to_resumed_job_name $program
354     program=$REPLY
355
356     # No background process found.
357     if [[ -z $program ]]; then
358         return
359     fi
360
361     # Don't track the time for certain (possible) long running processes which
362     # need no automatic notification.
363     local ignore
364     for ignore in elinks man mutt vim; do
365         case $program in
366             $ignore | $ignore\ *)
367                 zshrc_longrun_data=()
368                 return
369                 ;;
370         esac
371     done
372
373     zshrc_longrun_data=($program $EPOCHSECONDS)
374 }
375 zshrc_longrun_precmd() {
376     # No previous timestamp available or disabled for this command, ignore.
377     if [[ -z $zshrc_longrun_data ]]; then
378         return
379     fi
380
381     local difference=$(( EPOCHSECONDS - zshrc_longrun_data[2] ))
382     if [[ $difference -gt 60 ]]; then
383         echo
384         echo -n "${fg[yellow]}"
385         echo -n "~> ${(V)zshrc_longrun_data[1]} took $difference seconds."
386         echo -n "${fg[default]}"
387         echo    "\a" # send bell
388     fi
389
390     # Clear status. Prevents displaying old status information when pressing
391     # enter with an empty command line.
392     zshrc_longrun_data=()
393 }
394 preexec_functions+=(zshrc_longrun_preexec)
395 precmd_functions+=(zshrc_longrun_precmd)
396
397 # Set the prompt. A two line prompt is used. On the top left the current
398 # working directory is displayed, on the right vcs_info (if available) and the
399 # current time in hex. On the bottom left current user name and host is shown,
400 # the exit code of the last command if it wasn't 0, the number of running jobs
401 # if not 0.
402 #
403 # The prompt is in green and blue to make easily detectable, the error exit
404 # code in red and bold and the job count in yellow. Designed for dark
405 # terminals.
406 #
407 # Thanks to Adam's prompt for the basic idea of this prompt.
408 zshrc_prompt_precmd() {
409     # Regex to remove elements which take no space. Used to calculate the
410     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
411     # Functions/Prompts/prompt_*_setup.
412     local zero='%([BSUbfksu]|([FB]|){*})'
413
414     # Call vcs_info before every prompt.
415     if [[ -n $zshrc_use_vcs_info ]]; then
416         vcs_info
417     else
418         vcs_info_msg_0_=
419         vcs_info_msg_1_=
420     fi
421
422     # Setup. Create variables holding the formatted content.
423
424     # Current directory in yellow, truncated if necessary (WIDTH is replaced
425     # below).
426     local directory="${yellow}%WIDTH<..<%~%<<${default}"
427     # Minimal information about the VCS, only displayed if there are
428     # unstaged/staged changes.
429     local vcs_staged=${vcs_info_msg_1_}
430
431     # Information about the VCS in this directory.
432     local vcs=${vcs_info_msg_0_}
433     # Current time (seconds since epoch) in Hex in bright blue.
434     local seconds="${blue}%B0x$(([##16] EPOCHSECONDS))%b${default}"
435
436     # User name (%n) in bright green.
437     local user="${green}%B%n%b${default}"
438     # Host name (%m) in bright green; underlined if running on a remote system
439     # through SSH.
440     local host="${green}%B%m%b${default}"
441     if [[ -n $SSH_CONNECTION ]]; then
442         host="%U${host}%u"
443     fi
444
445     # Number of background processes in yellow if not zero.
446     local background="%(1j.${yellow}%j${default}.)"
447     # Exit code in bright red in parentheses if not zero.
448     local exitcode="%(?..(${red}%B%?%b${default}%) )"
449     # Prompt symbol, % for normal users, # in red for root.
450     local symbol="%(!.${red}#${default}.%%)"
451
452     # Prefix characters in first and second line.
453     local top_prefix="${blue}%B.-%b${default}"
454     local bottom_prefix="${blue}%B'%b${default}"
455
456     # Combine them to create the prompt.
457
458     local top_left=${vcs_staged}
459     local top_right="${vcs}(${seconds})"
460
461     local width_top_prefix=${#${(S%%)top_prefix//$~zero/}}
462     local width_top_left=${#${(S%%)top_left//$~zero/}}
463     local width_top_right=${#${(S%%)top_right//$~zero/}}
464
465     # Calculate the maximum width of ${top_left}. -2 are the braces of
466     # ${top_left}, -1 is one separator from ${top_separator} (we want at least
467     # one between left and right parts).
468     local top_left_width_max=$((
469         COLUMNS - $width_top_prefix
470                 - $width_top_left - 2
471                 - 1
472                 - $width_top_right
473     ))
474     # Truncate directory if necessary.
475     top_left="(${directory/WIDTH/${top_left_width_max}})${top_left}"
476     width_top_left=${#${(S%%)top_left//$~zero/}}
477
478     # Calculate the width of the top prompt to fill the middle with "-".
479     local width=$((
480         COLUMNS - width_top_prefix - width_top_left - width_top_right
481     ))
482     local top_separator="%B${blue}${(l:${width}::-:)}%b${default}"
483
484     PROMPT="${top_prefix}${top_left}${top_separator}${top_right}
485 ${bottom_prefix}${user}@${host} ${background}${symbol} ${exitcode}"
486 }
487 precmd_functions+=(zshrc_prompt_precmd)
488
489
490 # When GNU screen, tmux, xterm or rxvt is used set the name of the window to
491 # the currently running program.
492 #
493 # When a program is started preexec() sets the window's name to it; when it
494 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
495 # the window's name to the resumed job.
496 #
497 # It works with GNU screen, tmux, xterm and rxvt.
498 #
499 # If a command is run with sudo or if the shell is running as root then a ! is
500 # added at the beginning of the command to make this clear. If a command is
501 # running on a different computer with ssh a @ is added at the beginning. If
502 # screen/tmux is running on the remote machine instead of @screen @:hostname
503 # (or @tmux ..; hostname replaced by the machine's hostname) is displayed.
504 # This only works if the .zshrc on the server also uses this command.
505 #
506 # screen* is necessary as `screen` uses screen.linux for example for a linux
507 # console.
508 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
509     # Is set to a non empty value to reset the window name in the next
510     # precmd() call.
511     zshrc_window_reset=yes
512
513     zshrc_window_preexec() {
514         # Get the program name with its arguments.
515         local program_name=$1
516
517         # When sudo is used, use real program name instead, but with an
518         # exclamation mark at the beginning (handled below).
519         local program_sudo=
520         if [[ $program_name == sudo* ]]; then
521             program_name=${program_name#sudo }
522             program_sudo=yes
523         fi
524
525         # Handle fg.
526         local REPLY
527         zshrc_resolve_fg_to_resumed_job_name $program_name
528         program_name=$REPLY
529
530         # Remove all arguments from the program name.
531         program_name=${program_name%% *}
532
533         # Ignore often used commands which are only running for a very short
534         # time. This prevents a "blinking" name when it's changed to "cd" for
535         # example and then some milliseconds later back to "zsh".
536         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
537
538         # Change my shortcuts so the real name of the program is displayed.
539         case $program_name in
540             e)
541                 program_name=elinks
542                 ;;
543             g)
544                 program_name=git
545                 ;;
546             m)
547                 program_name=make
548                 ;;
549             p)
550                 program_name=less
551                 ;;
552             v)
553                 program_name=vim
554                 ;;
555             mu)
556                 program_name=mutt
557                 ;;
558         esac
559
560         # Add an exclamation mark at the beginning if running with sudo or if
561         # running zsh as root.
562         if [[ -n $program_sudo || $UID -eq 0 ]]; then
563             program_name=!$program_name
564         fi
565
566         # Add an at mark at the beginning if running through ssh on a
567         # different computer.
568         if [[ -n $SSH_CONNECTION ]]; then
569             program_name="@$program_name"
570
571             # If screen is running in SSH then display "@:hostname" as title
572             # in the term/outer screen.
573             if [[ $program_name == @screen || $program_name == @tmux ]]; then
574                 program_name="@:${HOST//.*/}"
575             # Use "@:!hostname" for root screens.
576             elif [[ $program_name == @!screen || $program_name == @!tmux ]]; then
577                 program_name="@:!${HOST//.*/}"
578             fi
579         fi
580
581         # Set the window name to the currently running program.
582         zshrc_window_title $program_name
583
584         # Tell precmd() to reset the window name when the program stops.
585         zshrc_window_reset=yes
586     }
587
588     zshrc_window_precmd() {
589         # Abort if no window name reset is necessary.
590         [[ -z $zshrc_window_reset ]] && return
591
592         # Reset the window name to 'zsh'.
593         local name=zsh
594         # If the function was called with an argument then reset the window
595         # name to '.zsh' (used by clear alias).
596         if [[ -n $1 ]]; then
597             name=.zsh
598         fi
599
600         # Prepend prefixes like in zshrc_window_preexec().
601         if [[ $UID -eq 0 ]]; then
602             name="!$name"
603         fi
604         if [[ -n $SSH_CONNECTION ]]; then
605             name="@$name"
606         fi
607         zshrc_window_title $name
608
609         # Just reset the name, so no screen reset necessary for the moment.
610         zshrc_window_reset=
611     }
612
613     # Sets the window title. Works with GNU screen, tmux (which uses screen as
614     # TERM), xterm and rxvt. (V) escapes all non-printable characters, thanks
615     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
616     if [[ $TERM == screen* ]]; then
617         zshrc_window_title() {
618             print -n "\ek${(V)1}\e\\"
619         }
620     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
621         zshrc_window_title() {
622             print -n "\e]2;${(V)1}\e\\"
623         }
624     else
625         # Fallback if another TERM is used.
626         zshrc_window_title() { }
627     fi
628
629     # Add the preexec() and precmd() hooks.
630     preexec_functions+=(zshrc_window_preexec)
631     precmd_functions+=(zshrc_window_precmd)
632 else
633     # Fallback if another TERM is used, necessary to run screen (see below in
634     # "RUN COMMANDS").
635     zshrc_window_preexec() { }
636 fi
637
638
639 # COMPLETION SETTINGS
640
641 # Load the complist module which provides additional features to completion
642 # lists (coloring, scrolling).
643 zmodload zsh/complist
644 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
645 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
646 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
647 # problem.
648 autoload -Uz compinit; compinit -d ~/.zsh/cache/zcompdump
649
650 # Use cache to speed up some slow completions (dpkg, perl modules, etc.).
651 zstyle ':completion:*' use-cache yes
652 zstyle ':completion:*' cache-path ~/.zsh/cache
653
654 # List all files in the current directory when pressing tab on an empty input,
655 # behave like complete-word otherwise. Thanks to John Eikenberry [1] for the
656 # code, read on 2014-03-15.
657 #
658 # [1]: http://unix.stackexchange.com/a/32426
659 complete-word-or-complete-list-of-files() {
660     if [[ $#BUFFER == 0 ]]; then
661         BUFFER='ls '
662         CURSOR=3
663         zle list-choices
664         zle backward-kill-word
665     else
666         zle complete-word
667     fi
668 }
669 zle -N complete-word-or-complete-list-of-files
670 # Let the completion system handle all completions, including expanding of
671 # shell wildcards (which is handled by other shell mechanisms if the default
672 # expand-or-complete is used).
673 bindkey '^I' complete-word-or-complete-list-of-files
674 # If there are multiple matches after pressing <Tab> always display them
675 # immediately without requiring another <Tab>. a<Tab> completes to aa and
676 # lists aaa, aab, aac as possible completions if the directory contains aaa,
677 # aab, aac, bbb instead of only completing to aa.
678 setopt nolistambiguous
679 # Support completions in the middle of a word, without this option zsh jumps
680 # to the end of the word before the completion process begins. Is required for
681 # the _prefix completer.
682 setopt completeinword
683
684 # Force a reload of the completion system if nothing matched; this fixes
685 # installing a program and then trying to tab-complete its name. Thanks to
686 # Alex Munroe [1] for the code, read on 2014-03-03.
687 #
688 # [1]: https://github.com/eevee/rc/blob/master/.zshrc
689 _force_rehash() {
690     if (( CURRENT == 1 )); then
691         rehash
692     fi
693     # We didn't really complete anything.
694     return 1
695 }
696
697 zstyle ':completion:::::' completer \
698     _force_rehash _expand _complete _prefix _ignored _approximate
699
700 # Match specification to be tried when completing items. Each group ('...') is
701 # tried after another if no matches were found, once matches are found no
702 # other groups are tried. Thanks to Mikachu in #zsh on Freenode (2012-08-28
703 # 18:48 CEST) for explanations.
704 #
705 # When matching also include the uppercase variant of typed characters
706 # ('m:{a-z}={A-Z}'); using '' before this group would try the unmodified match
707 # first, but I prefer to get all matches immediately (e.g. if Makefile and
708 # makefile exist in the current directory echo m<tab> matches both, with '' it
709 # would only match makefile because it found one match). This allows typing in
710 # lowercase most of the time and completion fixes the case, which is faster.
711 #
712 # Don't perform these fixes in _approximate to prevent it from changing the
713 # input too much. Thanks to the book "From Bash to Z Shell" page 249.
714 zstyle ':completion:*:(^approximate):*' matcher-list 'm:{a-z}={A-Z}'
715
716 # Allow one mistake per three characters. Thanks to the book "From Bash to Z
717 # Shell" page 248.
718 zstyle -e ':completion:*:approximate:*' max-errors \
719     'reply=( $(( ($#PREFIX + $#SUFFIX) / 3 )) )'
720
721 # Expand shell wildcards to all matching files after <Tab>. echo *<Tab>
722 # results in a b c if the directory contains the files a, b, c. Thanks to the
723 # book "From Bash to Z Shell" page 246.
724 zstyle ':completion:*:expand:*' tag-order all-expansions
725 # Keep prefixes unexpanded if possible: $HOME/<Tab> doesn't expand $HOME,
726 # while $HOME<Tab> does.
727 zstyle ':completion:*:expand:*' keep-prefix yes
728
729 # When completing multiple path components display all matching ambiguous
730 # components. For example /u/s/d/r/README<Tab> lists all matching READMEs
731 # instead of just the matching paths up to the r/ component. Can be slow if
732 # there are many matching files.
733 zstyle ':completion:*' list-suffixes yes
734
735 # Use ls-like colors for completions.
736 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
737
738 # Make completion lists scrollable so "do you wish to see all n possibilities"
739 # is no longer displayed. Display current position in percent (%p).
740 zstyle ':completion:*:default' list-prompt '%p'
741 # Display group name (%d) (like 'external command', 'alias', etc.), in bold.
742 # Also display a message if _approximate found errors and no matches were
743 # found.
744 zstyle ':completion:*'             format '    %B%d%b:'
745 zstyle ':completion:*:corrections' format '    %B%d%b (errors: %e)'
746 zstyle ':completion:*:warnings'    format '    %Bno matches for %d%b'
747 # Display different types of matches separately.
748 zstyle ':completion:*' group-name ''
749
750 # Separate man pages by section.
751 zstyle ':completion:*' separate-sections yes
752
753 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
754 # on Freenode for the fix (2010-12-17 13:46 CET).
755 zle_highlight=(suffix:none)
756
757 # Ignore completion functions.
758 zstyle ':completion:*:functions' ignored-patterns '_*'
759
760 # When offering typo corrections, do not propose anything which starts with an
761 # underscore (such as many of Zsh's shell functions). Thanks to paradigm [1]
762 # for the idea (read on 2013-04-07).
763 #
764 # [1]: https://github.com/paradigm/dotfiles/blob/master/.zshrc
765 CORRECT_IGNORE='_*'
766
767 # Ignore parent directory.
768 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
769 # Always complete file names only once in the current line. This makes it easy
770 # to complete multiple file names because I can just press tab to get all
771 # possible values. Otherwise I would have to skip the first value again and
772 # again. Thanks to Mikachu in #zsh on Freenode (2011-08-11 14:42 CEST) for the
773 # hint to use other. other is necessary so prefix<Tab> lists both prefix and
774 # prefixrest if the directory contains prefix and prefixrest.
775 zstyle ':completion:*:all-files' ignore-line other
776 # Except for mv and cp, because I often want to use to similar names, so I
777 # complete to the same and change it.
778 zstyle ':completion:*:(mv|cp):all-files' ignore-line no
779
780 # Don't complete ./config.* files, this makes running ./configure much
781 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
782 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
783 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
784 # Freenode (2010-06-06 04:54 CEST). See below for a way to complete them.
785 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns \
786     '*.aux' '*.log' '*.pdf' '*.bbl' '*.blg' '*.out' '*-blx.bib' '*.run.xml' \
787     '*.o' \
788     '*.pyc' \
789     '*.class'
790
791 # Provide a fallback completer which always completes files. Useful when Zsh's
792 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
793 # (http://www.zsh.org/mla/users/2009/msg01038.html).
794 zle -C complete-files complete-word _generic
795 zstyle ':completion:complete-files:*' completer _files
796 bindkey '^F' complete-files
797
798 # Completion for my wrapper scripts.
799 compdef slocate=locate
800 compdef srsync=rsync
801 compdef srsync-incremental=rsync
802 compdef sc=systemctl
803
804
805 # CUSTOM ALIASES AND FUNCTIONS
806
807 # If ^C is pressed while typing a command, add it to the history so it can be
808 # easily retrieved later and then abort like ^C normally does. This is useful
809 # when I want to abort an command to do something in between and then finish
810 # typing the command.
811 #
812 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
813 # starting with - don't cause errors; and to Nadav Har'El
814 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
815 # correctly, both on the Zsh mailing list.
816 TRAPINT() {
817     # Don't store this line in history if histignorespace is enabled and the
818     # line starts with a space.
819     if [[ -o histignorespace && ${BUFFER[1]} = ' ' ]]; then
820         return $1
821     fi
822
823     # Store the current buffer in the history.
824     zle && print -s -r -- $BUFFER
825
826     # Return the default exit code so Zsh aborts the current command.
827     return $1
828 }
829
830 # Load aliases and similar functions also used by other shells.
831 if [[ -f ~/.shell/aliases ]]; then
832     . ~/.shell/aliases
833 fi
834
835 # Make sure aliases are expanded when using sudo.
836 alias sudo='sudo '
837
838 # Global aliases for often used redirections.
839 alias -g E='2>&1'
840 alias -g N='>/dev/null'
841 alias -g EN='2>/dev/null'
842 alias -g L='2>&1 | less'
843 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
844 alias -g D='2>&1 | colordiff | less'
845 # Global aliases for often used commands.
846 alias -g A='| awk'
847 alias -g A1="| awk '{ print \$1 }'"
848 alias -g A2="| awk '{ print \$2 }'"
849 alias -g A3="| awk '{ print \$3 }'"
850 alias -g G='| grep'
851 alias -g GB='| grep -vE "^Binary file .+ matches\$"'
852 alias -g H='| head'
853 alias -g P='| perl'
854 alias -g S='| sort'
855 alias -g SL='| sort | less'
856 alias -g T='| tail'
857 alias -g U='| uniq'
858 alias -g X='-- "$(xsel -p || xclip -o)"' # X selection
859
860 # Make going up directories simple.
861 alias -g ...='../..'
862 alias -g ....='../../..'
863 alias -g .....='../../../..'
864
865 # If the window naming feature is used (see above) then use ".zsh" (leading
866 # dot) as title name after running clear so it's clear to me that the window
867 # is empty. I open so much windows that I don't know in which I have something
868 # important. This helps me to remember which windows are empty (I run clear
869 # after I finished my work in a window).
870 if [[ -n $zshrc_window_reset ]]; then
871     alias clear='clear; zshrc_window_reset=yes; zshrc_window_precmd reset'
872 fi
873
874
875 # CUSTOM COMMANDS
876
877 # Display all branches (except stash) in gitk but only 200 commits as this is
878 # much faster. Also put in the background and disown. Thanks to drizzd in #git
879 # on Freenode (2010-04-03 17:55 CEST).
880 (( $+commands[gitk] )) && gitk() {
881     command gitk --max-count=200 --branches --remotes --tags "$@" &
882     disown %command
883 }
884 # Same for tig (except the disown part as it's no GUI program).
885 (( $+commands[tig] )) && tig() {
886     command tig --max-count=200 --branches --remotes --tags "$@"
887 }
888
889 # Choose the "best" PDF viewer available. Also setup completion for `pdf`.
890 if (( $+commands[katarakt] )); then
891     pdf() {
892         command katarakt "$@" 2>/dev/null &
893         disown %command
894     }
895     # No completion for katarakt yet.
896     compdef pdf=xpdf
897 elif (( $+commands[xpdf] )); then
898     pdf() {
899         command xpdf "$@" 2>/dev/null &
900         disown %command
901     }
902     compdef pdf=xpdf
903 elif (( $+commands[zathura] )); then
904     pdf() {
905         command zathura "$@" 2>/dev/null &
906         disown %command
907     }
908     # No completion for zathura yet.
909     compdef pdf=xpdf
910 fi
911
912
913 # OS SPECIFIC SETTINGS
914
915 if [[ $OSTYPE == linux* ]]; then
916     # Settings when creating Debian packages.
917     export DEBEMAIL=simon@ruderich.org
918     export DEBFULLNAME='Simon Ruderich'
919 fi
920
921
922 # LOAD ADDITIONAL CONFIGURATION FILES
923
924 # Configuration options for rc.local.
925
926 # Multiplexer to use. By default GNU screen is used. Possible values: screen,
927 # tmux and empty (no multiplexer).
928 zshrc_use_multiplexer=screen
929 # Additional arguments for fortune.
930 zshrc_fortune_arguments=()
931
932 source_config ~/.zsh/rc.local
933
934
935 # RUN COMMANDS
936
937 # Make sure the multiplexer is available. Otherwise the exec terminates our
938 # session.
939 if [[ -n $zshrc_use_multiplexer ]]; then
940     if ! (( $+commands[$zshrc_use_multiplexer] )); then
941         echo "Multiplexer '$zshrc_use_multiplexer' not found." >&2
942         zshrc_use_multiplexer=
943     fi
944 fi
945
946 # If not already in screen or tmux, reattach to a running session or create a
947 # new one. This also starts screen/tmux on a remote server when connecting
948 # through ssh.
949 if [[ $TERM != dumb && $TERM != dialup && $TERM != linux
950         && -z $STY && -z $TMUX ]]; then
951     # Get running detached sessions.
952     if [[ $zshrc_use_multiplexer = screen ]]; then
953         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
954     elif [[ $zshrc_use_multiplexer = tmux ]]; then
955         session=$(tmux list-sessions 2>/dev/null \
956                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
957     fi
958
959     # As we exec later we have to set the title here.
960     if [[ $zshrc_use_multiplexer = screen ]]; then
961         zshrc_window_preexec screen
962     elif [[ $zshrc_use_multiplexer = tmux ]]; then
963         zshrc_window_preexec tmux
964     fi
965
966     # Create a new session if none is running.
967     if [[ -z $session ]]; then
968         if [[ $zshrc_use_multiplexer = screen ]]; then
969             exec screen
970         elif [[ $zshrc_use_multiplexer = tmux ]]; then
971             exec tmux
972         fi
973     # Reattach to a running session.
974     else
975         if [[ $zshrc_use_multiplexer = screen ]]; then
976             exec screen -r $session
977         elif [[ $zshrc_use_multiplexer = tmux ]]; then
978             exec tmux attach-session -t $session
979         fi
980     fi
981 fi
982
983 # Colorize stderr in bold red. Very useful when looking for errors.
984 if [[ $LD_PRELOAD != *libcoloredstderr.so* ]]; then
985     # coloredstderr found, use it.
986     if [[ -f ~/.zsh/libcoloredstderr.so ]]; then
987         export LD_PRELOAD="$HOME/.zsh/libcoloredstderr.so:$LD_PRELOAD"
988         export COLORED_STDERR_FDS=2,
989         export COLORED_STDERR_PRE=$'\033[91m' # bright red
990         export COLORED_STDERR_IGNORED_BINARIES=/usr/bin/tset
991     # Use the fallback solution.
992     #
993     # Thanks to http://gentoo-wiki.com/wiki/Zsh for the basic script and
994     # Mikachu in #zsh on Freenode (2010-03-07 04:03 CET) for some improvements
995     # (-r, printf). It's not yet perfect and doesn't work with su and git for
996     # example, but it can handle most interactive output quite well (even with
997     # no trailing new line) and in cases it doesn't work, the E alias can be
998     # used as workaround.
999     #
1000     # Moved in the "run commands" section to prevent one unnecessary zsh
1001     # process when starting GNU screen/tmux (see above).
1002     else
1003         exec 2>>(while read -r -k -u 0 line; do
1004             printf '\e[91m%s\e[0m' $line
1005             print -n $'\0'
1006         done &)
1007
1008         # Reset doesn't work with this hack.
1009         reset() {
1010             command reset "$@" 2>&1
1011         }
1012     fi
1013 fi
1014
1015 # Display possible log messages from ~/.xinitrc (if `xmessage` wasn't
1016 # installed). No race condition as xinitrc has finished before a shell is
1017 # executed and only one shell is started on login.
1018 if [[ -f ~/.xinitrc.errors ]]; then
1019     echo "${fg_bold[red]}xinitrc failed!${fg_bold[default]}"
1020     echo
1021     cat ~/.xinitrc.errors
1022     rm ~/.xinitrc.errors
1023     echo
1024 fi
1025
1026 # Run the following programs every 4 hours (and when zsh starts).
1027 PERIOD=14400
1028 periodic() {
1029     # Display fortunes.
1030     (( $+commands[fortune] )) && fortune -ac "${zshrc_fortune_arguments[@]}"
1031     # Display reminders.
1032     (( $+commands[rem] )) && [[ -f ~/.reminders ]] && rem -h
1033 }
1034
1035
1036 # RESTART SETTINGS
1037
1038 zmodload -F zsh/stat b:zstat
1039
1040 # Remember startup time. Used to perform automatic restarts when ~/.zshrc is
1041 # modified.
1042 zshrc_startup_time=$EPOCHSECONDS
1043
1044 # Automatically restart Zsh if ~/.zshrc was modified.
1045 zshrc_restart_precmd() {
1046     local stat
1047     if ! zstat -A stat +mtime ~/.zshrc; then
1048         return
1049     fi
1050
1051     # ~/.zshrc wasn't modified, nothing to do.
1052     if [[ $stat -le $zshrc_startup_time ]]; then
1053         return
1054     fi
1055
1056     local startup
1057     strftime -s startup '%Y-%m-%d %H:%M:%S' $zshrc_startup_time
1058
1059     echo -n "${fg[magenta]}"
1060     echo -n "~/.zshrc modified since startup ($startup) ... "
1061     echo -n "${fg[default]}"
1062
1063     if [[ -n $zshrc_disable_restart ]]; then
1064         echo 'automatic restart disabled.'
1065         return
1066     fi
1067
1068     # Don't exec if we have background processes because execing will let us
1069     # lose control over them.
1070     if [[ ${#${(k)jobstates}} -ne 0 ]]; then
1071         echo 'active background jobs!'
1072         return
1073     fi
1074
1075     # Try to start a new interactive shell. If it fails, something is wrong.
1076     # Don't kill our current session by execing it, abort instead.
1077     zsh -i -c 'exit 42'
1078     if [[ $? -ne 42 ]]; then
1079         echo -n ${fg_bold[red]}
1080         echo 'failed to start new zsh!'
1081         echo -n ${fg_bold[default]}
1082         return
1083     fi
1084
1085     echo 'restarting zsh.'
1086     echo
1087
1088     exec zsh
1089 }
1090 precmd_functions+=(zshrc_restart_precmd)
1091
1092
1093 # RELOAD SETTINGS
1094
1095 zshenv_reload_time=0 # load before first command
1096 zshenv_boot_time=$(date -d "$(uptime -s)" '+%s') # uptime in epoch seconds
1097
1098 # Automatically source ~/.zsh/env.update when the file changes (and exists).
1099 # Can be used e.g. to update SSH_AGENT_PID and GPG_AGENT_INFO variables in
1100 # running zsh processes. Sourced immediately before executing shell commands
1101 # (preexec) to ensure the environment is always up to date.
1102 zshenv_reload_preexec() {
1103     local file
1104     file=~/.zsh/env.update
1105
1106     local stat
1107     if ! zstat -A stat +mtime $file 2>/dev/null; then
1108         return
1109     fi
1110     # File was modified before reboot. Skip it to prevent loading of old
1111     # values.
1112     if [[ $stat -lt $zshenv_boot_time ]]; then
1113         return
1114     fi
1115     # File wasn't modified, nothing to do.
1116     if [[ $stat -le $zshenv_reload_time ]]; then
1117         return
1118     fi
1119     zshenv_reload_time=$EPOCHSECONDS
1120
1121     unsetopt warn_create_global
1122     . $file
1123     setopt warn_create_global
1124 }
1125 preexec_functions+=(zshenv_reload_preexec)
1126
1127 # vim: ft=zsh