tig.pl

   1 #!/usr/bin/perl
   2
   3 # tig-like git log output. Used when tig is not available or broken.
   4
   5 # Copyright (C) 2013  Simon Ruderich
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 use strict;
  22 use warnings;
  23
  24 use POSIX ();
  25 use Term::ANSIColor qw(colored);
  26
  27
  28 my $color_graph         = 'yellow';
  29 my $color_hash          = 'cyan';
  30 my $color_ref_sep       = 'cyan';
  31 my $color_ref_head      = 'cyan bold';
  32 my $color_ref_branch    = 'green bold';
  33 my $color_ref_reference = 'red bold';
  34 my $color_author        = 'magenta';
  35
  36
  37 my $format = '%x00'         # separator from --graph
  38            . '%h'  . '%x00' # abbreviated commit hash
  39            . '%at' . '%x00' # author date
  40            . '%an' . '%x00' # author name
  41            . '%s'  . '%x00' # subject
  42            . '%d';          # ref names
  43 my $cmd = "git log --all --graph --format='$format'";
  44 open my $fh, '-|', $cmd or die $!;
  45
  46 while (my $line = <$fh>) {
  47     # History graph line.
  48     if ($line =~ m{^([|/\\_ ]+)$}) {
  49         print colored($line, $color_graph);
  50         next;
  51     }
  52
  53     # Commit line.
  54     $line =~ /^([ *|.-]+)\x00(.+)\x00(.+)\x00(.+)\x00(.+)\x00(.*)$/
  55         or die $line;
  56     my $prefix  = $1;
  57     my $hash    = colored($2, $color_hash);
  58     my $date    = POSIX::strftime('%Y-%m-%d', localtime($3));
  59     my $author  = colored($4, $color_author);
  60     my $message = $5;
  61     my $refs    = $6;
  62
  63     # Strip trailing whitespace.
  64     $prefix =~ s/\s+$//;
  65     # Color "graph".
  66     $prefix =~ s/\|/colored($&, $color_graph)/ge;
  67
  68     # Strip leading whitespace and braces.
  69     $refs =~ s/^\s+//;
  70     $refs =~ tr/()//d;
  71
  72     # Color refs.
  73     $refs = join colored(', ', $color_ref_sep), map {
  74         my $color;
  75         if ($_ eq 'HEAD') {
  76             $color = $color_ref_head;
  77         } elsif (m{/}) {
  78             $color = $color_ref_reference;
  79         } else {
  80             $color = $color_ref_branch;
  81         }
  82         colored($_, $color);
  83     } split /, /, $refs;
  84
  85     if ($refs ne '') {
  86         $refs = ' '
  87               . colored('(', $color_ref_sep)
  88               . $refs
  89               . colored(')', $color_ref_sep);
  90     }
  91
  92     printf "%s %s %s %s%s %s\n",
  93            $prefix, $hash, $date, $author, $refs, $message;
  94 }
  95
  96 close $fh or die $!;