vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82
  83 " EDIT SETTINGS
  84
  85 " Enable automatic file detection, plugin and indention support.
  86 if has('autocmd')
  87     filetype off " necessary for pathogen to force a reload of ftplugins
  88     filetype plugin indent on
  89 endif
  90
  91 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  92 " existing files.
  93 set fileencodings=utf-8,latin1
  94
  95 " Wrap text after 78 characters.
  96 set textwidth=78
  97
  98 " Set tabs to 4 spaces, use softtabs.
  99 set shiftwidth=4
 100 set softtabstop=4
 101 set expandtab
 102 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 103 set shiftround
 104 " Use the default value for real tabs.
 105 set tabstop=8
 106
 107 " Enable auto indention.
 108 set autoindent
 109
 110 " When joining lines only add one space after a sentence.
 111 set nojoinspaces
 112
 113 " Allow backspacing over autoindent and line breaks.
 114 set backspace=indent,eol
 115
 116 " Start a comment when hitting enter after a commented line (r) and when using
 117 " o or O around a commented line (o).
 118 set formatoptions+=ro
 119 " Don't break a line if was already longer then 'textwidth' when insert mode
 120 " started.
 121 set formatoptions+=l
 122
 123 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 124 " no character) in visual block mode.
 125 set virtualedit=block
 126
 127 " Already display matches while typing the search command. This makes spotting
 128 " errors easy.
 129 set incsearch
 130
 131 " Activate syntax folding.
 132 if has('folding')
 133     set foldmethod=syntax
 134     set foldcolumn=2
 135     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 136                      " folding which is not what I want
 137 endif
 138
 139 " Only check for case if the searched word contains a capital character.
 140 set ignorecase
 141 set smartcase
 142
 143 " Activate spell checking, use English as default.
 144 if exists('+spell') && has('syntax')
 145     " But not when diffing as spell checking is distracting in this case.
 146     if !&diff
 147         set spell
 148     endif
 149     set spelllang=en_us
 150 endif
 151
 152 " Allow buffers with changes to be hidden. Very important for effective
 153 " editing with multiple buffers.
 154 set hidden
 155
 156
 157 " DISPLAY SETTINGS
 158
 159 " Use a dark background. Doesn't change the background color, only sets text
 160 " colors for a dark terminal.
 161 set background=dark
 162
 163 " Display line numbers.
 164 set number
 165 " But use as little space as necessary for the numbers column. Thanks to James
 166 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 167 if exists('+numberwidth')
 168     set numberwidth=1
 169 endif
 170 " Display the ruler with current line/file position. If 'statusline' is used
 171 " then this only affects <C-G>.
 172 set ruler
 173 " Display partial commands in the status line.
 174 set showcmd
 175
 176 " Don't redraw screen when executing macros; increases speed. Thanks to James
 177 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 178 set lazyredraw
 179
 180 " Visualize the line the cursor is currently in.
 181 if exists('+cursorline')
 182     set cursorline
 183 endif
 184
 185 " Display tabs, trailing space, non breakable spaces and long lines (when
 186 " wrapping is disabled).
 187 set list
 188 set listchars=trail:-,extends:>
 189 if v:version >= 700
 190     set listchars+=nbsp:!
 191 endif
 192
 193 if has('statusline')
 194     " Always display the status line even if there is only one window.
 195     set laststatus=2
 196
 197     set statusline=
 198     " on the left
 199     set statusline+=%02n: " buffer number
 200     set statusline+=%f\   " path to current file in buffer
 201     set statusline+=%h    " [help] if buffer is help file
 202     set statusline+=%w    " [Preview] if buffer is preview buffer
 203     set statusline+=%m    " [+] if buffer was modified,
 204                           " [-] if 'modifiable' is off
 205     set statusline+=%r    " [RO] if buffer is read only
 206
 207     " on the right
 208     set statusline+=%=                " right align
 209     set statusline+=0x%-8B\           " current character under cursor as hex
 210     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 211                                       " column number (%c),
 212                                       " virtual column number if different
 213                                       "                       than %c (%V)
 214     set statusline+=%P                " position in file in percent
 215 endif
 216
 217
 218 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 219
 220 " noremap is used to make sure the right side is executed as is and can't be
 221 " modified by a plugin or other settings. Except for <Nop> which isn't
 222 " affected by mappings.
 223
 224 " Easy way to exit insert mode.
 225 inoremap jj <Esc>
 226 inoremap jk <Esc>
 227 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 228 " (2010-10-15).
 229 cnoremap jj <C-C>
 230 cnoremap jk <C-C>
 231
 232 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 233 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 234 map <Right>  <Nop>
 235 map <Left>   <Nop>
 236 map <Up>     <Nop>
 237 map <Down>   <Nop>
 238 imap <Right> <Nop>
 239 imap <Left>  <Nop>
 240 imap <Up>    <Nop>
 241 imap <Down>  <Nop>
 242 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 243 " below).
 244 cmap <Up>    <Nop>
 245 cmap <Down>  <Nop>
 246 cmap <Right> <Nop>
 247 cmap <Left>  <Nop>
 248
 249 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 250 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 251 cnoremap <C-P> <Up>
 252 cnoremap <C-N> <Down>
 253
 254 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 255 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 256 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 257
 258 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 259 " in #vim on Freenode (2011-08-15 00:17 CEST).
 260 nnoremap <C-G> 2<C-G>
 261
 262 " Use <Space> to move down a page and - to move up one like in mutt.
 263 nnoremap <Space> <C-F>
 264 nnoremap - <C-B>
 265
 266 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 267 " (2010-05-16 18:38 CEST) for this idea.
 268 nnoremap <silent> gb :bnext<CR>
 269 nnoremap <silent> gB :bprev<CR>
 270
 271 " Fast access to buffers.
 272 nnoremap <silent> <Leader>1 :1buffer<CR>
 273 nnoremap <silent> <Leader>2 :2buffer<CR>
 274 nnoremap <silent> <Leader>3 :3buffer<CR>
 275 nnoremap <silent> <Leader>4 :4buffer<CR>
 276 nnoremap <silent> <Leader>5 :5buffer<CR>
 277 nnoremap <silent> <Leader>6 :6buffer<CR>
 278 nnoremap <silent> <Leader>7 :7buffer<CR>
 279 nnoremap <silent> <Leader>8 :8buffer<CR>
 280 nnoremap <silent> <Leader>9 :9buffer<CR>
 281 nnoremap <silent> <Leader>0 :10buffer<CR>
 282
 283 " Make last active window the only window. Similar to <C-W> o.
 284 nnoremap <C-W>O <C-W>p<C-W>o
 285
 286 " Maps to change spell language between English and German and disable spell
 287 " checking.
 288 if exists('+spell')
 289     noremap <silent> <Leader>sn :set nospell<CR>
 290     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 291     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 292 endif
 293
 294 " Add semicolon to the end of the line. Thanks to
 295 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 296 " on Freenode for an improved version which doesn't clobber any marks.
 297 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 298
 299 " * and # for selections in visual mode. Thanks to
 300 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 301 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 302 if has('eval')
 303     function! s:VSetSearch()
 304         let l:temp = @@
 305         normal! gvy
 306         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 307         let @@ = l:temp
 308     endfunction
 309     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 310     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 311 endif
 312
 313 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 314 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 315 " mailing list for the commands.
 316 if v:version < 700
 317     cnoreabbrev W w
 318     cnoreabbrev Wa wa
 319     cnoreabbrev Wq wq
 320     cnoreabbrev Wqa wqa
 321 else
 322     cnoreabbrev <expr> W
 323         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 324     cnoreabbrev <expr> Wa
 325         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 326     cnoreabbrev <expr> Wq
 327         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 328     cnoreabbrev <expr> Wqa
 329         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 330 endif
 331 " Also fix my typo with "Q".
 332 if v:version < 700
 333     cnoreabbrev Q q
 334     cnoreabbrev Qa qa
 335 else
 336     cnoreabbrev <expr> Q
 337         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 338     cnoreabbrev <expr> Qa
 339         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 340 endif
 341
 342 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 343 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 344 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 345
 346 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 347 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 348 " Vim's source.
 349 inoremap <C-U> <C-G>u<C-U>
 350 " Same for <C-@> (insert previously inserted text and leave insert mode).
 351 inoremap <C-@> <C-G>u<C-@>
 352 " And for <C-A> (insert previously inserted text).
 353 inoremap <C-A> <C-G>u<C-A>
 354 " And for <C-W> (delete word before cursor).
 355 inoremap <C-W> <C-G>u<C-W>
 356
 357 if has('eval')
 358 " New text-objects ii and ai to work on text with the same indentation. Thanks
 359 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 360 " (visited on 2011-11-19).
 361     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 362     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 363     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 364     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 365
 366     function! s:IndTxtObj(inner)
 367         let curline = line(".")
 368         let lastline = line("$")
 369         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 370         let i = i < 0 ? 0 : i
 371         if getline(".") !~ "^\\s*$"
 372             let p = line(".") - 1
 373             let nextblank = getline(p) =~ "^\\s*$"
 374             while p > 0
 375                     \ && ((i == 0 && !nextblank)
 376                         \ || (i > 0 && ((indent(p) >= i
 377                             \ && !(nextblank && a:inner))
 378                             \ || (nextblank && !a:inner))))
 379                 -
 380                 let p = line(".") - 1
 381                 let nextblank = getline(p) =~ "^\\s*$"
 382             endwhile
 383             normal! 0V
 384             call cursor(curline, 0)
 385             let p = line(".") + 1
 386             let nextblank = getline(p) =~ "^\\s*$"
 387             while p <= lastline
 388                     \ && ((i == 0 && !nextblank)
 389                         \ || (i > 0 && ((indent(p) >= i
 390                             \ && !(nextblank && a:inner))
 391                             \ || (nextblank && !a:inner))))
 392                 +
 393                 let p = line(".") + 1
 394                 let nextblank = getline(p) =~ "^\\s*$"
 395             endwhile
 396             normal! $
 397         endif
 398     endfunction
 399 endif
 400
 401
 402 " ABBREVIATIONS
 403
 404 " Fix some of my spelling mistakes.
 405 iabbrev relle reelle
 406 iabbrev reele reelle
 407
 408
 409 " SYNTAX SETTINGS
 410
 411 " Activate syntax coloring.
 412 if has('syntax')
 413     syntax enable
 414
 415 " Don't highlight more than 500 columns as I normally don't have that long
 416 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 417 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 418     if exists('+synmaxcol')
 419         set synmaxcol=500
 420     endif
 421
 422 " Use (limited) syntax based omni completion if no other omni completion is
 423 " available. Taken from :help ft-syntax-omni.
 424     if has('autocmd') && exists('+omnifunc')
 425         autocmd FileType *
 426             \ if &omnifunc == '' |
 427             \     setlocal omnifunc=syntaxcomplete#Complete |
 428             \ endif
 429     endif
 430
 431 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 432 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 433 " disabled when necessary with :2match (in Vim >= 700).
 434     if exists(':2match')
 435         2match Todo /\%>78v./
 436     else
 437         match Todo /\%>78v./
 438     endif
 439
 440     if exists('*matchadd')
 441 " Highlight some important keywords in all documents.
 442         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 443             call matchadd('Todo', s:x)
 444         endfor
 445
 446 " Highlight unicode whitespace which is no normal whitespace (0x20).
 447         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 448                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 449                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 450                 \ 'feff']
 451             call matchadd('Error', '\%u' . s:x)
 452         endfor
 453     endif
 454
 455 " Settings for specific filetypes.
 456
 457     " Haskell.
 458     let g:hs_highlight_delimiters = 1
 459     let g:hs_highlight_boolean = 1
 460     let g:hs_highlight_types = 1
 461     let g:hs_highlight_more_types = 1
 462     " Perl.
 463     let g:perl_fold = 1
 464     let g:perl_fold_blocks = 1
 465     let g:perl_nofold_packages = 1
 466     let g:perl_include_pod = 1 " syntax coloring for PODs
 467     " Python.
 468     let g:python_highlight_all = 1
 469     " Vim, enable folding for autogroups (a) and functions (f).
 470     let g:vimsyn_folding = "af"
 471     " XML.
 472     let g:xml_syntax_folding = 1
 473 endif
 474
 475
 476 " PLUGIN SETTINGS
 477
 478 if has('eval')
 479 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 480 " installing/removing/updating plugins simple. (Used for plugins with more
 481 " than one file.)
 482     if v:version >= 700
 483         execute 'call pathogen#runtime_append_all_bundles()'
 484     endif
 485
 486 " Settings for the NERD commenter.
 487     " Don't create any mappings I don't want to use.
 488     let g:NERDCreateDefaultMappings = 0
 489     " Map toggle comment.
 490     map <Leader><Leader> <Plug>NERDCommenterToggle
 491
 492 " XPTemplate settings.
 493     " Try to maintain snippet rendering even after editing outside of a
 494     " snippet.
 495     let g:xptemplate_strict = 0
 496     " Don't complete any braces automatically.
 497     let g:xptemplate_brace_complete = 0
 498     " Only highlight the current placeholder.
 499     let g:xptemplate_highlight = 'current'
 500 endif
 501
 502
 503 " AUTO COMMANDS
 504
 505 " Use a custom auto group to prevent problems when the vimrc files is sourced
 506 " twice.
 507 if has('autocmd')
 508     augroup vimrc
 509 " Remove all autocmds from the current group.
 510         autocmd!
 511
 512 " Go to last position of opened files. Taken from :help last-position-jump.
 513         autocmd BufReadPost *
 514             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 515             \     execute "normal! g'\"" |
 516             \ endif
 517 " But not for Git commits, go to beginning of the file.
 518         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 519
 520 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 521 " when switching to a help buffer which is in the background with :buffer as
 522 " these options are local to windows (and not only to buffers). This happens
 523 " because I often want to use only one window and thus the help buffer is in
 524 " the background.
 525         autocmd BufWinEnter *.txt
 526             \ if &filetype == 'help' |
 527             \     setlocal nolist |
 528             \     setlocal nonumber |
 529             \ endif
 530
 531 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 532 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 533 " want to paste once and then 'paste' gets automatically unset.
 534         if exists('##InsertLeave')
 535             autocmd InsertLeave * set nopaste
 536         endif
 537
 538 " Write file when running :mak[e] before 'makeprg' is called.
 539         autocmd QuickFixCmdPre * write
 540
 541 " AFTER/FTPLUGIN AUTO COMMANDS
 542
 543 " Disable spell checking for files which don't need it.
 544         autocmd FileType deb  setlocal nospell
 545         autocmd FileType diff setlocal nospell
 546         autocmd FileType tar  setlocal nospell
 547 " Fix to allow Vim edit crontab files as crontab doesn't work with
 548 " backupcopy=auto.
 549         autocmd FileType crontab setlocal backupcopy=yes
 550 " Don't use the modeline in git commits as the diff created by `git commit -v`
 551 " may contain one which could change the filetype or other settings of the
 552 " commit buffer. Also make sure we use only 72 characters per line which is
 553 " the recommendation for git commit messages (http://tpope.net/node/106).
 554         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 555                                  \ setlocal textwidth=72
 556 " Use the same comment string as for Vim files in Vimperator files.
 557         autocmd FileType vimperator setlocal commentstring=\"%s
 558 " Use tex compiler for (La)TeX files.
 559         autocmd FileType tex compiler tex
 560
 561 " FTDETECT AUTO COMMANDS
 562
 563 " Recognize .md as markdown files (Vim default is .mkd).
 564         autocmd BufRead,BufNewFile *.md set filetype=mkd
 565 " Recognize .test as Tcl files.
 566         autocmd BufRead,BufNewFile *.test set filetype=tcl
 567
 568 " OTHER AUTO COMMANDS
 569
 570 " Disable spell checking, displaying of list characters and long lines when
 571 " viewing documentation.
 572         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 573
 574 " Use diff filetype for mercurial patches in patch queue.
 575         autocmd BufReadPost */.hg/patches/* set filetype=diff
 576
 577     augroup END
 578 endif
 579
 580
 581 " CUSTOM FUNCTIONS AND COMMANDS
 582
 583 if has('eval')
 584 " Convenient command to see the difference between the current buffer and the
 585 " file it was loaded from, thus the changes you made. Thanks to the
 586 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 587 " for the diffed file than the filetype for the original file.
 588     if !exists(":DiffOrig")
 589         command DiffOrig
 590             \ let s:diff_orig_filetype = &filetype
 591             \ | vertical new
 592             \ | let &filetype = s:diff_orig_filetype
 593             \ | unlet s:diff_orig_filetype
 594             \ | set buftype=nofile
 595             \ | read ++edit #
 596             \ | 0d_
 597             \ | diffthis
 598             \ | wincmd p
 599             \ | diffthis
 600     endif
 601 endif