vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     " Only use fold column if we have enough space (for example in a (virtual)
 143     " terminals).
 144     if &columns > 80
 145         set foldcolumn=2
 146     endif
 147     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 148                      " folding which is not what I want
 149 endif
 150
 151 " Only check for case if the searched word contains a capital character.
 152 set ignorecase
 153 set smartcase
 154
 155 " Activate spell checking, use English as default.
 156 if exists('+spell') && has('syntax')
 157     " But not when diffing because spell checking is distracting in this case.
 158     if !&diff
 159         set spell
 160     endif
 161     set spelllang=en_us
 162 endif
 163
 164 " Allow buffers with changes to be hidden. Very important for effective
 165 " editing with multiple buffers.
 166 set hidden
 167
 168
 169 " DISPLAY SETTINGS
 170
 171 " Use a dark background. Doesn't change the background color, only sets text
 172 " colors for a dark terminal.
 173 set background=dark
 174
 175 " Display line numbers.
 176 set number
 177 " But use as little space as necessary for the numbers column. Thanks to James
 178 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 179 if exists('+numberwidth')
 180     set numberwidth=1
 181 endif
 182 " Display the ruler with current line/file position. If 'statusline' is used
 183 " then this only affects <C-G>.
 184 set ruler
 185 " Display partial commands in the status line.
 186 set showcmd
 187
 188 " Don't redraw screen when executing macros; increases speed. Thanks to James
 189 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 190 set lazyredraw
 191
 192 " Visualize the line the cursor is currently in.
 193 if exists('+cursorline')
 194     set cursorline
 195 endif
 196
 197 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 198 " remove the highlighting until the next search.
 199 set hlsearch
 200
 201 " Display tabs, trailing space, non breakable spaces and long lines (when
 202 " wrapping is disabled).
 203 set list
 204 set listchars=trail:-,extends:>
 205 if v:version >= 700
 206     set listchars+=nbsp:!
 207 endif
 208
 209 if has('statusline')
 210     " Always display the status line even if there is only one window.
 211     set laststatus=2
 212
 213     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 214     " is the highest buffer number, otherwise return nothing. Used in
 215     " 'statusline' to get an overview of available buffer numbers.
 216     function! StatuslineBufferCount()
 217         let l:bufnr = bufnr('$')
 218         if l:bufnr > 1
 219             let l:result = '/'
 220             if exists('*printf')
 221                 let l:result .= printf('%02d', l:bufnr)
 222             else
 223                 " Older Vims don't have printf() (and no .= either). Emulate
 224                 " "%02d".
 225                 if l:bufnr < 10
 226                     let l:result = l:result . '0'
 227                 endif
 228                 let l:result = l:result . l:bufnr
 229             endif
 230             return l:result
 231         else
 232             return ''
 233         endif
 234     endfunction
 235
 236     set statusline=
 237     " on the left
 238     set statusline+=%02n  " buffer number
 239     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 240     set statusline+=:
 241     set statusline+=%f\   " path to current file in buffer
 242     set statusline+=%h    " [help] if buffer is help file
 243     set statusline+=%w    " [Preview] if buffer is preview buffer
 244     set statusline+=%m    " [+] if buffer was modified,
 245                           " [-] if 'modifiable' is off
 246     set statusline+=%r    " [RO] if buffer is read only
 247
 248     " on the right
 249     set statusline+=%=                " right align
 250     set statusline+=0x%-8B\           " current character under cursor as hex
 251     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 252                                       " column number (%c),
 253                                       " virtual column number if different
 254                                       "                       than %c (%V)
 255     set statusline+=%P                " position in file in percent
 256 endif
 257
 258
 259 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 260
 261 " noremap is used to make sure the right side is executed as is and can't be
 262 " modified by a plugin or other settings. Except for <Nop> which isn't
 263 " affected by mappings.
 264
 265 " Easy way to exit insert mode.
 266 inoremap jj <Esc>
 267 inoremap jk <Esc>
 268 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 269 " (2010-10-15).
 270 cnoremap jj <C-C>
 271 cnoremap jk <C-C>
 272
 273 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 274 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 275 map <Right>  <Nop>
 276 map <Left>   <Nop>
 277 map <Up>     <Nop>
 278 map <Down>   <Nop>
 279 imap <Right> <Nop>
 280 imap <Left>  <Nop>
 281 imap <Up>    <Nop>
 282 imap <Down>  <Nop>
 283 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 284 " below).
 285 cmap <Up>    <Nop>
 286 cmap <Down>  <Nop>
 287 cmap <Right> <Nop>
 288 cmap <Left>  <Nop>
 289
 290 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 291 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 292 cnoremap <C-P> <Up>
 293 cnoremap <C-N> <Down>
 294
 295 if has('eval')
 296 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 297 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 298 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 299 " directly because it also enables that feature for other commands which I
 300 " don't want.
 301
 302     " Set 'nostartofline' for a single movement.
 303     function! s:TemporaryNostartofline(movement)
 304         let l:startofline = &startofline
 305         set nostartofline
 306         execute 'normal! ' . a:movement
 307         let &startofline = l:startofline
 308     endfunction
 309
 310     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 311     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 312     nnoremap <silent> <C-F>
 313         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 314     nnoremap <silent> <C-B>
 315         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 316     nnoremap <silent> <C-D>
 317         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 318     nnoremap <silent> <C-U>
 319         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 320 endif
 321
 322 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 323 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 324 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 325
 326 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 327 " in #vim on Freenode (2011-08-15 00:17 CEST).
 328 nnoremap <C-G> 2<C-G>
 329
 330 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 331 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 332 nmap <Space> <C-F>
 333 nmap - <C-B>
 334
 335 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 336 " (2010-05-16 18:38 CEST) for this idea.
 337 nnoremap <silent> gb :bnext<CR>
 338 nnoremap <silent> gB :bprev<CR>
 339
 340 " Fast access to buffers.
 341 nnoremap <silent> <Leader>1 :1buffer<CR>
 342 nnoremap <silent> <Leader>2 :2buffer<CR>
 343 nnoremap <silent> <Leader>3 :3buffer<CR>
 344 nnoremap <silent> <Leader>4 :4buffer<CR>
 345 nnoremap <silent> <Leader>5 :5buffer<CR>
 346 nnoremap <silent> <Leader>6 :6buffer<CR>
 347 nnoremap <silent> <Leader>7 :7buffer<CR>
 348 nnoremap <silent> <Leader>8 :8buffer<CR>
 349 nnoremap <silent> <Leader>9 :9buffer<CR>
 350 nnoremap <silent> <Leader>0 :10buffer<CR>
 351
 352 " Make last active window the only window. Similar to <C-W> o.
 353 nnoremap <C-W>O <C-W>p<C-W>o
 354
 355 " Maps to change spell language between English and German and disable spell
 356 " checking.
 357 if exists('+spell')
 358     nnoremap <silent> <Leader>sn :set nospell<CR>
 359     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 360     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 361 endif
 362
 363 " Add semicolon to the end of the line. Thanks to
 364 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 365 " on Freenode for an improved version which doesn't clobber any marks.
 366 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 367
 368 " * and # for selections in visual mode. Thanks to
 369 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 370 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 371 if has('eval')
 372     function! s:VSetSearch()
 373         let l:temp = @@
 374         normal! gvy
 375         " Added \C to force 'noignorecase' while searching the current visual
 376         " selection. I want to search for the exact string in this case.
 377         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 378         let @@ = l:temp
 379     endfunction
 380     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 381     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 382 endif
 383
 384 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 385 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 386 " mailing list for the commands.
 387 if v:version < 700
 388     cnoreabbrev W w
 389     cnoreabbrev Wa wa
 390     cnoreabbrev Wq wq
 391     cnoreabbrev Wqa wqa
 392 else
 393     cnoreabbrev <expr> W
 394         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 395     cnoreabbrev <expr> Wa
 396         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 397     cnoreabbrev <expr> Wq
 398         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 399     cnoreabbrev <expr> Wqa
 400         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 401 endif
 402 " Also fix my typo with "Q".
 403 if v:version < 700
 404     cnoreabbrev Q q
 405     cnoreabbrev Qa qa
 406 else
 407     cnoreabbrev <expr> Q
 408         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 409     cnoreabbrev <expr> Qa
 410         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 411 endif
 412
 413 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 414 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 415 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 416
 417 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 418 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 419 " Vim's source.
 420 inoremap <C-U> <C-G>u<C-U>
 421 " Same for <C-@> (insert previously inserted text and leave insert mode).
 422 inoremap <C-@> <C-G>u<C-@>
 423 " And for <C-A> (insert previously inserted text).
 424 inoremap <C-A> <C-G>u<C-A>
 425 " And for <C-W> (delete word before cursor).
 426 inoremap <C-W> <C-G>u<C-W>
 427
 428 if has('eval')
 429 " New text-objects ii and ai to work on text with the same indentation. Thanks
 430 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 431 " (visited on 2011-11-19).
 432     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 433     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 434     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 435     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 436
 437     function! s:IndTxtObj(inner)
 438         let curline = line(".")
 439         let lastline = line("$")
 440         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 441         let i = i < 0 ? 0 : i
 442         if getline(".") !~ "^\\s*$"
 443             let p = line(".") - 1
 444             let nextblank = getline(p) =~ "^\\s*$"
 445             while p > 0
 446                     \ && ((i == 0 && !nextblank)
 447                         \ || (i > 0 && ((indent(p) >= i
 448                             \ && !(nextblank && a:inner))
 449                             \ || (nextblank && !a:inner))))
 450                 -
 451                 let p = line(".") - 1
 452                 let nextblank = getline(p) =~ "^\\s*$"
 453             endwhile
 454             normal! 0V
 455             call cursor(curline, 0)
 456             let p = line(".") + 1
 457             let nextblank = getline(p) =~ "^\\s*$"
 458             while p <= lastline
 459                     \ && ((i == 0 && !nextblank)
 460                         \ || (i > 0 && ((indent(p) >= i
 461                             \ && !(nextblank && a:inner))
 462                             \ || (nextblank && !a:inner))))
 463                 +
 464                 let p = line(".") + 1
 465                 let nextblank = getline(p) =~ "^\\s*$"
 466             endwhile
 467             normal! $
 468         endif
 469     endfunction
 470 endif
 471
 472
 473 " ABBREVIATIONS
 474
 475 " Fix some of my spelling mistakes.
 476 iabbrev relle reelle
 477 iabbrev reele reelle
 478
 479
 480 " SYNTAX SETTINGS
 481
 482 " Activate syntax coloring.
 483 if has('syntax')
 484     syntax enable
 485
 486 " Don't highlight more than 500 columns as I normally don't have that long
 487 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 488 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 489     if exists('+synmaxcol')
 490         set synmaxcol=500
 491     endif
 492
 493 " Use (limited) syntax based omni completion if no other omni completion is
 494 " available. Taken from :help ft-syntax-omni.
 495     if has('autocmd') && exists('+omnifunc')
 496         augroup vimrc
 497             autocmd FileType *
 498                 \ if &omnifunc == '' |
 499                 \     setlocal omnifunc=syntaxcomplete#Complete |
 500                 \ endif
 501         augroup END
 502     endif
 503
 504 " Function to enable all custom highlights. Necessary as highlights are
 505 " window-local and thus must be set for each new window.
 506     function! s:CustomSyntaxHighlights()
 507         " Not the first time called, nothing to do.
 508         if exists('w:vimrc_syntax_run')
 509             return
 510         endif
 511         let w:vimrc_syntax_run = 1
 512
 513 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 514 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 515 " disabled when necessary with :2match (in Vim >= 700).
 516         if exists(':2match')
 517             2match Todo /\%>78v./
 518         else
 519             match Todo /\%>78v./
 520         endif
 521
 522         if exists('*matchadd')
 523 " Highlight some important keywords in all documents.
 524             let l:todos = ['TODO', 'XXX', 'FIXME',
 525                          \ 'CHANGED', 'REMOVED', 'DELETED']
 526             " Compatibility fix for Vim 6.4 which can't handle for in function
 527             " (without function it's ignored).
 528             execute '  for l:x in l:todos'
 529                   \ '|     call matchadd("Todo", l:x)'
 530                   \ '| endfor'
 531
 532 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 533             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 534                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 535                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 536                           \ '205f', '2060', '3000', 'feff']
 537             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 538             " it won't work!
 539             execute '  for l:x in l:spaces'
 540                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 541                   \ '| endfor'
 542         endif
 543     endfunction
 544 " Enable highlights for the current and all new windows. Thanks to bairui in
 545 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 546     call <SID>CustomSyntaxHighlights()
 547     if has('autocmd')
 548         augroup vimrc
 549             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 550         augroup END
 551     endif
 552
 553 " Settings for specific filetypes.
 554
 555     " Haskell.
 556     let g:hs_highlight_delimiters = 1
 557     let g:hs_highlight_boolean = 1
 558     let g:hs_highlight_types = 1
 559     let g:hs_highlight_more_types = 1
 560     " Perl.
 561     let g:perl_fold = 1
 562     let g:perl_fold_blocks = 1
 563     let g:perl_nofold_packages = 1
 564     let g:perl_include_pod = 1 " syntax coloring for PODs
 565     " Python.
 566     let g:python_highlight_all = 1
 567     " Shell.
 568     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 569     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 570     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 571     " Vim.
 572     let g:vimsyn_embed = 0      " don't highlight embedded languages
 573     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 574     " XML.
 575     let g:xml_syntax_folding = 1
 576 endif
 577
 578
 579 " PLUGIN SETTINGS
 580
 581 if has('eval')
 582 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 583 " installing/removing/updating plugins simple. (Used for plugins with more
 584 " than one file.) Ignore errors in case pathogen is not installed.
 585     if v:version >= 700
 586         silent! execute 'call pathogen#runtime_append_all_bundles()'
 587     endif
 588
 589 " Settings for the NERD commenter.
 590     " Don't create any mappings I don't want to use.
 591     let g:NERDCreateDefaultMappings = 0
 592     " Map toggle comment.
 593     map <Leader><Leader> <Plug>NERDCommenterToggle
 594
 595 " XPTemplate settings.
 596     " Try to maintain snippet rendering even after editing outside of a
 597     " snippet.
 598     let g:xptemplate_strict = 0
 599     " Don't complete any braces automatically.
 600     let g:xptemplate_brace_complete = 0
 601     " Only highlight the current placeholder.
 602     let g:xptemplate_highlight = 'current'
 603 endif
 604
 605
 606 " AUTO COMMANDS
 607
 608 " Use a custom auto group to prevent problems when the vimrc files is sourced
 609 " twice.
 610 if has('autocmd')
 611     augroup vimrc
 612
 613 " Go to last position of opened files. Taken from :help last-position-jump.
 614         autocmd BufReadPost *
 615             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 616             \     execute "normal! g'\"" |
 617             \ endif
 618 " But not for Git commits, go to beginning of the file.
 619         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 620
 621 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 622 " when switching to a help buffer which is in the background with :buffer as
 623 " these options are local to windows (and not only to buffers). This happens
 624 " because I often want to use only one window and thus the help buffer is in
 625 " the background.
 626         autocmd BufWinEnter *.txt
 627             \ if &filetype == 'help' |
 628             \     setlocal nolist |
 629             \     setlocal nonumber |
 630             \ endif
 631
 632 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 633 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 634 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 635 " doesn't exist in older Vims.
 636         if exists('##InsertLeave')
 637             autocmd InsertLeave * set nopaste
 638         endif
 639
 640 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 641 " doesn't exist in older Vims.
 642         if exists('##QuickFixCmdPre')
 643             autocmd QuickFixCmdPre * write
 644         endif
 645
 646 " Don't ignore case while in insert mode, but ignore case in all other modes.
 647 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 648 " capitalization. But while searching (/) 'ignorecase' is used.
 649 " InsertEnter/InsertLeave doesn't exist in older Vims.
 650         if exists('##InsertEnter') && exists('##InsertLeave')
 651             autocmd InsertEnter * set noignorecase
 652             autocmd InsertLeave * set   ignorecase
 653         endif
 654
 655 " AFTER/FTPLUGIN AUTO COMMANDS
 656
 657 " Disable spell checking for files which don't need it.
 658         autocmd FileType deb  setlocal nospell
 659         autocmd FileType diff setlocal nospell
 660         autocmd FileType tar  setlocal nospell
 661 " Fix to allow Vim edit crontab files as crontab doesn't work with
 662 " backupcopy=auto.
 663         autocmd FileType crontab setlocal backupcopy=yes
 664 " Don't use the modeline in git commits as the diff created by `git commit -v`
 665 " may contain one which could change the filetype or other settings of the
 666 " commit buffer. Also make sure we use only 72 characters per line which is
 667 " the recommendation for git commit messages (http://tpope.net/node/106).
 668         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 669                                  \ setlocal textwidth=72
 670 " Use the same comment string as for Vim files in Vimperator files.
 671         autocmd FileType vimperator setlocal commentstring=\"%s
 672 " Use tex compiler for (La)TeX files.
 673         autocmd FileType tex compiler tex
 674
 675 " FTDETECT AUTO COMMANDS
 676
 677 " Recognize .md as markdown files (Vim default is .mkd).
 678         autocmd BufRead,BufNewFile *.md set filetype=mkd
 679 " Recognize .test as Tcl files.
 680         autocmd BufRead,BufNewFile *.test set filetype=tcl
 681
 682 " OTHER AUTO COMMANDS
 683
 684 " Disable spell checking, displaying of list characters and long lines when
 685 " viewing documentation.
 686         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 687
 688 " Use diff filetype for mercurial patches in patch queue.
 689         autocmd BufReadPost */.hg/patches/* set filetype=diff
 690
 691     augroup END
 692 endif
 693
 694
 695 " CUSTOM FUNCTIONS AND COMMANDS
 696
 697 if has('eval')
 698 " Convenient command to see the difference between the current buffer and the
 699 " file it was loaded from, thus the changes you made. Thanks to the
 700 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 701 " for the diffed file than the filetype for the original file.
 702     if !exists(':DiffOrig')
 703         command DiffOrig
 704             \ let s:diff_orig_filetype = &filetype
 705             \ | vertical new
 706             \ | let &filetype = s:diff_orig_filetype
 707             \ | unlet s:diff_orig_filetype
 708             \ | set buftype=nofile
 709             \ | read ++edit #
 710             \ | 0d_
 711             \ | diffthis
 712             \ | wincmd p
 713             \ | diffthis
 714     endif
 715 endif