vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2016  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Disallow :autocmd, shell and write commands in .vimrc and .exrc files in the
  45 " current directory. Only used if 'exrc' is enabled (off by default),
  46 " precaution just in case somebody enables 'exrc'.
  47 set secure
  48
  49 " Try to use pipes instead of temporary files. Prevents some auto commands
  50 " from running for temporary files but also prevents the file's content to be
  51 " written to disk.
  52 set noshelltemp
  53
  54 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  55 " affect reading files in different encodings, see 'fileencodings' for that.
  56 set encoding=utf-8
  57
  58 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  59 " runtime files) if available.
  60 set runtimepath-=~/.vim
  61 set runtimepath^=~/.vim,~/.vim/runtime
  62
  63 " Don't store swap files in the same directory as the edited file, but only if
  64 " we have a "safe" writable directory available.
  65 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  66     set directory-=.
  67 endif
  68 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  69 set directory^=~/.tmp
  70 " Never use /tmp which gets cleaned on reboot.
  71 set directory-=/tmp
  72
  73 " Disable modelines as they may cause security problems. Instead use
  74 " securemodelines (Vim script #1876).
  75 set nomodeline
  76
  77 " Complete to longest common string (list:longest) and then complete all full
  78 " matches after another (full). Thanks to pbrisbin
  79 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  80 set wildmode=list:longest,full
  81 " Ignore case when completing files/directories.
  82 if exists('+wildignorecase')
  83     set wildignorecase
  84 endif
  85
  86 " Ignore files with the following extensions because I almost never want to
  87 " edit them in Vim (specifying them manually still works of course).
  88 set wildignore=
  89 " C
  90 set wildignore+=*.o,*.d,*.so
  91 " Java
  92 set wildignore+=*.class
  93 " LaTeX
  94 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  95 " Python
  96 set wildignore+=*.pyc
  97
  98 " Show completion menu even if only one entry matches.
  99 if exists('+completeopt')
 100     set completeopt+=menuone
 101 endif
 102
 103 " Increase history of executed commands (:) and search patterns (/).
 104 set history=1000
 105
 106 " Increase number of possible undos.
 107 set undolevels=1000
 108
 109 " Remember marks (including the last cursor position) for more files. ^= is
 110 " necessary because 'viminfo' is parsed from the beginning and the first match
 111 " is used.
 112 if has('viminfo')
 113     set viminfo^='1000
 114 endif
 115
 116 " Use strong encryption if possible, also used for swap/undo files.
 117 if exists('+cryptmethod')
 118     set cryptmethod=blowfish
 119 endif
 120
 121 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 122 " is used multiple times. Necessary to support reloading the vimrc.
 123 if has('autocmd')
 124     augroup vimrc
 125         autocmd!
 126     augroup END
 127 endif
 128
 129
 130 " HELPER FUNCTIONS
 131
 132 if has('eval')
 133 " Check if the given syntax group is available. Thanks to bairui in #vim on
 134 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 135     function! s:HasSyntaxGroup(group)
 136         try
 137             execute 'silent highlight ' . a:group
 138         " \a = [A-Za-z]
 139         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 140             return 0
 141         endtry
 142         return 1
 143     endfunction
 144
 145 " Check if the given Vim version and patch is available.
 146     function! s:HasVersionAndPatch(version, patch)
 147         return v:version > a:version
 148             \ || (v:version == a:version && has('patch' . a:patch))
 149     endfunction
 150 endif
 151
 152
 153 " TERMINAL SETTINGS
 154
 155 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 156 " connections.
 157 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 158     set ttyfast
 159 endif
 160
 161
 162 " EDIT SETTINGS
 163
 164 " Enable automatic file detection, plugin and indention support.
 165 if has('autocmd')
 166     filetype off " necessary for pathogen to force a reload of ftplugins
 167     filetype plugin indent on
 168 endif
 169
 170 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 171 " existing files.
 172 set fileencodings=utf-8,latin1
 173
 174 " Always use unix line-endings for new files. DOS line endings in existing
 175 " files are recognized.
 176 set fileformats=unix,dos
 177
 178 " Wrap text after 78 characters.
 179 set textwidth=78
 180
 181 " Set tabs to 4 spaces, use softtabs.
 182 set shiftwidth=4
 183 set softtabstop=4
 184 set expandtab
 185 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 186 set shiftround
 187 " Use the default value for real tabs.
 188 set tabstop=8
 189
 190 " Enable auto indention.
 191 set autoindent
 192
 193 " When joining lines only add one space after a sentence.
 194 set nojoinspaces
 195
 196 " Allow backspacing over autoindent and line breaks.
 197 set backspace=indent,eol
 198
 199 " Start a comment when hitting enter after a commented line (r) and when using
 200 " o or O around a commented line (o).
 201 set formatoptions+=ro
 202 " Don't break a line if was already longer then 'textwidth' when insert mode
 203 " started.
 204 set formatoptions+=l
 205 " Remove comment leader when joining lines where it makes sense.
 206 if s:HasVersionAndPatch(703, 541)
 207     set formatoptions+=j
 208 endif
 209
 210 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 211 " no character) in visual block mode.
 212 set virtualedit=block
 213
 214 " Already display matches while typing the search command. This makes spotting
 215 " typos easy and searching faster.
 216 set incsearch
 217
 218 " Activate syntax folding.
 219 if has('folding')
 220     set foldmethod=syntax
 221     " Only use fold column if we have enough space (for example not in a
 222     " (virtual) terminal which has only 80 columns).
 223     if &columns > 80
 224         set foldcolumn=2
 225     endif
 226     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 227                      " folding which is not what I want
 228     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 229     set foldopen-=block
 230 endif
 231
 232 " Only check case if the searched word contains a capital character.
 233 set ignorecase
 234 set smartcase
 235
 236 " Activate spell checking, use English as default.
 237 if exists('+spell') && has('syntax')
 238     " But not when diffing because spell checking is distracting in this case.
 239     if !&diff
 240         set spell
 241     endif
 242     set spelllang=en_us
 243 endif
 244
 245 " Allow buffers with changes to be hidden. Very important for efficient
 246 " editing with multiple buffers. Prevents the "E37: No write since last change
 247 " (add ! to override)" warning when switching modified buffers.
 248 set hidden
 249
 250 " When splitting vertically put the new window right of the current one.
 251 if has('vertsplit')
 252     set splitright
 253 endif
 254
 255
 256 " DISPLAY SETTINGS
 257
 258 " Use a dark background. Doesn't change the background color, only sets text
 259 " colors for a dark terminal.
 260 set background=dark
 261
 262 " Use my color scheme if 256 colors are available.
 263 if &t_Co == 256 || has('gui_running')
 264     colorscheme simon
 265 endif
 266
 267 " Display line numbers.
 268 set number
 269 " But use as little space as possible for the numbers column. Thanks to James
 270 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 271 if exists('+numberwidth')
 272     set numberwidth=1
 273 endif
 274 " Display the ruler with current line/file position. If 'statusline' is used,
 275 " then this only affects <C-G>.
 276 set ruler
 277 " Display partial commands in the status line.
 278 set showcmd
 279
 280 " Don't redraw screen when executing macros; increases speed. Thanks to James
 281 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 282 set lazyredraw
 283
 284 " Visualize the line the cursor is currently in.
 285 if exists('+cursorline')
 286     set cursorline
 287 endif
 288
 289 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 290 " remove the highlighting until the next search.
 291 set hlsearch
 292
 293 " Display some special characters.
 294 set list
 295 set listchars=
 296 " Display tabs as ">--------".
 297 set listchars+=tab:>-
 298 " Display trailing whitespace as "-".
 299 set listchars+=trail:-
 300 " Display markers for long lines when wrapping is disabled.
 301 set listchars+=extends:>,precedes:<
 302 " Display non-breakable space as "!".
 303 if v:version >= 700
 304     set listchars+=nbsp:!
 305 endif
 306
 307 " Don't draw the vertical split separator by using space as character. Thanks
 308 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 309 " non-breakable space. But a simple space works as well, as long as the
 310 " current color scheme is not reset.
 311 if has('windows') && has('folding')
 312     set fillchars+=vert:\  " comment to prevent trailing whitespace
 313 endif
 314
 315 if has('statusline')
 316     " Always display the status line even if there is only one window.
 317     set laststatus=2
 318
 319     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 320     " is the highest buffer number, otherwise return nothing. Used in
 321     " 'statusline' to get an overview of available buffer numbers.
 322     function! s:StatuslineBufferCount()
 323         let l:bufnr = bufnr('$')
 324         if l:bufnr > 1
 325             let l:result = '/'
 326             if exists('*printf')
 327                 let l:result .= printf('%02d', l:bufnr)
 328             else
 329                 " Older Vims don't have printf() (and no .= either). Emulate
 330                 " "%02d".
 331                 if l:bufnr < 10
 332                     let l:result = l:result . '0'
 333                 endif
 334                 let l:result = l:result . l:bufnr
 335             endif
 336             return l:result
 337         else
 338             return ''
 339         endif
 340     endfunction
 341
 342     " Like %f but use relative filename if it's shorter than the absolute path
 343     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 344     " not enough because it doesn't create '../'s.
 345     function! s:StatuslineRelativeFilename()
 346         " Display only filename for help files.
 347         if &buftype == 'help'
 348             return expand('%:t')
 349         endif
 350         " Special case for scratch files.
 351         if &buftype == 'nofile'
 352             return '[Scratch]'
 353         endif
 354
 355         let l:path = expand('%')
 356         " No file.
 357         if l:path == ''
 358             return '[No Name]'
 359         endif
 360         " Path is already relative, nothing to do.
 361         if stridx(l:path, '/') != 0
 362             return l:path
 363         endif
 364
 365         " Absolute path to this file.
 366         let l:path = expand('%:p')
 367         " Shortened path to this file, thanks to bairui in #vim on Freenode
 368         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 369         " Vim normally uses as %f (minus some exceptions).
 370         let l:original_path = fnamemodify(l:path, ':~')
 371         " Absolute path to the current working directory.
 372         let l:cwd = getcwd()
 373
 374         " Working directory completely contained in path, replace it with a
 375         " relative path. Happens for example when opening a file with netrw.
 376         " %f displays this as absolute path, but we want a relative path of
 377         " course.
 378         if stridx(l:path, l:cwd) == 0
 379             return strpart(l:path, strlen(l:cwd) + 1)
 380         endif
 381
 382         let l:path_list = split(l:path, '/')
 383         let l:cwd_list  = split(l:cwd,  '/')
 384
 385         " Remove the common path.
 386         while l:path_list[0] == l:cwd_list[0]
 387             call remove(l:path_list, 0)
 388             call remove(l:cwd_list,  0)
 389         endwhile
 390
 391         " Add as many '..' as necessary for the relative path and join the
 392         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 393         " the hint to use repeat() instead of a loop.
 394         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 395
 396         " Use the shorter path, either relative or absolute.
 397         if strlen(l:path) < strlen(l:original_path)
 398             return l:path
 399         else
 400             return l:original_path
 401         endif
 402     endfunction
 403
 404     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 405     function! s:StatuslineFileFormat()
 406         if &fileformat != 'unix'
 407             return '[' . &fileformat . ']'
 408         else
 409             return ''
 410         endif
 411     endfunction
 412     function! s:StatuslineFileEncoding()
 413         if &fileencoding != '' && &fileencoding != 'utf-8'
 414                 \ && &filetype != 'help'
 415             return '[' . &fileencoding . ']'
 416         else
 417             return ''
 418         endif
 419     endfunction
 420     function! s:StatuslineFileBOMB()
 421         if exists('+bomb') && &bomb
 422             return '[BOM]'
 423         else
 424             return ''
 425         endif
 426     endfunction
 427
 428     " Return current syntax group in brackets or nothing if there's none.
 429     function! s:StatuslineSyntaxGroup()
 430         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 431         if l:group != ''
 432             return '[' . l:group . '] '
 433         else
 434             return ''
 435         endif
 436     endfunction
 437
 438     " Short function names to make 'statusline' more readable.
 439     function! SBC()
 440         return s:StatuslineBufferCount()
 441     endfunction
 442     function! SRF()
 443         return s:StatuslineRelativeFilename()
 444     endfunction
 445     function! SFF()
 446         return s:StatuslineFileFormat()
 447     endfunction
 448     function! SFE()
 449         return s:StatuslineFileEncoding()
 450     endfunction
 451     function! SFB()
 452         return s:StatuslineFileBOMB()
 453     endfunction
 454     function! SSG()
 455         return s:StatuslineSyntaxGroup()
 456     endfunction
 457
 458     set statusline=
 459     " on the left
 460     set statusline+=%02n              " buffer number
 461     set statusline+=%{SBC()}          " highest buffer number
 462     set statusline+=:
 463     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 464         set statusline+=%{SRF()}      " path to current file
 465     else
 466         set statusline+=%f            " path to current file in buffer
 467     endif
 468     set statusline+=\                 " space after path
 469     set statusline+=%h                " [help] if buffer is help file
 470     set statusline+=%w                " [Preview] if buffer is preview buffer
 471     set statusline+=%m                " [+] if buffer was modified,
 472                                       " [-] if 'modifiable' is off
 473     set statusline+=%r                " [RO] if buffer is read only
 474     if v:version >= 700               " %#..# needs 7.0
 475         set statusline+=%#Error#      " display warnings
 476         set statusline+=%{SFF()}      "   - unexpected file format
 477         set statusline+=%{SFE()}      "   - unexpected file encoding
 478         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 479         set statusline+=%##           " continue with normal colors
 480     endif
 481
 482     " on the right
 483     set statusline+=%=                " right align
 484     set statusline+=0x%-8B\           " current character under cursor as hex
 485     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 486                                       " column number (%c),
 487                                       " virtual column number if different
 488                                       "                       than %c (%V)
 489     set statusline+=%P                " position in file in percent
 490 endif
 491
 492
 493 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 494
 495 " noremap is used to make sure the right side is executed as is and can't be
 496 " modified by a plugin or other settings. Except for <Nop> which isn't
 497 " affected by mappings.
 498
 499 " Easy way to exit insert mode (jj is too slow).
 500 inoremap jk <Esc>
 501 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 502 " (2010-10-15).
 503 cnoremap jk <C-C>
 504 " And fix my typos ...
 505 inoremap JK <Esc>
 506 inoremap Jk <Esc>
 507 inoremap jK <Esc>
 508 cnoremap JK <C-C>
 509 cnoremap Jk <C-C>
 510 cnoremap jK <C-C>
 511
 512 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 513 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 514 map <Right>  <Nop>
 515 map <Left>   <Nop>
 516 map <Up>     <Nop>
 517 map <Down>   <Nop>
 518 imap <Right> <Nop>
 519 imap <Left>  <Nop>
 520 imap <Up>    <Nop>
 521 imap <Down>  <Nop>
 522 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 523 " below).
 524 cmap <Up>    <Nop>
 525 cmap <Down>  <Nop>
 526 cmap <Right> <Nop>
 527 cmap <Left>  <Nop>
 528
 529 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 530 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 531 cnoremap <C-P> <Up>
 532 cnoremap <C-N> <Down>
 533
 534 if has('eval')
 535 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 536 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 537 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 538 " directly because it also enables that feature for other commands which I
 539 " don't want.
 540
 541     " Set 'nostartofline' for a single movement.
 542     function! s:TemporaryNostartofline(movement)
 543         let l:startofline = &startofline
 544         set nostartofline
 545         execute 'normal! ' . a:movement
 546         let &startofline = l:startofline
 547     endfunction
 548
 549     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 550     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 551     nnoremap <silent> <C-F>
 552         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 553     nnoremap <silent> <C-B>
 554         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 555     nnoremap <silent> <C-D>
 556         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 557     nnoremap <silent> <C-U>
 558         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 559 endif
 560
 561 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 562 " yank a line. This fixes a weird inconsistency in Vi(m).
 563 nnoremap Y y$
 564
 565 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 566 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 567 " Only the current buffer is written, thus switching to another buffer works
 568 " too.
 569 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 570
 571 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 572 " in #vim on Freenode (2011-08-15 00:17 CEST).
 573 nnoremap <C-G> 2<C-G>
 574
 575 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 576 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 577 nmap <Space> <C-F>
 578 nmap - <C-B>
 579
 580 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 581 " (2010-05-16 18:38 CEST) for this idea.
 582 nnoremap <silent> gb :bnext<CR>
 583 nnoremap <silent> gB :bprevious<CR>
 584 if has('eval')
 585     " But when starting again at the first buffer, print a warning which
 586     " reminds me that I've already seen that buffer.
 587     function! s:NextBuffer()
 588         " Are we currently on the last buffer and moving to the first?
 589         let l:last_buffer = 0
 590         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 591             let l:last_buffer = 1
 592         endif
 593
 594         " Go to the next buffer.
 595         if !l:last_buffer
 596             bnext
 597
 598         " Go to the first buffer, silent is necessary or the following message
 599         " won't be displayed because it's overwritten by the status message
 600         " displayed when entering a buffer.
 601         else
 602             silent bnext
 603
 604             echohl WarningMsg
 605             echo 'Starting again at first buffer.'
 606             echohl None
 607         endif
 608     endfunction
 609     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 610 endif
 611
 612 " Fast access to buffers.
 613 nnoremap <silent> <Leader>1 :1buffer<CR>
 614 nnoremap <silent> <Leader>2 :2buffer<CR>
 615 nnoremap <silent> <Leader>3 :3buffer<CR>
 616 nnoremap <silent> <Leader>4 :4buffer<CR>
 617 nnoremap <silent> <Leader>5 :5buffer<CR>
 618 nnoremap <silent> <Leader>6 :6buffer<CR>
 619 nnoremap <silent> <Leader>7 :7buffer<CR>
 620 nnoremap <silent> <Leader>8 :8buffer<CR>
 621 nnoremap <silent> <Leader>9 :9buffer<CR>
 622 nnoremap <silent> <Leader>0 :10buffer<CR>
 623
 624 " Use real tabs instead of soft tabs.
 625 if has('eval')
 626 " Switch from soft tabs to real tabs.
 627     function! s:UseTabs()
 628         setlocal noexpandtab shiftwidth=8 softtabstop=8
 629     endfunction
 630     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 631 endif
 632 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 633 " coloring. 'list' is not changed, see next mapping.
 634 nnoremap <silent> <Leader>v :setlocal nowrap nospell synmaxcol=0<CR>
 635                           \ :2match<CR>
 636 " Toggle 'list'.
 637 nnoremap <silent> <Leader>l :set invlist<CR>
 638
 639 " Make last active window the only window. Similar to <C-W> o.
 640 nnoremap <C-W>O <C-W>p<C-W>o
 641
 642 " Maps to change spell language between English and German and disable spell
 643 " checking.
 644 if exists('+spell')
 645     nnoremap <silent> <Leader>sn :set nospell<CR>
 646     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 647     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 648 " If no spell support is available, these mappings do nothing.
 649 else
 650     nmap <Leader>sn <Nop>
 651     nmap <Leader>se <Nop>
 652     nmap <Leader>sd <Nop>
 653 endif
 654
 655 if has('eval')
 656 " * and # for selections in visual mode. Thanks to
 657 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 658 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 659     function! s:VSetSearch()
 660         let l:temp = @@ " unnamed register
 661         normal! gvy
 662         " Added \C to force 'noignorecase' while searching the current visual
 663         " selection. I want to search for the exact string in this case.
 664         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 665         let @@ = l:temp
 666     endfunction
 667     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 668     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 669
 670 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 671 " Thanks to the writers of s:VSetSearch(), see above.
 672     function! s:NSetSearch()
 673         let l:cword = expand('<cword>')
 674         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 675         let @/ = '\C\V'. '\<' . l:regex . '\>'
 676     endfunction
 677     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 678     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 679 endif
 680
 681 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 682 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 683 " mailing list for the commands.
 684 if v:version < 700
 685     cnoreabbrev W w
 686     cnoreabbrev Wa wa
 687     cnoreabbrev Wq wq
 688     cnoreabbrev Wqa wqa
 689 else
 690     cnoreabbrev <expr> W
 691         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 692     cnoreabbrev <expr> Wa
 693         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 694     cnoreabbrev <expr> Wq
 695         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 696     cnoreabbrev <expr> Wqa
 697         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 698 endif
 699 " Also fix my typo with "Q".
 700 if v:version < 700
 701     cnoreabbrev Q q
 702     cnoreabbrev Qa qa
 703 else
 704     cnoreabbrev <expr> Q
 705         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 706     cnoreabbrev <expr> Qa
 707         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 708 endif
 709
 710 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 711 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 712 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 713
 714 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 715 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 716 " Vim's source.
 717 inoremap <C-U> <C-G>u<C-U>
 718 " Same for <C-@> (insert previously inserted text and leave insert mode).
 719 inoremap <C-@> <C-G>u<C-@>
 720 " And for <C-A> (insert previously inserted text).
 721 inoremap <C-A> <C-G>u<C-A>
 722 " And for <C-W> (delete word before cursor).
 723 inoremap <C-W> <C-G>u<C-W>
 724
 725 if has('eval')
 726 " New text-objects ii and ai to work on text with the same indentation. Thanks
 727 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 728 " (visited on 2011-11-19).
 729     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 730     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 731     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 732     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 733
 734     function! s:IndTxtObj(inner)
 735         let curline = line(".")
 736         let lastline = line("$")
 737         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 738         let i = i < 0 ? 0 : i
 739         if getline(".") !~ "^\\s*$"
 740             let p = line(".") - 1
 741             let nextblank = getline(p) =~ "^\\s*$"
 742             while p > 0
 743                     \ && ((i == 0 && !nextblank)
 744                         \ || (i > 0 && ((indent(p) >= i
 745                             \ && !(nextblank && a:inner))
 746                             \ || (nextblank && !a:inner))))
 747                 -
 748                 let p = line(".") - 1
 749                 let nextblank = getline(p) =~ "^\\s*$"
 750             endwhile
 751             normal! 0V
 752             call cursor(curline, 0)
 753             let p = line(".") + 1
 754             let nextblank = getline(p) =~ "^\\s*$"
 755             while p <= lastline
 756                     \ && ((i == 0 && !nextblank)
 757                         \ || (i > 0 && ((indent(p) >= i
 758                             \ && !(nextblank && a:inner))
 759                             \ || (nextblank && !a:inner))))
 760                 +
 761                 let p = line(".") + 1
 762                 let nextblank = getline(p) =~ "^\\s*$"
 763             endwhile
 764             normal! $
 765         endif
 766     endfunction
 767 endif
 768
 769
 770 " ABBREVIATIONS
 771
 772 " Fix some of my spelling mistakes (German).
 773 inoreabbrev relle reelle
 774 inoreabbrev reele reelle
 775 " Fix some of my spelling mistakes (English).
 776 inoreabbrev completly completely
 777
 778
 779 " SYNTAX SETTINGS
 780
 781 " Activate syntax coloring.
 782 if has('syntax')
 783     " But only if it wasn't already active. Prevents breaking the syntax
 784     " coloring when reloading the vimrc. Thanks to johnLate for the idea.
 785     if !exists('g:syntax_on')
 786         syntax enable
 787     endif
 788
 789 " Don't highlight more than 500 columns as I normally don't have that long
 790 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 791 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 792     if exists('+synmaxcol')
 793         set synmaxcol=500
 794     endif
 795
 796 " Use (limited) syntax based omni completion if no other omni completion is
 797 " available. Taken from :help ft-syntax-omni.
 798     if has('autocmd') && exists('+omnifunc')
 799         augroup vimrc
 800             autocmd FileType *
 801                 \ if &omnifunc == '' |
 802                 \     setlocal omnifunc=syntaxcomplete#Complete |
 803                 \ endif
 804         augroup END
 805     endif
 806
 807 " Function to enable all custom highlights. Necessary as highlights are
 808 " window-local and thus must be set for each new window.
 809     function! s:CustomSyntaxHighlights()
 810         " Not the first time called, nothing to do.
 811         if exists('w:vimrc_syntax_run')
 812             return
 813         endif
 814         let w:vimrc_syntax_run = 1
 815
 816 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 817 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 818 " disabled when necessary with :2match (in Vim >= 700).
 819         if !&diff && exists(':2match')
 820             " Use ColorColumn for overlong lines if available and my color
 821             " scheme is used.
 822             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 823                 2match ColorColumn /\%>78v./
 824             else
 825                 2match Todo /\%>78v./
 826             endif
 827         elseif !&diff
 828             match Todo /\%>78v./
 829         endif
 830
 831         if exists('*matchadd')
 832 " Highlight some important keywords in all documents.
 833             let l:todos = ['TODO', 'XXX', 'FIXME', 'NOTE',
 834                          \ 'CHANGED', 'REMOVED', 'DELETED']
 835             " Compatibility fix for Vim 6.4 which can't parse for in functions
 836             " (without function it's ignored).
 837             execute '  for l:x in l:todos'
 838                   \ '|     call matchadd("Todo", l:x)'
 839                   \ '| endfor'
 840
 841 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 842             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 843                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 844                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 845                           \ '205f', '2060', '3000', 'feff']
 846             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 847             " it won't work!
 848             execute '  for l:x in l:spaces'
 849                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 850                   \ '| endfor'
 851
 852 " Special highlight for tabs to reduce their visibility in contrast to other
 853 " SpecialKey characters (e.g. ^L).
 854             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 855                 call matchadd('specialKeyTab', '\t')
 856             endif
 857         endif
 858     endfunction
 859 " Enable highlights for the current and all new windows. Thanks to bairui in
 860 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 861     call s:CustomSyntaxHighlights()
 862     if has('autocmd')
 863         augroup vimrc
 864             autocmd WinEnter * call s:CustomSyntaxHighlights()
 865         augroup END
 866     endif
 867
 868 " Settings for specific filetypes.
 869
 870     " C
 871     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 872     " Haskell
 873     let g:hs_highlight_delimiters = 1
 874     let g:hs_highlight_boolean = 1
 875     let g:hs_highlight_types = 1
 876     let g:hs_highlight_more_types = 1
 877     " Java
 878     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 879     " Perl
 880     let g:perl_fold = 1
 881     let g:perl_fold_blocks = 1
 882     let g:perl_nofold_packages = 1
 883     let g:perl_include_pod = 1 " syntax coloring for PODs
 884     " PHP
 885     let g:php_folding = 3    " fold functions
 886     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 887     let g:php_sql_query = 1  " highlight SQL queries in strings
 888     " Python
 889     let g:python_highlight_all = 1
 890     " Shell
 891     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 892     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 893     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 894     " Vim
 895     let g:vimsyn_embed = 0      " don't highlight embedded languages
 896     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 897     " XML
 898     let g:xml_syntax_folding = 1
 899 endif
 900
 901
 902 " PLUGIN SETTINGS
 903
 904 if has('eval')
 905 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 906 " installing/removing/updating plugins simple. (Used for plugins with more
 907 " than one file.) Ignore errors in case pathogen is not installed.
 908     if v:version >= 700
 909         silent! execute 'call pathogen#infect()'
 910     endif
 911
 912 " Settings for securemodelines.
 913     " Only allow items I need (also includes spl which is not enabled by
 914     " default).
 915     if v:version >= 700 " need lists
 916         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 917                                               \ 'sw', 'sts', 'noet']
 918     endif
 919
 920 " Settings for the NERD commenter.
 921     " Don't create any mappings I don't want to use.
 922     let g:NERDCreateDefaultMappings = 0
 923     " Map toggle comment.
 924     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 925
 926 " XPTemplate settings.
 927     " Try to maintain snippet rendering even after editing outside of a
 928     " snippet.
 929     let g:xptemplate_strict = 0
 930     " Don't complete any braces automatically.
 931     let g:xptemplate_brace_complete = 0
 932     " Only highlight the current placeholder.
 933     let g:xptemplate_highlight = 'current'
 934
 935 " CtrlP settings.
 936     " Don't manage the working directory (the default setting is too slow for
 937     " me).
 938     let g:ctrlp_working_path_mode = 0
 939
 940     " Path to cache directory. I prefer to keep generated files as local as
 941     " possible.
 942     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 943     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 944     " cache manually.
 945     let g:ctrlp_clear_cache_on_exit = 0
 946
 947     " Don't switch the window if the selected buffer is already open. I want
 948     " to open another view on this buffer in most cases.
 949     let g:ctrlp_switch_buffer = 0
 950
 951 " FSWitch settings.
 952     " Defaults don't work well for my projects.
 953     augroup vimrc
 954         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 955                           \ | let b:fswitchlocs = './'
 956         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 957                           \ | let b:fswitchlocs = './'
 958     augroup END
 959
 960     " Switch to corresponding header/source file.
 961     nnoremap <silent> <Leader>h :FSHere<CR>
 962
 963 " netrw settings.
 964     " Don't create ~/.vim/.netrwhist history file.
 965     let g:netrw_dirhistmax = 0
 966 endif
 967
 968
 969 " AUTO COMMANDS
 970
 971 " Use a custom auto group to prevent problems when the vimrc files is sourced
 972 " multiple times.
 973 if has('autocmd')
 974     augroup vimrc
 975
 976 " Go to last position of opened files. Taken from :help last-position-jump.
 977         autocmd BufReadPost *
 978             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 979             \     execute "normal! g'\"" |
 980             \ endif
 981 " But not for Git commits, go to beginning of the file.
 982         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 983
 984 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 985 " when switching to a help buffer which is in the background with :buffer as
 986 " these options are local to windows (and not only to buffers). This happens
 987 " because I often want to use only one window and thus the help buffer is in
 988 " the background.
 989         autocmd BufWinEnter *.txt
 990             \ if &filetype == 'help' |
 991             \     setlocal nolist |
 992             \     setlocal nonumber |
 993             \ endif
 994
 995 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 996 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 997 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 998 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
 999 " 'paste' in this case.
1000         if exists('##InsertLeave')
1001             autocmd InsertLeave * set nopaste
1002         endif
1003
1004 " Write all files when running :mak[e] before 'makeprg' is called.
1005 " QuickFixCmdPre doesn't exist in older Vims.
1006         if exists('##QuickFixCmdPre')
1007             autocmd QuickFixCmdPre * wall
1008         endif
1009
1010 " Don't ignore case while in insert mode, but ignore case in all other modes.
1011 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
1012 " capitalization. But while searching (/) 'ignorecase' is used.
1013 " InsertEnter/InsertLeave doesn't exist in older Vims.
1014         if exists('##InsertEnter') && exists('##InsertLeave')
1015             autocmd InsertEnter * set noignorecase
1016             autocmd InsertLeave * set   ignorecase
1017         endif
1018
1019 " Display a warning when editing a file which contains "do not edit" (ignoring
1020 " the case) and similar messages in the first lines of the file, for example
1021 " template files which were preprocessed or auto-generated files. Especially
1022 " useful when the header is not displayed on the first screen, e.g. when the
1023 " old position is restored.
1024         function! s:SearchForDoNotEditHeader()
1025             " Only search the first 20 lines to prevent false positives, e.g.
1026             " in scripts which write files containing this warning and ignore
1027             " the case (\c). (Can't use search()'s {stopline} as we might not
1028             " start searching from the top.)
1029             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1030             let l:match = search(l:search, 'n')
1031             if l:match == 0 || l:match > 20
1032                 return
1033             endif
1034
1035             echoerr 'Do not edit this file! (Maybe a template file.)'
1036         endfunction
1037         autocmd BufRead * call s:SearchForDoNotEditHeader()
1038
1039 " AFTER/FTPLUGIN AUTO COMMANDS
1040
1041 " Disable spell checking for files which don't need it.
1042         autocmd FileType deb  setlocal nospell
1043         autocmd FileType diff setlocal nospell
1044         autocmd FileType tar  setlocal nospell
1045 " Fix to allow Vim edit crontab files as crontab doesn't work with
1046 " backupcopy=auto.
1047         autocmd FileType crontab setlocal backupcopy=yes
1048 " Don't use the modeline in git commits as the diff created by `git commit -v`
1049 " may contain one which could change the filetype or other settings of the
1050 " commit buffer. Also make sure we use only 72 characters per line which is
1051 " the recommendation for git commit messages (http://tpope.net/node/106).
1052         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1053                                  \ setlocal textwidth=72
1054 " Fix 'include' setting for shell files to recognize '.' and 'source'
1055 " commands.
1056         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1057 " Use the same comment string as for Vim files in Vimperator files.
1058         autocmd FileType vimperator setlocal commentstring=\"%s
1059 " Use TeX compiler for (La)TeX files.
1060         autocmd FileType tex compiler tex
1061
1062 " FTDETECT AUTO COMMANDS
1063
1064 " Recognize .md as markdown files (Vim default is .mkd).
1065         autocmd BufRead,BufNewFile *.md set filetype=mkd
1066 " Recognize .test as Tcl files.
1067         autocmd BufRead,BufNewFile *.test set filetype=tcl
1068
1069 " OTHER AUTO COMMANDS
1070
1071 " Disable spell checking, displaying of list characters and long lines when
1072 " viewing documentation.
1073         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1074
1075 " Use diff filetype for mercurial patches in patch queue.
1076         autocmd BufReadPost */.hg/patches/* set filetype=diff
1077
1078     augroup END
1079 endif
1080
1081
1082 " CUSTOM FUNCTIONS AND COMMANDS
1083
1084 if has('eval')
1085 " Convenient command to see the difference between the current buffer and the
1086 " file it was loaded from, thus the changes you made. Thanks to the
1087 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1088 " for the diffed file as the filetype for the original file.
1089     if !exists(':DiffOrig')
1090         command DiffOrig
1091             \ let s:diff_orig_filetype = &filetype
1092             \ | vertical new
1093             \ | let &filetype = s:diff_orig_filetype
1094             \ | unlet s:diff_orig_filetype
1095             \ | set buftype=nofile
1096             \ | read ++edit #
1097             \ | 0d_
1098             \ | diffthis
1099             \ | wincmd p
1100             \ | diffthis
1101     endif
1102 endif