vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68
  69 " Increase history of executed commands (:).
  70 set history=1000
  71
  72 " Increase number of possible undos.
  73 set undolevels=1000
  74
  75 " Remember marks (including the last cursor position) for more files.
  76 if has('viminfo')
  77     set viminfo^='1000
  78 endif
  79
  80 " Use strong encryption if possible, also used for swap/undo files.
  81 if exists('+cryptmethod')
  82     set cryptmethod=blowfish
  83 endif
  84
  85 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  86 " is used multiple times.
  87 if has('autocmd')
  88     augroup vimrc
  89         autocmd!
  90     augroup END
  91 endif
  92
  93
  94 " HELPER FUNCTIONS
  95
  96 if has('eval')
  97 " Check if the given syntax group is available. Thanks to bairui in #vim on
  98 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  99     function! s:HasSyntaxGroup(group)
 100         try
 101             execute 'silent highlight ' . a:group
 102         " \a = [A-Za-z]
 103         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 104             return 0
 105         endtry
 106         return 1
 107     endfunction
 108
 109 " Check if the given Vim version and patch is available.
 110     function! s:HasVersionAndPatch(version, patch)
 111         return v:version > a:version
 112             \ || (v:version == a:version && has('patch' . a:patch))
 113     endfunction
 114 endif
 115
 116
 117 " EDIT SETTINGS
 118
 119 " Enable automatic file detection, plugin and indention support.
 120 if has('autocmd')
 121     filetype off " necessary for pathogen to force a reload of ftplugins
 122     filetype plugin indent on
 123 endif
 124
 125 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 126 " existing files.
 127 set fileencodings=utf-8,latin1
 128
 129 " Always use unix line-endings for new files.
 130 set fileformats=unix,dos
 131
 132 " Wrap text after 78 characters.
 133 set textwidth=78
 134
 135 " Set tabs to 4 spaces, use softtabs.
 136 set shiftwidth=4
 137 set softtabstop=4
 138 set expandtab
 139 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 140 set shiftround
 141 " Use the default value for real tabs.
 142 set tabstop=8
 143
 144 " Enable auto indention.
 145 set autoindent
 146
 147 " When joining lines only add one space after a sentence.
 148 set nojoinspaces
 149
 150 " Allow backspacing over autoindent and line breaks.
 151 set backspace=indent,eol
 152
 153 " Start a comment when hitting enter after a commented line (r) and when using
 154 " o or O around a commented line (o).
 155 set formatoptions+=ro
 156 " Don't break a line if was already longer then 'textwidth' when insert mode
 157 " started.
 158 set formatoptions+=l
 159 " Remove comment leader when joining lines where it makes sense.
 160 if <SID>HasVersionAndPatch(703, 541)
 161     set formatoptions+=j
 162 endif
 163
 164 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 165 " no character) in visual block mode.
 166 set virtualedit=block
 167
 168 " Already display matches while typing the search command. This makes spotting
 169 " errors easy.
 170 set incsearch
 171
 172 " Activate syntax folding.
 173 if has('folding')
 174     set foldmethod=syntax
 175     " Only use fold column if we have enough space (for example not in a
 176     " (virtual) terminal which has only 80 columns).
 177     if &columns > 80
 178         set foldcolumn=2
 179     endif
 180     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 181                      " folding which is not what I want
 182 endif
 183
 184 " Only check case if the searched word contains a capital character.
 185 set ignorecase
 186 set smartcase
 187
 188 " Activate spell checking, use English as default.
 189 if exists('+spell') && has('syntax')
 190     " But not when diffing because spell checking is distracting in this case.
 191     if !&diff
 192         set spell
 193     endif
 194     set spelllang=en_us
 195 endif
 196
 197 " Allow buffers with changes to be hidden. Very important for effective
 198 " editing with multiple buffers. Prevents the "E37: No write since last change
 199 " (add ! to override)" warning.
 200 set hidden
 201
 202
 203 " DISPLAY SETTINGS
 204
 205 " Use a dark background. Doesn't change the background color, only sets text
 206 " colors for a dark terminal.
 207 set background=dark
 208
 209 " Use my color scheme if 256 colors are available.
 210 if &t_Co == 256 || has('gui_running')
 211     colorscheme simon
 212 endif
 213
 214 " Display line numbers.
 215 set number
 216 " But use as little space as possible for the numbers column. Thanks to James
 217 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 218 if exists('+numberwidth')
 219     set numberwidth=1
 220 endif
 221 " Display the ruler with current line/file position. If 'statusline' is used
 222 " then this only affects <C-G>.
 223 set ruler
 224 " Display partial commands in the status line.
 225 set showcmd
 226
 227 " Don't redraw screen when executing macros; increases speed. Thanks to James
 228 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 229 set lazyredraw
 230
 231 " Visualize the line the cursor is currently in.
 232 if exists('+cursorline')
 233     set cursorline
 234 endif
 235
 236 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 237 " remove the highlighting until the next search.
 238 set hlsearch
 239
 240 " Display some special characters.
 241 set list
 242 set listchars=
 243 " Display tabs as ">--------".
 244 set listchars+=tab:>-
 245 " Display trailing whitespace as "-".
 246 set listchars+=trail:-
 247 " Display markers for long lines when wrapping is disabled.
 248 set listchars+=extends:>,precedes:<
 249 " Display non-breakable space as "!".
 250 if v:version >= 700
 251     set listchars+=nbsp:!
 252 endif
 253
 254 " Don't draw the vertical split separator by using space as character. Thanks
 255 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 256 " non-breakable space. But a simple space works as well, as long as the
 257 " current color scheme is not reset.
 258 if has('windows') && has('folding')
 259     set fillchars+=vert:\  " comment to prevent trailing whitespace
 260 endif
 261
 262 if has('statusline')
 263     " Always display the status line even if there is only one window.
 264     set laststatus=2
 265
 266     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 267     " is the highest buffer number, otherwise return nothing. Used in
 268     " 'statusline' to get an overview of available buffer numbers.
 269     function! StatuslineBufferCount()
 270         let l:bufnr = bufnr('$')
 271         if l:bufnr > 1
 272             let l:result = '/'
 273             if exists('*printf')
 274                 let l:result .= printf('%02d', l:bufnr)
 275             else
 276                 " Older Vims don't have printf() (and no .= either). Emulate
 277                 " "%02d".
 278                 if l:bufnr < 10
 279                     let l:result = l:result . '0'
 280                 endif
 281                 let l:result = l:result . l:bufnr
 282             endif
 283             return l:result
 284         else
 285             return ''
 286         endif
 287     endfunction
 288
 289     " Like %f but use relative filename if it's shorter than the absolute path
 290     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 291     " not enough because it doesn't create '../'s.
 292     function! StatuslineRelativeFilename()
 293         " Display only filename for help files.
 294         if &buftype == 'help'
 295             return expand('%:t')
 296         endif
 297         " Special case for scratch files.
 298         if &buftype == 'nofile'
 299             return '[Scratch]'
 300         endif
 301
 302         let l:path = expand('%')
 303         " No file.
 304         if l:path == ''
 305             return '[No Name]'
 306         endif
 307         " Path is already relative, nothing to do.
 308         if stridx(l:path, '/') != 0
 309             return l:path
 310         endif
 311
 312         " Absolute path to this file.
 313         let l:path = expand('%:p')
 314         " Shortened path to this file, thanks to bairui in #vim on Freenode
 315         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 316         " Vim normally uses as %f (minus some exceptions).
 317         let l:original_path = fnamemodify(l:path, ':~')
 318         " Absolute path to the current working directory.
 319         let l:cwd = getcwd()
 320
 321         " Working directory completely contained in path, replace it with a
 322         " relative path. Happens for example when opening a file with netrw.
 323         " %f displays this as absolute path, but we want a relative path of
 324         " course.
 325         if stridx(l:path, l:cwd) == 0
 326             return strpart(l:path, strlen(l:cwd) + 1)
 327         endif
 328
 329         let l:path_list = split(l:path, '/')
 330         let l:cwd_list  = split(l:cwd,  '/')
 331
 332         " Remove the common path.
 333         while l:path_list[0] == l:cwd_list[0]
 334             call remove(l:path_list, 0)
 335             call remove(l:cwd_list,  0)
 336         endwhile
 337
 338         " Add as many '..' as necessary for the relative path and join the
 339         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 340         " the hint to use repeat() instead of a loop.
 341         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 342
 343         " Use the shorter path, either relative or absolute.
 344         if strlen(l:path) < strlen(l:original_path)
 345             return l:path
 346         else
 347             return l:original_path
 348         endif
 349     endfunction
 350
 351     set statusline=
 352     " on the left
 353     set statusline+=%02n  " buffer number
 354     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 355     set statusline+=:
 356     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 357         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 358         set statusline+=\     " space after path
 359     else
 360         set statusline+=%f\   " path to current file in buffer
 361     endif
 362     set statusline+=%h    " [help] if buffer is help file
 363     set statusline+=%w    " [Preview] if buffer is preview buffer
 364     set statusline+=%m    " [+] if buffer was modified,
 365                           " [-] if 'modifiable' is off
 366     set statusline+=%r    " [RO] if buffer is read only
 367
 368     " on the right
 369     set statusline+=%=                " right align
 370     set statusline+=0x%-8B\           " current character under cursor as hex
 371     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 372                                       " column number (%c),
 373                                       " virtual column number if different
 374                                       "                       than %c (%V)
 375     set statusline+=%P                " position in file in percent
 376 endif
 377
 378
 379 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 380
 381 " noremap is used to make sure the right side is executed as is and can't be
 382 " modified by a plugin or other settings. Except for <Nop> which isn't
 383 " affected by mappings.
 384
 385 " Easy way to exit insert mode. jk is preferred because it's faster.
 386 inoremap jj <Esc>
 387 inoremap jk <Esc>
 388 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 389 " (2010-10-15).
 390 cnoremap jj <C-C>
 391 cnoremap jk <C-C>
 392
 393 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 394 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 395 map <Right>  <Nop>
 396 map <Left>   <Nop>
 397 map <Up>     <Nop>
 398 map <Down>   <Nop>
 399 imap <Right> <Nop>
 400 imap <Left>  <Nop>
 401 imap <Up>    <Nop>
 402 imap <Down>  <Nop>
 403 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 404 " below).
 405 cmap <Up>    <Nop>
 406 cmap <Down>  <Nop>
 407 cmap <Right> <Nop>
 408 cmap <Left>  <Nop>
 409
 410 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 411 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 412 cnoremap <C-P> <Up>
 413 cnoremap <C-N> <Down>
 414
 415 if has('eval')
 416 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 417 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 418 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 419 " directly because it also enables that feature for other commands which I
 420 " don't want.
 421
 422     " Set 'nostartofline' for a single movement.
 423     function! s:TemporaryNostartofline(movement)
 424         let l:startofline = &startofline
 425         set nostartofline
 426         execute 'normal! ' . a:movement
 427         let &startofline = l:startofline
 428     endfunction
 429
 430     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 431     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 432     nnoremap <silent> <C-F>
 433         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 434     nnoremap <silent> <C-B>
 435         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 436     nnoremap <silent> <C-D>
 437         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 438     nnoremap <silent> <C-U>
 439         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 440 endif
 441
 442 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 443 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 444 " Only the current buffer is written, thus switching to another buffer works
 445 " too.
 446 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 447
 448 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 449 " in #vim on Freenode (2011-08-15 00:17 CEST).
 450 nnoremap <C-G> 2<C-G>
 451
 452 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 453 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 454 nmap <Space> <C-F>
 455 nmap - <C-B>
 456
 457 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 458 " (2010-05-16 18:38 CEST) for this idea.
 459 nnoremap <silent> gb :bnext<CR>
 460 nnoremap <silent> gB :bprevious<CR>
 461 if has('eval')
 462     " But when starting again at the first buffer, print a warning which
 463     " reminds me that I've already seen that buffer.
 464     function! s:NextBuffer()
 465         " Are we currently on the last buffer and moving to the first?
 466         let l:last_buffer = 0
 467         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 468             let l:last_buffer = 1
 469         endif
 470
 471         " Go to the next buffer.
 472         if !l:last_buffer
 473             bnext
 474
 475         " Go to the first buffer, silent is necessary or the following message
 476         " won't be displayed because it's overwritten by the status message
 477         " displayed when entering a buffer.
 478         else
 479             silent bnext
 480
 481             echohl WarningMsg
 482             echo 'Starting again at first buffer.'
 483             echohl None
 484         endif
 485     endfunction
 486     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 487 endif
 488
 489 " Fast access to buffers.
 490 nnoremap <silent> <Leader>1 :1buffer<CR>
 491 nnoremap <silent> <Leader>2 :2buffer<CR>
 492 nnoremap <silent> <Leader>3 :3buffer<CR>
 493 nnoremap <silent> <Leader>4 :4buffer<CR>
 494 nnoremap <silent> <Leader>5 :5buffer<CR>
 495 nnoremap <silent> <Leader>6 :6buffer<CR>
 496 nnoremap <silent> <Leader>7 :7buffer<CR>
 497 nnoremap <silent> <Leader>8 :8buffer<CR>
 498 nnoremap <silent> <Leader>9 :9buffer<CR>
 499 nnoremap <silent> <Leader>0 :10buffer<CR>
 500
 501 " Make last active window the only window. Similar to <C-W> o.
 502 nnoremap <C-W>O <C-W>p<C-W>o
 503
 504 " Maps to change spell language between English and German and disable spell
 505 " checking.
 506 if exists('+spell')
 507     nnoremap <silent> <Leader>sn :set nospell<CR>
 508     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 509     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 510 endif
 511
 512 " Add semicolon to the end of the line. Thanks to
 513 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 514 " on Freenode for an improved version which doesn't clobber any marks.
 515 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 516
 517 " * and # for selections in visual mode. Thanks to
 518 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 519 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 520 if has('eval')
 521     function! s:VSetSearch()
 522         let l:temp = @@
 523         normal! gvy
 524         " Added \C to force 'noignorecase' while searching the current visual
 525         " selection. I want to search for the exact string in this case.
 526         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 527         let @@ = l:temp
 528     endfunction
 529     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 530     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 531 endif
 532
 533 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 534 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 535 " mailing list for the commands.
 536 if v:version < 700
 537     cnoreabbrev W w
 538     cnoreabbrev Wa wa
 539     cnoreabbrev Wq wq
 540     cnoreabbrev Wqa wqa
 541 else
 542     cnoreabbrev <expr> W
 543         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 544     cnoreabbrev <expr> Wa
 545         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 546     cnoreabbrev <expr> Wq
 547         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 548     cnoreabbrev <expr> Wqa
 549         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 550 endif
 551 " Also fix my typo with "Q".
 552 if v:version < 700
 553     cnoreabbrev Q q
 554     cnoreabbrev Qa qa
 555 else
 556     cnoreabbrev <expr> Q
 557         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 558     cnoreabbrev <expr> Qa
 559         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 560 endif
 561
 562 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 563 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 564 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 565
 566 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 567 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 568 " Vim's source.
 569 inoremap <C-U> <C-G>u<C-U>
 570 " Same for <C-@> (insert previously inserted text and leave insert mode).
 571 inoremap <C-@> <C-G>u<C-@>
 572 " And for <C-A> (insert previously inserted text).
 573 inoremap <C-A> <C-G>u<C-A>
 574 " And for <C-W> (delete word before cursor).
 575 inoremap <C-W> <C-G>u<C-W>
 576
 577 if has('eval')
 578 " New text-objects ii and ai to work on text with the same indentation. Thanks
 579 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 580 " (visited on 2011-11-19).
 581     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 582     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 583     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 584     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 585
 586     function! s:IndTxtObj(inner)
 587         let curline = line(".")
 588         let lastline = line("$")
 589         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 590         let i = i < 0 ? 0 : i
 591         if getline(".") !~ "^\\s*$"
 592             let p = line(".") - 1
 593             let nextblank = getline(p) =~ "^\\s*$"
 594             while p > 0
 595                     \ && ((i == 0 && !nextblank)
 596                         \ || (i > 0 && ((indent(p) >= i
 597                             \ && !(nextblank && a:inner))
 598                             \ || (nextblank && !a:inner))))
 599                 -
 600                 let p = line(".") - 1
 601                 let nextblank = getline(p) =~ "^\\s*$"
 602             endwhile
 603             normal! 0V
 604             call cursor(curline, 0)
 605             let p = line(".") + 1
 606             let nextblank = getline(p) =~ "^\\s*$"
 607             while p <= lastline
 608                     \ && ((i == 0 && !nextblank)
 609                         \ || (i > 0 && ((indent(p) >= i
 610                             \ && !(nextblank && a:inner))
 611                             \ || (nextblank && !a:inner))))
 612                 +
 613                 let p = line(".") + 1
 614                 let nextblank = getline(p) =~ "^\\s*$"
 615             endwhile
 616             normal! $
 617         endif
 618     endfunction
 619 endif
 620
 621
 622 " ABBREVIATIONS
 623
 624 " Fix some of my spelling mistakes (German).
 625 inoreabbrev relle reelle
 626 inoreabbrev reele reelle
 627 " Fix some of my spelling mistakes (English).
 628 inoreabbrev completly completely
 629
 630
 631 " SYNTAX SETTINGS
 632
 633 " Activate syntax coloring.
 634 if has('syntax')
 635     syntax enable
 636
 637 " Don't highlight more than 500 columns as I normally don't have that long
 638 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 639 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 640     if exists('+synmaxcol')
 641         set synmaxcol=500
 642     endif
 643
 644 " Use (limited) syntax based omni completion if no other omni completion is
 645 " available. Taken from :help ft-syntax-omni.
 646     if has('autocmd') && exists('+omnifunc')
 647         augroup vimrc
 648             autocmd FileType *
 649                 \ if &omnifunc == '' |
 650                 \     setlocal omnifunc=syntaxcomplete#Complete |
 651                 \ endif
 652         augroup END
 653     endif
 654
 655 " Function to enable all custom highlights. Necessary as highlights are
 656 " window-local and thus must be set for each new window.
 657     function! s:CustomSyntaxHighlights()
 658         " Not the first time called, nothing to do.
 659         if exists('w:vimrc_syntax_run')
 660             return
 661         endif
 662         let w:vimrc_syntax_run = 1
 663
 664 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 665 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 666 " disabled when necessary with :2match (in Vim >= 700).
 667         if !&diff && exists(':2match')
 668             " Use ColorColumn for overlong lines if available and my color
 669             " scheme is used.
 670             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 671                 2match ColorColumn /\%>78v./
 672             else
 673                 2match Todo /\%>78v./
 674             endif
 675         elseif !&diff
 676             match Todo /\%>78v./
 677         endif
 678
 679         if exists('*matchadd')
 680 " Highlight some important keywords in all documents.
 681             let l:todos = ['TODO', 'XXX', 'FIXME',
 682                          \ 'CHANGED', 'REMOVED', 'DELETED']
 683             " Compatibility fix for Vim 6.4 which can't handle for in function
 684             " (without function it's ignored).
 685             execute '  for l:x in l:todos'
 686                   \ '|     call matchadd("Todo", l:x)'
 687                   \ '| endfor'
 688
 689 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 690             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 691                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 692                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 693                           \ '205f', '2060', '3000', 'feff']
 694             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 695             " it won't work!
 696             execute '  for l:x in l:spaces'
 697                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 698                   \ '| endfor'
 699
 700 " Special highlight for tabs to reduce their visibility in contrast to other
 701 " SpecialKey characters (e.g. ^L).
 702             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 703                 call matchadd('specialKeyTab', '\t')
 704             endif
 705         endif
 706     endfunction
 707 " Enable highlights for the current and all new windows. Thanks to bairui in
 708 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 709     call <SID>CustomSyntaxHighlights()
 710     if has('autocmd')
 711         augroup vimrc
 712             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 713         augroup END
 714     endif
 715
 716 " Settings for specific filetypes.
 717
 718     " C
 719     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 720     " Haskell.
 721     let g:hs_highlight_delimiters = 1
 722     let g:hs_highlight_boolean = 1
 723     let g:hs_highlight_types = 1
 724     let g:hs_highlight_more_types = 1
 725     " Perl.
 726     let g:perl_fold = 1
 727     let g:perl_fold_blocks = 1
 728     let g:perl_nofold_packages = 1
 729     let g:perl_include_pod = 1 " syntax coloring for PODs
 730     " Python.
 731     let g:python_highlight_all = 1
 732     " Shell.
 733     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 734     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 735     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 736     " Vim.
 737     let g:vimsyn_embed = 0      " don't highlight embedded languages
 738     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 739     " XML.
 740     let g:xml_syntax_folding = 1
 741 endif
 742
 743
 744 " PLUGIN SETTINGS
 745
 746 if has('eval')
 747 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 748 " installing/removing/updating plugins simple. (Used for plugins with more
 749 " than one file.) Ignore errors in case pathogen is not installed.
 750     if v:version >= 700
 751         silent! execute 'call pathogen#infect()'
 752     endif
 753
 754 " Settings for securemodelines.
 755     " Only allow items I need (also includes spl which is not enabled by
 756     " default).
 757     if v:version >= 700 " need lists
 758         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 759                                               \ 'sw', 'sts', 'noet']
 760     endif
 761
 762 " Settings for the NERD commenter.
 763     " Don't create any mappings I don't want to use.
 764     let g:NERDCreateDefaultMappings = 0
 765     " Map toggle comment.
 766     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 767
 768 " XPTemplate settings.
 769     " Try to maintain snippet rendering even after editing outside of a
 770     " snippet.
 771     let g:xptemplate_strict = 0
 772     " Don't complete any braces automatically.
 773     let g:xptemplate_brace_complete = 0
 774     " Only highlight the current placeholder.
 775     let g:xptemplate_highlight = 'current'
 776 endif
 777
 778
 779 " AUTO COMMANDS
 780
 781 " Use a custom auto group to prevent problems when the vimrc files is sourced
 782 " twice.
 783 if has('autocmd')
 784     augroup vimrc
 785
 786 " Go to last position of opened files. Taken from :help last-position-jump.
 787         autocmd BufReadPost *
 788             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 789             \     execute "normal! g'\"" |
 790             \ endif
 791 " But not for Git commits, go to beginning of the file.
 792         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 793
 794 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 795 " when switching to a help buffer which is in the background with :buffer as
 796 " these options are local to windows (and not only to buffers). This happens
 797 " because I often want to use only one window and thus the help buffer is in
 798 " the background.
 799         autocmd BufWinEnter *.txt
 800             \ if &filetype == 'help' |
 801             \     setlocal nolist |
 802             \     setlocal nonumber |
 803             \ endif
 804
 805 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 806 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 807 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 808 " doesn't exist in older Vims.
 809         if exists('##InsertLeave')
 810             autocmd InsertLeave * set nopaste
 811         endif
 812
 813 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 814 " doesn't exist in older Vims.
 815         if exists('##QuickFixCmdPre')
 816             autocmd QuickFixCmdPre * write
 817         endif
 818
 819 " Don't ignore case while in insert mode, but ignore case in all other modes.
 820 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 821 " capitalization. But while searching (/) 'ignorecase' is used.
 822 " InsertEnter/InsertLeave doesn't exist in older Vims.
 823         if exists('##InsertEnter') && exists('##InsertLeave')
 824             autocmd InsertEnter * set noignorecase
 825             autocmd InsertLeave * set   ignorecase
 826         endif
 827
 828 " AFTER/FTPLUGIN AUTO COMMANDS
 829
 830 " Disable spell checking for files which don't need it.
 831         autocmd FileType deb  setlocal nospell
 832         autocmd FileType diff setlocal nospell
 833         autocmd FileType tar  setlocal nospell
 834 " Fix to allow Vim edit crontab files as crontab doesn't work with
 835 " backupcopy=auto.
 836         autocmd FileType crontab setlocal backupcopy=yes
 837 " Don't use the modeline in git commits as the diff created by `git commit -v`
 838 " may contain one which could change the filetype or other settings of the
 839 " commit buffer. Also make sure we use only 72 characters per line which is
 840 " the recommendation for git commit messages (http://tpope.net/node/106).
 841         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 842                                  \ setlocal textwidth=72
 843 " Use the same comment string as for Vim files in Vimperator files.
 844         autocmd FileType vimperator setlocal commentstring=\"%s
 845 " Use TeX compiler for (La)TeX files.
 846         autocmd FileType tex compiler tex
 847
 848 " FTDETECT AUTO COMMANDS
 849
 850 " Recognize .md as markdown files (Vim default is .mkd).
 851         autocmd BufRead,BufNewFile *.md set filetype=mkd
 852 " Recognize .test as Tcl files.
 853         autocmd BufRead,BufNewFile *.test set filetype=tcl
 854
 855 " OTHER AUTO COMMANDS
 856
 857 " Disable spell checking, displaying of list characters and long lines when
 858 " viewing documentation.
 859         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 860
 861 " Use diff filetype for mercurial patches in patch queue.
 862         autocmd BufReadPost */.hg/patches/* set filetype=diff
 863
 864     augroup END
 865 endif
 866
 867
 868 " CUSTOM FUNCTIONS AND COMMANDS
 869
 870 if has('eval')
 871 " Convenient command to see the difference between the current buffer and the
 872 " file it was loaded from, thus the changes you made. Thanks to the
 873 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 874 " for the diffed file than the filetype for the original file.
 875     if !exists(':DiffOrig')
 876         command DiffOrig
 877             \ let s:diff_orig_filetype = &filetype
 878             \ | vertical new
 879             \ | let &filetype = s:diff_orig_filetype
 880             \ | unlet s:diff_orig_filetype
 881             \ | set buftype=nofile
 882             \ | read ++edit #
 883             \ | 0d_
 884             \ | diffthis
 885             \ | wincmd p
 886             \ | diffthis
 887     endif
 888 endif